sim/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.5)dnl
   3 AC_INIT(Makefile.in)
   4
   5 AC_PROG_CC
   6 AC_PROG_INSTALL
   7 AC_CHECK_TOOL(AR, ar)
   8 AC_CHECK_TOOL(RANLIB, ranlib, :)
   9
  10 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  11 AC_CANONICAL_SYSTEM
  12 AC_ARG_PROGRAM
  13 AC_PROG_CC
  14 AC_SUBST(CFLAGS)
  15 AC_SUBST(HDEFINES)
  16 AR=${AR-ar}
  17 AC_SUBST(AR)
  18 AC_PROG_RANLIB
  19
  20 # Put a plausible default for CC_FOR_BUILD in Makefile.
  21 AC_C_CROSS
  22 if test "x$cross_compiling" = "xno"; then
  23   CC_FOR_BUILD='$(CC)'
  24 else
  25   CC_FOR_BUILD=gcc
  26 fi
  27 AC_SUBST(CC_FOR_BUILD)
  28
  29 # If a cpu ever has more than one simulator to choose from, use
  30 # --enable-sim=... to choose.
  31 AC_ARG_ENABLE(sim,
  32 [  --enable-sim ],
  33 [case "${enableval}" in
  34 yes | no) ;;
  35 *)      AC_MSG_ERROR(bad value ${enableval} given for --enable-sim option) ;;
  36 esac])
  37
  38 # Assume simulator can be built with cc.
  39 # If the user passes --enable-sim built it regardless of $(CC).
  40 only_if_gcc=no
  41
  42 # WHEN ADDING ENTRIES TO THIS MATRIX:
  43 #  Make sure that the left side always has two dashes.  Otherwise you
  44 #  can get spurious matches.  Even for unambiguous cases, do this as a
  45 #  convention, else the table becomes a real mess to understand and maintain.
  46
  47 case "${target}" in
  48   arm*-*-*)             sim_target=arm ;;
  49 # start-sanitize-d10v
  50   d10v-*-*)             sim_target=d10v ;;
  51 # end-sanitize-d10v
  52   h8300*-*-*)           sim_target=h8300 ;;
  53   h8500-*-*)            sim_target=h8500 ;;
  54   mips*-*-*)
  55         # The MIPS simulator can only be compiled by gcc.
  56         sim_target=mips
  57         only_if_gcc=yes
  58         ;;
  59   mn10300*-*-*)
  60         # The mn10300 simulator can only be compiled by gcc.
  61         sim_target=mn10300
  62         only_if_gcc=yes
  63         ;;
  64   sh*-*-*)              sim_target=sh ;;
  65   powerpc*-*-eabi* | powerpc*-*-solaris* | powerpc*-*-sysv4* | powerpc*-*-elf* | powerpc*-*-linux* )
  66         # The PowerPC simulator uses the GCC extension long long as well as
  67         # ANSI prototypes, so don't enable it for random host compilers
  68         # unless asked to.
  69         sim_target=ppc
  70         only_if_gcc=yes
  71         ;;
  72 # start-sanitize-v850
  73   v850-*-*)
  74         # The V850 simulator can only be compiled by gcc.
  75         sim_target=v850
  76         only_if_gcc=yes
  77         ;;
  78 # end-sanitize-v850
  79   w65-*-*)              sim_target=w65 ;;
  80   z8k*-*-*)             sim_target=z8k ;;
  81   sparc*-*-*)
  82         # The SPARC simulator can only be compiled by gcc.
  83         sim_target=erc32
  84         only_if_gcc=yes
  85         ;;
  86   *)                    sim_target=none ;;
  87 esac
  88
  89 case "${enable_sim}" in
  90 no)     sim_target=none ;;
  91 yes)
  92         if test ${only_if_gcc} = yes ; then
  93                 if test "${GCC}" != yes ; then
  94                         echo "Can't enable simulator since not compiling with GCC."
  95                         sim_target=none
  96                 fi
  97         fi
  98         ;;
  99 *)
 100         if test ${only_if_gcc} = yes ; then
 101                 if test "${GCC}" != yes ; then
 102                         sim_target=none
 103                 fi
 104         fi
 105         ;;
 106 esac
 107
 108 configdirs="common ${sim_target}"
 109 AC_CONFIG_SUBDIRS($configdirs)
 110
 111 AC_OUTPUT(Makefile)
 112
 113 exit 0