simd/x86_64/jfdctint-avx2.asm

   1 ;
   2 ; jfdctint.asm - accurate integer FDCT (64-bit AVX2)
   3 ;
   4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
   5 ; Copyright (C) 2009, 2016, 2018, 2020, D. R. Commander.
   6 ;
   7 ; Based on the x86 SIMD extension for IJG JPEG library
   8 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
   9 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
  10 ;
  11 ; This file should be assembled with NASM (Netwide Assembler),
  12 ; can *not* be assembled with Microsoft's MASM or any compatible
  13 ; assembler (including Borland's Turbo Assembler).
  14 ; NASM is available from http://nasm.sourceforge.net/ or
  15 ; http://sourceforge.net/project/showfiles.php?group_id=6208
  16 ;
  17 ; This file contains a slower but more accurate integer implementation of the
  18 ; forward DCT (Discrete Cosine Transform). The following code is based
  19 ; directly on the IJG's original jfdctint.c; see the jfdctint.c for
  20 ; more details.
  21
  22 %include "jsimdext.inc"
  23 %include "jdct.inc"
  24
  25 ; --------------------------------------------------------------------------
  26
  27 %define CONST_BITS  13
  28 %define PASS1_BITS  2
  29
  30 %define DESCALE_P1  (CONST_BITS - PASS1_BITS)
  31 %define DESCALE_P2  (CONST_BITS + PASS1_BITS)
  32
  33 %if CONST_BITS == 13
  34 F_0_298 equ  2446  ; FIX(0.298631336)
  35 F_0_390 equ  3196  ; FIX(0.390180644)
  36 F_0_541 equ  4433  ; FIX(0.541196100)
  37 F_0_765 equ  6270  ; FIX(0.765366865)
  38 F_0_899 equ  7373  ; FIX(0.899976223)
  39 F_1_175 equ  9633  ; FIX(1.175875602)
  40 F_1_501 equ 12299  ; FIX(1.501321110)
  41 F_1_847 equ 15137  ; FIX(1.847759065)
  42 F_1_961 equ 16069  ; FIX(1.961570560)
  43 F_2_053 equ 16819  ; FIX(2.053119869)
  44 F_2_562 equ 20995  ; FIX(2.562915447)
  45 F_3_072 equ 25172  ; FIX(3.072711026)
  46 %else
  47 ; NASM cannot do compile-time arithmetic on floating-point constants.
  48 %define DESCALE(x, n)  (((x) + (1 << ((n) - 1))) >> (n))
  49 F_0_298 equ DESCALE( 320652955, 30 - CONST_BITS)  ; FIX(0.298631336)
  50 F_0_390 equ DESCALE( 418953276, 30 - CONST_BITS)  ; FIX(0.390180644)
  51 F_0_541 equ DESCALE( 581104887, 30 - CONST_BITS)  ; FIX(0.541196100)
  52 F_0_765 equ DESCALE( 821806413, 30 - CONST_BITS)  ; FIX(0.765366865)
  53 F_0_899 equ DESCALE( 966342111, 30 - CONST_BITS)  ; FIX(0.899976223)
  54 F_1_175 equ DESCALE(1262586813, 30 - CONST_BITS)  ; FIX(1.175875602)
  55 F_1_501 equ DESCALE(1612031267, 30 - CONST_BITS)  ; FIX(1.501321110)
  56 F_1_847 equ DESCALE(1984016188, 30 - CONST_BITS)  ; FIX(1.847759065)
  57 F_1_961 equ DESCALE(2106220350, 30 - CONST_BITS)  ; FIX(1.961570560)
  58 F_2_053 equ DESCALE(2204520673, 30 - CONST_BITS)  ; FIX(2.053119869)
  59 F_2_562 equ DESCALE(2751909506, 30 - CONST_BITS)  ; FIX(2.562915447)
  60 F_3_072 equ DESCALE(3299298341, 30 - CONST_BITS)  ; FIX(3.072711026)
  61 %endif
  62
  63 ; --------------------------------------------------------------------------
  64 ; In-place 8x8x16-bit matrix transpose using AVX2 instructions
  65 ; %1-%4: Input/output registers
  66 ; %5-%8: Temp registers
  67
  68 %macro dotranspose 8
  69     ; %1=(00 01 02 03 04 05 06 07  40 41 42 43 44 45 46 47)
  70     ; %2=(10 11 12 13 14 15 16 17  50 51 52 53 54 55 56 57)
  71     ; %3=(20 21 22 23 24 25 26 27  60 61 62 63 64 65 66 67)
  72     ; %4=(30 31 32 33 34 35 36 37  70 71 72 73 74 75 76 77)
  73
  74     vpunpcklwd  %5, %1, %2
  75     vpunpckhwd  %6, %1, %2
  76     vpunpcklwd  %7, %3, %4
  77     vpunpckhwd  %8, %3, %4
  78     ; transpose coefficients(phase 1)
  79     ; %5=(00 10 01 11 02 12 03 13  40 50 41 51 42 52 43 53)
  80     ; %6=(04 14 05 15 06 16 07 17  44 54 45 55 46 56 47 57)
  81     ; %7=(20 30 21 31 22 32 23 33  60 70 61 71 62 72 63 73)
  82     ; %8=(24 34 25 35 26 36 27 37  64 74 65 75 66 76 67 77)
  83
  84     vpunpckldq  %1, %5, %7
  85     vpunpckhdq  %2, %5, %7
  86     vpunpckldq  %3, %6, %8
  87     vpunpckhdq  %4, %6, %8
  88     ; transpose coefficients(phase 2)
  89     ; %1=(00 10 20 30 01 11 21 31  40 50 60 70 41 51 61 71)
  90     ; %2=(02 12 22 32 03 13 23 33  42 52 62 72 43 53 63 73)
  91     ; %3=(04 14 24 34 05 15 25 35  44 54 64 74 45 55 65 75)
  92     ; %4=(06 16 26 36 07 17 27 37  46 56 66 76 47 57 67 77)
  93
  94     vpermq      %1, %1, 0x8D
  95     vpermq      %2, %2, 0x8D
  96     vpermq      %3, %3, 0xD8
  97     vpermq      %4, %4, 0xD8
  98     ; transpose coefficients(phase 3)
  99     ; %1=(01 11 21 31 41 51 61 71  00 10 20 30 40 50 60 70)
 100     ; %2=(03 13 23 33 43 53 63 73  02 12 22 32 42 52 62 72)
 101     ; %3=(04 14 24 34 44 54 64 74  05 15 25 35 45 55 65 75)
 102     ; %4=(06 16 26 36 46 56 66 76  07 17 27 37 47 57 67 77)
 103 %endmacro
 104
 105 ; --------------------------------------------------------------------------
 106 ; In-place 8x8x16-bit accurate integer forward DCT using AVX2 instructions
 107 ; %1-%4: Input/output registers
 108 ; %5-%8: Temp registers
 109 ; %9:    Pass (1 or 2)
 110
 111 %macro dodct 9
 112     vpsubw      %5, %1, %4              ; %5=data1_0-data6_7=tmp6_7
 113     vpaddw      %6, %1, %4              ; %6=data1_0+data6_7=tmp1_0
 114     vpaddw      %7, %2, %3              ; %7=data3_2+data4_5=tmp3_2
 115     vpsubw      %8, %2, %3              ; %8=data3_2-data4_5=tmp4_5
 116
 117     ; -- Even part
 118
 119     vperm2i128  %6, %6, %6, 0x01        ; %6=tmp0_1
 120     vpaddw      %1, %6, %7              ; %1=tmp0_1+tmp3_2=tmp10_11
 121     vpsubw      %6, %6, %7              ; %6=tmp0_1-tmp3_2=tmp13_12
 122
 123     vperm2i128  %7, %1, %1, 0x01        ; %7=tmp11_10
 124     vpsignw     %1, %1, [rel PW_1_NEG1]  ; %1=tmp10_neg11
 125     vpaddw      %7, %7, %1              ; %7=(tmp10+tmp11)_(tmp10-tmp11)
 126 %if %9 == 1
 127     vpsllw      %1, %7, PASS1_BITS      ; %1=data0_4
 128 %else
 129     vpaddw      %7, %7, [rel PW_DESCALE_P2X]
 130     vpsraw      %1, %7, PASS1_BITS      ; %1=data0_4
 131 %endif
 132
 133     ; (Original)
 134     ; z1 = (tmp12 + tmp13) * 0.541196100;
 135     ; data2 = z1 + tmp13 * 0.765366865;
 136     ; data6 = z1 + tmp12 * -1.847759065;
 137     ;
 138     ; (This implementation)
 139     ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
 140     ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
 141
 142     vperm2i128  %7, %6, %6, 0x01        ; %7=tmp12_13
 143     vpunpcklwd  %2, %6, %7
 144     vpunpckhwd  %6, %6, %7
 145     vpmaddwd    %2, %2, [rel PW_F130_F054_MF130_F054]  ; %2=data2_6L
 146     vpmaddwd    %6, %6, [rel PW_F130_F054_MF130_F054]  ; %6=data2_6H
 147
 148     vpaddd      %2, %2, [rel PD_DESCALE_P %+ %9]
 149     vpaddd      %6, %6, [rel PD_DESCALE_P %+ %9]
 150     vpsrad      %2, %2, DESCALE_P %+ %9
 151     vpsrad      %6, %6, DESCALE_P %+ %9
 152
 153     vpackssdw   %3, %2, %6              ; %6=data2_6
 154
 155     ; -- Odd part
 156
 157     vpaddw      %7, %8, %5              ; %7=tmp4_5+tmp6_7=z3_4
 158
 159     ; (Original)
 160     ; z5 = (z3 + z4) * 1.175875602;
 161     ; z3 = z3 * -1.961570560;  z4 = z4 * -0.390180644;
 162     ; z3 += z5;  z4 += z5;
 163     ;
 164     ; (This implementation)
 165     ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
 166     ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
 167
 168     vperm2i128  %2, %7, %7, 0x01        ; %2=z4_3
 169     vpunpcklwd  %6, %7, %2
 170     vpunpckhwd  %7, %7, %2
 171     vpmaddwd    %6, %6, [rel PW_MF078_F117_F078_F117]  ; %6=z3_4L
 172     vpmaddwd    %7, %7, [rel PW_MF078_F117_F078_F117]  ; %7=z3_4H
 173
 174     ; (Original)
 175     ; z1 = tmp4 + tmp7;  z2 = tmp5 + tmp6;
 176     ; tmp4 = tmp4 * 0.298631336;  tmp5 = tmp5 * 2.053119869;
 177     ; tmp6 = tmp6 * 3.072711026;  tmp7 = tmp7 * 1.501321110;
 178     ; z1 = z1 * -0.899976223;  z2 = z2 * -2.562915447;
 179     ; data7 = tmp4 + z1 + z3;  data5 = tmp5 + z2 + z4;
 180     ; data3 = tmp6 + z2 + z3;  data1 = tmp7 + z1 + z4;
 181     ;
 182     ; (This implementation)
 183     ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
 184     ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
 185     ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
 186     ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
 187     ; data7 = tmp4 + z3;  data5 = tmp5 + z4;
 188     ; data3 = tmp6 + z3;  data1 = tmp7 + z4;
 189
 190     vperm2i128  %4, %5, %5, 0x01        ; %4=tmp7_6
 191     vpunpcklwd  %2, %8, %4
 192     vpunpckhwd  %4, %8, %4
 193     vpmaddwd    %2, %2, [rel PW_MF060_MF089_MF050_MF256]  ; %2=tmp4_5L
 194     vpmaddwd    %4, %4, [rel PW_MF060_MF089_MF050_MF256]  ; %4=tmp4_5H
 195
 196     vpaddd      %2, %2, %6              ; %2=data7_5L
 197     vpaddd      %4, %4, %7              ; %4=data7_5H
 198
 199     vpaddd      %2, %2, [rel PD_DESCALE_P %+ %9]
 200     vpaddd      %4, %4, [rel PD_DESCALE_P %+ %9]
 201     vpsrad      %2, %2, DESCALE_P %+ %9
 202     vpsrad      %4, %4, DESCALE_P %+ %9
 203
 204     vpackssdw   %4, %2, %4              ; %4=data7_5
 205
 206     vperm2i128  %2, %8, %8, 0x01        ; %2=tmp5_4
 207     vpunpcklwd  %8, %5, %2
 208     vpunpckhwd  %5, %5, %2
 209     vpmaddwd    %8, %8, [rel PW_F050_MF256_F060_MF089]  ; %8=tmp6_7L
 210     vpmaddwd    %5, %5, [rel PW_F050_MF256_F060_MF089]  ; %5=tmp6_7H
 211
 212     vpaddd      %8, %8, %6              ; %8=data3_1L
 213     vpaddd      %5, %5, %7              ; %5=data3_1H
 214
 215     vpaddd      %8, %8, [rel PD_DESCALE_P %+ %9]
 216     vpaddd      %5, %5, [rel PD_DESCALE_P %+ %9]
 217     vpsrad      %8, %8, DESCALE_P %+ %9
 218     vpsrad      %5, %5, DESCALE_P %+ %9
 219
 220     vpackssdw   %2, %8, %5              ; %2=data3_1
 221 %endmacro
 222
 223 ; --------------------------------------------------------------------------
 224     SECTION     SEG_CONST
 225
 226     alignz      32
 227     GLOBAL_DATA(jconst_fdct_islow_avx2)
 228
 229 EXTN(jconst_fdct_islow_avx2):
 230
 231 PW_F130_F054_MF130_F054    times 4  dw  (F_0_541 + F_0_765),  F_0_541
 232                            times 4  dw  (F_0_541 - F_1_847),  F_0_541
 233 PW_MF078_F117_F078_F117    times 4  dw  (F_1_175 - F_1_961),  F_1_175
 234                            times 4  dw  (F_1_175 - F_0_390),  F_1_175
 235 PW_MF060_MF089_MF050_MF256 times 4  dw  (F_0_298 - F_0_899), -F_0_899
 236                            times 4  dw  (F_2_053 - F_2_562), -F_2_562
 237 PW_F050_MF256_F060_MF089   times 4  dw  (F_3_072 - F_2_562), -F_2_562
 238                            times 4  dw  (F_1_501 - F_0_899), -F_0_899
 239 PD_DESCALE_P1              times 8  dd  1 << (DESCALE_P1 - 1)
 240 PD_DESCALE_P2              times 8  dd  1 << (DESCALE_P2 - 1)
 241 PW_DESCALE_P2X             times 16 dw  1 << (PASS1_BITS - 1)
 242 PW_1_NEG1                  times 8  dw  1
 243                            times 8  dw -1
 244
 245     alignz      32
 246
 247 ; --------------------------------------------------------------------------
 248     SECTION     SEG_TEXT
 249     BITS        64
 250 ;
 251 ; Perform the forward DCT on one block of samples.
 252 ;
 253 ; GLOBAL(void)
 254 ; jsimd_fdct_islow_avx2(DCTELEM *data)
 255 ;
 256
 257 ; r10 = DCTELEM *data
 258
 259     align       32
 260     GLOBAL_FUNCTION(jsimd_fdct_islow_avx2)
 261
 262 EXTN(jsimd_fdct_islow_avx2):
 263     push        rbp
 264     mov         rbp, rsp
 265     collect_args 1
 266
 267     ; ---- Pass 1: process rows.
 268
 269     vmovdqu     ymm4, YMMWORD [YMMBLOCK(0,0,r10,SIZEOF_DCTELEM)]
 270     vmovdqu     ymm5, YMMWORD [YMMBLOCK(2,0,r10,SIZEOF_DCTELEM)]
 271     vmovdqu     ymm6, YMMWORD [YMMBLOCK(4,0,r10,SIZEOF_DCTELEM)]
 272     vmovdqu     ymm7, YMMWORD [YMMBLOCK(6,0,r10,SIZEOF_DCTELEM)]
 273     ; ymm4=(00 01 02 03 04 05 06 07  10 11 12 13 14 15 16 17)
 274     ; ymm5=(20 21 22 23 24 25 26 27  30 31 32 33 34 35 36 37)
 275     ; ymm6=(40 41 42 43 44 45 46 47  50 51 52 53 54 55 56 57)
 276     ; ymm7=(60 61 62 63 64 65 66 67  70 71 72 73 74 75 76 77)
 277
 278     vperm2i128  ymm0, ymm4, ymm6, 0x20
 279     vperm2i128  ymm1, ymm4, ymm6, 0x31
 280     vperm2i128  ymm2, ymm5, ymm7, 0x20
 281     vperm2i128  ymm3, ymm5, ymm7, 0x31
 282     ; ymm0=(00 01 02 03 04 05 06 07  40 41 42 43 44 45 46 47)
 283     ; ymm1=(10 11 12 13 14 15 16 17  50 51 52 53 54 55 56 57)
 284     ; ymm2=(20 21 22 23 24 25 26 27  60 61 62 63 64 65 66 67)
 285     ; ymm3=(30 31 32 33 34 35 36 37  70 71 72 73 74 75 76 77)
 286
 287     dotranspose ymm0, ymm1, ymm2, ymm3, ymm4, ymm5, ymm6, ymm7
 288
 289     dodct       ymm0, ymm1, ymm2, ymm3, ymm4, ymm5, ymm6, ymm7, 1
 290     ; ymm0=data0_4, ymm1=data3_1, ymm2=data2_6, ymm3=data7_5
 291
 292     ; ---- Pass 2: process columns.
 293
 294     vperm2i128  ymm4, ymm1, ymm3, 0x20  ; ymm4=data3_7
 295     vperm2i128  ymm1, ymm1, ymm3, 0x31  ; ymm1=data1_5
 296
 297     dotranspose ymm0, ymm1, ymm2, ymm4, ymm3, ymm5, ymm6, ymm7
 298
 299     dodct       ymm0, ymm1, ymm2, ymm4, ymm3, ymm5, ymm6, ymm7, 2
 300     ; ymm0=data0_4, ymm1=data3_1, ymm2=data2_6, ymm4=data7_5
 301
 302     vperm2i128 ymm3, ymm0, ymm1, 0x30   ; ymm3=data0_1
 303     vperm2i128 ymm5, ymm2, ymm1, 0x20   ; ymm5=data2_3
 304     vperm2i128 ymm6, ymm0, ymm4, 0x31   ; ymm6=data4_5
 305     vperm2i128 ymm7, ymm2, ymm4, 0x21   ; ymm7=data6_7
 306
 307     vmovdqu     YMMWORD [YMMBLOCK(0,0,r10,SIZEOF_DCTELEM)], ymm3
 308     vmovdqu     YMMWORD [YMMBLOCK(2,0,r10,SIZEOF_DCTELEM)], ymm5
 309     vmovdqu     YMMWORD [YMMBLOCK(4,0,r10,SIZEOF_DCTELEM)], ymm6
 310     vmovdqu     YMMWORD [YMMBLOCK(6,0,r10,SIZEOF_DCTELEM)], ymm7
 311
 312     vzeroupper
 313     uncollect_args 1
 314     pop         rbp
 315     ret
 316
 317 ; For some reason, the OS X linker does not honor the request to align the
 318 ; segment unless we do this.
 319     align       32