sim/mips/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.59)dnl
   3 AC_INIT(Makefile.in)
   4 AC_CONFIG_HEADER(config.h:config.in)
   5
   6 sinclude(../common/aclocal.m4)
   7
   8 # Bugs in autoconf 2.59 break the call to SIM_AC_COMMON, hack around
   9 # it by inlining the macro's contents.
  10 sinclude(../common/common.m4)
  11
  12 dnl Options available in this module
  13 SIM_AC_OPTION_INLINE()
  14 SIM_AC_OPTION_ALIGNMENT(NONSTRICT_ALIGNMENT)
  15 SIM_AC_OPTION_HOSTENDIAN
  16 SIM_AC_OPTION_WARNINGS
  17 SIM_AC_OPTION_RESERVED_BITS(1)
  18
  19 # DEPRECATED
  20 #
  21 # Instead of defining a `subtarget' macro, code should be checking
  22 # the value of {STATE,CPU}_ARCHITECTURE to identify the architecture
  23 # in question.
  24 #
  25 case "${target}" in
  26   mips64vr*-*-*)        SIM_SUBTARGET="-DTARGET_ENABLE_FR=1" ;;
  27   mips*tx39*)           SIM_SUBTARGET="-DSUBTARGET_R3900=1";;
  28   mipsisa32*-*-*)       SIM_SUBTARGET="-DTARGET_ENABLE_FR=1";;
  29   mipsisa64*-*-*)       SIM_SUBTARGET="-DTARGET_ENABLE_FR=1";;
  30   *)                    SIM_SUBTARGET="";;
  31 esac
  32 AC_SUBST(SIM_SUBTARGET)
  33
  34
  35
  36 #
  37 # Select the byte order of the target
  38 #
  39 mips_endian=
  40 default_endian=
  41 case "${target}" in
  42   mips64el*-*-*)        mips_endian=LITTLE_ENDIAN ;;
  43   mips64vr*el-*-*)      default_endian=LITTLE_ENDIAN ;;
  44   mips64*-*-*)          default_endian=BIG_ENDIAN ;;
  45   mips16*-*-*)          default_endian=BIG_ENDIAN ;;
  46   mipsisa32*-*-*)       default_endian=BIG_ENDIAN ;;
  47   mipsisa64*-*-*)       default_endian=BIG_ENDIAN ;;
  48   mips*-*-*)            default_endian=BIG_ENDIAN ;;
  49   *)                    default_endian=BIG_ENDIAN ;;
  50 esac
  51 SIM_AC_OPTION_ENDIAN($mips_endian,$default_endian)
  52
  53
  54
  55 #
  56 # Select the bitsize of the target
  57 #
  58 mips_addr_bitsize=
  59 case "${target}" in
  60   mips64*-*-*)          mips_bitsize=64 ; mips_msb=63 ;;
  61   mips16*-*-*)          mips_bitsize=64 ; mips_msb=63 ;;
  62   mipsisa32*-*-*)       mips_bitsize=32 ; mips_msb=31 ;;
  63   mipsisa64*-*-*)       mips_bitsize=64 ; mips_msb=63 ;;
  64   mips*-*-*)            mips_bitsize=32 ; mips_msb=31 ;;
  65   *)                    mips_bitsize=64 ; mips_msb=63 ;;
  66 esac
  67 SIM_AC_OPTION_BITSIZE($mips_bitsize,$mips_msb,$mips_addr_bitsize)
  68
  69
  70
  71 #
  72 # Select the floating hardware support of the target
  73 #
  74 mips_fpu=HARDWARE_FLOATING_POINT
  75 mips_fpu_bitsize=
  76 case "${target}" in
  77   mips*tx39*)           mips_fpu=HARD_FLOATING_POINT
  78                         mips_fpu_bitsize=32
  79                         ;;
  80   mips64*-*-*)          mips_fpu=HARD_FLOATING_POINT ;;
  81   mips16*-*-*)          mips_fpu=HARD_FLOATING_POINT ;;
  82   mipsisa32*-*-*)       mips_fpu=HARD_FLOATING_POINT ; mips_fpu_bitsize=64 ;;
  83   mipsisa64*-*-*)       mips_fpu=HARD_FLOATING_POINT ; mips_fpu_bitsize=64 ;;
  84   mips*-*-*)            mips_fpu=HARD_FLOATING_POINT ; mips_fpu_bitsize=32 ;;
  85   *)                    mips_fpu=HARD_FLOATING_POINT ;;
  86 esac
  87 SIM_AC_OPTION_FLOAT($mips_fpu,$mips_fpu_bitsize)
  88
  89
  90
  91 #
  92 # Select the level of SMP support
  93 #
  94 case "${target}" in
  95   *)                    mips_smp=0 ;;
  96 esac
  97 SIM_AC_OPTION_SMP($mips_smp)
  98
  99
 100
 101 #
 102 # Select the IGEN architecture
 103 #
 104 sim_gen=IGEN
 105 sim_igen_machine="-M mipsIV"
 106 sim_m16_machine="-M mips16,mipsIII"
 107 sim_igen_filter="32,64,f"
 108 sim_m16_filter="16"
 109 sim_mach_default="mips8000"
 110
 111 case "${target}" in
 112   mips*tx39*)           sim_gen=IGEN
 113                         sim_igen_filter="32,f"
 114                         sim_igen_machine="-M r3900"
 115                         ;;
 116   mips64vr43*-*-*)      sim_gen=IGEN
 117                         sim_igen_machine="-M mipsIV"
 118                         sim_mach_default="mips8000"
 119                         ;;
 120   mips64vr5*-*-*)       sim_gen=IGEN
 121                         sim_igen_machine="-M vr5000"
 122                         sim_mach_default="mips5000"
 123                         ;;
 124   mips64vr41*)          sim_gen=M16
 125                         sim_igen_machine="-M vr4100"
 126                         sim_m16_machine="-M vr4100"
 127                         sim_igen_filter="32,64,f"
 128                         sim_m16_filter="16"
 129                         sim_mach_default="mips4100"
 130                         ;;
 131   mips64vr-*-* | mips64vrel-*-*)
 132                         sim_gen=MULTI
 133                         sim_multi_configs="\
 134                           vr4100:mipsIII,mips16,vr4100:32,64:mips4100,mips4111\
 135                           vr4120:mipsIII,mips16,vr4120:32,64:mips4120\
 136                           vr5000:mipsIV:32,64,f:mips4300,mips5000\
 137                           vr5400:mipsIV,vr5400:32,64,f:mips5400\
 138                           vr5500:mipsIV,vr5500:32,64,f:mips5500"
 139                         sim_multi_default=mips5000
 140                         ;;
 141   mips64*-*-*)          sim_igen_filter="32,64,f"
 142                         sim_gen=IGEN
 143                         ;;
 144   mips16*-*-*)          sim_gen=M16
 145                         sim_igen_filter="32,64,f"
 146                         sim_m16_filter="16"
 147                         ;;
 148   mipsisa32r2*-*-*)     sim_gen=M16
 149                         sim_igen_machine="-M mips32r2,mips16,mips16e,dsp"
 150                         sim_m16_machine="-M mips16,mips16e,mips32r2"
 151                         sim_igen_filter="32,f"
 152                         sim_mach_default="mipsisa32r2"
 153                         ;;
 154   mipsisa32*-*-*)       sim_gen=M16
 155                         sim_igen_machine="-M mips32,mips16,mips16e,dsp"
 156                         sim_m16_machine="-M mips16,mips16e,mips32"
 157                         sim_igen_filter="32,f"
 158                         sim_mach_default="mipsisa32"
 159                         ;;
 160   mipsisa64r2*-*-*)     sim_gen=M16
 161                         sim_igen_machine="-M mips64r2,mips3d,mips16,mips16e,dsp"
 162                         sim_m16_machine="-M mips16,mips16e,mips64r2"
 163                         sim_igen_filter="32,64,f"
 164                         sim_mach_default="mipsisa64r2"
 165                         ;;
 166   mipsisa64sb1*-*-*)    sim_gen=IGEN
 167                         sim_igen_machine="-M mips64,mips3d,sb1"
 168                         sim_igen_filter="32,64,f"
 169                         sim_mach_default="mips_sb1"
 170                         ;;
 171   mipsisa64*-*-*)       sim_gen=M16
 172                         sim_igen_machine="-M mips64,mips3d,mips16,mips16e,dsp"
 173                         sim_m16_machine="-M mips16,mips16e,mips64"
 174                         sim_igen_filter="32,64,f"
 175                         sim_mach_default="mipsisa64"
 176                         ;;
 177   mips*lsi*)            sim_gen=M16
 178                         sim_igen_machine="-M mipsIII,mips16"
 179                         sim_m16_machine="-M mips16,mipsIII"
 180                         sim_igen_filter="32,f"
 181                         sim_m16_filter="16"
 182                         sim_mach_default="mips4000"
 183                         ;;
 184   mips*-*-*)            sim_gen=IGEN
 185                         sim_igen_filter="32,f"
 186                         ;;
 187 esac
 188
 189 # The MULTI generator can combine several simulation engines into one.
 190 # executable.  A configuration which uses the MULTI should set two
 191 # variables: ${sim_multi_configs} and ${sim_multi_default}.
 192 #
 193 # ${sim_multi_configs} is the list of engines to build.  Each
 194 # space-separated entry has the form NAME:MACHINE:FILTER:BFDMACHS,
 195 # where:
 196 #
 197 # - NAME is a C-compatible prefix for the engine,
 198 # - MACHINE is a -M argument,
 199 # - FILTER is a -F argument, and
 200 # - BFDMACHS is a comma-separated list of bfd machines that the
 201 #     simulator can run.
 202 #
 203 # Each entry will have a separate simulation engine whose prefix is
 204 # m32<NAME>.  If the machine list includes "mips16", there will also
 205 # be a mips16 engine, prefix m16<NAME>.  The mips16 engine will be
 206 # generated using the same machine list as the 32-bit version,
 207 # but the filter will be "16" instead of FILTER.
 208 #
 209 # The simulator compares the bfd mach against BFDMACHS to decide
 210 # which engine to use.  Entries in BFDMACHS should be bfd_mach
 211 # values with "bfd_mach_" removed.  ${sim_multi_default} says
 212 # which entry should be the default.
 213 if test ${sim_gen} = MULTI; then
 214
 215   # Simple sanity check.
 216   if test -z "${sim_multi_configs}" || test -z "${sim_multi_default}"; then
 217     AC_MSG_ERROR(Error in configure.in: MULTI simulator not set up correctly)
 218   fi
 219
 220   # Start in a known state.
 221   rm -f multi-include.h multi-run.c
 222   sim_multi_flags=
 223   sim_multi_src=
 224   sim_multi_obj=multi-run.o
 225   sim_multi_igen_configs=
 226   sim_seen_default=no
 227
 228   cat << __EOF__ > multi-run.c
 229 /* Main entry point for MULTI simulators.
 230    Copyright (C) 2003 Free Software Foundation, Inc.
 231
 232    This program is free software; you can redistribute it and/or modify
 233    it under the terms of the GNU General Public License as published by
 234    the Free Software Foundation; either version 2 of the License, or
 235    (at your option) any later version.
 236
 237    This program is distributed in the hope that it will be useful,
 238    but WITHOUT ANY WARRANTY; without even the implied warranty of
 239    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 240    GNU General Public License for more details.
 241
 242    You should have received a copy of the GNU General Public License
 243    along with this program; if not, write to the Free Software
 244    Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
 245
 246    --
 247
 248    This file was generated by sim/mips/configure.  */
 249
 250 #include "sim-main.h"
 251 #include "multi-include.h"
 252
 253 #define SD sd
 254 #define CPU cpu
 255
 256 void
 257 sim_engine_run (SIM_DESC sd,
 258                 int next_cpu_nr,
 259                 int nr_cpus,
 260                 int signal) /* ignore */
 261 {
 262   int mach;
 263
 264   if (STATE_ARCHITECTURE (sd) == NULL)
 265     mach = bfd_mach_${sim_multi_default};
 266   else
 267     mach = STATE_ARCHITECTURE (SD)->mach;
 268
 269   switch (mach)
 270     {
 271 __EOF__
 272
 273   for fc in ${sim_multi_configs}; do
 274
 275     # Split up the entry.  ${c} contains the first three elements.
 276     # Note: outer sqaure brackets are m4 quotes.
 277     c=`echo ${fc} | sed ['s/:[^:]*$//']`
 278     bfdmachs=`echo ${fc} | sed 's/.*://'`
 279     name=`echo ${c} | sed 's/:.*//'`
 280     machine=`echo ${c} | sed 's/.*:\(.*\):.*/\1/'`
 281     filter=`echo ${c} | sed 's/.*://'`
 282
 283     # Build the following lists:
 284     #
 285     #   sim_multi_flags: all -M and -F flags used by the simulator
 286     #   sim_multi_src: all makefile-generated source files
 287     #   sim_multi_obj: the objects for ${sim_multi_src}
 288     #   sim_multi_igen_configs: igen configuration strings.
 289     #
 290     # Each entry in ${sim_multi_igen_configs} is a prefix (m32
 291     # or m16) followed by the NAME, MACHINE and FILTER part of
 292     # the ${sim_multi_configs} entry.
 293     sim_multi_flags="${sim_multi_flags} -F ${filter} -M ${machine}"
 294
 295     # Check whether mips16 handling is needed.
 296     case ${c} in
 297       *:*mips16*:*)
 298         # Run igen twice, once for normal mode and once for mips16.
 299         ws="m32 m16"
 300
 301         # The top-level function for the mips16 simulator is
 302         # in a file m16${name}_run.c, generated by the
 303         # tmp-run-multi Makefile rule.
 304         sim_multi_src="${sim_multi_src} m16${name}_run.c"
 305         sim_multi_obj="${sim_multi_obj} m16${name}_run.o"
 306         sim_multi_flags="${sim_multi_flags} -F 16"
 307         ;;
 308       *)
 309         ws=m32
 310         ;;
 311     esac
 312
 313     # Now add the list of igen-generated files to ${sim_multi_src}
 314     # and ${sim_multi_obj}.
 315     for w in ${ws}; do
 316       for base in engine icache idecode model semantics support; do
 317         sim_multi_src="${sim_multi_src} ${w}${name}_${base}.c"
 318         sim_multi_src="${sim_multi_src} ${w}${name}_${base}.h"
 319         sim_multi_obj="${sim_multi_obj} ${w}${name}_${base}.o"
 320       done
 321       sim_multi_igen_configs="${sim_multi_igen_configs} ${w}${c}"
 322     done
 323
 324     # Add an include for the engine.h file.  This file declares the
 325     # top-level foo_engine_run() function.
 326     echo "#include \"${w}${name}_engine.h\"" >> multi-include.h
 327
 328     # Add case statements for this engine to sim_engine_run().
 329     for mach in `echo ${bfdmachs} | sed 's/,/ /g'`; do
 330       echo "    case bfd_mach_${mach}:" >> multi-run.c
 331       if test ${mach} = ${sim_multi_default}; then
 332         echo "    default:" >> multi-run.c
 333         sim_seen_default=yes
 334       fi
 335     done
 336     echo "      ${w}${name}_engine_run (sd, next_cpu_nr, nr_cpus, signal);" \
 337       >> multi-run.c
 338     echo "      break;" >> multi-run.c
 339   done
 340
 341   # Check whether we added a 'default:' label.
 342   if test ${sim_seen_default} = no; then
 343     AC_MSG_ERROR(Error in configure.in: \${sim_multi_configs} doesn't have an entry for \${sim_multi_default})
 344   fi
 345
 346   cat << __EOF__ >> multi-run.c
 347     }
 348 }
 349
 350 int
 351 mips_mach_multi (SIM_DESC sd)
 352 {
 353   if (STATE_ARCHITECTURE (sd) == NULL)
 354     return bfd_mach_${sim_multi_default};
 355
 356   switch (STATE_ARCHITECTURE (SD)->mach)
 357     {
 358 __EOF__
 359
 360   # Add case statements for this engine to mips_mach_multi().
 361   for fc in ${sim_multi_configs}; do
 362
 363     # Split up the entry.  ${c} contains the first three elements.
 364     # Note: outer sqaure brackets are m4 quotes.
 365     c=`echo ${fc} | sed ['s/:[^:]*$//']`
 366     bfdmachs=`echo ${fc} | sed 's/.*://'`
 367
 368     for mach in `echo ${bfdmachs} | sed 's/,/ /g'`; do
 369       echo "    case bfd_mach_${mach}:" >> multi-run.c
 370     done
 371   done
 372
 373   cat << __EOF__ >> multi-run.c
 374       return (STATE_ARCHITECTURE (SD)->mach);
 375     default:
 376       return bfd_mach_${sim_multi_default};
 377     }
 378 }
 379 __EOF__
 380
 381   SIM_SUBTARGET="$SIM_SUBTARGET -DMIPS_MACH_MULTI"
 382 else
 383   # For clean-extra
 384   sim_multi_src=doesnt-exist.c
 385
 386   if test x"${sim_mach_default}" = x""; then
 387     AC_MSG_ERROR(Error in configure.in: \${sim_mach_default} not defined)
 388   fi
 389   SIM_SUBTARGET="$SIM_SUBTARGET -DMIPS_MACH_DEFAULT=bfd_mach_${sim_mach_default}"
 390 fi
 391 sim_igen_flags="-F ${sim_igen_filter} ${sim_igen_machine} ${sim_igen_smp}"
 392 sim_m16_flags=" -F ${sim_m16_filter}  ${sim_m16_machine}  ${sim_igen_smp}"
 393 AC_SUBST(sim_igen_flags)
 394 AC_SUBST(sim_m16_flags)
 395 AC_SUBST(sim_gen)
 396 AC_SUBST(sim_multi_flags)
 397 AC_SUBST(sim_multi_igen_configs)
 398 AC_SUBST(sim_multi_src)
 399 AC_SUBST(sim_multi_obj)
 400
 401
 402 #
 403 # Add simulated hardware devices
 404 #
 405 hw_enabled=no
 406 case "${target}" in
 407   mips*tx39*)
 408         hw_enabled=yes
 409         hw_extra_devices="tx3904cpu tx3904irc tx3904tmr tx3904sio"
 410         mips_extra_objs="dv-sockser.o"
 411         SIM_SUBTARGET="$SIM_SUBTARGET -DTARGET_TX3904=1"
 412         ;;
 413   *)
 414         mips_extra_objs=""
 415         ;;
 416 esac
 417 SIM_AC_OPTION_HARDWARE($hw_enabled,$hw_devices,$hw_extra_devices)
 418 AC_SUBST(mips_extra_objs)
 419
 420
 421 # Choose simulator engine
 422 case "${target}" in
 423   *)    mips_igen_engine="engine.o"
 424         ;;
 425 esac
 426 AC_SUBST(mips_igen_engine)
 427
 428
 429 AC_PATH_X
 430 mips_extra_libs=""
 431 AC_SUBST(mips_extra_libs)
 432
 433 AC_CHECK_HEADERS(string.h strings.h stdlib.h stdlib.h)
 434 AC_CHECK_LIB(m, fabs)
 435 AC_CHECK_FUNCS(aint anint sqrt)
 436
 437 SIM_AC_OUTPUT