simd/i386/jfdctint-sse2.asm

   1 ;
   2 ; jfdctint.asm - accurate integer FDCT (SSE2)
   3 ;
   4 ; Copyright 2009 Pierre Ossman <ossman@cendio.se> for Cendio AB
   5 ; Copyright (C) 2016, D. R. Commander.
   6 ;
   7 ; Based on the x86 SIMD extension for IJG JPEG library
   8 ; Copyright (C) 1999-2006, MIYASAKA Masaru.
   9 ; For conditions of distribution and use, see copyright notice in jsimdext.inc
  10 ;
  11 ; This file should be assembled with NASM (Netwide Assembler),
  12 ; can *not* be assembled with Microsoft's MASM or any compatible
  13 ; assembler (including Borland's Turbo Assembler).
  14 ; NASM is available from http://nasm.sourceforge.net/ or
  15 ; http://sourceforge.net/project/showfiles.php?group_id=6208
  16 ;
  17 ; This file contains a slow-but-accurate integer implementation of the
  18 ; forward DCT (Discrete Cosine Transform). The following code is based
  19 ; directly on the IJG's original jfdctint.c; see the jfdctint.c for
  20 ; more details.
  21 ;
  22 ; [TAB8]
  23
  24 %include "jsimdext.inc"
  25 %include "jdct.inc"
  26
  27 ; --------------------------------------------------------------------------
  28
  29 %define CONST_BITS  13
  30 %define PASS1_BITS  2
  31
  32 %define DESCALE_P1  (CONST_BITS - PASS1_BITS)
  33 %define DESCALE_P2  (CONST_BITS + PASS1_BITS)
  34
  35 %if CONST_BITS == 13
  36 F_0_298 equ  2446  ; FIX(0.298631336)
  37 F_0_390 equ  3196  ; FIX(0.390180644)
  38 F_0_541 equ  4433  ; FIX(0.541196100)
  39 F_0_765 equ  6270  ; FIX(0.765366865)
  40 F_0_899 equ  7373  ; FIX(0.899976223)
  41 F_1_175 equ  9633  ; FIX(1.175875602)
  42 F_1_501 equ 12299  ; FIX(1.501321110)
  43 F_1_847 equ 15137  ; FIX(1.847759065)
  44 F_1_961 equ 16069  ; FIX(1.961570560)
  45 F_2_053 equ 16819  ; FIX(2.053119869)
  46 F_2_562 equ 20995  ; FIX(2.562915447)
  47 F_3_072 equ 25172  ; FIX(3.072711026)
  48 %else
  49 ; NASM cannot do compile-time arithmetic on floating-point constants.
  50 %define DESCALE(x, n)  (((x) + (1 << ((n) - 1))) >> (n))
  51 F_0_298 equ DESCALE( 320652955, 30 - CONST_BITS)  ; FIX(0.298631336)
  52 F_0_390 equ DESCALE( 418953276, 30 - CONST_BITS)  ; FIX(0.390180644)
  53 F_0_541 equ DESCALE( 581104887, 30 - CONST_BITS)  ; FIX(0.541196100)
  54 F_0_765 equ DESCALE( 821806413, 30 - CONST_BITS)  ; FIX(0.765366865)
  55 F_0_899 equ DESCALE( 966342111, 30 - CONST_BITS)  ; FIX(0.899976223)
  56 F_1_175 equ DESCALE(1262586813, 30 - CONST_BITS)  ; FIX(1.175875602)
  57 F_1_501 equ DESCALE(1612031267, 30 - CONST_BITS)  ; FIX(1.501321110)
  58 F_1_847 equ DESCALE(1984016188, 30 - CONST_BITS)  ; FIX(1.847759065)
  59 F_1_961 equ DESCALE(2106220350, 30 - CONST_BITS)  ; FIX(1.961570560)
  60 F_2_053 equ DESCALE(2204520673, 30 - CONST_BITS)  ; FIX(2.053119869)
  61 F_2_562 equ DESCALE(2751909506, 30 - CONST_BITS)  ; FIX(2.562915447)
  62 F_3_072 equ DESCALE(3299298341, 30 - CONST_BITS)  ; FIX(3.072711026)
  63 %endif
  64
  65 ; --------------------------------------------------------------------------
  66     SECTION     SEG_CONST
  67
  68     alignz      32
  69     GLOBAL_DATA(jconst_fdct_islow_sse2)
  70
  71 EXTN(jconst_fdct_islow_sse2):
  72
  73 PW_F130_F054   times 4 dw  (F_0_541 + F_0_765),  F_0_541
  74 PW_F054_MF130  times 4 dw  F_0_541, (F_0_541 - F_1_847)
  75 PW_MF078_F117  times 4 dw  (F_1_175 - F_1_961),  F_1_175
  76 PW_F117_F078   times 4 dw  F_1_175, (F_1_175 - F_0_390)
  77 PW_MF060_MF089 times 4 dw  (F_0_298 - F_0_899), -F_0_899
  78 PW_MF089_F060  times 4 dw -F_0_899, (F_1_501 - F_0_899)
  79 PW_MF050_MF256 times 4 dw  (F_2_053 - F_2_562), -F_2_562
  80 PW_MF256_F050  times 4 dw -F_2_562, (F_3_072 - F_2_562)
  81 PD_DESCALE_P1  times 4 dd  1 << (DESCALE_P1 - 1)
  82 PD_DESCALE_P2  times 4 dd  1 << (DESCALE_P2 - 1)
  83 PW_DESCALE_P2X times 8 dw  1 << (PASS1_BITS - 1)
  84
  85     alignz      32
  86
  87 ; --------------------------------------------------------------------------
  88     SECTION     SEG_TEXT
  89     BITS        32
  90 ;
  91 ; Perform the forward DCT on one block of samples.
  92 ;
  93 ; GLOBAL(void)
  94 ; jsimd_fdct_islow_sse2(DCTELEM *data)
  95 ;
  96
  97 %define data(b)       (b) + 8           ; DCTELEM *data
  98
  99 %define original_ebp  ebp + 0
 100 %define wk(i)         ebp - (WK_NUM - (i)) * SIZEOF_XMMWORD
 101                                         ; xmmword wk[WK_NUM]
 102 %define WK_NUM        6
 103
 104     align       32
 105     GLOBAL_FUNCTION(jsimd_fdct_islow_sse2)
 106
 107 EXTN(jsimd_fdct_islow_sse2):
 108     push        ebp
 109     mov         eax, esp                     ; eax = original ebp
 110     sub         esp, byte 4
 111     and         esp, byte (-SIZEOF_XMMWORD)  ; align to 128 bits
 112     mov         [esp], eax
 113     mov         ebp, esp                     ; ebp = aligned ebp
 114     lea         esp, [wk(0)]
 115     pushpic     ebx
 116 ;   push        ecx                     ; unused
 117 ;   push        edx                     ; need not be preserved
 118 ;   push        esi                     ; unused
 119 ;   push        edi                     ; unused
 120
 121     get_GOT     ebx                     ; get GOT address
 122
 123     ; ---- Pass 1: process rows.
 124
 125     mov         edx, POINTER [data(eax)]  ; (DCTELEM *)
 126
 127     movdqa      xmm0, XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_DCTELEM)]
 128     movdqa      xmm1, XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_DCTELEM)]
 129     movdqa      xmm2, XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_DCTELEM)]
 130     movdqa      xmm3, XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_DCTELEM)]
 131
 132     ; xmm0=(00 01 02 03 04 05 06 07), xmm2=(20 21 22 23 24 25 26 27)
 133     ; xmm1=(10 11 12 13 14 15 16 17), xmm3=(30 31 32 33 34 35 36 37)
 134
 135     movdqa      xmm4, xmm0              ; transpose coefficients(phase 1)
 136     punpcklwd   xmm0, xmm1              ; xmm0=(00 10 01 11 02 12 03 13)
 137     punpckhwd   xmm4, xmm1              ; xmm4=(04 14 05 15 06 16 07 17)
 138     movdqa      xmm5, xmm2              ; transpose coefficients(phase 1)
 139     punpcklwd   xmm2, xmm3              ; xmm2=(20 30 21 31 22 32 23 33)
 140     punpckhwd   xmm5, xmm3              ; xmm5=(24 34 25 35 26 36 27 37)
 141
 142     movdqa      xmm6, XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_DCTELEM)]
 143     movdqa      xmm7, XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_DCTELEM)]
 144     movdqa      xmm1, XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_DCTELEM)]
 145     movdqa      xmm3, XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_DCTELEM)]
 146
 147     ; xmm6=( 4 12 20 28 36 44 52 60), xmm1=( 6 14 22 30 38 46 54 62)
 148     ; xmm7=( 5 13 21 29 37 45 53 61), xmm3=( 7 15 23 31 39 47 55 63)
 149
 150     movdqa      XMMWORD [wk(0)], xmm2   ; wk(0)=(20 30 21 31 22 32 23 33)
 151     movdqa      XMMWORD [wk(1)], xmm5   ; wk(1)=(24 34 25 35 26 36 27 37)
 152
 153     movdqa      xmm2, xmm6              ; transpose coefficients(phase 1)
 154     punpcklwd   xmm6, xmm7              ; xmm6=(40 50 41 51 42 52 43 53)
 155     punpckhwd   xmm2, xmm7              ; xmm2=(44 54 45 55 46 56 47 57)
 156     movdqa      xmm5, xmm1              ; transpose coefficients(phase 1)
 157     punpcklwd   xmm1, xmm3              ; xmm1=(60 70 61 71 62 72 63 73)
 158     punpckhwd   xmm5, xmm3              ; xmm5=(64 74 65 75 66 76 67 77)
 159
 160     movdqa      xmm7, xmm6              ; transpose coefficients(phase 2)
 161     punpckldq   xmm6, xmm1              ; xmm6=(40 50 60 70 41 51 61 71)
 162     punpckhdq   xmm7, xmm1              ; xmm7=(42 52 62 72 43 53 63 73)
 163     movdqa      xmm3, xmm2              ; transpose coefficients(phase 2)
 164     punpckldq   xmm2, xmm5              ; xmm2=(44 54 64 74 45 55 65 75)
 165     punpckhdq   xmm3, xmm5              ; xmm3=(46 56 66 76 47 57 67 77)
 166
 167     movdqa      xmm1, XMMWORD [wk(0)]   ; xmm1=(20 30 21 31 22 32 23 33)
 168     movdqa      xmm5, XMMWORD [wk(1)]   ; xmm5=(24 34 25 35 26 36 27 37)
 169     movdqa      XMMWORD [wk(2)], xmm7   ; wk(2)=(42 52 62 72 43 53 63 73)
 170     movdqa      XMMWORD [wk(3)], xmm2   ; wk(3)=(44 54 64 74 45 55 65 75)
 171
 172     movdqa      xmm7, xmm0              ; transpose coefficients(phase 2)
 173     punpckldq   xmm0, xmm1              ; xmm0=(00 10 20 30 01 11 21 31)
 174     punpckhdq   xmm7, xmm1              ; xmm7=(02 12 22 32 03 13 23 33)
 175     movdqa      xmm2, xmm4              ; transpose coefficients(phase 2)
 176     punpckldq   xmm4, xmm5              ; xmm4=(04 14 24 34 05 15 25 35)
 177     punpckhdq   xmm2, xmm5              ; xmm2=(06 16 26 36 07 17 27 37)
 178
 179     movdqa      xmm1, xmm0              ; transpose coefficients(phase 3)
 180     punpcklqdq  xmm0, xmm6              ; xmm0=(00 10 20 30 40 50 60 70)=data0
 181     punpckhqdq  xmm1, xmm6              ; xmm1=(01 11 21 31 41 51 61 71)=data1
 182     movdqa      xmm5, xmm2              ; transpose coefficients(phase 3)
 183     punpcklqdq  xmm2, xmm3              ; xmm2=(06 16 26 36 46 56 66 76)=data6
 184     punpckhqdq  xmm5, xmm3              ; xmm5=(07 17 27 37 47 57 67 77)=data7
 185
 186     movdqa      xmm6, xmm1
 187     movdqa      xmm3, xmm0
 188     psubw       xmm1, xmm2              ; xmm1=data1-data6=tmp6
 189     psubw       xmm0, xmm5              ; xmm0=data0-data7=tmp7
 190     paddw       xmm6, xmm2              ; xmm6=data1+data6=tmp1
 191     paddw       xmm3, xmm5              ; xmm3=data0+data7=tmp0
 192
 193     movdqa      xmm2, XMMWORD [wk(2)]   ; xmm2=(42 52 62 72 43 53 63 73)
 194     movdqa      xmm5, XMMWORD [wk(3)]   ; xmm5=(44 54 64 74 45 55 65 75)
 195     movdqa      XMMWORD [wk(0)], xmm1   ; wk(0)=tmp6
 196     movdqa      XMMWORD [wk(1)], xmm0   ; wk(1)=tmp7
 197
 198     movdqa      xmm1, xmm7              ; transpose coefficients(phase 3)
 199     punpcklqdq  xmm7, xmm2              ; xmm7=(02 12 22 32 42 52 62 72)=data2
 200     punpckhqdq  xmm1, xmm2              ; xmm1=(03 13 23 33 43 53 63 73)=data3
 201     movdqa      xmm0, xmm4              ; transpose coefficients(phase 3)
 202     punpcklqdq  xmm4, xmm5              ; xmm4=(04 14 24 34 44 54 64 74)=data4
 203     punpckhqdq  xmm0, xmm5              ; xmm0=(05 15 25 35 45 55 65 75)=data5
 204
 205     movdqa      xmm2, xmm1
 206     movdqa      xmm5, xmm7
 207     paddw       xmm1, xmm4              ; xmm1=data3+data4=tmp3
 208     paddw       xmm7, xmm0              ; xmm7=data2+data5=tmp2
 209     psubw       xmm2, xmm4              ; xmm2=data3-data4=tmp4
 210     psubw       xmm5, xmm0              ; xmm5=data2-data5=tmp5
 211
 212     ; -- Even part
 213
 214     movdqa      xmm4, xmm3
 215     movdqa      xmm0, xmm6
 216     paddw       xmm3, xmm1              ; xmm3=tmp10
 217     paddw       xmm6, xmm7              ; xmm6=tmp11
 218     psubw       xmm4, xmm1              ; xmm4=tmp13
 219     psubw       xmm0, xmm7              ; xmm0=tmp12
 220
 221     movdqa      xmm1, xmm3
 222     paddw       xmm3, xmm6              ; xmm3=tmp10+tmp11
 223     psubw       xmm1, xmm6              ; xmm1=tmp10-tmp11
 224
 225     psllw       xmm3, PASS1_BITS        ; xmm3=data0
 226     psllw       xmm1, PASS1_BITS        ; xmm1=data4
 227
 228     movdqa      XMMWORD [wk(2)], xmm3   ; wk(2)=data0
 229     movdqa      XMMWORD [wk(3)], xmm1   ; wk(3)=data4
 230
 231     ; (Original)
 232     ; z1 = (tmp12 + tmp13) * 0.541196100;
 233     ; data2 = z1 + tmp13 * 0.765366865;
 234     ; data6 = z1 + tmp12 * -1.847759065;
 235     ;
 236     ; (This implementation)
 237     ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
 238     ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
 239
 240     movdqa      xmm7, xmm4              ; xmm4=tmp13
 241     movdqa      xmm6, xmm4
 242     punpcklwd   xmm7, xmm0              ; xmm0=tmp12
 243     punpckhwd   xmm6, xmm0
 244     movdqa      xmm4, xmm7
 245     movdqa      xmm0, xmm6
 246     pmaddwd     xmm7, [GOTOFF(ebx,PW_F130_F054)]   ; xmm7=data2L
 247     pmaddwd     xmm6, [GOTOFF(ebx,PW_F130_F054)]   ; xmm6=data2H
 248     pmaddwd     xmm4, [GOTOFF(ebx,PW_F054_MF130)]  ; xmm4=data6L
 249     pmaddwd     xmm0, [GOTOFF(ebx,PW_F054_MF130)]  ; xmm0=data6H
 250
 251     paddd       xmm7, [GOTOFF(ebx,PD_DESCALE_P1)]
 252     paddd       xmm6, [GOTOFF(ebx,PD_DESCALE_P1)]
 253     psrad       xmm7, DESCALE_P1
 254     psrad       xmm6, DESCALE_P1
 255     paddd       xmm4, [GOTOFF(ebx,PD_DESCALE_P1)]
 256     paddd       xmm0, [GOTOFF(ebx,PD_DESCALE_P1)]
 257     psrad       xmm4, DESCALE_P1
 258     psrad       xmm0, DESCALE_P1
 259
 260     packssdw    xmm7, xmm6              ; xmm7=data2
 261     packssdw    xmm4, xmm0              ; xmm4=data6
 262
 263     movdqa      XMMWORD [wk(4)], xmm7   ; wk(4)=data2
 264     movdqa      XMMWORD [wk(5)], xmm4   ; wk(5)=data6
 265
 266     ; -- Odd part
 267
 268     movdqa      xmm3, XMMWORD [wk(0)]   ; xmm3=tmp6
 269     movdqa      xmm1, XMMWORD [wk(1)]   ; xmm1=tmp7
 270
 271     movdqa      xmm6, xmm2              ; xmm2=tmp4
 272     movdqa      xmm0, xmm5              ; xmm5=tmp5
 273     paddw       xmm6, xmm3              ; xmm6=z3
 274     paddw       xmm0, xmm1              ; xmm0=z4
 275
 276     ; (Original)
 277     ; z5 = (z3 + z4) * 1.175875602;
 278     ; z3 = z3 * -1.961570560;  z4 = z4 * -0.390180644;
 279     ; z3 += z5;  z4 += z5;
 280     ;
 281     ; (This implementation)
 282     ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
 283     ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
 284
 285     movdqa      xmm7, xmm6
 286     movdqa      xmm4, xmm6
 287     punpcklwd   xmm7, xmm0
 288     punpckhwd   xmm4, xmm0
 289     movdqa      xmm6, xmm7
 290     movdqa      xmm0, xmm4
 291     pmaddwd     xmm7, [GOTOFF(ebx,PW_MF078_F117)]  ; xmm7=z3L
 292     pmaddwd     xmm4, [GOTOFF(ebx,PW_MF078_F117)]  ; xmm4=z3H
 293     pmaddwd     xmm6, [GOTOFF(ebx,PW_F117_F078)]   ; xmm6=z4L
 294     pmaddwd     xmm0, [GOTOFF(ebx,PW_F117_F078)]   ; xmm0=z4H
 295
 296     movdqa      XMMWORD [wk(0)], xmm7   ; wk(0)=z3L
 297     movdqa      XMMWORD [wk(1)], xmm4   ; wk(1)=z3H
 298
 299     ; (Original)
 300     ; z1 = tmp4 + tmp7;  z2 = tmp5 + tmp6;
 301     ; tmp4 = tmp4 * 0.298631336;  tmp5 = tmp5 * 2.053119869;
 302     ; tmp6 = tmp6 * 3.072711026;  tmp7 = tmp7 * 1.501321110;
 303     ; z1 = z1 * -0.899976223;  z2 = z2 * -2.562915447;
 304     ; data7 = tmp4 + z1 + z3;  data5 = tmp5 + z2 + z4;
 305     ; data3 = tmp6 + z2 + z3;  data1 = tmp7 + z1 + z4;
 306     ;
 307     ; (This implementation)
 308     ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
 309     ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
 310     ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
 311     ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
 312     ; data7 = tmp4 + z3;  data5 = tmp5 + z4;
 313     ; data3 = tmp6 + z3;  data1 = tmp7 + z4;
 314
 315     movdqa      xmm7, xmm2
 316     movdqa      xmm4, xmm2
 317     punpcklwd   xmm7, xmm1
 318     punpckhwd   xmm4, xmm1
 319     movdqa      xmm2, xmm7
 320     movdqa      xmm1, xmm4
 321     pmaddwd     xmm7, [GOTOFF(ebx,PW_MF060_MF089)]  ; xmm7=tmp4L
 322     pmaddwd     xmm4, [GOTOFF(ebx,PW_MF060_MF089)]  ; xmm4=tmp4H
 323     pmaddwd     xmm2, [GOTOFF(ebx,PW_MF089_F060)]   ; xmm2=tmp7L
 324     pmaddwd     xmm1, [GOTOFF(ebx,PW_MF089_F060)]   ; xmm1=tmp7H
 325
 326     paddd       xmm7, XMMWORD [wk(0)]   ; xmm7=data7L
 327     paddd       xmm4, XMMWORD [wk(1)]   ; xmm4=data7H
 328     paddd       xmm2, xmm6              ; xmm2=data1L
 329     paddd       xmm1, xmm0              ; xmm1=data1H
 330
 331     paddd       xmm7, [GOTOFF(ebx,PD_DESCALE_P1)]
 332     paddd       xmm4, [GOTOFF(ebx,PD_DESCALE_P1)]
 333     psrad       xmm7, DESCALE_P1
 334     psrad       xmm4, DESCALE_P1
 335     paddd       xmm2, [GOTOFF(ebx,PD_DESCALE_P1)]
 336     paddd       xmm1, [GOTOFF(ebx,PD_DESCALE_P1)]
 337     psrad       xmm2, DESCALE_P1
 338     psrad       xmm1, DESCALE_P1
 339
 340     packssdw    xmm7, xmm4              ; xmm7=data7
 341     packssdw    xmm2, xmm1              ; xmm2=data1
 342
 343     movdqa      xmm4, xmm5
 344     movdqa      xmm1, xmm5
 345     punpcklwd   xmm4, xmm3
 346     punpckhwd   xmm1, xmm3
 347     movdqa      xmm5, xmm4
 348     movdqa      xmm3, xmm1
 349     pmaddwd     xmm4, [GOTOFF(ebx,PW_MF050_MF256)]  ; xmm4=tmp5L
 350     pmaddwd     xmm1, [GOTOFF(ebx,PW_MF050_MF256)]  ; xmm1=tmp5H
 351     pmaddwd     xmm5, [GOTOFF(ebx,PW_MF256_F050)]   ; xmm5=tmp6L
 352     pmaddwd     xmm3, [GOTOFF(ebx,PW_MF256_F050)]   ; xmm3=tmp6H
 353
 354     paddd       xmm4, xmm6              ; xmm4=data5L
 355     paddd       xmm1, xmm0              ; xmm1=data5H
 356     paddd       xmm5, XMMWORD [wk(0)]   ; xmm5=data3L
 357     paddd       xmm3, XMMWORD [wk(1)]   ; xmm3=data3H
 358
 359     paddd       xmm4, [GOTOFF(ebx,PD_DESCALE_P1)]
 360     paddd       xmm1, [GOTOFF(ebx,PD_DESCALE_P1)]
 361     psrad       xmm4, DESCALE_P1
 362     psrad       xmm1, DESCALE_P1
 363     paddd       xmm5, [GOTOFF(ebx,PD_DESCALE_P1)]
 364     paddd       xmm3, [GOTOFF(ebx,PD_DESCALE_P1)]
 365     psrad       xmm5, DESCALE_P1
 366     psrad       xmm3, DESCALE_P1
 367
 368     packssdw    xmm4, xmm1              ; xmm4=data5
 369     packssdw    xmm5, xmm3              ; xmm5=data3
 370
 371     ; ---- Pass 2: process columns.
 372
 373 ;   mov         edx, POINTER [data(eax)]  ; (DCTELEM *)
 374
 375     movdqa      xmm6, XMMWORD [wk(2)]   ; xmm6=col0
 376     movdqa      xmm0, XMMWORD [wk(4)]   ; xmm0=col2
 377
 378     ; xmm6=(00 10 20 30 40 50 60 70), xmm0=(02 12 22 32 42 52 62 72)
 379     ; xmm2=(01 11 21 31 41 51 61 71), xmm5=(03 13 23 33 43 53 63 73)
 380
 381     movdqa      xmm1, xmm6              ; transpose coefficients(phase 1)
 382     punpcklwd   xmm6, xmm2              ; xmm6=(00 01 10 11 20 21 30 31)
 383     punpckhwd   xmm1, xmm2              ; xmm1=(40 41 50 51 60 61 70 71)
 384     movdqa      xmm3, xmm0              ; transpose coefficients(phase 1)
 385     punpcklwd   xmm0, xmm5              ; xmm0=(02 03 12 13 22 23 32 33)
 386     punpckhwd   xmm3, xmm5              ; xmm3=(42 43 52 53 62 63 72 73)
 387
 388     movdqa      xmm2, XMMWORD [wk(3)]   ; xmm2=col4
 389     movdqa      xmm5, XMMWORD [wk(5)]   ; xmm5=col6
 390
 391     ; xmm2=(04 14 24 34 44 54 64 74), xmm5=(06 16 26 36 46 56 66 76)
 392     ; xmm4=(05 15 25 35 45 55 65 75), xmm7=(07 17 27 37 47 57 67 77)
 393
 394     movdqa      XMMWORD [wk(0)], xmm0   ; wk(0)=(02 03 12 13 22 23 32 33)
 395     movdqa      XMMWORD [wk(1)], xmm3   ; wk(1)=(42 43 52 53 62 63 72 73)
 396
 397     movdqa      xmm0, xmm2              ; transpose coefficients(phase 1)
 398     punpcklwd   xmm2, xmm4              ; xmm2=(04 05 14 15 24 25 34 35)
 399     punpckhwd   xmm0, xmm4              ; xmm0=(44 45 54 55 64 65 74 75)
 400     movdqa      xmm3, xmm5              ; transpose coefficients(phase 1)
 401     punpcklwd   xmm5, xmm7              ; xmm5=(06 07 16 17 26 27 36 37)
 402     punpckhwd   xmm3, xmm7              ; xmm3=(46 47 56 57 66 67 76 77)
 403
 404     movdqa      xmm4, xmm2              ; transpose coefficients(phase 2)
 405     punpckldq   xmm2, xmm5              ; xmm2=(04 05 06 07 14 15 16 17)
 406     punpckhdq   xmm4, xmm5              ; xmm4=(24 25 26 27 34 35 36 37)
 407     movdqa      xmm7, xmm0              ; transpose coefficients(phase 2)
 408     punpckldq   xmm0, xmm3              ; xmm0=(44 45 46 47 54 55 56 57)
 409     punpckhdq   xmm7, xmm3              ; xmm7=(64 65 66 67 74 75 76 77)
 410
 411     movdqa      xmm5, XMMWORD [wk(0)]   ; xmm5=(02 03 12 13 22 23 32 33)
 412     movdqa      xmm3, XMMWORD [wk(1)]   ; xmm3=(42 43 52 53 62 63 72 73)
 413     movdqa      XMMWORD [wk(2)], xmm4   ; wk(2)=(24 25 26 27 34 35 36 37)
 414     movdqa      XMMWORD [wk(3)], xmm0   ; wk(3)=(44 45 46 47 54 55 56 57)
 415
 416     movdqa      xmm4, xmm6              ; transpose coefficients(phase 2)
 417     punpckldq   xmm6, xmm5              ; xmm6=(00 01 02 03 10 11 12 13)
 418     punpckhdq   xmm4, xmm5              ; xmm4=(20 21 22 23 30 31 32 33)
 419     movdqa      xmm0, xmm1              ; transpose coefficients(phase 2)
 420     punpckldq   xmm1, xmm3              ; xmm1=(40 41 42 43 50 51 52 53)
 421     punpckhdq   xmm0, xmm3              ; xmm0=(60 61 62 63 70 71 72 73)
 422
 423     movdqa      xmm5, xmm6              ; transpose coefficients(phase 3)
 424     punpcklqdq  xmm6, xmm2              ; xmm6=(00 01 02 03 04 05 06 07)=data0
 425     punpckhqdq  xmm5, xmm2              ; xmm5=(10 11 12 13 14 15 16 17)=data1
 426     movdqa      xmm3, xmm0              ; transpose coefficients(phase 3)
 427     punpcklqdq  xmm0, xmm7              ; xmm0=(60 61 62 63 64 65 66 67)=data6
 428     punpckhqdq  xmm3, xmm7              ; xmm3=(70 71 72 73 74 75 76 77)=data7
 429
 430     movdqa      xmm2, xmm5
 431     movdqa      xmm7, xmm6
 432     psubw       xmm5, xmm0              ; xmm5=data1-data6=tmp6
 433     psubw       xmm6, xmm3              ; xmm6=data0-data7=tmp7
 434     paddw       xmm2, xmm0              ; xmm2=data1+data6=tmp1
 435     paddw       xmm7, xmm3              ; xmm7=data0+data7=tmp0
 436
 437     movdqa      xmm0, XMMWORD [wk(2)]   ; xmm0=(24 25 26 27 34 35 36 37)
 438     movdqa      xmm3, XMMWORD [wk(3)]   ; xmm3=(44 45 46 47 54 55 56 57)
 439     movdqa      XMMWORD [wk(0)], xmm5   ; wk(0)=tmp6
 440     movdqa      XMMWORD [wk(1)], xmm6   ; wk(1)=tmp7
 441
 442     movdqa      xmm5, xmm4              ; transpose coefficients(phase 3)
 443     punpcklqdq  xmm4, xmm0              ; xmm4=(20 21 22 23 24 25 26 27)=data2
 444     punpckhqdq  xmm5, xmm0              ; xmm5=(30 31 32 33 34 35 36 37)=data3
 445     movdqa      xmm6, xmm1              ; transpose coefficients(phase 3)
 446     punpcklqdq  xmm1, xmm3              ; xmm1=(40 41 42 43 44 45 46 47)=data4
 447     punpckhqdq  xmm6, xmm3              ; xmm6=(50 51 52 53 54 55 56 57)=data5
 448
 449     movdqa      xmm0, xmm5
 450     movdqa      xmm3, xmm4
 451     paddw       xmm5, xmm1              ; xmm5=data3+data4=tmp3
 452     paddw       xmm4, xmm6              ; xmm4=data2+data5=tmp2
 453     psubw       xmm0, xmm1              ; xmm0=data3-data4=tmp4
 454     psubw       xmm3, xmm6              ; xmm3=data2-data5=tmp5
 455
 456     ; -- Even part
 457
 458     movdqa      xmm1, xmm7
 459     movdqa      xmm6, xmm2
 460     paddw       xmm7, xmm5              ; xmm7=tmp10
 461     paddw       xmm2, xmm4              ; xmm2=tmp11
 462     psubw       xmm1, xmm5              ; xmm1=tmp13
 463     psubw       xmm6, xmm4              ; xmm6=tmp12
 464
 465     movdqa      xmm5, xmm7
 466     paddw       xmm7, xmm2              ; xmm7=tmp10+tmp11
 467     psubw       xmm5, xmm2              ; xmm5=tmp10-tmp11
 468
 469     paddw       xmm7, [GOTOFF(ebx,PW_DESCALE_P2X)]
 470     paddw       xmm5, [GOTOFF(ebx,PW_DESCALE_P2X)]
 471     psraw       xmm7, PASS1_BITS        ; xmm7=data0
 472     psraw       xmm5, PASS1_BITS        ; xmm5=data4
 473
 474     movdqa      XMMWORD [XMMBLOCK(0,0,edx,SIZEOF_DCTELEM)], xmm7
 475     movdqa      XMMWORD [XMMBLOCK(4,0,edx,SIZEOF_DCTELEM)], xmm5
 476
 477     ; (Original)
 478     ; z1 = (tmp12 + tmp13) * 0.541196100;
 479     ; data2 = z1 + tmp13 * 0.765366865;
 480     ; data6 = z1 + tmp12 * -1.847759065;
 481     ;
 482     ; (This implementation)
 483     ; data2 = tmp13 * (0.541196100 + 0.765366865) + tmp12 * 0.541196100;
 484     ; data6 = tmp13 * 0.541196100 + tmp12 * (0.541196100 - 1.847759065);
 485
 486     movdqa      xmm4, xmm1              ; xmm1=tmp13
 487     movdqa      xmm2, xmm1
 488     punpcklwd   xmm4, xmm6              ; xmm6=tmp12
 489     punpckhwd   xmm2, xmm6
 490     movdqa      xmm1, xmm4
 491     movdqa      xmm6, xmm2
 492     pmaddwd     xmm4, [GOTOFF(ebx,PW_F130_F054)]   ; xmm4=data2L
 493     pmaddwd     xmm2, [GOTOFF(ebx,PW_F130_F054)]   ; xmm2=data2H
 494     pmaddwd     xmm1, [GOTOFF(ebx,PW_F054_MF130)]  ; xmm1=data6L
 495     pmaddwd     xmm6, [GOTOFF(ebx,PW_F054_MF130)]  ; xmm6=data6H
 496
 497     paddd       xmm4, [GOTOFF(ebx,PD_DESCALE_P2)]
 498     paddd       xmm2, [GOTOFF(ebx,PD_DESCALE_P2)]
 499     psrad       xmm4, DESCALE_P2
 500     psrad       xmm2, DESCALE_P2
 501     paddd       xmm1, [GOTOFF(ebx,PD_DESCALE_P2)]
 502     paddd       xmm6, [GOTOFF(ebx,PD_DESCALE_P2)]
 503     psrad       xmm1, DESCALE_P2
 504     psrad       xmm6, DESCALE_P2
 505
 506     packssdw    xmm4, xmm2              ; xmm4=data2
 507     packssdw    xmm1, xmm6              ; xmm1=data6
 508
 509     movdqa      XMMWORD [XMMBLOCK(2,0,edx,SIZEOF_DCTELEM)], xmm4
 510     movdqa      XMMWORD [XMMBLOCK(6,0,edx,SIZEOF_DCTELEM)], xmm1
 511
 512     ; -- Odd part
 513
 514     movdqa      xmm7, XMMWORD [wk(0)]   ; xmm7=tmp6
 515     movdqa      xmm5, XMMWORD [wk(1)]   ; xmm5=tmp7
 516
 517     movdqa      xmm2, xmm0              ; xmm0=tmp4
 518     movdqa      xmm6, xmm3              ; xmm3=tmp5
 519     paddw       xmm2, xmm7              ; xmm2=z3
 520     paddw       xmm6, xmm5              ; xmm6=z4
 521
 522     ; (Original)
 523     ; z5 = (z3 + z4) * 1.175875602;
 524     ; z3 = z3 * -1.961570560;  z4 = z4 * -0.390180644;
 525     ; z3 += z5;  z4 += z5;
 526     ;
 527     ; (This implementation)
 528     ; z3 = z3 * (1.175875602 - 1.961570560) + z4 * 1.175875602;
 529     ; z4 = z3 * 1.175875602 + z4 * (1.175875602 - 0.390180644);
 530
 531     movdqa      xmm4, xmm2
 532     movdqa      xmm1, xmm2
 533     punpcklwd   xmm4, xmm6
 534     punpckhwd   xmm1, xmm6
 535     movdqa      xmm2, xmm4
 536     movdqa      xmm6, xmm1
 537     pmaddwd     xmm4, [GOTOFF(ebx,PW_MF078_F117)]  ; xmm4=z3L
 538     pmaddwd     xmm1, [GOTOFF(ebx,PW_MF078_F117)]  ; xmm1=z3H
 539     pmaddwd     xmm2, [GOTOFF(ebx,PW_F117_F078)]   ; xmm2=z4L
 540     pmaddwd     xmm6, [GOTOFF(ebx,PW_F117_F078)]   ; xmm6=z4H
 541
 542     movdqa      XMMWORD [wk(0)], xmm4   ; wk(0)=z3L
 543     movdqa      XMMWORD [wk(1)], xmm1   ; wk(1)=z3H
 544
 545     ; (Original)
 546     ; z1 = tmp4 + tmp7;  z2 = tmp5 + tmp6;
 547     ; tmp4 = tmp4 * 0.298631336;  tmp5 = tmp5 * 2.053119869;
 548     ; tmp6 = tmp6 * 3.072711026;  tmp7 = tmp7 * 1.501321110;
 549     ; z1 = z1 * -0.899976223;  z2 = z2 * -2.562915447;
 550     ; data7 = tmp4 + z1 + z3;  data5 = tmp5 + z2 + z4;
 551     ; data3 = tmp6 + z2 + z3;  data1 = tmp7 + z1 + z4;
 552     ;
 553     ; (This implementation)
 554     ; tmp4 = tmp4 * (0.298631336 - 0.899976223) + tmp7 * -0.899976223;
 555     ; tmp5 = tmp5 * (2.053119869 - 2.562915447) + tmp6 * -2.562915447;
 556     ; tmp6 = tmp5 * -2.562915447 + tmp6 * (3.072711026 - 2.562915447);
 557     ; tmp7 = tmp4 * -0.899976223 + tmp7 * (1.501321110 - 0.899976223);
 558     ; data7 = tmp4 + z3;  data5 = tmp5 + z4;
 559     ; data3 = tmp6 + z3;  data1 = tmp7 + z4;
 560
 561     movdqa      xmm4, xmm0
 562     movdqa      xmm1, xmm0
 563     punpcklwd   xmm4, xmm5
 564     punpckhwd   xmm1, xmm5
 565     movdqa      xmm0, xmm4
 566     movdqa      xmm5, xmm1
 567     pmaddwd     xmm4, [GOTOFF(ebx,PW_MF060_MF089)]  ; xmm4=tmp4L
 568     pmaddwd     xmm1, [GOTOFF(ebx,PW_MF060_MF089)]  ; xmm1=tmp4H
 569     pmaddwd     xmm0, [GOTOFF(ebx,PW_MF089_F060)]   ; xmm0=tmp7L
 570     pmaddwd     xmm5, [GOTOFF(ebx,PW_MF089_F060)]   ; xmm5=tmp7H
 571
 572     paddd       xmm4,  XMMWORD [wk(0)]  ; xmm4=data7L
 573     paddd       xmm1,  XMMWORD [wk(1)]  ; xmm1=data7H
 574     paddd       xmm0, xmm2              ; xmm0=data1L
 575     paddd       xmm5, xmm6              ; xmm5=data1H
 576
 577     paddd       xmm4, [GOTOFF(ebx,PD_DESCALE_P2)]
 578     paddd       xmm1, [GOTOFF(ebx,PD_DESCALE_P2)]
 579     psrad       xmm4, DESCALE_P2
 580     psrad       xmm1, DESCALE_P2
 581     paddd       xmm0, [GOTOFF(ebx,PD_DESCALE_P2)]
 582     paddd       xmm5, [GOTOFF(ebx,PD_DESCALE_P2)]
 583     psrad       xmm0, DESCALE_P2
 584     psrad       xmm5, DESCALE_P2
 585
 586     packssdw    xmm4, xmm1              ; xmm4=data7
 587     packssdw    xmm0, xmm5              ; xmm0=data1
 588
 589     movdqa      XMMWORD [XMMBLOCK(7,0,edx,SIZEOF_DCTELEM)], xmm4
 590     movdqa      XMMWORD [XMMBLOCK(1,0,edx,SIZEOF_DCTELEM)], xmm0
 591
 592     movdqa      xmm1, xmm3
 593     movdqa      xmm5, xmm3
 594     punpcklwd   xmm1, xmm7
 595     punpckhwd   xmm5, xmm7
 596     movdqa      xmm3, xmm1
 597     movdqa      xmm7, xmm5
 598     pmaddwd     xmm1, [GOTOFF(ebx,PW_MF050_MF256)]  ; xmm1=tmp5L
 599     pmaddwd     xmm5, [GOTOFF(ebx,PW_MF050_MF256)]  ; xmm5=tmp5H
 600     pmaddwd     xmm3, [GOTOFF(ebx,PW_MF256_F050)]   ; xmm3=tmp6L
 601     pmaddwd     xmm7, [GOTOFF(ebx,PW_MF256_F050)]   ; xmm7=tmp6H
 602
 603     paddd       xmm1, xmm2              ; xmm1=data5L
 604     paddd       xmm5, xmm6              ; xmm5=data5H
 605     paddd       xmm3, XMMWORD [wk(0)]   ; xmm3=data3L
 606     paddd       xmm7, XMMWORD [wk(1)]   ; xmm7=data3H
 607
 608     paddd       xmm1, [GOTOFF(ebx,PD_DESCALE_P2)]
 609     paddd       xmm5, [GOTOFF(ebx,PD_DESCALE_P2)]
 610     psrad       xmm1, DESCALE_P2
 611     psrad       xmm5, DESCALE_P2
 612     paddd       xmm3, [GOTOFF(ebx,PD_DESCALE_P2)]
 613     paddd       xmm7, [GOTOFF(ebx,PD_DESCALE_P2)]
 614     psrad       xmm3, DESCALE_P2
 615     psrad       xmm7, DESCALE_P2
 616
 617     packssdw    xmm1, xmm5              ; xmm1=data5
 618     packssdw    xmm3, xmm7              ; xmm3=data3
 619
 620     movdqa      XMMWORD [XMMBLOCK(5,0,edx,SIZEOF_DCTELEM)], xmm1
 621     movdqa      XMMWORD [XMMBLOCK(3,0,edx,SIZEOF_DCTELEM)], xmm3
 622
 623 ;   pop         edi                     ; unused
 624 ;   pop         esi                     ; unused
 625 ;   pop         edx                     ; need not be preserved
 626 ;   pop         ecx                     ; unused
 627     poppic      ebx
 628     mov         esp, ebp                ; esp <- aligned ebp
 629     pop         esp                     ; esp <- original ebp
 630     pop         ebp
 631     ret
 632
 633 ; For some reason, the OS X linker does not honor the request to align the
 634 ; segment unless we do this.
 635     align       32