source/CMakeLists.txt

   1 # Copyright (c) 2015-2016 The Khronos Group Inc.
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 set(GRAMMAR_PROCESSING_SCRIPT "${spirv-tools_SOURCE_DIR}/utils/generate_grammar_tables.py")
  16 set(VIMSYNTAX_PROCESSING_SCRIPT "${spirv-tools_SOURCE_DIR}/utils/generate_vim_syntax.py")
  17 set(XML_REGISTRY_PROCESSING_SCRIPT "${spirv-tools_SOURCE_DIR}/utils/generate_registry_tables.py")
  18
  19 # macro() definitions are used in the following because we need to append .inc
  20 # file paths into some global lists (*_CPP_DEPENDS). And those global lists are
  21 # later used by set_source_files_properties() calls.
  22 # function() definitions are not suitable because they create new scopes.
  23 macro(spvtools_core_tables VERSION)
  24   set(GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/spirv.core.grammar.json")
  25   set(GRAMMAR_INSTS_INC_FILE "${spirv-tools_BINARY_DIR}/core.insts-${VERSION}.inc")
  26   set(GRAMMAR_KINDS_INC_FILE "${spirv-tools_BINARY_DIR}/operand.kinds-${VERSION}.inc")
  27   add_custom_command(OUTPUT ${GRAMMAR_INSTS_INC_FILE} ${GRAMMAR_KINDS_INC_FILE}
  28     COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
  29       --spirv-core-grammar=${GRAMMAR_JSON_FILE}
  30       --core-insts-output=${GRAMMAR_INSTS_INC_FILE}
  31       --operand-kinds-output=${GRAMMAR_KINDS_INC_FILE}
  32     DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${GRAMMAR_JSON_FILE}
  33     COMMENT "Generate info tables for SPIR-V v${VERSION} core instructions and operands.")
  34   list(APPEND OPCODE_CPP_DEPENDS ${GRAMMAR_INSTS_INC_FILE})
  35   list(APPEND OPERAND_CPP_DEPENDS ${GRAMMAR_KINDS_INC_FILE})
  36 endmacro(spvtools_core_tables)
  37
  38 macro(spvtools_vimsyntax VERSION CLVERSION)
  39   set(GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/spirv.core.grammar.json")
  40   set(GLSL_GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/extinst.glsl.std.450.grammar.json")
  41   set(OPENCL_GRAMMAR_JSON_FILE "${CMAKE_CURRENT_SOURCE_DIR}/extinst-1.0.opencl.std.grammar.json")
  42   set(VIMSYNTAX_FILE "${spirv-tools_BINARY_DIR}/spvasm.vim")
  43   add_custom_command(OUTPUT ${VIMSYNTAX_FILE}
  44       COMMAND ${PYTHON_EXECUTABLE} ${VIMSYNTAX_PROCESSING_SCRIPT}
  45       --spirv-core-grammar=${GRAMMAR_JSON_FILE}
  46       --extinst-glsl-grammar=${GLSL_GRAMMAR_JSON_FILE}
  47       --extinst-opencl-grammar=${OPENCL_GRAMMAR_JSON_FILE}
  48       >${VIMSYNTAX_FILE}
  49     DEPENDS ${VIMSYNTAX_PROCESSING_SCRIPT} ${GRAMMAR_JSON_FILE}
  50             ${GLSL_GRAMMAR_JSON_FILE} ${OPENCL_GRAMMAR_JSON_FILE}
  51     COMMENT "Generate spvasm.vim: Vim syntax file for SPIR-V assembly.")
  52 endmacro(spvtools_vimsyntax)
  53
  54 macro(spvtools_glsl_tables VERSION)
  55   set(CORE_GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/spirv.core.grammar.json")
  56   set(GLSL_GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/extinst.glsl.std.450.grammar.json")
  57   set(GRAMMAR_INC_FILE "${spirv-tools_BINARY_DIR}/glsl.std.450.insts-${VERSION}.inc")
  58   add_custom_command(OUTPUT ${GRAMMAR_INC_FILE}
  59     COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
  60       --spirv-core-grammar=${CORE_GRAMMAR_JSON_FILE}
  61       --extinst-glsl-grammar=${GLSL_GRAMMAR_JSON_FILE}
  62       --glsl-insts-output=${GRAMMAR_INC_FILE}
  63     DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${CORE_GRAMMAR_JSON_FILE} ${GLSL_GRAMMAR_JSON_FILE}
  64     COMMENT "Generate info tables for GLSL extended instructions and operands v${VERSION}.")
  65   list(APPEND EXTINST_CPP_DEPENDS ${GRAMMAR_INC_FILE})
  66 endmacro(spvtools_glsl_tables)
  67
  68 macro(spvtools_opencl_tables VERSION)
  69   set(CORE_GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/spirv.core.grammar.json")
  70   set(OPENCL_GRAMMAR_JSON_FILE "${CMAKE_CURRENT_SOURCE_DIR}/extinst-${VERSION}.opencl.std.grammar.json")
  71   set(GRAMMAR_INC_FILE "${spirv-tools_BINARY_DIR}/opencl.std.insts-${VERSION}.inc")
  72   add_custom_command(OUTPUT ${GRAMMAR_INC_FILE}
  73     COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
  74       --spirv-core-grammar=${CORE_GRAMMAR_JSON_FILE}
  75       --extinst-opencl-grammar=${OPENCL_GRAMMAR_JSON_FILE}
  76       --opencl-insts-output=${GRAMMAR_INC_FILE}
  77     DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${CORE_GRAMMAR_JSON_FILE} ${OPENCL_GRAMMAR_JSON_FILE}
  78     COMMENT "Generate info tables for OpenCL extended instructions and operands v${VERSION}.")
  79   list(APPEND EXTINST_CPP_DEPENDS ${GRAMMAR_INC_FILE})
  80 endmacro(spvtools_opencl_tables)
  81
  82 spvtools_core_tables("1.0")
  83 spvtools_core_tables("1.1")
  84 spvtools_opencl_tables("1.0")
  85 spvtools_glsl_tables("1.0")
  86
  87 spvtools_vimsyntax("1.1" "1.0")
  88 add_custom_target(spirv-tools-vimsyntax DEPENDS ${VIMSYNTAX_FILE})
  89
  90
  91 # Extract the list of known generators from the SPIR-V XML registry file.
  92 set(GENERATOR_INC_FILE ${spirv-tools_BINARY_DIR}/generators.inc)
  93 set(SPIRV_XML_REGISTRY_FILE ${SPIRV_HEADER_INCLUDE_DIR}/spirv/spir-v.xml)
  94 add_custom_command(OUTPUT ${GENERATOR_INC_FILE}
  95   COMMAND ${PYTHON_EXECUTABLE} ${XML_REGISTRY_PROCESSING_SCRIPT}
  96     --xml=${SPIRV_XML_REGISTRY_FILE}
  97     --generator-output=${GENERATOR_INC_FILE}
  98   DEPENDS ${XML_REGISTRY_PROCESSING_SCRIPT} ${SPIRV_XML_REGISTRY_FILE}
  99   COMMENT "Generate tables based on the SPIR-V XML registry.")
 100 list(APPEND OPCODE_CPP_DEPENDS ${GENERATOR_INC_FILE})
 101
 102 # The following .cpp files include the above generated .inc files.
 103 # Add those .inc files as their dependencies.
 104 #
 105 # Why using such an awkward way?
 106 # * If we use add_custom_target() to define a target to generate all .inc files
 107 #   and let ${SPIRV_TOOLS} depend on it, then we need to run ninja twice every
 108 #   time the grammar is updated: the first time is for generating those .inc
 109 #   files, and the second time is for rebuilding .cpp files, when ninja finds
 110 #   out that .inc files are updated.
 111 # * If we use add_custom_command() with PRE_BUILD, then the grammar processing
 112 #   script will always run no matter whether the grammar is updated.
 113 # * add_dependencies() is used to add *target* dependencies to a target.
 114 # * The following solution only generates .inc files when the script or the
 115 #   grammar files is updated, and in a single ninja run.
 116 set_source_files_properties(
 117   ${CMAKE_CURRENT_SOURCE_DIR}/opcode.cpp
 118   PROPERTIES OBJECT_DEPENDS "${OPCODE_CPP_DEPENDS}")
 119 set_source_files_properties(
 120   ${CMAKE_CURRENT_SOURCE_DIR}/operand.cpp
 121   PROPERTIES OBJECT_DEPENDS "${OPERAND_CPP_DEPENDS}")
 122 set_source_files_properties(
 123   ${CMAKE_CURRENT_SOURCE_DIR}/ext_inst.cpp
 124   PROPERTIES OBJECT_DEPENDS "${EXTINST_CPP_DEPENDS}")
 125
 126 set(SPIRV_TOOLS_BUILD_VERSION_INC
 127   ${spirv-tools_BINARY_DIR}/build-version.inc)
 128 set(SPIRV_TOOLS_BUILD_VERSION_INC_GENERATOR
 129   ${spirv-tools_SOURCE_DIR}/utils/update_build_version.py)
 130 set(SPIRV_TOOLS_CHANGES_FILE
 131   ${spirv-tools_SOURCE_DIR}/CHANGES)
 132 add_custom_command(OUTPUT ${SPIRV_TOOLS_BUILD_VERSION_INC}
 133    COMMAND ${PYTHON_EXECUTABLE}
 134            ${SPIRV_TOOLS_BUILD_VERSION_INC_GENERATOR}
 135            ${spirv-tools_SOURCE_DIR} ${SPIRV_TOOLS_BUILD_VERSION_INC}
 136    DEPENDS ${SPIRV_TOOLS_BUILD_VERSION_INC_GENERATOR}
 137            ${SPIRV_TOOLS_CHANGES_FILE}
 138    COMMENT "Update build-version.inc in the SPIRV-Tools build directory (if necessary).")
 139 # Convenience target for standalone generation of the build-version.inc file.
 140 # This is not required for any dependence chain.
 141 add_custom_target(spirv-tools-build-version
 142    DEPENDS ${SPIRV_TOOLS_BUILD_VERSION_INC})
 143
 144 add_subdirectory(opt)
 145
 146 set(SPIRV_SOURCES
 147   ${spirv-tools_SOURCE_DIR}/include/spirv-tools/libspirv.h
 148
 149   ${CMAKE_CURRENT_SOURCE_DIR}/util/bitutils.h
 150   ${CMAKE_CURRENT_SOURCE_DIR}/util/hex_float.h
 151   ${CMAKE_CURRENT_SOURCE_DIR}/util/parse_number.h
 152   ${CMAKE_CURRENT_SOURCE_DIR}/assembly_grammar.h
 153   ${CMAKE_CURRENT_SOURCE_DIR}/binary.h
 154   ${CMAKE_CURRENT_SOURCE_DIR}/diagnostic.h
 155   ${CMAKE_CURRENT_SOURCE_DIR}/enum_set.h
 156   ${CMAKE_CURRENT_SOURCE_DIR}/ext_inst.h
 157   ${CMAKE_CURRENT_SOURCE_DIR}/instruction.h
 158   ${CMAKE_CURRENT_SOURCE_DIR}/macro.h
 159   ${CMAKE_CURRENT_SOURCE_DIR}/name_mapper.h
 160   ${CMAKE_CURRENT_SOURCE_DIR}/opcode.h
 161   ${CMAKE_CURRENT_SOURCE_DIR}/operand.h
 162   ${CMAKE_CURRENT_SOURCE_DIR}/parsed_operand.h
 163   ${CMAKE_CURRENT_SOURCE_DIR}/print.h
 164   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_constant.h
 165   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_definition.h
 166   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_endian.h
 167   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_target_env.h
 168   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_validator_options.h
 169   ${CMAKE_CURRENT_SOURCE_DIR}/table.h
 170   ${CMAKE_CURRENT_SOURCE_DIR}/text.h
 171   ${CMAKE_CURRENT_SOURCE_DIR}/text_handler.h
 172   ${CMAKE_CURRENT_SOURCE_DIR}/validate.h
 173
 174   ${CMAKE_CURRENT_SOURCE_DIR}/util/parse_number.cpp
 175   ${CMAKE_CURRENT_SOURCE_DIR}/assembly_grammar.cpp
 176   ${CMAKE_CURRENT_SOURCE_DIR}/binary.cpp
 177   ${CMAKE_CURRENT_SOURCE_DIR}/diagnostic.cpp
 178   ${CMAKE_CURRENT_SOURCE_DIR}/disassemble.cpp
 179   ${CMAKE_CURRENT_SOURCE_DIR}/ext_inst.cpp
 180   ${CMAKE_CURRENT_SOURCE_DIR}/libspirv.cpp
 181   ${CMAKE_CURRENT_SOURCE_DIR}/message.cpp
 182   ${CMAKE_CURRENT_SOURCE_DIR}/name_mapper.cpp
 183   ${CMAKE_CURRENT_SOURCE_DIR}/opcode.cpp
 184   ${CMAKE_CURRENT_SOURCE_DIR}/operand.cpp
 185   ${CMAKE_CURRENT_SOURCE_DIR}/parsed_operand.cpp
 186   ${CMAKE_CURRENT_SOURCE_DIR}/print.cpp
 187   ${CMAKE_CURRENT_SOURCE_DIR}/software_version.cpp
 188   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_endian.cpp
 189   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_target_env.cpp
 190   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_validator_options.cpp
 191   ${CMAKE_CURRENT_SOURCE_DIR}/table.cpp
 192   ${CMAKE_CURRENT_SOURCE_DIR}/text.cpp
 193   ${CMAKE_CURRENT_SOURCE_DIR}/text_handler.cpp
 194   ${CMAKE_CURRENT_SOURCE_DIR}/validate.cpp
 195   ${CMAKE_CURRENT_SOURCE_DIR}/validate_cfg.cpp
 196   ${CMAKE_CURRENT_SOURCE_DIR}/validate_id.cpp
 197   ${CMAKE_CURRENT_SOURCE_DIR}/validate_instruction.cpp
 198   ${CMAKE_CURRENT_SOURCE_DIR}/validate_datarules.cpp
 199   ${CMAKE_CURRENT_SOURCE_DIR}/validate_decorations.cpp
 200   ${CMAKE_CURRENT_SOURCE_DIR}/validate_layout.cpp
 201   ${CMAKE_CURRENT_SOURCE_DIR}/val/decoration.h
 202   ${CMAKE_CURRENT_SOURCE_DIR}/val/basic_block.cpp
 203   ${CMAKE_CURRENT_SOURCE_DIR}/val/construct.cpp
 204   ${CMAKE_CURRENT_SOURCE_DIR}/val/function.cpp
 205   ${CMAKE_CURRENT_SOURCE_DIR}/val/instruction.cpp
 206   ${CMAKE_CURRENT_SOURCE_DIR}/val/validation_state.cpp)
 207
 208 # The software_version.cpp file includes build-version.inc.
 209 # Rebuild the software_version.cpp object file if it is older than
 210 # build-version.inc or whenever build-version.inc itself is out of
 211 # date.  In the latter case, rebuild build-version.inc first.
 212 # CMake is not smart enough to detect this dependency automatically.
 213 # Without this, the dependency detection system for #included files
 214 # does not kick in on a clean build for the following reason:  The
 215 # build will fail early because it doesn't know how to build the
 216 # missing source file build-version.inc. That occurs before the
 217 # preprocessor is run on software_version.cpp to detect the
 218 # #include dependency.
 219 set_source_files_properties(
 220   ${CMAKE_CURRENT_SOURCE_DIR}/software_version.cpp
 221   PROPERTIES OBJECT_DEPENDS "${SPIRV_TOOLS_BUILD_VERSION_INC}")
 222
 223 add_library(${SPIRV_TOOLS} ${SPIRV_SOURCES})
 224 spvtools_default_compile_options(${SPIRV_TOOLS})
 225 target_include_directories(${SPIRV_TOOLS}
 226   PUBLIC ${spirv-tools_SOURCE_DIR}/include
 227   PRIVATE ${spirv-tools_BINARY_DIR}
 228   PRIVATE ${SPIRV_HEADER_INCLUDE_DIR}
 229   )
 230
 231 install(TARGETS ${SPIRV_TOOLS}
 232   RUNTIME DESTINATION bin
 233   LIBRARY DESTINATION lib
 234   ARCHIVE DESTINATION lib)