simd/x86_64/jfdctint-sse2.asm

   1 ;
   2 ; jfdctint.asm - accurate integer FDCT (64-bit SSE2)
   3 ;
   4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
   5 ; Copyright (C) 2009, 2016, 2020, D. R. Commander.
   6 ; Copyright (C) 2023, Aliaksiej Kandracienka.
   7 ;
   8 ; Based on the x86 SIMD extension for IJG JPEG library
   9 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
  10 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
  11 ;
  12 ; This file should be assembled with NASM (Netwide Assembler),
  13 ; can *not* be assembled with Microsoft's MASM or any compatible
  14 ; assembler (including Borland's Turbo Assembler).
  15 ; NASM is available from http://nasm.sourceforge.net/ or
  16 ; http://sourceforge.net/project/showfiles.php?group_id=6208
  17 ;
  18 ; This file contains a slower but more accurate integer implementation of the
  19 ; forward DCT (Discrete Cosine Transform). The following code is based
  20 ; directly on the IJG's original jfdctint.c; see the jfdctint.c for
  21 ; more details.
  22
  23 %include "jsimdext.inc"
  24 %include "jdct.inc"
  25
  26 ; --------------------------------------------------------------------------
  27
  28 %define CONST_BITS  13
  29 %define PASS1_BITS  2
  30
  31 %define DESCALE_P1  (CONST_BITS - PASS1_BITS)
  32 %define DESCALE_P2  (CONST_BITS + PASS1_BITS)
  33
  34 %if CONST_BITS == 13
  35 F_0_298 equ  2446  ; FIX(0.298631336)
  36 F_0_390 equ  3196  ; FIX(0.390180644)
  37 F_0_541 equ  4433  ; FIX(0.541196100)
  38 F_0_765 equ  6270  ; FIX(0.765366865)
  39 F_0_899 equ  7373  ; FIX(0.899976223)
  40 F_1_175 equ  9633  ; FIX(1.175875602)
  41 F_1_501 equ 12299  ; FIX(1.501321110)
  42 F_1_847 equ 15137  ; FIX(1.847759065)
  43 F_1_961 equ 16069  ; FIX(1.961570560)
  44 F_2_053 equ 16819  ; FIX(2.053119869)
  45 F_2_562 equ 20995  ; FIX(2.562915447)
  46 F_3_072 equ 25172  ; FIX(3.072711026)
  47 %else
  48 ; NASM cannot do compile-time arithmetic on floating-point constants.
  49 %define DESCALE(x, n)  (((x) + (1 << ((n) - 1))) >> (n))
  50 F_0_298 equ DESCALE( 320652955, 30 - CONST_BITS)  ; FIX(0.298631336)
  51 F_0_390 equ DESCALE( 418953276, 30 - CONST_BITS)  ; FIX(0.390180644)
  52 F_0_541 equ DESCALE( 581104887, 30 - CONST_BITS)  ; FIX(0.541196100)
  53 F_0_765 equ DESCALE( 821806413, 30 - CONST_BITS)  ; FIX(0.765366865)
  54 F_0_899 equ DESCALE( 966342111, 30 - CONST_BITS)  ; FIX(0.899976223)
  55 F_1_175 equ DESCALE(1262586813, 30 - CONST_BITS)  ; FIX(1.175875602)
  56 F_1_501 equ DESCALE(1612031267, 30 - CONST_BITS)  ; FIX(1.501321110)
  57 F_1_847 equ DESCALE(1984016188, 30 - CONST_BITS)  ; FIX(1.847759065)
  58 F_1_961 equ DESCALE(2106220350, 30 - CONST_BITS)  ; FIX(1.961570560)
  59 F_2_053 equ DESCALE(2204520673, 30 - CONST_BITS)  ; FIX(2.053119869)
  60 F_2_562 equ DESCALE(2751909506, 30 - CONST_BITS)  ; FIX(2.562915447)
  61 F_3_072 equ DESCALE(3299298341, 30 - CONST_BITS)  ; FIX(3.072711026)
  62 %endif
  63
  64 ; --------------------------------------------------------------------------
  65     SECTION     SEG_CONST
  66
  67     alignz      32
  68     GLOBAL_DATA(jconst_fdct_islow_sse2)
  69
  70 EXTN(jconst_fdct_islow_sse2):
  71
  72 PW_F130_F054   times 4 dw  (F_0_541 + F_0_765),  F_0_541
  73 PW_F054_MF130  times 4 dw  F_0_541, (F_0_541 - F_1_847)
  74 PW_MF078_F117  times 4 dw  (F_1_175 - F_1_961),  F_1_175
  75 PW_F117_F078   times 4 dw  F_1_175, (F_1_175 - F_0_390)
  76 PW_MF060_MF089 times 4 dw  (F_0_298 - F_0_899), -F_0_899
  77 PW_MF089_F060  times 4 dw -F_0_899, (F_1_501 - F_0_899)
  78 PW_MF050_MF256 times 4 dw  (F_2_053 - F_2_562), -F_2_562
  79 PW_MF256_F050  times 4 dw -F_2_562, (F_3_072 - F_2_562)
  80 PD_DESCALE_P1  times 4 dd  1 << (DESCALE_P1 - 1)
  81 PD_DESCALE_P2  times 4 dd  1 << (DESCALE_P2 - 1)
  82 PW_DESCALE_P2X times 8 dw  1 << (PASS1_BITS - 1)
  83
  84     alignz      32
  85
  86 ; --------------------------------------------------------------------------
  87     SECTION     SEG_TEXT
  88     BITS        64
  89 ;
  90 ; Perform the forward DCT on one block of samples.
  91 ;
  92 ; GLOBAL(void)
  93 ; jsimd_fdct_islow_sse2(DCTELEM *data)
  94 ;
  95
  96 ; r10 = DCTELEM *data
  97
  98 %define wk(i)   r15 - (WK_NUM - (i)) * SIZEOF_XMMWORD  ; xmmword wk[WK_NUM]
  99 %define WK_NUM  6
 100
 101     align       32
 102     GLOBAL_FUNCTION(jsimd_fdct_islow_sse2)
 103
 104 EXTN(jsimd_fdct_islow_sse2):
 105     push        rbp
 106     mov         rbp, rsp
 107     push        r15
 108     and         rsp, byte (-SIZEOF_XMMWORD)  ; align to 128 bits
 109     ; Allocate stack space for wk array.  r15 is used to access it.
 110     mov         r15, rsp
 111     sub         rsp, byte (SIZEOF_XMMWORD * WK_NUM)
 112     collect_args 1
 113
 114     ; ---- Pass 1: process rows.
 115
 116     mov         rdx, r10                ; (DCTELEM *)
 117
 118     movdqa      xmm0, XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_DCTELEM)]
 119     movdqa      xmm1, XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_DCTELEM)]
 120     movdqa      xmm2, XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_DCTELEM)]
 121     movdqa      xmm3, XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_DCTELEM)]
 122
 123     ; xmm0=(00 01 02 03 04 05 06 07), xmm2=(20 21 22 23 24 25 26 27)
 124     ; xmm1=(10 11 12 13 14 15 16 17), xmm3=(30 31 32 33 34 35 36 37)
 125
 126     movdqa      xmm4, xmm0              ; transpose coefficients(phase 1)
 127     punpcklwd   xmm0, xmm1              ; xmm0=(00 10 01 11 02 12 03 13)
 128     punpckhwd   xmm4, xmm1              ; xmm4=(04 14 05 15 06 16 07 17)
 129     movdqa      xmm5, xmm2              ; transpose coefficients(phase 1)
 130     punpcklwd   xmm2, xmm3              ; xmm2=(20 30 21 31 22 32 23 33)
 131     punpckhwd   xmm5, xmm3              ; xmm5=(24 34 25 35 26 36 27 37)
 132
 133     movdqa      xmm6, XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_DCTELEM)]
 134     movdqa      xmm7, XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_DCTELEM)]
 135     movdqa      xmm1, XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_DCTELEM)]
 136     movdqa      xmm3, XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_DCTELEM)]
 137
 138     ; xmm6=( 4 12 20 28 36 44 52 60), xmm1=( 6 14 22 30 38 46 54 62)
 139     ; xmm7=( 5 13 21 29 37 45 53 61), xmm3=( 7 15 23 31 39 47 55 63)
 140
 141     movdqa      XMMWORD [wk(0)], xmm2   ; wk(0)=(20 30 21 31 22 32 23 33)
 142     movdqa      XMMWORD [wk(1)], xmm5   ; wk(1)=(24 34 25 35 26 36 27 37)
 143
 144     movdqa      xmm2, xmm6              ; transpose coefficients(phase 1)
 145     punpcklwd   xmm6, xmm7              ; xmm6=(40 50 41 51 42 52 43 53)
 146     punpckhwd   xmm2, xmm7              ; xmm2=(44 54 45 55 46 56 47 57)
 147     movdqa      xmm5, xmm1              ; transpose coefficients(phase 1)
 148     punpcklwd   xmm1, xmm3              ; xmm1=(60 70 61 71 62 72 63 73)
 149     punpckhwd   xmm5, xmm3              ; xmm5=(64 74 65 75 66 76 67 77)
 150
 151     movdqa      xmm7, xmm6              ; transpose coefficients(phase 2)
 152     punpckldq   xmm6, xmm1              ; xmm6=(40 50 60 70 41 51 61 71)
 153     punpckhdq   xmm7, xmm1              ; xmm7=(42 52 62 72 43 53 63 73)
 154     movdqa      xmm3, xmm2              ; transpose coefficients(phase 2)
 155     punpckldq   xmm2, xmm5              ; xmm2=(44 54 64 74 45 55 65 75)
 156     punpckhdq   xmm3, xmm5              ; xmm3=(46 56 66 76 47 57 67 77)
 157
 158     movdqa      xmm1, XMMWORD [wk(0)]   ; xmm1=(20 30 21 31 22 32 23 33)
 159     movdqa      xmm5, XMMWORD [wk(1)]   ; xmm5=(24 34 25 35 26 36 27 37)
 160     movdqa      XMMWORD [wk(2)], xmm7   ; wk(2)=(42 52 62 72 43 53 63 73)
 161     movdqa      XMMWORD [wk(3)], xmm2   ; wk(3)=(44 54 64 74 45 55 65 75)
 162
 163     movdqa      xmm7, xmm0              ; transpose coefficients(phase 2)
 164     punpckldq   xmm0, xmm1              ; xmm0=(00 10 20 30 01 11 21 31)
 165     punpckhdq   xmm7, xmm1              ; xmm7=(02 12 22 32 03 13 23 33)
 166     movdqa      xmm2, xmm4              ; transpose coefficients(phase 2)
 167     punpckldq   xmm4, xmm5              ; xmm4=(04 14 24 34 05 15 25 35)
 168     punpckhdq   xmm2, xmm5              ; xmm2=(06 16 26 36 07 17 27 37)
 169
 170     movdqa      xmm1, xmm0              ; transpose coefficients(phase 3)
 171     punpcklqdq  xmm0, xmm6              ; xmm0=(00 10 20 30 40 50 60 70)=data0
 172     punpckhqdq  xmm1, xmm6              ; xmm1=(01 11 21 31 41 51 61 71)=data1
 173     movdqa      xmm5, xmm2              ; transpose coefficients(phase 3)
 174     punpcklqdq  xmm2, xmm3              ; xmm2=(06 16 26 36 46 56 66 76)=data6
 175     punpckhqdq  xmm5, xmm3              ; xmm5=(07 17 27 37 47 57 67 77)=data7
 176
 177     movdqa      xmm6, xmm1
 178     movdqa      xmm3, xmm0
 179     psubw       xmm1, xmm2              ; xmm1=data1-data6=tmp6
 180     psubw       xmm0, xmm5              ; xmm0=data0-data7=tmp7
 181     paddw       xmm6, xmm2              ; xmm6=data1+data6=tmp1
 182     paddw       xmm3, xmm5              ; xmm3=data0+data7=tmp0
 183
 184     movdqa      xmm2, XMMWORD [wk(2)]   ; xmm2=(42 52 62 72 43 53 63 73)
 185     movdqa      xmm5, XMMWORD [wk(3)]   ; xmm5=(44 54 64 74 45 55 65 75)
 186     movdqa      XMMWORD [wk(0)], xmm1   ; wk(0)=tmp6
 187     movdqa      XMMWORD [wk(1)], xmm0   ; wk(1)=tmp7
 188
 189     movdqa      xmm1, xmm7              ; transpose coefficients(phase 3)
 190     punpcklqdq  xmm7, xmm2              ; xmm7=(02 12 22 32 42 52 62 72)=data2
 191     punpckhqdq  xmm1, xmm2              ; xmm1=(03 13 23 33 43 53 63 73)=data3
 192     movdqa      xmm0, xmm4              ; transpose coefficients(phase 3)
 193     punpcklqdq  xmm4, xmm5              ; xmm4=(04 14 24 34 44 54 64 74)=data4
 194     punpckhqdq  xmm0, xmm5              ; xmm0=(05 15 25 35 45 55 65 75)=data5
 195
 196     movdqa      xmm2, xmm1
 197     movdqa      xmm5, xmm7
 198     paddw       xmm1, xmm4              ; xmm1=data3+data4=tmp3
 199     paddw       xmm7, xmm0              ; xmm7=data2+data5=tmp2
 200     psubw       xmm2, xmm4              ; xmm2=data3-data4=tmp4
 201     psubw       xmm5, xmm0              ; xmm5=data2-data5=tmp5
 202
 203     ; -- Even part
 204
 205     movdqa      xmm4, xmm3
 206     movdqa      xmm0, xmm6
 207     paddw       xmm3, xmm1              ; xmm3=tmp10
 208     paddw       xmm6, xmm7              ; xmm6=tmp11
 209     psubw       xmm4, xmm1              ; xmm4=tmp13
 210     psubw       xmm0, xmm7              ; xmm0=tmp12
 211
 212     movdqa      xmm1, xmm3
 213     paddw       xmm3, xmm6              ; xmm3=tmp10+tmp11
 214     psubw       xmm1, xmm6              ; xmm1=tmp10-tmp11
 215
 216     psllw       xmm3, PASS1_BITS        ; xmm3=data0
 217     psllw       xmm1, PASS1_BITS        ; xmm1=data4
 218
 219     movdqa      XMMWORD [wk(2)], xmm3   ; wk(2)=data0
 220     movdqa      XMMWORD [wk(3)], xmm1   ; wk(3)=data4
 221
 222     ; (Original)
 223     ; z1 = (tmp12 + tmp13) * 0.541196100;
 224     ; data2 = z1 + tmp13 * 0.765366865;
 225     ; data6 = z1 + tmp12 * -1.847759065;
 226     ;
 227     ; (This implementation)
 228     ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
 229     ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
 230
 231     movdqa      xmm7, xmm4              ; xmm4=tmp13
 232     movdqa      xmm6, xmm4
 233     punpcklwd   xmm7, xmm0              ; xmm0=tmp12
 234     punpckhwd   xmm6, xmm0
 235     movdqa      xmm4, xmm7
 236     movdqa      xmm0, xmm6
 237     pmaddwd     xmm7, [rel PW_F130_F054]   ; xmm7=data2L
 238     pmaddwd     xmm6, [rel PW_F130_F054]   ; xmm6=data2H
 239     pmaddwd     xmm4, [rel PW_F054_MF130]  ; xmm4=data6L
 240     pmaddwd     xmm0, [rel PW_F054_MF130]  ; xmm0=data6H
 241
 242     paddd       xmm7, [rel PD_DESCALE_P1]
 243     paddd       xmm6, [rel PD_DESCALE_P1]
 244     psrad       xmm7, DESCALE_P1
 245     psrad       xmm6, DESCALE_P1
 246     paddd       xmm4, [rel PD_DESCALE_P1]
 247     paddd       xmm0, [rel PD_DESCALE_P1]
 248     psrad       xmm4, DESCALE_P1
 249     psrad       xmm0, DESCALE_P1
 250
 251     packssdw    xmm7, xmm6              ; xmm7=data2
 252     packssdw    xmm4, xmm0              ; xmm4=data6
 253
 254     movdqa      XMMWORD [wk(4)], xmm7   ; wk(4)=data2
 255     movdqa      XMMWORD [wk(5)], xmm4   ; wk(5)=data6
 256
 257     ; -- Odd part
 258
 259     movdqa      xmm3, XMMWORD [wk(0)]   ; xmm3=tmp6
 260     movdqa      xmm1, XMMWORD [wk(1)]   ; xmm1=tmp7
 261
 262     movdqa      xmm6, xmm2              ; xmm2=tmp4
 263     movdqa      xmm0, xmm5              ; xmm5=tmp5
 264     paddw       xmm6, xmm3              ; xmm6=z3
 265     paddw       xmm0, xmm1              ; xmm0=z4
 266
 267     ; (Original)
 268     ; z5 = (z3 + z4) * 1.175875602;
 269     ; z3 = z3 * -1.961570560;  z4 = z4 * -0.390180644;
 270     ; z3 += z5;  z4 += z5;
 271     ;
 272     ; (This implementation)
 273     ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
 274     ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
 275
 276     movdqa      xmm7, xmm6
 277     movdqa      xmm4, xmm6
 278     punpcklwd   xmm7, xmm0
 279     punpckhwd   xmm4, xmm0
 280     movdqa      xmm6, xmm7
 281     movdqa      xmm0, xmm4
 282     pmaddwd     xmm7, [rel PW_MF078_F117]  ; xmm7=z3L
 283     pmaddwd     xmm4, [rel PW_MF078_F117]  ; xmm4=z3H
 284     pmaddwd     xmm6, [rel PW_F117_F078]   ; xmm6=z4L
 285     pmaddwd     xmm0, [rel PW_F117_F078]   ; xmm0=z4H
 286
 287     movdqa      XMMWORD [wk(0)], xmm7   ; wk(0)=z3L
 288     movdqa      XMMWORD [wk(1)], xmm4   ; wk(1)=z3H
 289
 290     ; (Original)
 291     ; z1 = tmp4 + tmp7;  z2 = tmp5 + tmp6;
 292     ; tmp4 = tmp4 * 0.298631336;  tmp5 = tmp5 * 2.053119869;
 293     ; tmp6 = tmp6 * 3.072711026;  tmp7 = tmp7 * 1.501321110;
 294     ; z1 = z1 * -0.899976223;  z2 = z2 * -2.562915447;
 295     ; data7 = tmp4 + z1 + z3;  data5 = tmp5 + z2 + z4;
 296     ; data3 = tmp6 + z2 + z3;  data1 = tmp7 + z1 + z4;
 297     ;
 298     ; (This implementation)
 299     ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
 300     ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
 301     ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
 302     ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
 303     ; data7 = tmp4 + z3;  data5 = tmp5 + z4;
 304     ; data3 = tmp6 + z3;  data1 = tmp7 + z4;
 305
 306     movdqa      xmm7, xmm2
 307     movdqa      xmm4, xmm2
 308     punpcklwd   xmm7, xmm1
 309     punpckhwd   xmm4, xmm1
 310     movdqa      xmm2, xmm7
 311     movdqa      xmm1, xmm4
 312     pmaddwd     xmm7, [rel PW_MF060_MF089]  ; xmm7=tmp4L
 313     pmaddwd     xmm4, [rel PW_MF060_MF089]  ; xmm4=tmp4H
 314     pmaddwd     xmm2, [rel PW_MF089_F060]   ; xmm2=tmp7L
 315     pmaddwd     xmm1, [rel PW_MF089_F060]   ; xmm1=tmp7H
 316
 317     paddd       xmm7, XMMWORD [wk(0)]   ; xmm7=data7L
 318     paddd       xmm4, XMMWORD [wk(1)]   ; xmm4=data7H
 319     paddd       xmm2, xmm6              ; xmm2=data1L
 320     paddd       xmm1, xmm0              ; xmm1=data1H
 321
 322     paddd       xmm7, [rel PD_DESCALE_P1]
 323     paddd       xmm4, [rel PD_DESCALE_P1]
 324     psrad       xmm7, DESCALE_P1
 325     psrad       xmm4, DESCALE_P1
 326     paddd       xmm2, [rel PD_DESCALE_P1]
 327     paddd       xmm1, [rel PD_DESCALE_P1]
 328     psrad       xmm2, DESCALE_P1
 329     psrad       xmm1, DESCALE_P1
 330
 331     packssdw    xmm7, xmm4              ; xmm7=data7
 332     packssdw    xmm2, xmm1              ; xmm2=data1
 333
 334     movdqa      xmm4, xmm5
 335     movdqa      xmm1, xmm5
 336     punpcklwd   xmm4, xmm3
 337     punpckhwd   xmm1, xmm3
 338     movdqa      xmm5, xmm4
 339     movdqa      xmm3, xmm1
 340     pmaddwd     xmm4, [rel PW_MF050_MF256]  ; xmm4=tmp5L
 341     pmaddwd     xmm1, [rel PW_MF050_MF256]  ; xmm1=tmp5H
 342     pmaddwd     xmm5, [rel PW_MF256_F050]   ; xmm5=tmp6L
 343     pmaddwd     xmm3, [rel PW_MF256_F050]   ; xmm3=tmp6H
 344
 345     paddd       xmm4, xmm6              ; xmm4=data5L
 346     paddd       xmm1, xmm0              ; xmm1=data5H
 347     paddd       xmm5, XMMWORD [wk(0)]   ; xmm5=data3L
 348     paddd       xmm3, XMMWORD [wk(1)]   ; xmm3=data3H
 349
 350     paddd       xmm4, [rel PD_DESCALE_P1]
 351     paddd       xmm1, [rel PD_DESCALE_P1]
 352     psrad       xmm4, DESCALE_P1
 353     psrad       xmm1, DESCALE_P1
 354     paddd       xmm5, [rel PD_DESCALE_P1]
 355     paddd       xmm3, [rel PD_DESCALE_P1]
 356     psrad       xmm5, DESCALE_P1
 357     psrad       xmm3, DESCALE_P1
 358
 359     packssdw    xmm4, xmm1              ; xmm4=data5
 360     packssdw    xmm5, xmm3              ; xmm5=data3
 361
 362     ; ---- Pass 2: process columns.
 363
 364     movdqa      xmm6, XMMWORD [wk(2)]   ; xmm6=col0
 365     movdqa      xmm0, XMMWORD [wk(4)]   ; xmm0=col2
 366
 367     ; xmm6=(00 10 20 30 40 50 60 70), xmm0=(02 12 22 32 42 52 62 72)
 368     ; xmm2=(01 11 21 31 41 51 61 71), xmm5=(03 13 23 33 43 53 63 73)
 369
 370     movdqa      xmm1, xmm6              ; transpose coefficients(phase 1)
 371     punpcklwd   xmm6, xmm2              ; xmm6=(00 01 10 11 20 21 30 31)
 372     punpckhwd   xmm1, xmm2              ; xmm1=(40 41 50 51 60 61 70 71)
 373     movdqa      xmm3, xmm0              ; transpose coefficients(phase 1)
 374     punpcklwd   xmm0, xmm5              ; xmm0=(02 03 12 13 22 23 32 33)
 375     punpckhwd   xmm3, xmm5              ; xmm3=(42 43 52 53 62 63 72 73)
 376
 377     movdqa      xmm2, XMMWORD [wk(3)]   ; xmm2=col4
 378     movdqa      xmm5, XMMWORD [wk(5)]   ; xmm5=col6
 379
 380     ; xmm2=(04 14 24 34 44 54 64 74), xmm5=(06 16 26 36 46 56 66 76)
 381     ; xmm4=(05 15 25 35 45 55 65 75), xmm7=(07 17 27 37 47 57 67 77)
 382
 383     movdqa      XMMWORD [wk(0)], xmm0   ; wk(0)=(02 03 12 13 22 23 32 33)
 384     movdqa      XMMWORD [wk(1)], xmm3   ; wk(1)=(42 43 52 53 62 63 72 73)
 385
 386     movdqa      xmm0, xmm2              ; transpose coefficients(phase 1)
 387     punpcklwd   xmm2, xmm4              ; xmm2=(04 05 14 15 24 25 34 35)
 388     punpckhwd   xmm0, xmm4              ; xmm0=(44 45 54 55 64 65 74 75)
 389     movdqa      xmm3, xmm5              ; transpose coefficients(phase 1)
 390     punpcklwd   xmm5, xmm7              ; xmm5=(06 07 16 17 26 27 36 37)
 391     punpckhwd   xmm3, xmm7              ; xmm3=(46 47 56 57 66 67 76 77)
 392
 393     movdqa      xmm4, xmm2              ; transpose coefficients(phase 2)
 394     punpckldq   xmm2, xmm5              ; xmm2=(04 05 06 07 14 15 16 17)
 395     punpckhdq   xmm4, xmm5              ; xmm4=(24 25 26 27 34 35 36 37)
 396     movdqa      xmm7, xmm0              ; transpose coefficients(phase 2)
 397     punpckldq   xmm0, xmm3              ; xmm0=(44 45 46 47 54 55 56 57)
 398     punpckhdq   xmm7, xmm3              ; xmm7=(64 65 66 67 74 75 76 77)
 399
 400     movdqa      xmm5, XMMWORD [wk(0)]   ; xmm5=(02 03 12 13 22 23 32 33)
 401     movdqa      xmm3, XMMWORD [wk(1)]   ; xmm3=(42 43 52 53 62 63 72 73)
 402     movdqa      XMMWORD [wk(2)], xmm4   ; wk(2)=(24 25 26 27 34 35 36 37)
 403     movdqa      XMMWORD [wk(3)], xmm0   ; wk(3)=(44 45 46 47 54 55 56 57)
 404
 405     movdqa      xmm4, xmm6              ; transpose coefficients(phase 2)
 406     punpckldq   xmm6, xmm5              ; xmm6=(00 01 02 03 10 11 12 13)
 407     punpckhdq   xmm4, xmm5              ; xmm4=(20 21 22 23 30 31 32 33)
 408     movdqa      xmm0, xmm1              ; transpose coefficients(phase 2)
 409     punpckldq   xmm1, xmm3              ; xmm1=(40 41 42 43 50 51 52 53)
 410     punpckhdq   xmm0, xmm3              ; xmm0=(60 61 62 63 70 71 72 73)
 411
 412     movdqa      xmm5, xmm6              ; transpose coefficients(phase 3)
 413     punpcklqdq  xmm6, xmm2              ; xmm6=(00 01 02 03 04 05 06 07)=data0
 414     punpckhqdq  xmm5, xmm2              ; xmm5=(10 11 12 13 14 15 16 17)=data1
 415     movdqa      xmm3, xmm0              ; transpose coefficients(phase 3)
 416     punpcklqdq  xmm0, xmm7              ; xmm0=(60 61 62 63 64 65 66 67)=data6
 417     punpckhqdq  xmm3, xmm7              ; xmm3=(70 71 72 73 74 75 76 77)=data7
 418
 419     movdqa      xmm2, xmm5
 420     movdqa      xmm7, xmm6
 421     psubw       xmm5, xmm0              ; xmm5=data1-data6=tmp6
 422     psubw       xmm6, xmm3              ; xmm6=data0-data7=tmp7
 423     paddw       xmm2, xmm0              ; xmm2=data1+data6=tmp1
 424     paddw       xmm7, xmm3              ; xmm7=data0+data7=tmp0
 425
 426     movdqa      xmm0, XMMWORD [wk(2)]   ; xmm0=(24 25 26 27 34 35 36 37)
 427     movdqa      xmm3, XMMWORD [wk(3)]   ; xmm3=(44 45 46 47 54 55 56 57)
 428     movdqa      XMMWORD [wk(0)], xmm5   ; wk(0)=tmp6
 429     movdqa      XMMWORD [wk(1)], xmm6   ; wk(1)=tmp7
 430
 431     movdqa      xmm5, xmm4              ; transpose coefficients(phase 3)
 432     punpcklqdq  xmm4, xmm0              ; xmm4=(20 21 22 23 24 25 26 27)=data2
 433     punpckhqdq  xmm5, xmm0              ; xmm5=(30 31 32 33 34 35 36 37)=data3
 434     movdqa      xmm6, xmm1              ; transpose coefficients(phase 3)
 435     punpcklqdq  xmm1, xmm3              ; xmm1=(40 41 42 43 44 45 46 47)=data4
 436     punpckhqdq  xmm6, xmm3              ; xmm6=(50 51 52 53 54 55 56 57)=data5
 437
 438     movdqa      xmm0, xmm5
 439     movdqa      xmm3, xmm4
 440     paddw       xmm5, xmm1              ; xmm5=data3+data4=tmp3
 441     paddw       xmm4, xmm6              ; xmm4=data2+data5=tmp2
 442     psubw       xmm0, xmm1              ; xmm0=data3-data4=tmp4
 443     psubw       xmm3, xmm6              ; xmm3=data2-data5=tmp5
 444
 445     ; -- Even part
 446
 447     movdqa      xmm1, xmm7
 448     movdqa      xmm6, xmm2
 449     paddw       xmm7, xmm5              ; xmm7=tmp10
 450     paddw       xmm2, xmm4              ; xmm2=tmp11
 451     psubw       xmm1, xmm5              ; xmm1=tmp13
 452     psubw       xmm6, xmm4              ; xmm6=tmp12
 453
 454     movdqa      xmm5, xmm7
 455     paddw       xmm7, xmm2              ; xmm7=tmp10+tmp11
 456     psubw       xmm5, xmm2              ; xmm5=tmp10-tmp11
 457
 458     paddw       xmm7, [rel PW_DESCALE_P2X]
 459     paddw       xmm5, [rel PW_DESCALE_P2X]
 460     psraw       xmm7, PASS1_BITS        ; xmm7=data0
 461     psraw       xmm5, PASS1_BITS        ; xmm5=data4
 462
 463     movdqa      XMMWORD [XMMBLOCK(0,0,rdx,SIZEOF_DCTELEM)], xmm7
 464     movdqa      XMMWORD [XMMBLOCK(4,0,rdx,SIZEOF_DCTELEM)], xmm5
 465
 466     ; (Original)
 467     ; z1 = (tmp12 + tmp13) * 0.541196100;
 468     ; data2 = z1 + tmp13 * 0.765366865;
 469     ; data6 = z1 + tmp12 * -1.847759065;
 470     ;
 471     ; (This implementation)
 472     ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
 473     ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
 474
 475     movdqa      xmm4, xmm1              ; xmm1=tmp13
 476     movdqa      xmm2, xmm1
 477     punpcklwd   xmm4, xmm6              ; xmm6=tmp12
 478     punpckhwd   xmm2, xmm6
 479     movdqa      xmm1, xmm4
 480     movdqa      xmm6, xmm2
 481     pmaddwd     xmm4, [rel PW_F130_F054]   ; xmm4=data2L
 482     pmaddwd     xmm2, [rel PW_F130_F054]   ; xmm2=data2H
 483     pmaddwd     xmm1, [rel PW_F054_MF130]  ; xmm1=data6L
 484     pmaddwd     xmm6, [rel PW_F054_MF130]  ; xmm6=data6H
 485
 486     paddd       xmm4, [rel PD_DESCALE_P2]
 487     paddd       xmm2, [rel PD_DESCALE_P2]
 488     psrad       xmm4, DESCALE_P2
 489     psrad       xmm2, DESCALE_P2
 490     paddd       xmm1, [rel PD_DESCALE_P2]
 491     paddd       xmm6, [rel PD_DESCALE_P2]
 492     psrad       xmm1, DESCALE_P2
 493     psrad       xmm6, DESCALE_P2
 494
 495     packssdw    xmm4, xmm2              ; xmm4=data2
 496     packssdw    xmm1, xmm6              ; xmm1=data6
 497
 498     movdqa      XMMWORD [XMMBLOCK(2,0,rdx,SIZEOF_DCTELEM)], xmm4
 499     movdqa      XMMWORD [XMMBLOCK(6,0,rdx,SIZEOF_DCTELEM)], xmm1
 500
 501     ; -- Odd part
 502
 503     movdqa      xmm7, XMMWORD [wk(0)]   ; xmm7=tmp6
 504     movdqa      xmm5, XMMWORD [wk(1)]   ; xmm5=tmp7
 505
 506     movdqa      xmm2, xmm0              ; xmm0=tmp4
 507     movdqa      xmm6, xmm3              ; xmm3=tmp5
 508     paddw       xmm2, xmm7              ; xmm2=z3
 509     paddw       xmm6, xmm5              ; xmm6=z4
 510
 511     ; (Original)
 512     ; z5 = (z3 + z4) * 1.175875602;
 513     ; z3 = z3 * -1.961570560;  z4 = z4 * -0.390180644;
 514     ; z3 += z5;  z4 += z5;
 515     ;
 516     ; (This implementation)
 517     ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
 518     ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
 519
 520     movdqa      xmm4, xmm2
 521     movdqa      xmm1, xmm2
 522     punpcklwd   xmm4, xmm6
 523     punpckhwd   xmm1, xmm6
 524     movdqa      xmm2, xmm4
 525     movdqa      xmm6, xmm1
 526     pmaddwd     xmm4, [rel PW_MF078_F117]  ; xmm4=z3L
 527     pmaddwd     xmm1, [rel PW_MF078_F117]  ; xmm1=z3H
 528     pmaddwd     xmm2, [rel PW_F117_F078]   ; xmm2=z4L
 529     pmaddwd     xmm6, [rel PW_F117_F078]   ; xmm6=z4H
 530
 531     movdqa      XMMWORD [wk(0)], xmm4   ; wk(0)=z3L
 532     movdqa      XMMWORD [wk(1)], xmm1   ; wk(1)=z3H
 533
 534     ; (Original)
 535     ; z1 = tmp4 + tmp7;  z2 = tmp5 + tmp6;
 536     ; tmp4 = tmp4 * 0.298631336;  tmp5 = tmp5 * 2.053119869;
 537     ; tmp6 = tmp6 * 3.072711026;  tmp7 = tmp7 * 1.501321110;
 538     ; z1 = z1 * -0.899976223;  z2 = z2 * -2.562915447;
 539     ; data7 = tmp4 + z1 + z3;  data5 = tmp5 + z2 + z4;
 540     ; data3 = tmp6 + z2 + z3;  data1 = tmp7 + z1 + z4;
 541     ;
 542     ; (This implementation)
 543     ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
 544     ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
 545     ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
 546     ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
 547     ; data7 = tmp4 + z3;  data5 = tmp5 + z4;
 548     ; data3 = tmp6 + z3;  data1 = tmp7 + z4;
 549
 550     movdqa      xmm4, xmm0
 551     movdqa      xmm1, xmm0
 552     punpcklwd   xmm4, xmm5
 553     punpckhwd   xmm1, xmm5
 554     movdqa      xmm0, xmm4
 555     movdqa      xmm5, xmm1
 556     pmaddwd     xmm4, [rel PW_MF060_MF089]  ; xmm4=tmp4L
 557     pmaddwd     xmm1, [rel PW_MF060_MF089]  ; xmm1=tmp4H
 558     pmaddwd     xmm0, [rel PW_MF089_F060]   ; xmm0=tmp7L
 559     pmaddwd     xmm5, [rel PW_MF089_F060]   ; xmm5=tmp7H
 560
 561     paddd       xmm4,  XMMWORD [wk(0)]  ; xmm4=data7L
 562     paddd       xmm1,  XMMWORD [wk(1)]  ; xmm1=data7H
 563     paddd       xmm0, xmm2              ; xmm0=data1L
 564     paddd       xmm5, xmm6              ; xmm5=data1H
 565
 566     paddd       xmm4, [rel PD_DESCALE_P2]
 567     paddd       xmm1, [rel PD_DESCALE_P2]
 568     psrad       xmm4, DESCALE_P2
 569     psrad       xmm1, DESCALE_P2
 570     paddd       xmm0, [rel PD_DESCALE_P2]
 571     paddd       xmm5, [rel PD_DESCALE_P2]
 572     psrad       xmm0, DESCALE_P2
 573     psrad       xmm5, DESCALE_P2
 574
 575     packssdw    xmm4, xmm1              ; xmm4=data7
 576     packssdw    xmm0, xmm5              ; xmm0=data1
 577
 578     movdqa      XMMWORD [XMMBLOCK(7,0,rdx,SIZEOF_DCTELEM)], xmm4
 579     movdqa      XMMWORD [XMMBLOCK(1,0,rdx,SIZEOF_DCTELEM)], xmm0
 580
 581     movdqa      xmm1, xmm3
 582     movdqa      xmm5, xmm3
 583     punpcklwd   xmm1, xmm7
 584     punpckhwd   xmm5, xmm7
 585     movdqa      xmm3, xmm1
 586     movdqa      xmm7, xmm5
 587     pmaddwd     xmm1, [rel PW_MF050_MF256]  ; xmm1=tmp5L
 588     pmaddwd     xmm5, [rel PW_MF050_MF256]  ; xmm5=tmp5H
 589     pmaddwd     xmm3, [rel PW_MF256_F050]   ; xmm3=tmp6L
 590     pmaddwd     xmm7, [rel PW_MF256_F050]   ; xmm7=tmp6H
 591
 592     paddd       xmm1, xmm2              ; xmm1=data5L
 593     paddd       xmm5, xmm6              ; xmm5=data5H
 594     paddd       xmm3, XMMWORD [wk(0)]   ; xmm3=data3L
 595     paddd       xmm7, XMMWORD [wk(1)]   ; xmm7=data3H
 596
 597     paddd       xmm1, [rel PD_DESCALE_P2]
 598     paddd       xmm5, [rel PD_DESCALE_P2]
 599     psrad       xmm1, DESCALE_P2
 600     psrad       xmm5, DESCALE_P2
 601     paddd       xmm3, [rel PD_DESCALE_P2]
 602     paddd       xmm7, [rel PD_DESCALE_P2]
 603     psrad       xmm3, DESCALE_P2
 604     psrad       xmm7, DESCALE_P2
 605
 606     packssdw    xmm1, xmm5              ; xmm1=data5
 607     packssdw    xmm3, xmm7              ; xmm3=data3
 608
 609     movdqa      XMMWORD [XMMBLOCK(5,0,rdx,SIZEOF_DCTELEM)], xmm1
 610     movdqa      XMMWORD [XMMBLOCK(3,0,rdx,SIZEOF_DCTELEM)], xmm3
 611
 612     uncollect_args 1
 613     lea         rsp, [rbp-8]
 614     pop         r15
 615     pop         rbp
 616     ret
 617
 618 ; For some reason, the OS X linker does not honor the request to align the
 619 ; segment unless we do this.
 620     align       32