simd/x86_64/jidctint-avx2.asm

   1 ;
   2 ; jidctint.asm - accurate integer IDCT (64-bit AVX2)
   3 ;
   4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
   5 ; Copyright (C) 2009, 2016, 2018, D. R. Commander.
   6 ;
   7 ; Based on the x86 SIMD extension for IJG JPEG library
   8 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
   9 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
  10 ;
  11 ; This file should be assembled with NASM (Netwide Assembler),
  12 ; can *not* be assembled with Microsoft's MASM or any compatible
  13 ; assembler (including Borland's Turbo Assembler).
  14 ; NASM is available from http://nasm.sourceforge.net/ or
  15 ; http://sourceforge.net/project/showfiles.php?group_id=6208
  16 ;
  17 ; This file contains a slow-but-accurate integer implementation of the
  18 ; inverse DCT (Discrete Cosine Transform). The following code is based
  19 ; directly on the IJG's original jidctint.c; see the jidctint.c for
  20 ; more details.
  21 ;
  22 ; [TAB8]
  23
  24 %include "jsimdext.inc"
  25 %include "jdct.inc"
  26
  27 ; --------------------------------------------------------------------------
  28
  29 %define CONST_BITS  13
  30 %define PASS1_BITS  2
  31
  32 %define DESCALE_P1  (CONST_BITS - PASS1_BITS)
  33 %define DESCALE_P2  (CONST_BITS + PASS1_BITS + 3)
  34
  35 %if CONST_BITS == 13
  36 F_0_298 equ  2446  ; FIX(0.298631336)
  37 F_0_390 equ  3196  ; FIX(0.390180644)
  38 F_0_541 equ  4433  ; FIX(0.541196100)
  39 F_0_765 equ  6270  ; FIX(0.765366865)
  40 F_0_899 equ  7373  ; FIX(0.899976223)
  41 F_1_175 equ  9633  ; FIX(1.175875602)
  42 F_1_501 equ 12299  ; FIX(1.501321110)
  43 F_1_847 equ 15137  ; FIX(1.847759065)
  44 F_1_961 equ 16069  ; FIX(1.961570560)
  45 F_2_053 equ 16819  ; FIX(2.053119869)
  46 F_2_562 equ 20995  ; FIX(2.562915447)
  47 F_3_072 equ 25172  ; FIX(3.072711026)
  48 %else
  49 ; NASM cannot do compile-time arithmetic on floating-point constants.
  50 %define DESCALE(x, n)  (((x) + (1 << ((n) - 1))) >> (n))
  51 F_0_298 equ DESCALE( 320652955, 30 - CONST_BITS)  ; FIX(0.298631336)
  52 F_0_390 equ DESCALE( 418953276, 30 - CONST_BITS)  ; FIX(0.390180644)
  53 F_0_541 equ DESCALE( 581104887, 30 - CONST_BITS)  ; FIX(0.541196100)
  54 F_0_765 equ DESCALE( 821806413, 30 - CONST_BITS)  ; FIX(0.765366865)
  55 F_0_899 equ DESCALE( 966342111, 30 - CONST_BITS)  ; FIX(0.899976223)
  56 F_1_175 equ DESCALE(1262586813, 30 - CONST_BITS)  ; FIX(1.175875602)
  57 F_1_501 equ DESCALE(1612031267, 30 - CONST_BITS)  ; FIX(1.501321110)
  58 F_1_847 equ DESCALE(1984016188, 30 - CONST_BITS)  ; FIX(1.847759065)
  59 F_1_961 equ DESCALE(2106220350, 30 - CONST_BITS)  ; FIX(1.961570560)
  60 F_2_053 equ DESCALE(2204520673, 30 - CONST_BITS)  ; FIX(2.053119869)
  61 F_2_562 equ DESCALE(2751909506, 30 - CONST_BITS)  ; FIX(2.562915447)
  62 F_3_072 equ DESCALE(3299298341, 30 - CONST_BITS)  ; FIX(3.072711026)
  63 %endif
  64
  65 ; --------------------------------------------------------------------------
  66 ; In-place 8x8x16-bit inverse matrix transpose using AVX2 instructions
  67 ; %1-%4: Input/output registers
  68 ; %5-%8: Temp registers
  69
  70 %macro dotranspose 8
  71     ; %5=(00 10 20 30 40 50 60 70  01 11 21 31 41 51 61 71)
  72     ; %6=(03 13 23 33 43 53 63 73  02 12 22 32 42 52 62 72)
  73     ; %7=(04 14 24 34 44 54 64 74  05 15 25 35 45 55 65 75)
  74     ; %8=(07 17 27 37 47 57 67 77  06 16 26 36 46 56 66 76)
  75
  76     vpermq      %5, %1, 0xD8
  77     vpermq      %6, %2, 0x72
  78     vpermq      %7, %3, 0xD8
  79     vpermq      %8, %4, 0x72
  80     ; transpose coefficients(phase 1)
  81     ; %5=(00 10 20 30 01 11 21 31  40 50 60 70 41 51 61 71)
  82     ; %6=(02 12 22 32 03 13 23 33  42 52 62 72 43 53 63 73)
  83     ; %7=(04 14 24 34 05 15 25 35  44 54 64 74 45 55 65 75)
  84     ; %8=(06 16 26 36 07 17 27 37  46 56 66 76 47 57 67 77)
  85
  86     vpunpcklwd  %1, %5, %6
  87     vpunpckhwd  %2, %5, %6
  88     vpunpcklwd  %3, %7, %8
  89     vpunpckhwd  %4, %7, %8
  90     ; transpose coefficients(phase 2)
  91     ; %1=(00 02 10 12 20 22 30 32  40 42 50 52 60 62 70 72)
  92     ; %2=(01 03 11 13 21 23 31 33  41 43 51 53 61 63 71 73)
  93     ; %3=(04 06 14 16 24 26 34 36  44 46 54 56 64 66 74 76)
  94     ; %4=(05 07 15 17 25 27 35 37  45 47 55 57 65 67 75 77)
  95
  96     vpunpcklwd  %5, %1, %2
  97     vpunpcklwd  %6, %3, %4
  98     vpunpckhwd  %7, %1, %2
  99     vpunpckhwd  %8, %3, %4
 100     ; transpose coefficients(phase 3)
 101     ; %5=(00 01 02 03 10 11 12 13  40 41 42 43 50 51 52 53)
 102     ; %6=(04 05 06 07 14 15 16 17  44 45 46 47 54 55 56 57)
 103     ; %7=(20 21 22 23 30 31 32 33  60 61 62 63 70 71 72 73)
 104     ; %8=(24 25 26 27 34 35 36 37  64 65 66 67 74 75 76 77)
 105
 106     vpunpcklqdq %1, %5, %6
 107     vpunpckhqdq %2, %5, %6
 108     vpunpcklqdq %3, %7, %8
 109     vpunpckhqdq %4, %7, %8
 110     ; transpose coefficients(phase 4)
 111     ; %1=(00 01 02 03 04 05 06 07  40 41 42 43 44 45 46 47)
 112     ; %2=(10 11 12 13 14 15 16 17  50 51 52 53 54 55 56 57)
 113     ; %3=(20 21 22 23 24 25 26 27  60 61 62 63 64 65 66 67)
 114     ; %4=(30 31 32 33 34 35 36 37  70 71 72 73 74 75 76 77)
 115 %endmacro
 116
 117 ; --------------------------------------------------------------------------
 118 ; In-place 8x8x16-bit slow integer inverse DCT using AVX2 instructions
 119 ; %1-%4:  Input/output registers
 120 ; %5-%12: Temp registers
 121 ; %9:     Pass (1 or 2)
 122
 123 %macro dodct 13
 124     ; -- Even part
 125
 126     ; (Original)
 127     ; z1 = (z2 + z3) * 0.541196100;
 128     ; tmp2 = z1 + z3 * -1.847759065;
 129     ; tmp3 = z1 + z2 * 0.765366865;
 130     ;
 131     ; (This implementation)
 132     ; tmp2 = z2 * 0.541196100 + z3 * (0.541196100 - 1.847759065);
 133     ; tmp3 = z2 * (0.541196100 + 0.765366865) + z3 * 0.541196100;
 134
 135     vperm2i128  %6, %3, %3, 0x01        ; %6=in6_2
 136     vpunpcklwd  %5, %3, %6              ; %5=in26_62L
 137     vpunpckhwd  %6, %3, %6              ; %6=in26_62H
 138     vpmaddwd    %5, %5, [rel PW_F130_F054_MF130_F054]  ; %5=tmp3_2L
 139     vpmaddwd    %6, %6, [rel PW_F130_F054_MF130_F054]  ; %6=tmp3_2H
 140
 141     vperm2i128  %7, %1, %1, 0x01        ; %7=in4_0
 142     vpsignw     %1, %1, [rel PW_1_NEG1]
 143     vpaddw      %7, %7, %1              ; %7=(in0+in4)_(in0-in4)
 144
 145     vpxor       %1, %1, %1
 146     vpunpcklwd  %8, %1, %7              ; %8=tmp0_1L
 147     vpunpckhwd  %1, %1, %7              ; %1=tmp0_1H
 148     vpsrad      %8, %8, (16-CONST_BITS)  ; vpsrad %8,16 & vpslld %8,CONST_BITS
 149     vpsrad      %1, %1, (16-CONST_BITS)  ; vpsrad %1,16 & vpslld %1,CONST_BITS
 150
 151     vpsubd      %11, %8, %5             ; %11=tmp0_1L-tmp3_2L=tmp13_12L
 152     vpaddd      %9, %8, %5              ; %9=tmp0_1L+tmp3_2L=tmp10_11L
 153     vpsubd      %12, %1, %6             ; %12=tmp0_1H-tmp3_2H=tmp13_12H
 154     vpaddd      %10, %1, %6             ; %10=tmp0_1H+tmp3_2H=tmp10_11H
 155
 156     ; -- Odd part
 157
 158     vpaddw      %1, %4, %2              ; %1=in7_5+in3_1=z3_4
 159
 160     ; (Original)
 161     ; z5 = (z3 + z4) * 1.175875602;
 162     ; z3 = z3 * -1.961570560;  z4 = z4 * -0.390180644;
 163     ; z3 += z5;  z4 += z5;
 164     ;
 165     ; (This implementation)
 166     ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
 167     ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
 168
 169     vperm2i128  %8, %1, %1, 0x01        ; %8=z4_3
 170     vpunpcklwd  %7, %1, %8              ; %7=z34_43L
 171     vpunpckhwd  %8, %1, %8              ; %8=z34_43H
 172     vpmaddwd    %7, %7, [rel PW_MF078_F117_F078_F117]  ; %7=z3_4L
 173     vpmaddwd    %8, %8, [rel PW_MF078_F117_F078_F117]  ; %8=z3_4H
 174
 175     ; (Original)
 176     ; z1 = tmp0 + tmp3;  z2 = tmp1 + tmp2;
 177     ; tmp0 = tmp0 * 0.298631336;  tmp1 = tmp1 * 2.053119869;
 178     ; tmp2 = tmp2 * 3.072711026;  tmp3 = tmp3 * 1.501321110;
 179     ; z1 = z1 * -0.899976223;  z2 = z2 * -2.562915447;
 180     ; tmp0 += z1 + z3;  tmp1 += z2 + z4;
 181     ; tmp2 += z2 + z3;  tmp3 += z1 + z4;
 182     ;
 183     ; (This implementation)
 184     ; tmp0 = tmp0 * (0.298631336 - 0.899976223) + tmp3 * -0.899976223;
 185     ; tmp1 = tmp1 * (2.053119869 - 2.562915447) + tmp2 * -2.562915447;
 186     ; tmp2 = tmp1 * -2.562915447 + tmp2 * (3.072711026 - 2.562915447);
 187     ; tmp3 = tmp0 * -0.899976223 + tmp3 * (1.501321110 - 0.899976223);
 188     ; tmp0 += z3;  tmp1 += z4;
 189     ; tmp2 += z3;  tmp3 += z4;
 190
 191     vperm2i128  %2, %2, %2, 0x01        ; %2=in1_3
 192     vpunpcklwd  %3, %4, %2              ; %3=in71_53L
 193     vpunpckhwd  %4, %4, %2              ; %4=in71_53H
 194
 195     vpmaddwd    %5, %3, [rel PW_MF060_MF089_MF050_MF256]  ; %5=tmp0_1L
 196     vpmaddwd    %6, %4, [rel PW_MF060_MF089_MF050_MF256]  ; %6=tmp0_1H
 197     vpaddd      %5, %5, %7              ; %5=tmp0_1L+z3_4L=tmp0_1L
 198     vpaddd      %6, %6, %8              ; %6=tmp0_1H+z3_4H=tmp0_1H
 199
 200     vpmaddwd    %3, %3, [rel PW_MF089_F060_MF256_F050]  ; %3=tmp3_2L
 201     vpmaddwd    %4, %4, [rel PW_MF089_F060_MF256_F050]  ; %4=tmp3_2H
 202     vperm2i128  %7, %7, %7, 0x01        ; %7=z4_3L
 203     vperm2i128  %8, %8, %8, 0x01        ; %8=z4_3H
 204     vpaddd      %7, %3, %7              ; %7=tmp3_2L+z4_3L=tmp3_2L
 205     vpaddd      %8, %4, %8              ; %8=tmp3_2H+z4_3H=tmp3_2H
 206
 207     ; -- Final output stage
 208
 209     vpaddd      %1, %9, %7              ; %1=tmp10_11L+tmp3_2L=data0_1L
 210     vpaddd      %2, %10, %8             ; %2=tmp10_11H+tmp3_2H=data0_1H
 211     vpaddd      %1, %1, [rel PD_DESCALE_P %+ %13]
 212     vpaddd      %2, %2, [rel PD_DESCALE_P %+ %13]
 213     vpsrad      %1, %1, DESCALE_P %+ %13
 214     vpsrad      %2, %2, DESCALE_P %+ %13
 215     vpackssdw   %1, %1, %2              ; %1=data0_1
 216
 217     vpsubd      %3, %9, %7              ; %3=tmp10_11L-tmp3_2L=data7_6L
 218     vpsubd      %4, %10, %8             ; %4=tmp10_11H-tmp3_2H=data7_6H
 219     vpaddd      %3, %3, [rel PD_DESCALE_P %+ %13]
 220     vpaddd      %4, %4, [rel PD_DESCALE_P %+ %13]
 221     vpsrad      %3, %3, DESCALE_P %+ %13
 222     vpsrad      %4, %4, DESCALE_P %+ %13
 223     vpackssdw   %4, %3, %4              ; %4=data7_6
 224
 225     vpaddd      %7, %11, %5             ; %7=tmp13_12L+tmp0_1L=data3_2L
 226     vpaddd      %8, %12, %6             ; %8=tmp13_12H+tmp0_1H=data3_2H
 227     vpaddd      %7, %7, [rel PD_DESCALE_P %+ %13]
 228     vpaddd      %8, %8, [rel PD_DESCALE_P %+ %13]
 229     vpsrad      %7, %7, DESCALE_P %+ %13
 230     vpsrad      %8, %8, DESCALE_P %+ %13
 231     vpackssdw   %2, %7, %8              ; %2=data3_2
 232
 233     vpsubd      %7, %11, %5             ; %7=tmp13_12L-tmp0_1L=data4_5L
 234     vpsubd      %8, %12, %6             ; %8=tmp13_12H-tmp0_1H=data4_5H
 235     vpaddd      %7, %7, [rel PD_DESCALE_P %+ %13]
 236     vpaddd      %8, %8, [rel PD_DESCALE_P %+ %13]
 237     vpsrad      %7, %7, DESCALE_P %+ %13
 238     vpsrad      %8, %8, DESCALE_P %+ %13
 239     vpackssdw   %3, %7, %8              ; %3=data4_5
 240 %endmacro
 241
 242 ; --------------------------------------------------------------------------
 243     SECTION     SEG_CONST
 244
 245     alignz      32
 246     GLOBAL_DATA(jconst_idct_islow_avx2)
 247
 248 EXTN(jconst_idct_islow_avx2):
 249
 250 PW_F130_F054_MF130_F054    times 4  dw  (F_0_541 + F_0_765),  F_0_541
 251                            times 4  dw  (F_0_541 - F_1_847),  F_0_541
 252 PW_MF078_F117_F078_F117    times 4  dw  (F_1_175 - F_1_961),  F_1_175
 253                            times 4  dw  (F_1_175 - F_0_390),  F_1_175
 254 PW_MF060_MF089_MF050_MF256 times 4  dw  (F_0_298 - F_0_899), -F_0_899
 255                            times 4  dw  (F_2_053 - F_2_562), -F_2_562
 256 PW_MF089_F060_MF256_F050   times 4  dw -F_0_899, (F_1_501 - F_0_899)
 257                            times 4  dw -F_2_562, (F_3_072 - F_2_562)
 258 PD_DESCALE_P1              times 8  dd  1 << (DESCALE_P1 - 1)
 259 PD_DESCALE_P2              times 8  dd  1 << (DESCALE_P2 - 1)
 260 PB_CENTERJSAMP             times 32 db  CENTERJSAMPLE
 261 PW_1_NEG1                  times 8  dw  1
 262                            times 8  dw -1
 263
 264     alignz      32
 265
 266 ; --------------------------------------------------------------------------
 267     SECTION     SEG_TEXT
 268     BITS        64
 269 ;
 270 ; Perform dequantization and inverse DCT on one block of coefficients.
 271 ;
 272 ; GLOBAL(void)
 273 ; jsimd_idct_islow_avx2(void *dct_table, JCOEFPTR coef_block,
 274 ;                       JSAMPARRAY output_buf, JDIMENSION output_col)
 275 ;
 276
 277 ; r10 = jpeg_component_info *compptr
 278 ; r11 = JCOEFPTR coef_block
 279 ; r12 = JSAMPARRAY output_buf
 280 ; r13d = JDIMENSION output_col
 281
 282     align       32
 283     GLOBAL_FUNCTION(jsimd_idct_islow_avx2)
 284
 285 EXTN(jsimd_idct_islow_avx2):
 286     push        rbp
 287     mov         rax, rsp                     ; rax = original rbp
 288     mov         rbp, rsp                     ; rbp = aligned rbp
 289     push_xmm    4
 290     collect_args 4
 291
 292     ; ---- Pass 1: process columns.
 293
 294 %ifndef NO_ZERO_COLUMN_TEST_ISLOW_AVX2
 295     mov         eax, DWORD [DWBLOCK(1,0,r11,SIZEOF_JCOEF)]
 296     or          eax, DWORD [DWBLOCK(2,0,r11,SIZEOF_JCOEF)]
 297     jnz         near .columnDCT
 298
 299     movdqa      xmm0, XMMWORD [XMMBLOCK(1,0,r11,SIZEOF_JCOEF)]
 300     movdqa      xmm1, XMMWORD [XMMBLOCK(2,0,r11,SIZEOF_JCOEF)]
 301     vpor        xmm0, xmm0, XMMWORD [XMMBLOCK(3,0,r11,SIZEOF_JCOEF)]
 302     vpor        xmm1, xmm1, XMMWORD [XMMBLOCK(4,0,r11,SIZEOF_JCOEF)]
 303     vpor        xmm0, xmm0, XMMWORD [XMMBLOCK(5,0,r11,SIZEOF_JCOEF)]
 304     vpor        xmm1, xmm1, XMMWORD [XMMBLOCK(6,0,r11,SIZEOF_JCOEF)]
 305     vpor        xmm0, xmm0, XMMWORD [XMMBLOCK(7,0,r11,SIZEOF_JCOEF)]
 306     vpor        xmm1, xmm1, xmm0
 307     vpacksswb   xmm1, xmm1, xmm1
 308     vpacksswb   xmm1, xmm1, xmm1
 309     movd        eax, xmm1
 310     test        rax, rax
 311     jnz         short .columnDCT
 312
 313     ; -- AC terms all zero
 314
 315     movdqa      xmm5, XMMWORD [XMMBLOCK(0,0,r11,SIZEOF_JCOEF)]
 316     vpmullw     xmm5, xmm5, XMMWORD [XMMBLOCK(0,0,r10,SIZEOF_ISLOW_MULT_TYPE)]
 317
 318     vpsllw      xmm5, xmm5, PASS1_BITS
 319
 320     vpunpcklwd  xmm4, xmm5, xmm5        ; xmm4=(00 00 01 01 02 02 03 03)
 321     vpunpckhwd  xmm5, xmm5, xmm5        ; xmm5=(04 04 05 05 06 06 07 07)
 322     vinserti128 ymm4, ymm4, xmm5, 1
 323
 324     vpshufd     ymm0, ymm4, 0x00        ; ymm0=col0_4=(00 00 00 00 00 00 00 00  04 04 04 04 04 04 04 04)
 325     vpshufd     ymm1, ymm4, 0x55        ; ymm1=col1_5=(01 01 01 01 01 01 01 01  05 05 05 05 05 05 05 05)
 326     vpshufd     ymm2, ymm4, 0xAA        ; ymm2=col2_6=(02 02 02 02 02 02 02 02  06 06 06 06 06 06 06 06)
 327     vpshufd     ymm3, ymm4, 0xFF        ; ymm3=col3_7=(03 03 03 03 03 03 03 03  07 07 07 07 07 07 07 07)
 328
 329     jmp         near .column_end
 330 %endif
 331 .columnDCT:
 332
 333     vmovdqu     ymm4, YMMWORD [YMMBLOCK(0,0,r11,SIZEOF_JCOEF)]  ; ymm4=in0_1
 334     vmovdqu     ymm5, YMMWORD [YMMBLOCK(2,0,r11,SIZEOF_JCOEF)]  ; ymm5=in2_3
 335     vmovdqu     ymm6, YMMWORD [YMMBLOCK(4,0,r11,SIZEOF_JCOEF)]  ; ymm6=in4_5
 336     vmovdqu     ymm7, YMMWORD [YMMBLOCK(6,0,r11,SIZEOF_JCOEF)]  ; ymm7=in6_7
 337     vpmullw     ymm4, ymm4, YMMWORD [YMMBLOCK(0,0,r10,SIZEOF_ISLOW_MULT_TYPE)]
 338     vpmullw     ymm5, ymm5, YMMWORD [YMMBLOCK(2,0,r10,SIZEOF_ISLOW_MULT_TYPE)]
 339     vpmullw     ymm6, ymm6, YMMWORD [YMMBLOCK(4,0,r10,SIZEOF_ISLOW_MULT_TYPE)]
 340     vpmullw     ymm7, ymm7, YMMWORD [YMMBLOCK(6,0,r10,SIZEOF_ISLOW_MULT_TYPE)]
 341
 342     vperm2i128  ymm0, ymm4, ymm6, 0x20  ; ymm0=in0_4
 343     vperm2i128  ymm1, ymm5, ymm4, 0x31  ; ymm1=in3_1
 344     vperm2i128  ymm2, ymm5, ymm7, 0x20  ; ymm2=in2_6
 345     vperm2i128  ymm3, ymm7, ymm6, 0x31  ; ymm3=in7_5
 346
 347     dodct ymm0, ymm1, ymm2, ymm3, ymm4, ymm5, ymm6, ymm7, ymm8, ymm9, ymm10, ymm11, 1
 348     ; ymm0=data0_1, ymm1=data3_2, ymm2=data4_5, ymm3=data7_6
 349
 350     dotranspose ymm0, ymm1, ymm2, ymm3, ymm4, ymm5, ymm6, ymm7
 351     ; ymm0=data0_4, ymm1=data1_5, ymm2=data2_6, ymm3=data3_7
 352
 353 .column_end:
 354
 355     ; -- Prefetch the next coefficient block
 356
 357     prefetchnta [r11 + DCTSIZE2*SIZEOF_JCOEF + 0*32]
 358     prefetchnta [r11 + DCTSIZE2*SIZEOF_JCOEF + 1*32]
 359     prefetchnta [r11 + DCTSIZE2*SIZEOF_JCOEF + 2*32]
 360     prefetchnta [r11 + DCTSIZE2*SIZEOF_JCOEF + 3*32]
 361
 362     ; ---- Pass 2: process rows.
 363
 364     vperm2i128  ymm4, ymm3, ymm1, 0x31  ; ymm3=in7_5
 365     vperm2i128  ymm1, ymm3, ymm1, 0x20  ; ymm1=in3_1
 366
 367     dodct ymm0, ymm1, ymm2, ymm4, ymm3, ymm5, ymm6, ymm7, ymm8, ymm9, ymm10, ymm11, 2
 368     ; ymm0=data0_1, ymm1=data3_2, ymm2=data4_5, ymm4=data7_6
 369
 370     dotranspose ymm0, ymm1, ymm2, ymm4, ymm3, ymm5, ymm6, ymm7
 371     ; ymm0=data0_4, ymm1=data1_5, ymm2=data2_6, ymm4=data3_7
 372
 373     vpacksswb   ymm0, ymm0, ymm1        ; ymm0=data01_45
 374     vpacksswb   ymm1, ymm2, ymm4        ; ymm1=data23_67
 375     vpaddb      ymm0, ymm0, [rel PB_CENTERJSAMP]
 376     vpaddb      ymm1, ymm1, [rel PB_CENTERJSAMP]
 377
 378     vextracti128 xmm6, ymm1, 1          ; xmm3=data67
 379     vextracti128 xmm4, ymm0, 1          ; xmm2=data45
 380     vextracti128 xmm2, ymm1, 0          ; xmm1=data23
 381     vextracti128 xmm0, ymm0, 0          ; xmm0=data01
 382
 383     vpshufd     xmm1, xmm0, 0x4E  ; xmm1=(10 11 12 13 14 15 16 17 00 01 02 03 04 05 06 07)
 384     vpshufd     xmm3, xmm2, 0x4E  ; xmm3=(30 31 32 33 34 35 36 37 20 21 22 23 24 25 26 27)
 385     vpshufd     xmm5, xmm4, 0x4E  ; xmm5=(50 51 52 53 54 55 56 57 40 41 42 43 44 45 46 47)
 386     vpshufd     xmm7, xmm6, 0x4E  ; xmm7=(70 71 72 73 74 75 76 77 60 61 62 63 64 65 66 67)
 387
 388     vzeroupper
 389
 390     mov         eax, r13d
 391
 392     mov         rdx, JSAMPROW [r12+0*SIZEOF_JSAMPROW]  ; (JSAMPLE *)
 393     mov         rsi, JSAMPROW [r12+1*SIZEOF_JSAMPROW]  ; (JSAMPLE *)
 394     movq        XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE], xmm0
 395     movq        XMM_MMWORD [rsi+rax*SIZEOF_JSAMPLE], xmm1
 396
 397     mov         rdx, JSAMPROW [r12+2*SIZEOF_JSAMPROW]  ; (JSAMPLE *)
 398     mov         rsi, JSAMPROW [r12+3*SIZEOF_JSAMPROW]  ; (JSAMPLE *)
 399     movq        XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE], xmm2
 400     movq        XMM_MMWORD [rsi+rax*SIZEOF_JSAMPLE], xmm3
 401
 402     mov         rdx, JSAMPROW [r12+4*SIZEOF_JSAMPROW]  ; (JSAMPLE *)
 403     mov         rsi, JSAMPROW [r12+5*SIZEOF_JSAMPROW]  ; (JSAMPLE *)
 404     movq        XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE], xmm4
 405     movq        XMM_MMWORD [rsi+rax*SIZEOF_JSAMPLE], xmm5
 406
 407     mov         rdx, JSAMPROW [r12+6*SIZEOF_JSAMPROW]  ; (JSAMPLE *)
 408     mov         rsi, JSAMPROW [r12+7*SIZEOF_JSAMPROW]  ; (JSAMPLE *)
 409     movq        XMM_MMWORD [rdx+rax*SIZEOF_JSAMPLE], xmm6
 410     movq        XMM_MMWORD [rsi+rax*SIZEOF_JSAMPLE], xmm7
 411
 412     uncollect_args 4
 413     pop_xmm     4
 414     pop         rbp
 415     ret
 416
 417 ; For some reason, the OS X linker does not honor the request to align the
 418 ; segment unless we do this.
 419     align       32