simd/jdclrss2-64.asm

   1 ;
   2 ; jdclrss2-64.asm - colorspace conversion (64-bit SSE2)
   3 ;
   4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
   5 ; Copyright 2009 D. R. Commander
   6 ;
   7 ; Based on
   8 ; x86 SIMD extension for IJG JPEG library
   9 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
  10 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
  11 ;
  12 ; This file should be assembled with NASM (Netwide Assembler),
  13 ; can *not* be assembled with Microsoft's MASM or any compatible
  14 ; assembler (including Borland's Turbo Assembler).
  15 ; NASM is available from http://nasm.sourceforge.net/ or
  16 ; http://sourceforge.net/project/showfiles.php?group_id=6208
  17 ;
  18 ; [TAB8]
  19
  20 %include "jcolsamp.inc"
  21
  22 ; --------------------------------------------------------------------------
  23 ;
  24 ; Convert some rows of samples to the output colorspace.
  25 ;
  26 ; GLOBAL(void)
  27 ; jsimd_ycc_rgb_convert_sse2 (JDIMENSION out_width,
  28 ;                             JSAMPIMAGE input_buf, JDIMENSION input_row,
  29 ;                             JSAMPARRAY output_buf, int num_rows)
  30 ;
  31
  32 ; r10 = JDIMENSION out_width
  33 ; r11 = JSAMPIMAGE input_buf
  34 ; r12 = JDIMENSION input_row
  35 ; r13 = JSAMPARRAY output_buf
  36 ; r14 = int num_rows
  37
  38 %define wk(i)           rbp-(WK_NUM-(i))*SIZEOF_XMMWORD ; xmmword wk[WK_NUM]
  39 %define WK_NUM          2
  40
  41         align   16
  42         global  EXTN(jsimd_ycc_rgb_convert_sse2)
  43
  44 EXTN(jsimd_ycc_rgb_convert_sse2):
  45         push    rbp
  46         mov     rax,rsp                         ; rax = original rbp
  47         sub     rsp, byte 4
  48         and     rsp, byte (-SIZEOF_XMMWORD)     ; align to 128 bits
  49         mov     [rsp],rax
  50         mov     rbp,rsp                         ; rbp = aligned rbp
  51         lea     rsp, [wk(0)]
  52         collect_args
  53         push    rbx
  54
  55         mov     rcx, r10        ; num_cols
  56         test    rcx,rcx
  57         jz      near .return
  58
  59         push    rcx
  60
  61         mov     rdi, r11
  62         mov     rcx, r12
  63         mov     rsi, JSAMPARRAY [rdi+0*SIZEOF_JSAMPARRAY]
  64         mov     rbx, JSAMPARRAY [rdi+1*SIZEOF_JSAMPARRAY]
  65         mov     rdx, JSAMPARRAY [rdi+2*SIZEOF_JSAMPARRAY]
  66         lea     rsi, [rsi+rcx*SIZEOF_JSAMPROW]
  67         lea     rbx, [rbx+rcx*SIZEOF_JSAMPROW]
  68         lea     rdx, [rdx+rcx*SIZEOF_JSAMPROW]
  69
  70         pop     rcx
  71
  72         mov     rdi, r13
  73         mov     eax, r14d
  74         test    rax,rax
  75         jle     near .return
  76 .rowloop:
  77         push    rax
  78         push    rdi
  79         push    rdx
  80         push    rbx
  81         push    rsi
  82         push    rcx                     ; col
  83
  84         mov     rsi, JSAMPROW [rsi]     ; inptr0
  85         mov     rbx, JSAMPROW [rbx]     ; inptr1
  86         mov     rdx, JSAMPROW [rdx]     ; inptr2
  87         mov     rdi, JSAMPROW [rdi]     ; outptr
  88 .columnloop:
  89
  90         movdqa  xmm5, XMMWORD [rbx]     ; xmm5=Cb(0123456789ABCDEF)
  91         movdqa  xmm1, XMMWORD [rdx]     ; xmm1=Cr(0123456789ABCDEF)
  92
  93         pcmpeqw xmm4,xmm4
  94         pcmpeqw xmm7,xmm7
  95         psrlw   xmm4,BYTE_BIT
  96         psllw   xmm7,7                  ; xmm7={0xFF80 0xFF80 0xFF80 0xFF80 ..}
  97         movdqa  xmm0,xmm4               ; xmm0=xmm4={0xFF 0x00 0xFF 0x00 ..}
  98
  99         pand    xmm4,xmm5               ; xmm4=Cb(02468ACE)=CbE
 100         psrlw   xmm5,BYTE_BIT           ; xmm5=Cb(13579BDF)=CbO
 101         pand    xmm0,xmm1               ; xmm0=Cr(02468ACE)=CrE
 102         psrlw   xmm1,BYTE_BIT           ; xmm1=Cr(13579BDF)=CrO
 103
 104         paddw   xmm4,xmm7
 105         paddw   xmm5,xmm7
 106         paddw   xmm0,xmm7
 107         paddw   xmm1,xmm7
 108
 109         ; (Original)
 110         ; R = Y                + 1.40200 * Cr
 111         ; G = Y - 0.34414 * Cb - 0.71414 * Cr
 112         ; B = Y + 1.77200 * Cb
 113         ;
 114         ; (This implementation)
 115         ; R = Y                + 0.40200 * Cr + Cr
 116         ; G = Y - 0.34414 * Cb + 0.28586 * Cr - Cr
 117         ; B = Y - 0.22800 * Cb + Cb + Cb
 118
 119         movdqa  xmm2,xmm4               ; xmm2=CbE
 120         movdqa  xmm3,xmm5               ; xmm3=CbO
 121         paddw   xmm4,xmm4               ; xmm4=2*CbE
 122         paddw   xmm5,xmm5               ; xmm5=2*CbO
 123         movdqa  xmm6,xmm0               ; xmm6=CrE
 124         movdqa  xmm7,xmm1               ; xmm7=CrO
 125         paddw   xmm0,xmm0               ; xmm0=2*CrE
 126         paddw   xmm1,xmm1               ; xmm1=2*CrO
 127
 128         pmulhw  xmm4,[rel PW_MF0228]    ; xmm4=(2*CbE * -FIX(0.22800))
 129         pmulhw  xmm5,[rel PW_MF0228]    ; xmm5=(2*CbO * -FIX(0.22800))
 130         pmulhw  xmm0,[rel PW_F0402]     ; xmm0=(2*CrE * FIX(0.40200))
 131         pmulhw  xmm1,[rel PW_F0402]     ; xmm1=(2*CrO * FIX(0.40200))
 132
 133         paddw   xmm4,[rel PW_ONE]
 134         paddw   xmm5,[rel PW_ONE]
 135         psraw   xmm4,1                  ; xmm4=(CbE * -FIX(0.22800))
 136         psraw   xmm5,1                  ; xmm5=(CbO * -FIX(0.22800))
 137         paddw   xmm0,[rel PW_ONE]
 138         paddw   xmm1,[rel PW_ONE]
 139         psraw   xmm0,1                  ; xmm0=(CrE * FIX(0.40200))
 140         psraw   xmm1,1                  ; xmm1=(CrO * FIX(0.40200))
 141
 142         paddw   xmm4,xmm2
 143         paddw   xmm5,xmm3
 144         paddw   xmm4,xmm2               ; xmm4=(CbE * FIX(1.77200))=(B-Y)E
 145         paddw   xmm5,xmm3               ; xmm5=(CbO * FIX(1.77200))=(B-Y)O
 146         paddw   xmm0,xmm6               ; xmm0=(CrE * FIX(1.40200))=(R-Y)E
 147         paddw   xmm1,xmm7               ; xmm1=(CrO * FIX(1.40200))=(R-Y)O
 148
 149         movdqa  XMMWORD [wk(0)], xmm4   ; wk(0)=(B-Y)E
 150         movdqa  XMMWORD [wk(1)], xmm5   ; wk(1)=(B-Y)O
 151
 152         movdqa    xmm4,xmm2
 153         movdqa    xmm5,xmm3
 154         punpcklwd xmm2,xmm6
 155         punpckhwd xmm4,xmm6
 156         pmaddwd   xmm2,[rel PW_MF0344_F0285]
 157         pmaddwd   xmm4,[rel PW_MF0344_F0285]
 158         punpcklwd xmm3,xmm7
 159         punpckhwd xmm5,xmm7
 160         pmaddwd   xmm3,[rel PW_MF0344_F0285]
 161         pmaddwd   xmm5,[rel PW_MF0344_F0285]
 162
 163         paddd     xmm2,[rel PD_ONEHALF]
 164         paddd     xmm4,[rel PD_ONEHALF]
 165         psrad     xmm2,SCALEBITS
 166         psrad     xmm4,SCALEBITS
 167         paddd     xmm3,[rel PD_ONEHALF]
 168         paddd     xmm5,[rel PD_ONEHALF]
 169         psrad     xmm3,SCALEBITS
 170         psrad     xmm5,SCALEBITS
 171
 172         packssdw  xmm2,xmm4     ; xmm2=CbE*-FIX(0.344)+CrE*FIX(0.285)
 173         packssdw  xmm3,xmm5     ; xmm3=CbO*-FIX(0.344)+CrO*FIX(0.285)
 174         psubw     xmm2,xmm6     ; xmm2=CbE*-FIX(0.344)+CrE*-FIX(0.714)=(G-Y)E
 175         psubw     xmm3,xmm7     ; xmm3=CbO*-FIX(0.344)+CrO*-FIX(0.714)=(G-Y)O
 176
 177         movdqa    xmm5, XMMWORD [rsi]   ; xmm5=Y(0123456789ABCDEF)
 178
 179         pcmpeqw   xmm4,xmm4
 180         psrlw     xmm4,BYTE_BIT         ; xmm4={0xFF 0x00 0xFF 0x00 ..}
 181         pand      xmm4,xmm5             ; xmm4=Y(02468ACE)=YE
 182         psrlw     xmm5,BYTE_BIT         ; xmm5=Y(13579BDF)=YO
 183
 184         paddw     xmm0,xmm4             ; xmm0=((R-Y)E+YE)=RE=R(02468ACE)
 185         paddw     xmm1,xmm5             ; xmm1=((R-Y)O+YO)=RO=R(13579BDF)
 186         packuswb  xmm0,xmm0             ; xmm0=R(02468ACE********)
 187         packuswb  xmm1,xmm1             ; xmm1=R(13579BDF********)
 188
 189         paddw     xmm2,xmm4             ; xmm2=((G-Y)E+YE)=GE=G(02468ACE)
 190         paddw     xmm3,xmm5             ; xmm3=((G-Y)O+YO)=GO=G(13579BDF)
 191         packuswb  xmm2,xmm2             ; xmm2=G(02468ACE********)
 192         packuswb  xmm3,xmm3             ; xmm3=G(13579BDF********)
 193
 194         paddw     xmm4, XMMWORD [wk(0)] ; xmm4=(YE+(B-Y)E)=BE=B(02468ACE)
 195         paddw     xmm5, XMMWORD [wk(1)] ; xmm5=(YO+(B-Y)O)=BO=B(13579BDF)
 196         packuswb  xmm4,xmm4             ; xmm4=B(02468ACE********)
 197         packuswb  xmm5,xmm5             ; xmm5=B(13579BDF********)
 198
 199 %if RGB_PIXELSIZE == 3 ; ---------------
 200
 201         ; xmmA=(00 02 04 06 08 0A 0C 0E **), xmmB=(01 03 05 07 09 0B 0D 0F **)
 202         ; xmmC=(10 12 14 16 18 1A 1C 1E **), xmmD=(11 13 15 17 19 1B 1D 1F **)
 203         ; xmmE=(20 22 24 26 28 2A 2C 2E **), xmmF=(21 23 25 27 29 2B 2D 2F **)
 204         ; xmmG=(** ** ** ** ** ** ** ** **), xmmH=(** ** ** ** ** ** ** ** **)
 205
 206         punpcklbw xmmA,xmmC     ; xmmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E)
 207         punpcklbw xmmE,xmmB     ; xmmE=(20 01 22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F)
 208         punpcklbw xmmD,xmmF     ; xmmD=(11 21 13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F)
 209
 210         movdqa    xmmG,xmmA
 211         movdqa    xmmH,xmmA
 212         punpcklwd xmmA,xmmE     ; xmmA=(00 10 20 01 02 12 22 03 04 14 24 05 06 16 26 07)
 213         punpckhwd xmmG,xmmE     ; xmmG=(08 18 28 09 0A 1A 2A 0B 0C 1C 2C 0D 0E 1E 2E 0F)
 214
 215         psrldq    xmmH,2        ; xmmH=(02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E -- --)
 216         psrldq    xmmE,2        ; xmmE=(22 03 24 05 26 07 28 09 2A 0B 2C 0D 2E 0F -- --)
 217
 218         movdqa    xmmC,xmmD
 219         movdqa    xmmB,xmmD
 220         punpcklwd xmmD,xmmH     ; xmmD=(11 21 02 12 13 23 04 14 15 25 06 16 17 27 08 18)
 221         punpckhwd xmmC,xmmH     ; xmmC=(19 29 0A 1A 1B 2B 0C 1C 1D 2D 0E 1E 1F 2F -- --)
 222
 223         psrldq    xmmB,2        ; xmmB=(13 23 15 25 17 27 19 29 1B 2B 1D 2D 1F 2F -- --)
 224
 225         movdqa    xmmF,xmmE
 226         punpcklwd xmmE,xmmB     ; xmmE=(22 03 13 23 24 05 15 25 26 07 17 27 28 09 19 29)
 227         punpckhwd xmmF,xmmB     ; xmmF=(2A 0B 1B 2B 2C 0D 1D 2D 2E 0F 1F 2F -- -- -- --)
 228
 229         pshufd    xmmH,xmmA,0x4E; xmmH=(04 14 24 05 06 16 26 07 00 10 20 01 02 12 22 03)
 230         movdqa    xmmB,xmmE
 231         punpckldq xmmA,xmmD     ; xmmA=(00 10 20 01 11 21 02 12 02 12 22 03 13 23 04 14)
 232         punpckldq xmmE,xmmH     ; xmmE=(22 03 13 23 04 14 24 05 24 05 15 25 06 16 26 07)
 233         punpckhdq xmmD,xmmB     ; xmmD=(15 25 06 16 26 07 17 27 17 27 08 18 28 09 19 29)
 234
 235         pshufd    xmmH,xmmG,0x4E; xmmH=(0C 1C 2C 0D 0E 1E 2E 0F 08 18 28 09 0A 1A 2A 0B)
 236         movdqa    xmmB,xmmF
 237         punpckldq xmmG,xmmC     ; xmmG=(08 18 28 09 19 29 0A 1A 0A 1A 2A 0B 1B 2B 0C 1C)
 238         punpckldq xmmF,xmmH     ; xmmF=(2A 0B 1B 2B 0C 1C 2C 0D 2C 0D 1D 2D 0E 1E 2E 0F)
 239         punpckhdq xmmC,xmmB     ; xmmC=(1D 2D 0E 1E 2E 0F 1F 2F 1F 2F -- -- -- -- -- --)
 240
 241         punpcklqdq xmmA,xmmE    ; xmmA=(00 10 20 01 11 21 02 12 22 03 13 23 04 14 24 05)
 242         punpcklqdq xmmD,xmmG    ; xmmD=(15 25 06 16 26 07 17 27 08 18 28 09 19 29 0A 1A)
 243         punpcklqdq xmmF,xmmC    ; xmmF=(2A 0B 1B 2B 0C 1C 2C 0D 1D 2D 0E 1E 2E 0F 1F 2F)
 244
 245         cmp     rcx, byte SIZEOF_XMMWORD
 246         jb      short .column_st32
 247
 248         test    rdi, SIZEOF_XMMWORD-1
 249         jnz     short .out1
 250         ; --(aligned)-------------------
 251         movntdq XMMWORD [rdi+0*SIZEOF_XMMWORD], xmmA
 252         movntdq XMMWORD [rdi+1*SIZEOF_XMMWORD], xmmD
 253         movntdq XMMWORD [rdi+2*SIZEOF_XMMWORD], xmmF
 254         add     rdi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD  ; outptr
 255         jmp     short .out0
 256 .out1:  ; --(unaligned)-----------------
 257         pcmpeqb    xmmH,xmmH                    ; xmmH=(all 1's)
 258         maskmovdqu xmmA,xmmH                    ; movntdqu XMMWORD [rdi], xmmA
 259         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 260         maskmovdqu xmmD,xmmH                    ; movntdqu XMMWORD [rdi], xmmD
 261         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 262         maskmovdqu xmmF,xmmH                    ; movntdqu XMMWORD [rdi], xmmF
 263         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 264 .out0:
 265         sub     rcx, byte SIZEOF_XMMWORD
 266         jz      near .nextrow
 267
 268         add     rsi, byte SIZEOF_XMMWORD        ; inptr0
 269         add     rbx, byte SIZEOF_XMMWORD        ; inptr1
 270         add     rdx, byte SIZEOF_XMMWORD        ; inptr2
 271         jmp     near .columnloop
 272
 273 .column_st32:
 274         pcmpeqb xmmH,xmmH                       ; xmmH=(all 1's)
 275         lea     rcx, [rcx+rcx*2]                ; imul ecx, RGB_PIXELSIZE
 276         cmp     rcx, byte 2*SIZEOF_XMMWORD
 277         jb      short .column_st16
 278         maskmovdqu xmmA,xmmH                    ; movntdqu XMMWORD [rdi], xmmA
 279         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 280         maskmovdqu xmmD,xmmH                    ; movntdqu XMMWORD [rdi], xmmD
 281         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 282         movdqa  xmmA,xmmF
 283         sub     rcx, byte 2*SIZEOF_XMMWORD
 284         jmp     short .column_st15
 285 .column_st16:
 286         cmp     rcx, byte SIZEOF_XMMWORD
 287         jb      short .column_st15
 288         maskmovdqu xmmA,xmmH                    ; movntdqu XMMWORD [rdi], xmmA
 289         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 290         movdqa  xmmA,xmmD
 291         sub     rcx, byte SIZEOF_XMMWORD
 292 .column_st15:
 293 %ifdef STRICT_MEMORY_ACCESS
 294         ; Store the lower 8 bytes of xmmA to the output when it has enough
 295         ; space.
 296         cmp     rcx, byte SIZEOF_MMWORD
 297         jb      short .column_st7
 298         movq    MMWORD [rdi], xmmA
 299         add     rdi, byte SIZEOF_MMWORD
 300         sub     rcx, byte SIZEOF_MMWORD
 301         psrldq  xmmA, SIZEOF_MMWORD
 302 .column_st7:
 303         ; Store the lower 4 bytes of xmmA to the output when it has enough
 304         ; space.
 305         cmp     rcx, byte SIZEOF_DWORD
 306         jb      short .column_st3
 307         movd    DWORD [rdi], xmmA
 308         add     rdi, byte SIZEOF_DWORD
 309         sub     rcx, byte SIZEOF_DWORD
 310         psrldq  xmmA, SIZEOF_DWORD
 311 .column_st3:
 312         ; Store the lower 2 bytes of rax to the output when it has enough
 313         ; space.
 314         movd    eax, xmmA
 315         cmp     rcx, byte SIZEOF_WORD
 316         jb      short .column_st1
 317         mov     WORD [rdi], ax
 318         add     rdi, byte SIZEOF_WORD
 319         sub     rcx, byte SIZEOF_WORD
 320         shr     rax, 16
 321 .column_st1:
 322         ; Store the lower 1 byte of rax to the output when it has enough
 323         ; space.
 324         test    rcx, rcx
 325         jz      short .nextrow
 326         mov     BYTE [rdi], al
 327 %else
 328         mov     rax,rcx
 329         xor     rcx, byte 0x0F
 330         shl     rcx, 2
 331         movd    xmmB,ecx
 332         psrlq   xmmH,4
 333         pcmpeqb xmmE,xmmE
 334         psrlq   xmmH,xmmB
 335         psrlq   xmmE,xmmB
 336         punpcklbw xmmE,xmmH
 337         ; ----------------
 338         mov     rcx,rdi
 339         and     rcx, byte SIZEOF_XMMWORD-1
 340         jz      short .adj0
 341         add     rax,rcx
 342         cmp     rax, byte SIZEOF_XMMWORD
 343         ja      short .adj0
 344         and     rdi, byte (-SIZEOF_XMMWORD)     ; align to 16-byte boundary
 345         shl     rcx, 3                  ; pslldq xmmA,ecx & pslldq xmmE,rcx
 346         movdqa  xmmG,xmmA
 347         movdqa  xmmC,xmmE
 348         pslldq  xmmA, SIZEOF_XMMWORD/2
 349         pslldq  xmmE, SIZEOF_XMMWORD/2
 350         movd    xmmD,ecx
 351         sub     rcx, byte (SIZEOF_XMMWORD/2)*BYTE_BIT
 352         jb      short .adj1
 353         movd    xmmF,ecx
 354         psllq   xmmA,xmmF
 355         psllq   xmmE,xmmF
 356         jmp     short .adj0
 357 .adj1:  neg     ecx
 358         movd    xmmF,ecx
 359         psrlq   xmmA,xmmF
 360         psrlq   xmmE,xmmF
 361         psllq   xmmG,xmmD
 362         psllq   xmmC,xmmD
 363         por     xmmA,xmmG
 364         por     xmmE,xmmC
 365 .adj0:  ; ----------------
 366         maskmovdqu xmmA,xmmE                    ; movntdqu XMMWORD [rdi], xmmA
 367 %endif ; STRICT_MEMORY_ACCESS ; ---------------
 368
 369 %else ; RGB_PIXELSIZE == 4 ; -----------
 370
 371 %ifdef RGBX_FILLER_0XFF
 372         pcmpeqb   xmm6,xmm6             ; xmm6=XE=X(02468ACE********)
 373         pcmpeqb   xmm7,xmm7             ; xmm7=XO=X(13579BDF********)
 374 %else
 375         pxor      xmm6,xmm6             ; xmm6=XE=X(02468ACE********)
 376         pxor      xmm7,xmm7             ; xmm7=XO=X(13579BDF********)
 377 %endif
 378         ; xmmA=(00 02 04 06 08 0A 0C 0E **), xmmB=(01 03 05 07 09 0B 0D 0F **)
 379         ; xmmC=(10 12 14 16 18 1A 1C 1E **), xmmD=(11 13 15 17 19 1B 1D 1F **)
 380         ; xmmE=(20 22 24 26 28 2A 2C 2E **), xmmF=(21 23 25 27 29 2B 2D 2F **)
 381         ; xmmG=(30 32 34 36 38 3A 3C 3E **), xmmH=(31 33 35 37 39 3B 3D 3F **)
 382
 383         punpcklbw xmmA,xmmC     ; xmmA=(00 10 02 12 04 14 06 16 08 18 0A 1A 0C 1C 0E 1E)
 384         punpcklbw xmmE,xmmG     ; xmmE=(20 30 22 32 24 34 26 36 28 38 2A 3A 2C 3C 2E 3E)
 385         punpcklbw xmmB,xmmD     ; xmmB=(01 11 03 13 05 15 07 17 09 19 0B 1B 0D 1D 0F 1F)
 386         punpcklbw xmmF,xmmH     ; xmmF=(21 31 23 33 25 35 27 37 29 39 2B 3B 2D 3D 2F 3F)
 387
 388         movdqa    xmmC,xmmA
 389         punpcklwd xmmA,xmmE     ; xmmA=(00 10 20 30 02 12 22 32 04 14 24 34 06 16 26 36)
 390         punpckhwd xmmC,xmmE     ; xmmC=(08 18 28 38 0A 1A 2A 3A 0C 1C 2C 3C 0E 1E 2E 3E)
 391         movdqa    xmmG,xmmB
 392         punpcklwd xmmB,xmmF     ; xmmB=(01 11 21 31 03 13 23 33 05 15 25 35 07 17 27 37)
 393         punpckhwd xmmG,xmmF     ; xmmG=(09 19 29 39 0B 1B 2B 3B 0D 1D 2D 3D 0F 1F 2F 3F)
 394
 395         movdqa    xmmD,xmmA
 396         punpckldq xmmA,xmmB     ; xmmA=(00 10 20 30 01 11 21 31 02 12 22 32 03 13 23 33)
 397         punpckhdq xmmD,xmmB     ; xmmD=(04 14 24 34 05 15 25 35 06 16 26 36 07 17 27 37)
 398         movdqa    xmmH,xmmC
 399         punpckldq xmmC,xmmG     ; xmmC=(08 18 28 38 09 19 29 39 0A 1A 2A 3A 0B 1B 2B 3B)
 400         punpckhdq xmmH,xmmG     ; xmmH=(0C 1C 2C 3C 0D 1D 2D 3D 0E 1E 2E 3E 0F 1F 2F 3F)
 401
 402         cmp     rcx, byte SIZEOF_XMMWORD
 403         jb      short .column_st32
 404
 405         test    rdi, SIZEOF_XMMWORD-1
 406         jnz     short .out1
 407         ; --(aligned)-------------------
 408         movntdq XMMWORD [rdi+0*SIZEOF_XMMWORD], xmmA
 409         movntdq XMMWORD [rdi+1*SIZEOF_XMMWORD], xmmD
 410         movntdq XMMWORD [rdi+2*SIZEOF_XMMWORD], xmmC
 411         movntdq XMMWORD [rdi+3*SIZEOF_XMMWORD], xmmH
 412         add     rdi, byte RGB_PIXELSIZE*SIZEOF_XMMWORD  ; outptr
 413         jmp     short .out0
 414 .out1:  ; --(unaligned)-----------------
 415         pcmpeqb    xmmE,xmmE                    ; xmmE=(all 1's)
 416         maskmovdqu xmmA,xmmE                    ; movntdqu XMMWORD [rdi], xmmA
 417         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 418         maskmovdqu xmmD,xmmE                    ; movntdqu XMMWORD [rdi], xmmD
 419         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 420         maskmovdqu xmmC,xmmE                    ; movntdqu XMMWORD [rdi], xmmC
 421         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 422         maskmovdqu xmmH,xmmE                    ; movntdqu XMMWORD [rdi], xmmH
 423         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 424 .out0:
 425         sub     rcx, byte SIZEOF_XMMWORD
 426         jz      near .nextrow
 427
 428         add     rsi, byte SIZEOF_XMMWORD        ; inptr0
 429         add     rbx, byte SIZEOF_XMMWORD        ; inptr1
 430         add     rdx, byte SIZEOF_XMMWORD        ; inptr2
 431         jmp     near .columnloop
 432
 433 .column_st32:
 434         pcmpeqb xmmE,xmmE                       ; xmmE=(all 1's)
 435         cmp     rcx, byte SIZEOF_XMMWORD/2
 436         jb      short .column_st16
 437         maskmovdqu xmmA,xmmE                    ; movntdqu XMMWORD [rdi], xmmA
 438         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 439         maskmovdqu xmmD,xmmE                    ; movntdqu XMMWORD [rdi], xmmD
 440         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 441         movdqa  xmmA,xmmC
 442         movdqa  xmmD,xmmH
 443         sub     rcx, byte SIZEOF_XMMWORD/2
 444 .column_st16:
 445         cmp     rcx, byte SIZEOF_XMMWORD/4
 446         jb      short .column_st15
 447         maskmovdqu xmmA,xmmE                    ; movntdqu XMMWORD [rdi], xmmA
 448         add     rdi, byte SIZEOF_XMMWORD        ; outptr
 449         movdqa  xmmA,xmmD
 450         sub     rcx, byte SIZEOF_XMMWORD/4
 451 .column_st15:
 452 %ifdef STRICT_MEMORY_ACCESS
 453         ; Store two pixels (8 bytes) of xmmA to the output when it has enough
 454         ; space.
 455         cmp     rcx, byte SIZEOF_XMMWORD/8
 456         jb      short .column_st7
 457         movq    MMWORD [rdi], xmmA
 458         add     rdi, byte SIZEOF_XMMWORD/8*4
 459         sub     rcx, byte SIZEOF_XMMWORD/8
 460         psrldq  xmmA, SIZEOF_XMMWORD/8*4
 461 .column_st7:
 462         ; Store one pixel (4 bytes) of xmmA to the output when it has enough
 463         ; space.
 464         test    rcx, rcx
 465         jz      short .nextrow
 466         movd    DWORD [rdi], xmmA
 467 %else
 468         cmp     rcx, byte SIZEOF_XMMWORD/16
 469         jb      near .nextrow
 470         mov     rax,rcx
 471         xor     rcx, byte 0x03
 472         inc     rcx
 473         shl     rcx, 4
 474         movd    xmmF,ecx
 475         psrlq   xmmE,xmmF
 476         punpcklbw xmmE,xmmE
 477         ; ----------------
 478         mov     rcx,rdi
 479         and     rcx, byte SIZEOF_XMMWORD-1
 480         jz      short .adj0
 481         lea     rax, [rcx+rax*4]        ; RGB_PIXELSIZE
 482         cmp     rax, byte SIZEOF_XMMWORD
 483         ja      short .adj0
 484         and     rdi, byte (-SIZEOF_XMMWORD)     ; align to 16-byte boundary
 485         shl     rcx, 3                  ; pslldq xmmA,ecx & pslldq xmmE,ecx
 486         movdqa  xmmB,xmmA
 487         movdqa  xmmG,xmmE
 488         pslldq  xmmA, SIZEOF_XMMWORD/2
 489         pslldq  xmmE, SIZEOF_XMMWORD/2
 490         movd    xmmC,ecx
 491         sub     rcx, byte (SIZEOF_XMMWORD/2)*BYTE_BIT
 492         jb      short .adj1
 493         movd    xmmH,ecx
 494         psllq   xmmA,xmmH
 495         psllq   xmmE,xmmH
 496         jmp     short .adj0
 497 .adj1:  neg     rcx
 498         movd    xmmH,ecx
 499         psrlq   xmmA,xmmH
 500         psrlq   xmmE,xmmH
 501         psllq   xmmB,xmmC
 502         psllq   xmmG,xmmC
 503         por     xmmA,xmmB
 504         por     xmmE,xmmG
 505 .adj0:  ; ----------------
 506         maskmovdqu xmmA,xmmE                    ; movntdqu XMMWORD [rdi], xmmA
 507 %endif ; STRICT_MEMORY_ACCESS ; ---------------
 508
 509 %endif ; RGB_PIXELSIZE ; ---------------
 510
 511 .nextrow:
 512         pop     rcx
 513         pop     rsi
 514         pop     rbx
 515         pop     rdx
 516         pop     rdi
 517         pop     rax
 518
 519         add     rsi, byte SIZEOF_JSAMPROW
 520         add     rbx, byte SIZEOF_JSAMPROW
 521         add     rdx, byte SIZEOF_JSAMPROW
 522         add     rdi, byte SIZEOF_JSAMPROW       ; output_buf
 523         dec     rax                             ; num_rows
 524         jg      near .rowloop
 525
 526         sfence          ; flush the write buffer
 527
 528 .return:
 529         pop     rbx
 530         uncollect_args
 531         mov     rsp,rbp         ; rsp <- aligned rbp
 532         pop     rsp             ; rsp <- original rbp
 533         pop     rbp
 534         ret
 535
 536 ; For some reason, the OS X linker does not honor the request to align the
 537 ; segment unless we do this.
 538         align   16