sim/bfin/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.64)dnl
   3 AC_INIT(Makefile.in)
   4 sinclude(../common/acinclude.m4)
   5
   6 SIM_AC_COMMON
   7
   8 SIM_AC_OPTION_ENDIAN(LITTLE_ENDIAN)
   9 SIM_AC_OPTION_ALIGNMENT(STRICT_ALIGNMENT,STRICT_ALIGNMENT)
  10 SIM_AC_OPTION_HOSTENDIAN
  11 SIM_AC_OPTION_DEFAULT_MODEL(bf537)
  12 SIM_AC_OPTION_ENVIRONMENT
  13 SIM_AC_OPTION_INLINE
  14 SIM_AC_OPTION_WARNINGS
  15 SIM_AC_OPTION_HARDWARE(yes,,\
  16         bfin_cec \
  17         bfin_ctimer \
  18         bfin_dma \
  19         bfin_dmac \
  20         bfin_ebiu_amc \
  21         bfin_ebiu_ddrc \
  22         bfin_ebiu_sdc \
  23         bfin_emac \
  24         bfin_eppi \
  25         bfin_evt \
  26         bfin_gpio \
  27         bfin_gpio2 \
  28         bfin_gptimer \
  29         bfin_jtag \
  30         bfin_mmu \
  31         bfin_nfc \
  32         bfin_otp \
  33         bfin_pfmon \
  34         bfin_pint \
  35         bfin_pll \
  36         bfin_ppi \
  37         bfin_rtc \
  38         bfin_sic \
  39         bfin_spi \
  40         bfin_trace \
  41         bfin_twi \
  42         bfin_uart \
  43         bfin_uart2 \
  44         bfin_wdog \
  45         bfin_wp \
  46         eth_phy \
  47 )
  48
  49 AC_CHECK_FUNCS([getuid getgid geteuid getegid setuid setgid mmap munmap kill pread])
  50 AC_CHECK_HEADERS([ \
  51         linux/if_tun.h \
  52         linux/mii.h \
  53         linux/types.h \
  54         net/if.h \
  55         sys/ioctl.h \
  56         sys/mman.h \
  57 ])
  58
  59 BFIN_SIM_EXTRA_OBJS=
  60
  61 dnl make sure the dv-sockser code can be supported (i.e. windows)
  62 case ${host} in
  63   *mingw32*) ;;
  64   *)
  65     AC_DEFINE_UNQUOTED([HAVE_DV_SOCKSER], 1, [Define if dv-sockser is usable.])
  66     BFIN_SIM_EXTRA_OBJS="${BFIN_SIM_EXTRA_OBJS} dv-sockser.o"
  67     ;;
  68 esac
  69
  70 AC_SUBST([BFIN_SIM_EXTRA_OBJS], ${BFIN_SIM_EXTRA_OBJS})
  71
  72 PKG_PROG_PKG_CONFIG
  73 PKG_CHECK_MODULES(SDL, sdl, [
  74         AC_CHECK_LIB(dl, dlopen, [
  75                 SDL_CFLAGS="${SDL_CFLAGS} -DHAVE_SDL"
  76                 SDL_LIBS="-ldl"
  77                 ], [SDL_CFLAGS= SDL_LIBS=])
  78         ], [:])
  79 AC_SUBST(SDL_CFLAGS)
  80 AC_SUBST(SDL_LIBS)
  81
  82 SIM_AC_OUTPUT