simd/jfss2int.asm

   1 ;
   2 ; jfss2int.asm - accurate integer FDCT (SSE2)
   3 ;
   4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
   5 ;
   6 ; Based on
   7 ; x86 SIMD extension for IJG JPEG library
   8 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
   9 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
  10 ;
  11 ; This file should be assembled with NASM (Netwide Assembler),
  12 ; can *not* be assembled with Microsoft's MASM or any compatible
  13 ; assembler (including Borland's Turbo Assembler).
  14 ; NASM is available from http://nasm.sourceforge.net/ or
  15 ; http://sourceforge.net/project/showfiles.php?group_id=6208
  16 ;
  17 ; This file contains a slow-but-accurate integer implementation of the
  18 ; forward DCT (Discrete Cosine Transform). The following code is based
  19 ; directly on the IJG's original jfdctint.c; see the jfdctint.c for
  20 ; more details.
  21 ;
  22 ; [TAB8]
  23
  24 %include "jsimdext.inc"
  25 %include "jdct.inc"
  26
  27 ; --------------------------------------------------------------------------
  28
  29 %define CONST_BITS      13
  30 %define PASS1_BITS      2
  31
  32 %define DESCALE_P1      (CONST_BITS-PASS1_BITS)
  33 %define DESCALE_P2      (CONST_BITS+PASS1_BITS)
  34
  35 %if CONST_BITS == 13
  36 F_0_298 equ      2446           ; FIX(0.298631336)
  37 F_0_390 equ      3196           ; FIX(0.390180644)
  38 F_0_541 equ      4433           ; FIX(0.541196100)
  39 F_0_765 equ      6270           ; FIX(0.765366865)
  40 F_0_899 equ      7373           ; FIX(0.899976223)
  41 F_1_175 equ      9633           ; FIX(1.175875602)
  42 F_1_501 equ     12299           ; FIX(1.501321110)
  43 F_1_847 equ     15137           ; FIX(1.847759065)
  44 F_1_961 equ     16069           ; FIX(1.961570560)
  45 F_2_053 equ     16819           ; FIX(2.053119869)
  46 F_2_562 equ     20995           ; FIX(2.562915447)
  47 F_3_072 equ     25172           ; FIX(3.072711026)
  48 %else
  49 ; NASM cannot do compile-time arithmetic on floating-point constants.
  50 %define DESCALE(x,n)  (((x)+(1<<((n)-1)))>>(n))
  51 F_0_298 equ     DESCALE( 320652955,30-CONST_BITS)       ; FIX(0.298631336)
  52 F_0_390 equ     DESCALE( 418953276,30-CONST_BITS)       ; FIX(0.390180644)
  53 F_0_541 equ     DESCALE( 581104887,30-CONST_BITS)       ; FIX(0.541196100)
  54 F_0_765 equ     DESCALE( 821806413,30-CONST_BITS)       ; FIX(0.765366865)
  55 F_0_899 equ     DESCALE( 966342111,30-CONST_BITS)       ; FIX(0.899976223)
  56 F_1_175 equ     DESCALE(1262586813,30-CONST_BITS)       ; FIX(1.175875602)
  57 F_1_501 equ     DESCALE(1612031267,30-CONST_BITS)       ; FIX(1.501321110)
  58 F_1_847 equ     DESCALE(1984016188,30-CONST_BITS)       ; FIX(1.847759065)
  59 F_1_961 equ     DESCALE(2106220350,30-CONST_BITS)       ; FIX(1.961570560)
  60 F_2_053 equ     DESCALE(2204520673,30-CONST_BITS)       ; FIX(2.053119869)
  61 F_2_562 equ     DESCALE(2751909506,30-CONST_BITS)       ; FIX(2.562915447)
  62 F_3_072 equ     DESCALE(3299298341,30-CONST_BITS)       ; FIX(3.072711026)
  63 %endif
  64
  65 ; --------------------------------------------------------------------------
  66         SECTION SEG_CONST
  67
  68         alignz  16
  69         global  EXTN(jconst_fdct_islow_sse2)
  70
  71 EXTN(jconst_fdct_islow_sse2):
  72
  73 PW_F130_F054    times 4 dw  (F_0_541+F_0_765), F_0_541
  74 PW_F054_MF130   times 4 dw  F_0_541, (F_0_541-F_1_847)
  75 PW_MF078_F117   times 4 dw  (F_1_175-F_1_961), F_1_175
  76 PW_F117_F078    times 4 dw  F_1_175, (F_1_175-F_0_390)
  77 PW_MF060_MF089  times 4 dw  (F_0_298-F_0_899),-F_0_899
  78 PW_MF089_F060   times 4 dw -F_0_899, (F_1_501-F_0_899)
  79 PW_MF050_MF256  times 4 dw  (F_2_053-F_2_562),-F_2_562
  80 PW_MF256_F050   times 4 dw -F_2_562, (F_3_072-F_2_562)
  81 PD_DESCALE_P1   times 4 dd  1 << (DESCALE_P1-1)
  82 PD_DESCALE_P2   times 4 dd  1 << (DESCALE_P2-1)
  83 PW_DESCALE_P2X  times 8 dw  1 << (PASS1_BITS-1)
  84
  85         alignz  16
  86
  87 ; --------------------------------------------------------------------------
  88         SECTION SEG_TEXT
  89         BITS    32
  90 ;
  91 ; Perform the forward DCT on one block of samples.
  92 ;
  93 ; GLOBAL(void)
  94 ; jsimd_fdct_islow_sse2 (DCTELEM * data)
  95 ;
  96
  97 %define data(b)         (b)+8           ; DCTELEM * data
  98
  99 %define original_ebp    ebp+0
 100 %define wk(i)           ebp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
 101 %define WK_NUM          6
 102
 103         align   16
 104         global  EXTN(jsimd_fdct_islow_sse2)
 105
 106 EXTN(jsimd_fdct_islow_sse2):
 107         push    ebp
 108         mov     eax,esp                         ; eax = original ebp
 109         sub     esp, byte 4
 110         and     esp, byte (-SIZEOF_XMMWORD)     ; align to 128 bits
 111         mov     [esp],eax
 112         mov     ebp,esp                         ; ebp = aligned ebp
 113         lea     esp, [wk(0)]
 114         pushpic ebx
 115 ;       push    ecx             ; unused
 116 ;       push    edx             ; need not be preserved
 117 ;       push    esi             ; unused
 118 ;       push    edi             ; unused
 119
 120         get_GOT ebx             ; get GOT address
 121
 122         ; ---- Pass 1: process rows.
 123
 124         mov     edx, POINTER [data(eax)]        ; (DCTELEM *)
 125
 126         movdqa  xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_DCTELEM)]
 127         movdqa  xmm1, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_DCTELEM)]
 128         movdqa  xmm2, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_DCTELEM)]
 129         movdqa  xmm3, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_DCTELEM)]
 130
 131         ; xmm0=(00 01 02 03 04 05 06 07), xmm2=(20 21 22 23 24 25 26 27)
 132         ; xmm1=(10 11 12 13 14 15 16 17), xmm3=(30 31 32 33 34 35 36 37)
 133
 134         movdqa    xmm4,xmm0             ; transpose coefficients(phase 1)
 135         punpcklwd xmm0,xmm1             ; xmm0=(00 10 01 11 02 12 03 13)
 136         punpckhwd xmm4,xmm1             ; xmm4=(04 14 05 15 06 16 07 17)
 137         movdqa    xmm5,xmm2             ; transpose coefficients(phase 1)
 138         punpcklwd xmm2,xmm3             ; xmm2=(20 30 21 31 22 32 23 33)
 139         punpckhwd xmm5,xmm3             ; xmm5=(24 34 25 35 26 36 27 37)
 140
 141         movdqa  xmm6, XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_DCTELEM)]
 142         movdqa  xmm7, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_DCTELEM)]
 143         movdqa  xmm1, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_DCTELEM)]
 144         movdqa  xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_DCTELEM)]
 145
 146         ; xmm6=( 4 12 20 28 36 44 52 60), xmm1=( 6 14 22 30 38 46 54 62)
 147         ; xmm7=( 5 13 21 29 37 45 53 61), xmm3=( 7 15 23 31 39 47 55 63)
 148
 149         movdqa  XMMWORD [wk(0)], xmm2   ; wk(0)=(20 30 21 31 22 32 23 33)
 150         movdqa  XMMWORD [wk(1)], xmm5   ; wk(1)=(24 34 25 35 26 36 27 37)
 151
 152         movdqa    xmm2,xmm6             ; transpose coefficients(phase 1)
 153         punpcklwd xmm6,xmm7             ; xmm6=(40 50 41 51 42 52 43 53)
 154         punpckhwd xmm2,xmm7             ; xmm2=(44 54 45 55 46 56 47 57)
 155         movdqa    xmm5,xmm1             ; transpose coefficients(phase 1)
 156         punpcklwd xmm1,xmm3             ; xmm1=(60 70 61 71 62 72 63 73)
 157         punpckhwd xmm5,xmm3             ; xmm5=(64 74 65 75 66 76 67 77)
 158
 159         movdqa    xmm7,xmm6             ; transpose coefficients(phase 2)
 160         punpckldq xmm6,xmm1             ; xmm6=(40 50 60 70 41 51 61 71)
 161         punpckhdq xmm7,xmm1             ; xmm7=(42 52 62 72 43 53 63 73)
 162         movdqa    xmm3,xmm2             ; transpose coefficients(phase 2)
 163         punpckldq xmm2,xmm5             ; xmm2=(44 54 64 74 45 55 65 75)
 164         punpckhdq xmm3,xmm5             ; xmm3=(46 56 66 76 47 57 67 77)
 165
 166         movdqa  xmm1, XMMWORD [wk(0)]   ; xmm1=(20 30 21 31 22 32 23 33)
 167         movdqa  xmm5, XMMWORD [wk(1)]   ; xmm5=(24 34 25 35 26 36 27 37)
 168         movdqa  XMMWORD [wk(2)], xmm7   ; wk(2)=(42 52 62 72 43 53 63 73)
 169         movdqa  XMMWORD [wk(3)], xmm2   ; wk(3)=(44 54 64 74 45 55 65 75)
 170
 171         movdqa    xmm7,xmm0             ; transpose coefficients(phase 2)
 172         punpckldq xmm0,xmm1             ; xmm0=(00 10 20 30 01 11 21 31)
 173         punpckhdq xmm7,xmm1             ; xmm7=(02 12 22 32 03 13 23 33)
 174         movdqa    xmm2,xmm4             ; transpose coefficients(phase 2)
 175         punpckldq xmm4,xmm5             ; xmm4=(04 14 24 34 05 15 25 35)
 176         punpckhdq xmm2,xmm5             ; xmm2=(06 16 26 36 07 17 27 37)
 177
 178         movdqa     xmm1,xmm0            ; transpose coefficients(phase 3)
 179         punpcklqdq xmm0,xmm6            ; xmm0=(00 10 20 30 40 50 60 70)=data0
 180         punpckhqdq xmm1,xmm6            ; xmm1=(01 11 21 31 41 51 61 71)=data1
 181         movdqa     xmm5,xmm2            ; transpose coefficients(phase 3)
 182         punpcklqdq xmm2,xmm3            ; xmm2=(06 16 26 36 46 56 66 76)=data6
 183         punpckhqdq xmm5,xmm3            ; xmm5=(07 17 27 37 47 57 67 77)=data7
 184
 185         movdqa  xmm6,xmm1
 186         movdqa  xmm3,xmm0
 187         psubw   xmm1,xmm2               ; xmm1=data1-data6=tmp6
 188         psubw   xmm0,xmm5               ; xmm0=data0-data7=tmp7
 189         paddw   xmm6,xmm2               ; xmm6=data1+data6=tmp1
 190         paddw   xmm3,xmm5               ; xmm3=data0+data7=tmp0
 191
 192         movdqa  xmm2, XMMWORD [wk(2)]   ; xmm2=(42 52 62 72 43 53 63 73)
 193         movdqa  xmm5, XMMWORD [wk(3)]   ; xmm5=(44 54 64 74 45 55 65 75)
 194         movdqa  XMMWORD [wk(0)], xmm1   ; wk(0)=tmp6
 195         movdqa  XMMWORD [wk(1)], xmm0   ; wk(1)=tmp7
 196
 197         movdqa     xmm1,xmm7            ; transpose coefficients(phase 3)
 198         punpcklqdq xmm7,xmm2            ; xmm7=(02 12 22 32 42 52 62 72)=data2
 199         punpckhqdq xmm1,xmm2            ; xmm1=(03 13 23 33 43 53 63 73)=data3
 200         movdqa     xmm0,xmm4            ; transpose coefficients(phase 3)
 201         punpcklqdq xmm4,xmm5            ; xmm4=(04 14 24 34 44 54 64 74)=data4
 202         punpckhqdq xmm0,xmm5            ; xmm0=(05 15 25 35 45 55 65 75)=data5
 203
 204         movdqa  xmm2,xmm1
 205         movdqa  xmm5,xmm7
 206         paddw   xmm1,xmm4               ; xmm1=data3+data4=tmp3
 207         paddw   xmm7,xmm0               ; xmm7=data2+data5=tmp2
 208         psubw   xmm2,xmm4               ; xmm2=data3-data4=tmp4
 209         psubw   xmm5,xmm0               ; xmm5=data2-data5=tmp5
 210
 211         ; -- Even part
 212
 213         movdqa  xmm4,xmm3
 214         movdqa  xmm0,xmm6
 215         paddw   xmm3,xmm1               ; xmm3=tmp10
 216         paddw   xmm6,xmm7               ; xmm6=tmp11
 217         psubw   xmm4,xmm1               ; xmm4=tmp13
 218         psubw   xmm0,xmm7               ; xmm0=tmp12
 219
 220         movdqa  xmm1,xmm3
 221         paddw   xmm3,xmm6               ; xmm3=tmp10+tmp11
 222         psubw   xmm1,xmm6               ; xmm1=tmp10-tmp11
 223
 224         psllw   xmm3,PASS1_BITS         ; xmm3=data0
 225         psllw   xmm1,PASS1_BITS         ; xmm1=data4
 226
 227         movdqa  XMMWORD [wk(2)], xmm3   ; wk(2)=data0
 228         movdqa  XMMWORD [wk(3)], xmm1   ; wk(3)=data4
 229
 230         ; (Original)
 231         ; z1 = (tmp12 + tmp13) * 0.541196100;
 232         ; data2 = z1 + tmp13 * 0.765366865;
 233         ; data6 = z1 + tmp12 * -1.847759065;
 234         ;
 235         ; (This implementation)
 236         ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
 237         ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
 238
 239         movdqa    xmm7,xmm4             ; xmm4=tmp13
 240         movdqa    xmm6,xmm4
 241         punpcklwd xmm7,xmm0             ; xmm0=tmp12
 242         punpckhwd xmm6,xmm0
 243         movdqa    xmm4,xmm7
 244         movdqa    xmm0,xmm6
 245         pmaddwd   xmm7,[GOTOFF(ebx,PW_F130_F054)]       ; xmm7=data2L
 246         pmaddwd   xmm6,[GOTOFF(ebx,PW_F130_F054)]       ; xmm6=data2H
 247         pmaddwd   xmm4,[GOTOFF(ebx,PW_F054_MF130)]      ; xmm4=data6L
 248         pmaddwd   xmm0,[GOTOFF(ebx,PW_F054_MF130)]      ; xmm0=data6H
 249
 250         paddd   xmm7,[GOTOFF(ebx,PD_DESCALE_P1)]
 251         paddd   xmm6,[GOTOFF(ebx,PD_DESCALE_P1)]
 252         psrad   xmm7,DESCALE_P1
 253         psrad   xmm6,DESCALE_P1
 254         paddd   xmm4,[GOTOFF(ebx,PD_DESCALE_P1)]
 255         paddd   xmm0,[GOTOFF(ebx,PD_DESCALE_P1)]
 256         psrad   xmm4,DESCALE_P1
 257         psrad   xmm0,DESCALE_P1
 258
 259         packssdw  xmm7,xmm6             ; xmm7=data2
 260         packssdw  xmm4,xmm0             ; xmm4=data6
 261
 262         movdqa  XMMWORD [wk(4)], xmm7   ; wk(4)=data2
 263         movdqa  XMMWORD [wk(5)], xmm4   ; wk(5)=data6
 264
 265         ; -- Odd part
 266
 267         movdqa  xmm3, XMMWORD [wk(0)]   ; xmm3=tmp6
 268         movdqa  xmm1, XMMWORD [wk(1)]   ; xmm1=tmp7
 269
 270         movdqa  xmm6,xmm2               ; xmm2=tmp4
 271         movdqa  xmm0,xmm5               ; xmm5=tmp5
 272         paddw   xmm6,xmm3               ; xmm6=z3
 273         paddw   xmm0,xmm1               ; xmm0=z4
 274
 275         ; (Original)
 276         ; z5 = (z3 + z4) * 1.175875602;
 277         ; z3 = z3 * -1.961570560;  z4 = z4 * -0.390180644;
 278         ; z3 += z5;  z4 += z5;
 279         ;
 280         ; (This implementation)
 281         ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
 282         ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
 283
 284         movdqa    xmm7,xmm6
 285         movdqa    xmm4,xmm6
 286         punpcklwd xmm7,xmm0
 287         punpckhwd xmm4,xmm0
 288         movdqa    xmm6,xmm7
 289         movdqa    xmm0,xmm4
 290         pmaddwd   xmm7,[GOTOFF(ebx,PW_MF078_F117)]      ; xmm7=z3L
 291         pmaddwd   xmm4,[GOTOFF(ebx,PW_MF078_F117)]      ; xmm4=z3H
 292         pmaddwd   xmm6,[GOTOFF(ebx,PW_F117_F078)]       ; xmm6=z4L
 293         pmaddwd   xmm0,[GOTOFF(ebx,PW_F117_F078)]       ; xmm0=z4H
 294
 295         movdqa  XMMWORD [wk(0)], xmm7   ; wk(0)=z3L
 296         movdqa  XMMWORD [wk(1)], xmm4   ; wk(1)=z3H
 297
 298         ; (Original)
 299         ; z1 = tmp4 + tmp7;  z2 = tmp5 + tmp6;
 300         ; tmp4 = tmp4 * 0.298631336;  tmp5 = tmp5 * 2.053119869;
 301         ; tmp6 = tmp6 * 3.072711026;  tmp7 = tmp7 * 1.501321110;
 302         ; z1 = z1 * -0.899976223;  z2 = z2 * -2.562915447;
 303         ; data7 = tmp4 + z1 + z3;  data5 = tmp5 + z2 + z4;
 304         ; data3 = tmp6 + z2 + z3;  data1 = tmp7 + z1 + z4;
 305         ;
 306         ; (This implementation)
 307         ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
 308         ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
 309         ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
 310         ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
 311         ; data7 = tmp4 + z3;  data5 = tmp5 + z4;
 312         ; data3 = tmp6 + z3;  data1 = tmp7 + z4;
 313
 314         movdqa    xmm7,xmm2
 315         movdqa    xmm4,xmm2
 316         punpcklwd xmm7,xmm1
 317         punpckhwd xmm4,xmm1
 318         movdqa    xmm2,xmm7
 319         movdqa    xmm1,xmm4
 320         pmaddwd   xmm7,[GOTOFF(ebx,PW_MF060_MF089)]     ; xmm7=tmp4L
 321         pmaddwd   xmm4,[GOTOFF(ebx,PW_MF060_MF089)]     ; xmm4=tmp4H
 322         pmaddwd   xmm2,[GOTOFF(ebx,PW_MF089_F060)]      ; xmm2=tmp7L
 323         pmaddwd   xmm1,[GOTOFF(ebx,PW_MF089_F060)]      ; xmm1=tmp7H
 324
 325         paddd   xmm7, XMMWORD [wk(0)]   ; xmm7=data7L
 326         paddd   xmm4, XMMWORD [wk(1)]   ; xmm4=data7H
 327         paddd   xmm2,xmm6               ; xmm2=data1L
 328         paddd   xmm1,xmm0               ; xmm1=data1H
 329
 330         paddd   xmm7,[GOTOFF(ebx,PD_DESCALE_P1)]
 331         paddd   xmm4,[GOTOFF(ebx,PD_DESCALE_P1)]
 332         psrad   xmm7,DESCALE_P1
 333         psrad   xmm4,DESCALE_P1
 334         paddd   xmm2,[GOTOFF(ebx,PD_DESCALE_P1)]
 335         paddd   xmm1,[GOTOFF(ebx,PD_DESCALE_P1)]
 336         psrad   xmm2,DESCALE_P1
 337         psrad   xmm1,DESCALE_P1
 338
 339         packssdw  xmm7,xmm4             ; xmm7=data7
 340         packssdw  xmm2,xmm1             ; xmm2=data1
 341
 342         movdqa    xmm4,xmm5
 343         movdqa    xmm1,xmm5
 344         punpcklwd xmm4,xmm3
 345         punpckhwd xmm1,xmm3
 346         movdqa    xmm5,xmm4
 347         movdqa    xmm3,xmm1
 348         pmaddwd   xmm4,[GOTOFF(ebx,PW_MF050_MF256)]     ; xmm4=tmp5L
 349         pmaddwd   xmm1,[GOTOFF(ebx,PW_MF050_MF256)]     ; xmm1=tmp5H
 350         pmaddwd   xmm5,[GOTOFF(ebx,PW_MF256_F050)]      ; xmm5=tmp6L
 351         pmaddwd   xmm3,[GOTOFF(ebx,PW_MF256_F050)]      ; xmm3=tmp6H
 352
 353         paddd   xmm4,xmm6               ; xmm4=data5L
 354         paddd   xmm1,xmm0               ; xmm1=data5H
 355         paddd   xmm5, XMMWORD [wk(0)]   ; xmm5=data3L
 356         paddd   xmm3, XMMWORD [wk(1)]   ; xmm3=data3H
 357
 358         paddd   xmm4,[GOTOFF(ebx,PD_DESCALE_P1)]
 359         paddd   xmm1,[GOTOFF(ebx,PD_DESCALE_P1)]
 360         psrad   xmm4,DESCALE_P1
 361         psrad   xmm1,DESCALE_P1
 362         paddd   xmm5,[GOTOFF(ebx,PD_DESCALE_P1)]
 363         paddd   xmm3,[GOTOFF(ebx,PD_DESCALE_P1)]
 364         psrad   xmm5,DESCALE_P1
 365         psrad   xmm3,DESCALE_P1
 366
 367         packssdw  xmm4,xmm1             ; xmm4=data5
 368         packssdw  xmm5,xmm3             ; xmm5=data3
 369
 370         ; ---- Pass 2: process columns.
 371
 372 ;       mov     edx, POINTER [data(eax)]        ; (DCTELEM *)
 373
 374         movdqa  xmm6, XMMWORD [wk(2)]   ; xmm6=col0
 375         movdqa  xmm0, XMMWORD [wk(4)]   ; xmm0=col2
 376
 377         ; xmm6=(00 10 20 30 40 50 60 70), xmm0=(02 12 22 32 42 52 62 72)
 378         ; xmm2=(01 11 21 31 41 51 61 71), xmm5=(03 13 23 33 43 53 63 73)
 379
 380         movdqa    xmm1,xmm6             ; transpose coefficients(phase 1)
 381         punpcklwd xmm6,xmm2             ; xmm6=(00 01 10 11 20 21 30 31)
 382         punpckhwd xmm1,xmm2             ; xmm1=(40 41 50 51 60 61 70 71)
 383         movdqa    xmm3,xmm0             ; transpose coefficients(phase 1)
 384         punpcklwd xmm0,xmm5             ; xmm0=(02 03 12 13 22 23 32 33)
 385         punpckhwd xmm3,xmm5             ; xmm3=(42 43 52 53 62 63 72 73)
 386
 387         movdqa  xmm2, XMMWORD [wk(3)]   ; xmm2=col4
 388         movdqa  xmm5, XMMWORD [wk(5)]   ; xmm5=col6
 389
 390         ; xmm2=(04 14 24 34 44 54 64 74), xmm5=(06 16 26 36 46 56 66 76)
 391         ; xmm4=(05 15 25 35 45 55 65 75), xmm7=(07 17 27 37 47 57 67 77)
 392
 393         movdqa  XMMWORD [wk(0)], xmm0   ; wk(0)=(02 03 12 13 22 23 32 33)
 394         movdqa  XMMWORD [wk(1)], xmm3   ; wk(1)=(42 43 52 53 62 63 72 73)
 395
 396         movdqa    xmm0,xmm2             ; transpose coefficients(phase 1)
 397         punpcklwd xmm2,xmm4             ; xmm2=(04 05 14 15 24 25 34 35)
 398         punpckhwd xmm0,xmm4             ; xmm0=(44 45 54 55 64 65 74 75)
 399         movdqa    xmm3,xmm5             ; transpose coefficients(phase 1)
 400         punpcklwd xmm5,xmm7             ; xmm5=(06 07 16 17 26 27 36 37)
 401         punpckhwd xmm3,xmm7             ; xmm3=(46 47 56 57 66 67 76 77)
 402
 403         movdqa    xmm4,xmm2             ; transpose coefficients(phase 2)
 404         punpckldq xmm2,xmm5             ; xmm2=(04 05 06 07 14 15 16 17)
 405         punpckhdq xmm4,xmm5             ; xmm4=(24 25 26 27 34 35 36 37)
 406         movdqa    xmm7,xmm0             ; transpose coefficients(phase 2)
 407         punpckldq xmm0,xmm3             ; xmm0=(44 45 46 47 54 55 56 57)
 408         punpckhdq xmm7,xmm3             ; xmm7=(64 65 66 67 74 75 76 77)
 409
 410         movdqa  xmm5, XMMWORD [wk(0)]   ; xmm5=(02 03 12 13 22 23 32 33)
 411         movdqa  xmm3, XMMWORD [wk(1)]   ; xmm3=(42 43 52 53 62 63 72 73)
 412         movdqa  XMMWORD [wk(2)], xmm4   ; wk(2)=(24 25 26 27 34 35 36 37)
 413         movdqa  XMMWORD [wk(3)], xmm0   ; wk(3)=(44 45 46 47 54 55 56 57)
 414
 415         movdqa    xmm4,xmm6             ; transpose coefficients(phase 2)
 416         punpckldq xmm6,xmm5             ; xmm6=(00 01 02 03 10 11 12 13)
 417         punpckhdq xmm4,xmm5             ; xmm4=(20 21 22 23 30 31 32 33)
 418         movdqa    xmm0,xmm1             ; transpose coefficients(phase 2)
 419         punpckldq xmm1,xmm3             ; xmm1=(40 41 42 43 50 51 52 53)
 420         punpckhdq xmm0,xmm3             ; xmm0=(60 61 62 63 70 71 72 73)
 421
 422         movdqa     xmm5,xmm6            ; transpose coefficients(phase 3)
 423         punpcklqdq xmm6,xmm2            ; xmm6=(00 01 02 03 04 05 06 07)=data0
 424         punpckhqdq xmm5,xmm2            ; xmm5=(10 11 12 13 14 15 16 17)=data1
 425         movdqa     xmm3,xmm0            ; transpose coefficients(phase 3)
 426         punpcklqdq xmm0,xmm7            ; xmm0=(60 61 62 63 64 65 66 67)=data6
 427         punpckhqdq xmm3,xmm7            ; xmm3=(70 71 72 73 74 75 76 77)=data7
 428
 429         movdqa  xmm2,xmm5
 430         movdqa  xmm7,xmm6
 431         psubw   xmm5,xmm0               ; xmm5=data1-data6=tmp6
 432         psubw   xmm6,xmm3               ; xmm6=data0-data7=tmp7
 433         paddw   xmm2,xmm0               ; xmm2=data1+data6=tmp1
 434         paddw   xmm7,xmm3               ; xmm7=data0+data7=tmp0
 435
 436         movdqa  xmm0, XMMWORD [wk(2)]   ; xmm0=(24 25 26 27 34 35 36 37)
 437         movdqa  xmm3, XMMWORD [wk(3)]   ; xmm3=(44 45 46 47 54 55 56 57)
 438         movdqa  XMMWORD [wk(0)], xmm5   ; wk(0)=tmp6
 439         movdqa  XMMWORD [wk(1)], xmm6   ; wk(1)=tmp7
 440
 441         movdqa     xmm5,xmm4            ; transpose coefficients(phase 3)
 442         punpcklqdq xmm4,xmm0            ; xmm4=(20 21 22 23 24 25 26 27)=data2
 443         punpckhqdq xmm5,xmm0            ; xmm5=(30 31 32 33 34 35 36 37)=data3
 444         movdqa     xmm6,xmm1            ; transpose coefficients(phase 3)
 445         punpcklqdq xmm1,xmm3            ; xmm1=(40 41 42 43 44 45 46 47)=data4
 446         punpckhqdq xmm6,xmm3            ; xmm6=(50 51 52 53 54 55 56 57)=data5
 447
 448         movdqa  xmm0,xmm5
 449         movdqa  xmm3,xmm4
 450         paddw   xmm5,xmm1               ; xmm5=data3+data4=tmp3
 451         paddw   xmm4,xmm6               ; xmm4=data2+data5=tmp2
 452         psubw   xmm0,xmm1               ; xmm0=data3-data4=tmp4
 453         psubw   xmm3,xmm6               ; xmm3=data2-data5=tmp5
 454
 455         ; -- Even part
 456
 457         movdqa  xmm1,xmm7
 458         movdqa  xmm6,xmm2
 459         paddw   xmm7,xmm5               ; xmm7=tmp10
 460         paddw   xmm2,xmm4               ; xmm2=tmp11
 461         psubw   xmm1,xmm5               ; xmm1=tmp13
 462         psubw   xmm6,xmm4               ; xmm6=tmp12
 463
 464         movdqa  xmm5,xmm7
 465         paddw   xmm7,xmm2               ; xmm7=tmp10+tmp11
 466         psubw   xmm5,xmm2               ; xmm5=tmp10-tmp11
 467
 468         paddw   xmm7,[GOTOFF(ebx,PW_DESCALE_P2X)]
 469         paddw   xmm5,[GOTOFF(ebx,PW_DESCALE_P2X)]
 470         psraw   xmm7,PASS1_BITS         ; xmm7=data0
 471         psraw   xmm5,PASS1_BITS         ; xmm5=data4
 472
 473         movdqa  XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_DCTELEM)], xmm7
 474         movdqa  XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_DCTELEM)], xmm5
 475
 476         ; (Original)
 477         ; z1 = (tmp12 + tmp13) * 0.541196100;
 478         ; data2 = z1 + tmp13 * 0.765366865;
 479         ; data6 = z1 + tmp12 * -1.847759065;
 480         ;
 481         ; (This implementation)
 482         ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
 483         ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
 484
 485         movdqa    xmm4,xmm1             ; xmm1=tmp13
 486         movdqa    xmm2,xmm1
 487         punpcklwd xmm4,xmm6             ; xmm6=tmp12
 488         punpckhwd xmm2,xmm6
 489         movdqa    xmm1,xmm4
 490         movdqa    xmm6,xmm2
 491         pmaddwd   xmm4,[GOTOFF(ebx,PW_F130_F054)]       ; xmm4=data2L
 492         pmaddwd   xmm2,[GOTOFF(ebx,PW_F130_F054)]       ; xmm2=data2H
 493         pmaddwd   xmm1,[GOTOFF(ebx,PW_F054_MF130)]      ; xmm1=data6L
 494         pmaddwd   xmm6,[GOTOFF(ebx,PW_F054_MF130)]      ; xmm6=data6H
 495
 496         paddd   xmm4,[GOTOFF(ebx,PD_DESCALE_P2)]
 497         paddd   xmm2,[GOTOFF(ebx,PD_DESCALE_P2)]
 498         psrad   xmm4,DESCALE_P2
 499         psrad   xmm2,DESCALE_P2
 500         paddd   xmm1,[GOTOFF(ebx,PD_DESCALE_P2)]
 501         paddd   xmm6,[GOTOFF(ebx,PD_DESCALE_P2)]
 502         psrad   xmm1,DESCALE_P2
 503         psrad   xmm6,DESCALE_P2
 504
 505         packssdw  xmm4,xmm2             ; xmm4=data2
 506         packssdw  xmm1,xmm6             ; xmm1=data6
 507
 508         movdqa  XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_DCTELEM)], xmm4
 509         movdqa  XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_DCTELEM)], xmm1
 510
 511         ; -- Odd part
 512
 513         movdqa  xmm7, XMMWORD [wk(0)]   ; xmm7=tmp6
 514         movdqa  xmm5, XMMWORD [wk(1)]   ; xmm5=tmp7
 515
 516         movdqa  xmm2,xmm0               ; xmm0=tmp4
 517         movdqa  xmm6,xmm3               ; xmm3=tmp5
 518         paddw   xmm2,xmm7               ; xmm2=z3
 519         paddw   xmm6,xmm5               ; xmm6=z4
 520
 521         ; (Original)
 522         ; z5 = (z3 + z4) * 1.175875602;
 523         ; z3 = z3 * -1.961570560;  z4 = z4 * -0.390180644;
 524         ; z3 += z5;  z4 += z5;
 525         ;
 526         ; (This implementation)
 527         ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
 528         ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
 529
 530         movdqa    xmm4,xmm2
 531         movdqa    xmm1,xmm2
 532         punpcklwd xmm4,xmm6
 533         punpckhwd xmm1,xmm6
 534         movdqa    xmm2,xmm4
 535         movdqa    xmm6,xmm1
 536         pmaddwd   xmm4,[GOTOFF(ebx,PW_MF078_F117)]      ; xmm4=z3L
 537         pmaddwd   xmm1,[GOTOFF(ebx,PW_MF078_F117)]      ; xmm1=z3H
 538         pmaddwd   xmm2,[GOTOFF(ebx,PW_F117_F078)]       ; xmm2=z4L
 539         pmaddwd   xmm6,[GOTOFF(ebx,PW_F117_F078)]       ; xmm6=z4H
 540
 541         movdqa  XMMWORD [wk(0)], xmm4   ; wk(0)=z3L
 542         movdqa  XMMWORD [wk(1)], xmm1   ; wk(1)=z3H
 543
 544         ; (Original)
 545         ; z1 = tmp4 + tmp7;  z2 = tmp5 + tmp6;
 546         ; tmp4 = tmp4 * 0.298631336;  tmp5 = tmp5 * 2.053119869;
 547         ; tmp6 = tmp6 * 3.072711026;  tmp7 = tmp7 * 1.501321110;
 548         ; z1 = z1 * -0.899976223;  z2 = z2 * -2.562915447;
 549         ; data7 = tmp4 + z1 + z3;  data5 = tmp5 + z2 + z4;
 550         ; data3 = tmp6 + z2 + z3;  data1 = tmp7 + z1 + z4;
 551         ;
 552         ; (This implementation)
 553         ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
 554         ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
 555         ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
 556         ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
 557         ; data7 = tmp4 + z3;  data5 = tmp5 + z4;
 558         ; data3 = tmp6 + z3;  data1 = tmp7 + z4;
 559
 560         movdqa    xmm4,xmm0
 561         movdqa    xmm1,xmm0
 562         punpcklwd xmm4,xmm5
 563         punpckhwd xmm1,xmm5
 564         movdqa    xmm0,xmm4
 565         movdqa    xmm5,xmm1
 566         pmaddwd   xmm4,[GOTOFF(ebx,PW_MF060_MF089)]     ; xmm4=tmp4L
 567         pmaddwd   xmm1,[GOTOFF(ebx,PW_MF060_MF089)]     ; xmm1=tmp4H
 568         pmaddwd   xmm0,[GOTOFF(ebx,PW_MF089_F060)]      ; xmm0=tmp7L
 569         pmaddwd   xmm5,[GOTOFF(ebx,PW_MF089_F060)]      ; xmm5=tmp7H
 570
 571         paddd   xmm4, XMMWORD [wk(0)]   ; xmm4=data7L
 572         paddd   xmm1, XMMWORD [wk(1)]   ; xmm1=data7H
 573         paddd   xmm0,xmm2               ; xmm0=data1L
 574         paddd   xmm5,xmm6               ; xmm5=data1H
 575
 576         paddd   xmm4,[GOTOFF(ebx,PD_DESCALE_P2)]
 577         paddd   xmm1,[GOTOFF(ebx,PD_DESCALE_P2)]
 578         psrad   xmm4,DESCALE_P2
 579         psrad   xmm1,DESCALE_P2
 580         paddd   xmm0,[GOTOFF(ebx,PD_DESCALE_P2)]
 581         paddd   xmm5,[GOTOFF(ebx,PD_DESCALE_P2)]
 582         psrad   xmm0,DESCALE_P2
 583         psrad   xmm5,DESCALE_P2
 584
 585         packssdw  xmm4,xmm1             ; xmm4=data7
 586         packssdw  xmm0,xmm5             ; xmm0=data1
 587
 588         movdqa  XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_DCTELEM)], xmm4
 589         movdqa  XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_DCTELEM)], xmm0
 590
 591         movdqa    xmm1,xmm3
 592         movdqa    xmm5,xmm3
 593         punpcklwd xmm1,xmm7
 594         punpckhwd xmm5,xmm7
 595         movdqa    xmm3,xmm1
 596         movdqa    xmm7,xmm5
 597         pmaddwd   xmm1,[GOTOFF(ebx,PW_MF050_MF256)]     ; xmm1=tmp5L
 598         pmaddwd   xmm5,[GOTOFF(ebx,PW_MF050_MF256)]     ; xmm5=tmp5H
 599         pmaddwd   xmm3,[GOTOFF(ebx,PW_MF256_F050)]      ; xmm3=tmp6L
 600         pmaddwd   xmm7,[GOTOFF(ebx,PW_MF256_F050)]      ; xmm7=tmp6H
 601
 602         paddd   xmm1,xmm2               ; xmm1=data5L
 603         paddd   xmm5,xmm6               ; xmm5=data5H
 604         paddd   xmm3, XMMWORD [wk(0)]   ; xmm3=data3L
 605         paddd   xmm7, XMMWORD [wk(1)]   ; xmm7=data3H
 606
 607         paddd   xmm1,[GOTOFF(ebx,PD_DESCALE_P2)]
 608         paddd   xmm5,[GOTOFF(ebx,PD_DESCALE_P2)]
 609         psrad   xmm1,DESCALE_P2
 610         psrad   xmm5,DESCALE_P2
 611         paddd   xmm3,[GOTOFF(ebx,PD_DESCALE_P2)]
 612         paddd   xmm7,[GOTOFF(ebx,PD_DESCALE_P2)]
 613         psrad   xmm3,DESCALE_P2
 614         psrad   xmm7,DESCALE_P2
 615
 616         packssdw  xmm1,xmm5             ; xmm1=data5
 617         packssdw  xmm3,xmm7             ; xmm3=data3
 618
 619         movdqa  XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_DCTELEM)], xmm1
 620         movdqa  XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_DCTELEM)], xmm3
 621
 622 ;       pop     edi             ; unused
 623 ;       pop     esi             ; unused
 624 ;       pop     edx             ; need not be preserved
 625 ;       pop     ecx             ; unused
 626         poppic  ebx
 627         mov     esp,ebp         ; esp <- aligned ebp
 628         pop     esp             ; esp <- original ebp
 629         pop     ebp
 630         ret
 631
 632 ; For some reason, the OS X linker does not honor the request to align the
 633 ; segment unless we do this.
 634         align   16