sim/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 m4_include([../config/override.m4])
   3 AC_PREREQ(2.59)dnl
   4 AC_INIT(Makefile.in)
   5
   6 AC_PROG_CC
   7 AC_PROG_INSTALL
   8 AC_CHECK_TOOL(AR, ar)
   9 AC_CHECK_TOOL(RANLIB, ranlib, :)
  10
  11 AC_CANONICAL_SYSTEM
  12 AC_ARG_PROGRAM
  13 AC_PROG_CC
  14 AC_SUBST(CFLAGS)
  15 AC_SUBST(HDEFINES)
  16 AR=${AR-ar}
  17 AC_SUBST(AR)
  18 AC_PROG_RANLIB
  19
  20 # Put a plausible default for CC_FOR_BUILD in Makefile.
  21 if test "x$cross_compiling" = "xno"; then
  22   CC_FOR_BUILD='$(CC)'
  23 else
  24   CC_FOR_BUILD=gcc
  25 fi
  26 AC_SUBST(CC_FOR_BUILD)
  27 CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
  28 AC_SUBST(CFLAGS_FOR_BUILD)
  29
  30 # If a cpu ever has more than one simulator to choose from, use
  31 # --enable-sim=... to choose.
  32 AC_ARG_ENABLE(sim,
  33 [AS_HELP_STRING([--enable-sim], [Enable the GNU simulator])],
  34 [case "${enableval}" in
  35 yes | no) ;;
  36 *)      AC_MSG_ERROR(bad value ${enableval} given for --enable-sim option) ;;
  37 esac])
  38
  39 m4_define([SIM_ARCH], [
  40   sim_arch=$1
  41   AC_CONFIG_SUBDIRS($1)
  42 ])
  43 if test "${enable_sim}" != no; then
  44    sinclude(configure.tgt)
  45    AC_CONFIG_SUBDIRS(testsuite)
  46    if test "$sim_igen" = yes; then
  47       AC_CONFIG_SUBDIRS(igen)
  48    fi
  49 fi
  50
  51 AC_OUTPUT(Makefile)
  52
  53 exit 0