sim/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.5)dnl
   3 AC_INIT(Makefile.in)
   4
   5 AC_PROG_CC
   6 AC_PROG_INSTALL
   7 AC_CHECK_TOOL(AR, ar)
   8 AC_CHECK_TOOL(RANLIB, ranlib, :)
   9
  10 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  11 AC_CANONICAL_SYSTEM
  12 AC_ARG_PROGRAM
  13 AC_PROG_CC
  14 AC_SUBST(CFLAGS)
  15 AC_SUBST(HDEFINES)
  16 AR=${AR-ar}
  17 AC_SUBST(AR)
  18 AC_PROG_RANLIB
  19
  20 # Put a plausible default for CC_FOR_BUILD in Makefile.
  21 AC_C_CROSS
  22 if test "x$cross_compiling" = "xno"; then
  23   CC_FOR_BUILD='$(CC)'
  24 else
  25   CC_FOR_BUILD=gcc
  26 fi
  27 AC_SUBST(CC_FOR_BUILD)
  28
  29 # If a cpu ever has more than one simulator to choose from, use
  30 # --enable-sim=... to choose.
  31 AC_ARG_ENABLE(sim,
  32 [  --enable-sim ],
  33 [case "${enableval}" in
  34 yes | no) ;;
  35 *)      AC_MSG_ERROR(bad value ${enableval} given for --enable-sim option) ;;
  36 esac])
  37
  38 # Assume simulator can be built with cc.
  39 # If the user passes --enable-sim built it regardless of $(CC).
  40 only_if_gcc=no
  41 extra_subdirs=common
  42
  43 # WHEN ADDING ENTRIES TO THIS MATRIX:
  44 #  Make sure that the left side always has two dashes.  Otherwise you
  45 #  can get spurious matches.  Even for unambiguous cases, do this as a
  46 #  convention, else the table becomes a real mess to understand and maintain.
  47
  48 case "${target}" in
  49   arm*-*-*)             sim_target=arm ;;
  50   d10v-*-*)             sim_target=d10v ;;
  51 # start-sanitize-d30v
  52   d30v-*-*)
  53         sim_target=d30v
  54         only_if_gcc=yes
  55         extra_subdirs="${extra_subdirs} igen testsuite"
  56         ;;
  57 # end-sanitize-d30v
  58   h8300*-*-*)           sim_target=h8300 ;;
  59   h8500-*-*)            sim_target=h8500 ;;
  60   mips*-*-*)
  61         # The MIPS simulator can only be compiled by gcc.
  62         sim_target=mips
  63         only_if_gcc=yes
  64         ;;
  65   mn10300*-*-*)
  66         # The mn10300 simulator can only be compiled by gcc.
  67         sim_target=mn10300
  68         only_if_gcc=yes
  69         ;;
  70   mn10200*-*-*)
  71         sim_target=mn10200
  72         ;;
  73   sh*-*-*)              sim_target=sh ;;
  74   powerpc*-*-eabi* | powerpc*-*-solaris* | powerpc*-*-sysv4* | powerpc*-*-elf* | powerpc*-*-linux* )
  75         # The PowerPC simulator uses the GCC extension long long as well as
  76         # ANSI prototypes, so don't enable it for random host compilers
  77         # unless asked to.
  78         sim_target=ppc
  79         only_if_gcc=yes
  80         #extra_subdirs="${extra_subdirs}"
  81         ;;
  82 # start-sanitize-v850
  83   v850-*-*)
  84         # The V850 simulator can only be compiled by gcc.
  85         sim_target=v850
  86         only_if_gcc=yes
  87         ;;
  88 # end-sanitize-v850
  89   w65-*-*)              sim_target=w65 ;;
  90   z8k*-*-*)             sim_target=z8k ;;
  91   sparc64-*-*)
  92         sim_target=none # Don't build erc32 if sparc64.
  93         ;;
  94   sparc*-*-*)
  95         # The SPARC simulator can only be compiled by gcc.
  96         sim_target=erc32
  97         only_if_gcc=yes
  98         ;;
  99   *)                    sim_target=none ;;
 100 esac
 101
 102 case "${enable_sim}" in
 103 no)     sim_target=none ;;
 104 yes)
 105         if test ${only_if_gcc} = yes ; then
 106                 if test "${GCC}" != yes ; then
 107                         echo "Can't enable simulator since not compiling with GCC."
 108                         sim_target=none
 109                 fi
 110         fi
 111         ;;
 112 *)
 113         if test ${only_if_gcc} = yes ; then
 114                 if test "${GCC}" != yes ; then
 115                         sim_target=none
 116                 fi
 117         fi
 118         ;;
 119 esac
 120
 121 if test x"${sim_target}" != xnone ; then
 122         configdirs="${extra_subdirs} ${sim_target}"
 123         AC_CONFIG_SUBDIRS($configdirs)
 124 fi
 125
 126 AC_OUTPUT(Makefile)
 127
 128 exit 0