source/CMakeLists.txt

   1 # Copyright (c) 2015-2016 The Khronos Group Inc.
   2 #
   3 # Licensed under the Apache License, Version 2.0 (the "License");
   4 # you may not use this file except in compliance with the License.
   5 # You may obtain a copy of the License at
   6 #
   7 #     http://www.apache.org/licenses/LICENSE-2.0
   8 #
   9 # Unless required by applicable law or agreed to in writing, software
  10 # distributed under the License is distributed on an "AS IS" BASIS,
  11 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  12 # See the License for the specific language governing permissions and
  13 # limitations under the License.
  14
  15 set(GRAMMAR_PROCESSING_SCRIPT "${spirv-tools_SOURCE_DIR}/utils/generate_grammar_tables.py")
  16 set(VIMSYNTAX_PROCESSING_SCRIPT "${spirv-tools_SOURCE_DIR}/utils/generate_vim_syntax.py")
  17 set(XML_REGISTRY_PROCESSING_SCRIPT "${spirv-tools_SOURCE_DIR}/utils/generate_registry_tables.py")
  18
  19 # macro() definitions are used in the following because we need to append .inc
  20 # file paths into some global lists (*_CPP_DEPENDS). And those global lists are
  21 # later used by set_source_files_properties() calls.
  22 # function() definitions are not suitable because they create new scopes.
  23 macro(spvtools_core_tables VERSION)
  24   set(GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/spirv.core.grammar.json")
  25   set(GRAMMAR_INSTS_INC_FILE "${spirv-tools_BINARY_DIR}/core.insts-${VERSION}.inc")
  26   set(GRAMMAR_KINDS_INC_FILE "${spirv-tools_BINARY_DIR}/operand.kinds-${VERSION}.inc")
  27   add_custom_command(OUTPUT ${GRAMMAR_INSTS_INC_FILE} ${GRAMMAR_KINDS_INC_FILE}
  28     COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
  29       --spirv-core-grammar=${GRAMMAR_JSON_FILE}
  30       --core-insts-output=${GRAMMAR_INSTS_INC_FILE}
  31       --operand-kinds-output=${GRAMMAR_KINDS_INC_FILE}
  32     DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${GRAMMAR_JSON_FILE}
  33     COMMENT "Generate info tables for SPIR-V v${VERSION} core instructions and operands.")
  34   list(APPEND OPCODE_CPP_DEPENDS ${GRAMMAR_INSTS_INC_FILE})
  35   list(APPEND OPERAND_CPP_DEPENDS ${GRAMMAR_KINDS_INC_FILE})
  36 endmacro(spvtools_core_tables)
  37
  38 macro(spvtools_enum_string_mapping VERSION)
  39   set(GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/spirv.core.grammar.json")
  40   set(GRAMMAR_EXTENSION_ENUM_INC_FILE "${spirv-tools_BINARY_DIR}/extension_enum.inc")
  41   set(GRAMMAR_ENUM_STRING_MAPPING_INC_FILE "${spirv-tools_BINARY_DIR}/enum_string_mapping.inc")
  42   add_custom_command(OUTPUT ${GRAMMAR_EXTENSION_ENUM_INC_FILE}
  43      ${GRAMMAR_ENUM_STRING_MAPPING_INC_FILE}
  44     COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
  45       --spirv-core-grammar=${GRAMMAR_JSON_FILE}
  46       --extension-enum-output=${GRAMMAR_EXTENSION_ENUM_INC_FILE}
  47       --enum-string-mapping-output=${GRAMMAR_ENUM_STRING_MAPPING_INC_FILE}
  48     DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${GRAMMAR_JSON_FILE}
  49     COMMENT "Generate enum-string mapping for SPIR-V v${VERSION}.")
  50   list(APPEND EXTENSION_H_DEPENDS ${GRAMMAR_EXTENSION_ENUM_INC_FILE})
  51   list(APPEND ENUM_STRING_MAPPING_CPP_DEPENDS ${GRAMMAR_ENUM_STRING_MAPPING_INC_FILE})
  52 endmacro(spvtools_enum_string_mapping)
  53
  54 macro(spvtools_vimsyntax VERSION CLVERSION)
  55   set(GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/spirv.core.grammar.json")
  56   set(GLSL_GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/extinst.glsl.std.450.grammar.json")
  57   set(OPENCL_GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/extinst.opencl.std.100.grammar.json")
  58   set(VIMSYNTAX_FILE "${spirv-tools_BINARY_DIR}/spvasm.vim")
  59   add_custom_command(OUTPUT ${VIMSYNTAX_FILE}
  60       COMMAND ${PYTHON_EXECUTABLE} ${VIMSYNTAX_PROCESSING_SCRIPT}
  61       --spirv-core-grammar=${GRAMMAR_JSON_FILE}
  62       --extinst-glsl-grammar=${GLSL_GRAMMAR_JSON_FILE}
  63       --extinst-opencl-grammar=${OPENCL_GRAMMAR_JSON_FILE}
  64       >${VIMSYNTAX_FILE}
  65     DEPENDS ${VIMSYNTAX_PROCESSING_SCRIPT} ${GRAMMAR_JSON_FILE}
  66             ${GLSL_GRAMMAR_JSON_FILE} ${OPENCL_GRAMMAR_JSON_FILE}
  67     COMMENT "Generate spvasm.vim: Vim syntax file for SPIR-V assembly.")
  68 endmacro(spvtools_vimsyntax)
  69
  70 macro(spvtools_glsl_tables VERSION)
  71   set(CORE_GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/spirv.core.grammar.json")
  72   set(GLSL_GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/extinst.glsl.std.450.grammar.json")
  73   set(GRAMMAR_INC_FILE "${spirv-tools_BINARY_DIR}/glsl.std.450.insts-${VERSION}.inc")
  74   add_custom_command(OUTPUT ${GRAMMAR_INC_FILE}
  75     COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
  76       --spirv-core-grammar=${CORE_GRAMMAR_JSON_FILE}
  77       --extinst-glsl-grammar=${GLSL_GRAMMAR_JSON_FILE}
  78       --glsl-insts-output=${GRAMMAR_INC_FILE}
  79     DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${CORE_GRAMMAR_JSON_FILE} ${GLSL_GRAMMAR_JSON_FILE}
  80     COMMENT "Generate info tables for GLSL extended instructions and operands v${VERSION}.")
  81   list(APPEND EXTINST_CPP_DEPENDS ${GRAMMAR_INC_FILE})
  82 endmacro(spvtools_glsl_tables)
  83
  84 macro(spvtools_opencl_tables VERSION)
  85   set(CORE_GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/spirv.core.grammar.json")
  86   set(OPENCL_GRAMMAR_JSON_FILE "${SPIRV_HEADER_INCLUDE_DIR}/spirv/${VERSION}/extinst.opencl.std.100.grammar.json")
  87   set(GRAMMAR_INC_FILE "${spirv-tools_BINARY_DIR}/opencl.std.insts-${VERSION}.inc")
  88   add_custom_command(OUTPUT ${GRAMMAR_INC_FILE}
  89     COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
  90       --spirv-core-grammar=${CORE_GRAMMAR_JSON_FILE}
  91       --extinst-opencl-grammar=${OPENCL_GRAMMAR_JSON_FILE}
  92       --opencl-insts-output=${GRAMMAR_INC_FILE}
  93     DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${CORE_GRAMMAR_JSON_FILE} ${OPENCL_GRAMMAR_JSON_FILE}
  94     COMMENT "Generate info tables for OpenCL extended instructions and operands v${VERSION}.")
  95   list(APPEND EXTINST_CPP_DEPENDS ${GRAMMAR_INC_FILE})
  96 endmacro(spvtools_opencl_tables)
  97
  98 macro(spvtools_vendor_tables VENDOR_TABLE)
  99   set(INSTS_FILE "${spirv-tools_BINARY_DIR}/${VENDOR_TABLE}.insts.inc")
 100   set(GRAMMAR_FILE "${spirv-tools_SOURCE_DIR}/source/extinst.${VENDOR_TABLE}.grammar.json")
 101   add_custom_command(OUTPUT ${INSTS_FILE}
 102     COMMAND ${PYTHON_EXECUTABLE} ${GRAMMAR_PROCESSING_SCRIPT}
 103       --extinst-vendor-grammar=${GRAMMAR_FILE}
 104       --vendor-insts-output=${INSTS_FILE}
 105     DEPENDS ${GRAMMAR_PROCESSING_SCRIPT} ${GRAMMAR_FILE}
 106     COMMENT "Generate extended instruction tables for ${VENDOR_TABLE}.")
 107   list(APPEND EXTINST_CPP_DEPENDS ${INSTS_FILE})
 108   add_custom_target(spirv-tools-${VENDOR_TABLE} DEPENDS ${INSTS_FILE})
 109   set_property(TARGET spirv-tools-${VENDOR_TABLE} PROPERTY FOLDER "SPIRV-Tools build")
 110 endmacro(spvtools_vendor_tables)
 111
 112 spvtools_core_tables("1.0")
 113 spvtools_core_tables("1.1")
 114 spvtools_core_tables("1.2")
 115 spvtools_enum_string_mapping("1.2")
 116 spvtools_opencl_tables("1.0")
 117 spvtools_glsl_tables("1.0")
 118 spvtools_vendor_tables("spv-amd-shader-explicit-vertex-parameter")
 119 spvtools_vendor_tables("spv-amd-shader-trinary-minmax")
 120 spvtools_vendor_tables("spv-amd-gcn-shader")
 121 spvtools_vendor_tables("spv-amd-shader-ballot")
 122
 123 spvtools_vimsyntax("1.2" "1.0")
 124 add_custom_target(spirv-tools-vimsyntax DEPENDS ${VIMSYNTAX_FILE})
 125 set_property(TARGET spirv-tools-vimsyntax PROPERTY FOLDER "SPIRV-Tools utilities")
 126
 127 # Extract the list of known generators from the SPIR-V XML registry file.
 128 set(GENERATOR_INC_FILE ${spirv-tools_BINARY_DIR}/generators.inc)
 129 set(SPIRV_XML_REGISTRY_FILE ${SPIRV_HEADER_INCLUDE_DIR}/spirv/spir-v.xml)
 130 add_custom_command(OUTPUT ${GENERATOR_INC_FILE}
 131   COMMAND ${PYTHON_EXECUTABLE} ${XML_REGISTRY_PROCESSING_SCRIPT}
 132     --xml=${SPIRV_XML_REGISTRY_FILE}
 133     --generator-output=${GENERATOR_INC_FILE}
 134   DEPENDS ${XML_REGISTRY_PROCESSING_SCRIPT} ${SPIRV_XML_REGISTRY_FILE}
 135   COMMENT "Generate tables based on the SPIR-V XML registry.")
 136 list(APPEND OPCODE_CPP_DEPENDS ${GENERATOR_INC_FILE})
 137
 138 # The following .cpp files include the above generated .inc files.
 139 # Add those .inc files as their dependencies.
 140 #
 141 # Why using such an awkward way?
 142 # * If we use add_custom_target() to define a target to generate all .inc files
 143 #   and let ${SPIRV_TOOLS} depend on it, then we need to run ninja twice every
 144 #   time the grammar is updated: the first time is for generating those .inc
 145 #   files, and the second time is for rebuilding .cpp files, when ninja finds
 146 #   out that .inc files are updated.
 147 # * If we use add_custom_command() with PRE_BUILD, then the grammar processing
 148 #   script will always run no matter whether the grammar is updated.
 149 # * add_dependencies() is used to add *target* dependencies to a target.
 150 # * The following solution only generates .inc files when the script or the
 151 #   grammar files is updated, and in a single ninja run.
 152 set_source_files_properties(
 153   ${CMAKE_CURRENT_SOURCE_DIR}/opcode.cpp
 154   PROPERTIES OBJECT_DEPENDS "${OPCODE_CPP_DEPENDS}")
 155 set_source_files_properties(
 156   ${CMAKE_CURRENT_SOURCE_DIR}/operand.cpp
 157   PROPERTIES OBJECT_DEPENDS "${OPERAND_CPP_DEPENDS}")
 158 set_source_files_properties(
 159   ${CMAKE_CURRENT_SOURCE_DIR}/ext_inst.cpp
 160   PROPERTIES OBJECT_DEPENDS "${EXTINST_CPP_DEPENDS}")
 161 set_source_files_properties(
 162   ${CMAKE_CURRENT_SOURCE_DIR}/enum_string_mapping.cpp
 163   PROPERTIES OBJECT_DEPENDS "${ENUM_STRING_MAPPING_CPP_DEPENDS}")
 164
 165 set_source_files_properties(
 166   ${CMAKE_CURRENT_SOURCE_DIR}/extension.h
 167   PROPERTIES HEADER_FILE_ONLY TRUE)
 168 set_source_files_properties(
 169   ${CMAKE_CURRENT_SOURCE_DIR}/extension.h
 170   PROPERTIES OBJECT_DEPENDS "${EXTENSION_H_DEPENDS}")
 171
 172 set(SPIRV_TOOLS_BUILD_VERSION_INC
 173   ${spirv-tools_BINARY_DIR}/build-version.inc)
 174 set(SPIRV_TOOLS_BUILD_VERSION_INC_GENERATOR
 175   ${spirv-tools_SOURCE_DIR}/utils/update_build_version.py)
 176 set(SPIRV_TOOLS_CHANGES_FILE
 177   ${spirv-tools_SOURCE_DIR}/CHANGES)
 178 add_custom_command(OUTPUT ${SPIRV_TOOLS_BUILD_VERSION_INC}
 179    COMMAND ${PYTHON_EXECUTABLE}
 180            ${SPIRV_TOOLS_BUILD_VERSION_INC_GENERATOR}
 181            ${spirv-tools_SOURCE_DIR} ${SPIRV_TOOLS_BUILD_VERSION_INC}
 182    DEPENDS ${SPIRV_TOOLS_BUILD_VERSION_INC_GENERATOR}
 183            ${SPIRV_TOOLS_CHANGES_FILE}
 184    COMMENT "Update build-version.inc in the SPIRV-Tools build directory (if necessary).")
 185 # Convenience target for standalone generation of the build-version.inc file.
 186 # This is not required for any dependence chain.
 187 add_custom_target(spirv-tools-build-version
 188    DEPENDS ${SPIRV_TOOLS_BUILD_VERSION_INC})
 189 set_property(TARGET spirv-tools-build-version PROPERTY FOLDER "SPIRV-Tools build")
 190
 191 add_subdirectory(opt)
 192
 193 set(SPIRV_SOURCES
 194   ${spirv-tools_SOURCE_DIR}/include/spirv-tools/libspirv.h
 195
 196   ${CMAKE_CURRENT_SOURCE_DIR}/util/bitutils.h
 197   ${CMAKE_CURRENT_SOURCE_DIR}/util/bit_stream.h
 198   ${CMAKE_CURRENT_SOURCE_DIR}/util/hex_float.h
 199   ${CMAKE_CURRENT_SOURCE_DIR}/util/parse_number.h
 200   ${CMAKE_CURRENT_SOURCE_DIR}/util/string_utils.h
 201   ${CMAKE_CURRENT_SOURCE_DIR}/assembly_grammar.h
 202   ${CMAKE_CURRENT_SOURCE_DIR}/binary.h
 203   ${CMAKE_CURRENT_SOURCE_DIR}/cfa.h
 204   ${CMAKE_CURRENT_SOURCE_DIR}/diagnostic.h
 205   ${CMAKE_CURRENT_SOURCE_DIR}/enum_set.h
 206   ${CMAKE_CURRENT_SOURCE_DIR}/enum_string_mapping.h
 207   ${CMAKE_CURRENT_SOURCE_DIR}/ext_inst.h
 208   ${CMAKE_CURRENT_SOURCE_DIR}/extensions.h
 209   ${CMAKE_CURRENT_SOURCE_DIR}/instruction.h
 210   ${CMAKE_CURRENT_SOURCE_DIR}/macro.h
 211   ${CMAKE_CURRENT_SOURCE_DIR}/name_mapper.h
 212   ${CMAKE_CURRENT_SOURCE_DIR}/opcode.h
 213   ${CMAKE_CURRENT_SOURCE_DIR}/operand.h
 214   ${CMAKE_CURRENT_SOURCE_DIR}/parsed_operand.h
 215   ${CMAKE_CURRENT_SOURCE_DIR}/print.h
 216   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_constant.h
 217   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_definition.h
 218   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_endian.h
 219   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_target_env.h
 220   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_validator_options.h
 221   ${CMAKE_CURRENT_SOURCE_DIR}/table.h
 222   ${CMAKE_CURRENT_SOURCE_DIR}/text.h
 223   ${CMAKE_CURRENT_SOURCE_DIR}/text_handler.h
 224   ${CMAKE_CURRENT_SOURCE_DIR}/validate.h
 225
 226   ${CMAKE_CURRENT_SOURCE_DIR}/util/bit_stream.cpp
 227   ${CMAKE_CURRENT_SOURCE_DIR}/util/parse_number.cpp
 228   ${CMAKE_CURRENT_SOURCE_DIR}/util/string_utils.cpp
 229   ${CMAKE_CURRENT_SOURCE_DIR}/assembly_grammar.cpp
 230   ${CMAKE_CURRENT_SOURCE_DIR}/binary.cpp
 231   ${CMAKE_CURRENT_SOURCE_DIR}/diagnostic.cpp
 232   ${CMAKE_CURRENT_SOURCE_DIR}/disassemble.cpp
 233   ${CMAKE_CURRENT_SOURCE_DIR}/enum_string_mapping.cpp
 234   ${CMAKE_CURRENT_SOURCE_DIR}/ext_inst.cpp
 235   ${CMAKE_CURRENT_SOURCE_DIR}/extensions.cpp
 236   ${CMAKE_CURRENT_SOURCE_DIR}/libspirv.cpp
 237   ${CMAKE_CURRENT_SOURCE_DIR}/message.cpp
 238   ${CMAKE_CURRENT_SOURCE_DIR}/name_mapper.cpp
 239   ${CMAKE_CURRENT_SOURCE_DIR}/opcode.cpp
 240   ${CMAKE_CURRENT_SOURCE_DIR}/operand.cpp
 241   ${CMAKE_CURRENT_SOURCE_DIR}/parsed_operand.cpp
 242   ${CMAKE_CURRENT_SOURCE_DIR}/print.cpp
 243   ${CMAKE_CURRENT_SOURCE_DIR}/software_version.cpp
 244   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_endian.cpp
 245   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_stats.cpp
 246   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_target_env.cpp
 247   ${CMAKE_CURRENT_SOURCE_DIR}/spirv_validator_options.cpp
 248   ${CMAKE_CURRENT_SOURCE_DIR}/table.cpp
 249   ${CMAKE_CURRENT_SOURCE_DIR}/text.cpp
 250   ${CMAKE_CURRENT_SOURCE_DIR}/text_handler.cpp
 251   ${CMAKE_CURRENT_SOURCE_DIR}/validate.cpp
 252   ${CMAKE_CURRENT_SOURCE_DIR}/validate_cfg.cpp
 253   ${CMAKE_CURRENT_SOURCE_DIR}/validate_capability.cpp
 254   ${CMAKE_CURRENT_SOURCE_DIR}/validate_id.cpp
 255   ${CMAKE_CURRENT_SOURCE_DIR}/validate_instruction.cpp
 256   ${CMAKE_CURRENT_SOURCE_DIR}/validate_datarules.cpp
 257   ${CMAKE_CURRENT_SOURCE_DIR}/validate_decorations.cpp
 258   ${CMAKE_CURRENT_SOURCE_DIR}/validate_layout.cpp
 259   ${CMAKE_CURRENT_SOURCE_DIR}/validate_type_unique.cpp
 260   ${CMAKE_CURRENT_SOURCE_DIR}/val/decoration.h
 261   ${CMAKE_CURRENT_SOURCE_DIR}/val/basic_block.cpp
 262   ${CMAKE_CURRENT_SOURCE_DIR}/val/construct.cpp
 263   ${CMAKE_CURRENT_SOURCE_DIR}/val/function.cpp
 264   ${CMAKE_CURRENT_SOURCE_DIR}/val/instruction.cpp
 265   ${CMAKE_CURRENT_SOURCE_DIR}/val/validation_state.cpp)
 266
 267 # The software_version.cpp file includes build-version.inc.
 268 # Rebuild the software_version.cpp object file if it is older than
 269 # build-version.inc or whenever build-version.inc itself is out of
 270 # date.  In the latter case, rebuild build-version.inc first.
 271 # CMake is not smart enough to detect this dependency automatically.
 272 # Without this, the dependency detection system for #included files
 273 # does not kick in on a clean build for the following reason:  The
 274 # build will fail early because it doesn't know how to build the
 275 # missing source file build-version.inc. That occurs before the
 276 # preprocessor is run on software_version.cpp to detect the
 277 # #include dependency.
 278 set_source_files_properties(
 279   ${CMAKE_CURRENT_SOURCE_DIR}/software_version.cpp
 280   PROPERTIES OBJECT_DEPENDS "${SPIRV_TOOLS_BUILD_VERSION_INC}")
 281
 282 add_library(${SPIRV_TOOLS} ${SPIRV_SOURCES})
 283 spvtools_default_compile_options(${SPIRV_TOOLS})
 284 target_include_directories(${SPIRV_TOOLS}
 285   PUBLIC ${spirv-tools_SOURCE_DIR}/include
 286   PRIVATE ${spirv-tools_BINARY_DIR}
 287   PRIVATE ${SPIRV_HEADER_INCLUDE_DIR}
 288   )
 289 set_property(TARGET ${SPIRV_TOOLS} PROPERTY FOLDER "SPIRV-Tools libraries")
 290
 291 install(TARGETS ${SPIRV_TOOLS}
 292   RUNTIME DESTINATION bin
 293   LIBRARY DESTINATION lib
 294   ARCHIVE DESTINATION lib)