sharedlib/CMakeLists.txt

   1 # Anything that must be linked against the shared C library on Windows must
   2 # be built in this subdirectory, because CMake doesn't allow us to override
   3 # the compiler flags for each build type except at directory scope.  Note
   4 # to CMake developers:  Add a COMPILE_FLAGS_<CONFIG> target property, or
   5 # better yet, provide a friendly way of configuring a Windows target to use the
   6 # static C library.
   7
   8 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/..)
   9 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/..)
  10 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/..)
  11
  12 if(MSVC)
  13   # Build all configurations against shared C library
  14   foreach(var CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
  15     CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
  16     if(${var} MATCHES "/MT")
  17       string(REGEX REPLACE "/MT" "/MD" ${var} "${${var}}")
  18     endif()
  19   endforeach()
  20 endif()
  21
  22 foreach(src ${JPEG_SOURCES})
  23   set(JPEG_SRCS ${JPEG_SRCS} ../${src})
  24 endforeach()
  25
  26 if(WITH_SIMD AND (MSVC_IDE OR XCODE))
  27   # This tells CMake that the "source" files haven't been generated yet
  28   set_source_files_properties(${SIMD_OBJS} PROPERTIES GENERATED 1)
  29 endif()
  30
  31 if(WIN32)
  32   set(DEFFILE ../win/jpeg${SO_MAJOR_VERSION}.def)
  33 endif()
  34 if(MSVC)
  35   configure_file(${CMAKE_SOURCE_DIR}/win/jpeg.rc.in
  36     ${CMAKE_BINARY_DIR}/win/jpeg.rc)
  37   set(JPEG_SRCS ${JPEG_SRCS} ${CMAKE_BINARY_DIR}/win/jpeg.rc)
  38 endif()
  39 add_library(jpeg SHARED ${JPEG_SRCS} ${DEFFILE} ${SIMD_TARGET_OBJECTS}
  40   ${SIMD_OBJS} $<TARGET_OBJECTS:jpeg12> $<TARGET_OBJECTS:jpeg16>)
  41
  42 set_target_properties(jpeg PROPERTIES SOVERSION ${SO_MAJOR_VERSION}
  43   VERSION ${SO_MAJOR_VERSION}.${SO_AGE}.${SO_MINOR_VERSION})
  44 if(APPLE AND (NOT CMAKE_OSX_DEPLOYMENT_TARGET OR
  45               CMAKE_OSX_DEPLOYMENT_TARGET VERSION_GREATER 10.4))
  46   if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG)
  47     set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG "-Wl,-rpath,")
  48   endif()
  49   set_target_properties(jpeg PROPERTIES MACOSX_RPATH 1)
  50 endif()
  51 if(MAPFLAG)
  52   set_target_properties(jpeg PROPERTIES
  53     LINK_FLAGS "${MAPFLAG}${CMAKE_CURRENT_BINARY_DIR}/../libjpeg.map")
  54 endif()
  55 if(MSVC)
  56   set_target_properties(jpeg PROPERTIES
  57     RUNTIME_OUTPUT_NAME jpeg${SO_MAJOR_VERSION})
  58   # The jsimd_*.c file is built using /MT, so this prevents a linker warning.
  59   set_target_properties(jpeg PROPERTIES LINK_FLAGS
  60     "/NODEFAULTLIB:LIBCMT /NODEFAULTLIB:LIBCMTD")
  61 elseif(MINGW)
  62   set_target_properties(jpeg PROPERTIES SUFFIX -${SO_MAJOR_VERSION}.dll)
  63 endif()
  64
  65 if(WIN32)
  66   set(USE_SETMODE "-DUSE_SETMODE")
  67 endif()
  68 set(CDJPEG_COMPILE_FLAGS
  69   "-DBMP_SUPPORTED -DGIF_SUPPORTED -DPPM_SUPPORTED -DTARGA_SUPPORTED ${USE_SETMODE}")
  70
  71 # Compile a separate version of these source files with 12-bit and 16-bit data
  72 # precision.
  73 add_library(cjpeg12 OBJECT ../rdgif.c ../rdppm.c)
  74 set_property(TARGET cjpeg12 PROPERTY COMPILE_FLAGS
  75   "-DBITS_IN_JSAMPLE=12 -DGIF_SUPPORTED -DPPM_SUPPORTED")
  76 add_library(cjpeg16 OBJECT ../rdgif.c ../rdppm.c)
  77 set_property(TARGET cjpeg16 PROPERTY COMPILE_FLAGS
  78   "-DBITS_IN_JSAMPLE=16 -DGIF_SUPPORTED -DPPM_SUPPORTED")
  79 add_executable(cjpeg ../cjpeg.c ../cdjpeg.c ../rdbmp.c ../rdgif.c ../rdppm.c
  80   ../rdswitch.c ../rdtarga.c $<TARGET_OBJECTS:cjpeg12>
  81   $<TARGET_OBJECTS:cjpeg16>)
  82 set_property(TARGET cjpeg PROPERTY COMPILE_FLAGS ${CDJPEG_COMPILE_FLAGS})
  83 target_link_libraries(cjpeg jpeg)
  84
  85 # Compile a separate version of these source files with 12-bit and 16-bit data
  86 # precision.
  87 add_library(djpeg12 OBJECT ../rdcolmap.c ../wrgif.c ../wrppm.c)
  88 set_property(TARGET djpeg12 PROPERTY COMPILE_FLAGS
  89   "-DBITS_IN_JSAMPLE=12 -DGIF_SUPPORTED -DPPM_SUPPORTED")
  90 add_library(djpeg16 OBJECT ../wrppm.c)
  91 set_property(TARGET djpeg16 PROPERTY COMPILE_FLAGS
  92   "-DBITS_IN_JSAMPLE=16 -DPPM_SUPPORTED")
  93 add_executable(djpeg ../djpeg.c ../cdjpeg.c ../rdcolmap.c ../rdswitch.c
  94   ../wrbmp.c ../wrgif.c ../wrppm.c ../wrtarga.c $<TARGET_OBJECTS:djpeg12>
  95   $<TARGET_OBJECTS:djpeg16>)
  96 set_property(TARGET djpeg PROPERTY COMPILE_FLAGS ${CDJPEG_COMPILE_FLAGS})
  97 target_link_libraries(djpeg jpeg)
  98
  99 add_executable(jpegtran ../jpegtran.c ../cdjpeg.c ../rdswitch.c ../transupp.c)
 100 target_link_libraries(jpegtran jpeg)
 101 set_property(TARGET jpegtran PROPERTY COMPILE_FLAGS "${USE_SETMODE}")
 102
 103 add_executable(example ../example.c)
 104 target_link_libraries(example jpeg)
 105
 106 add_executable(jcstest ../jcstest.c)
 107 target_link_libraries(jcstest jpeg)
 108
 109 install(TARGETS jpeg EXPORT ${CMAKE_PROJECT_NAME}Targets
 110   INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
 111   ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 112   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 113   RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 114 install(TARGETS cjpeg djpeg jpegtran
 115   RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
 116 if(NOT CMAKE_VERSION VERSION_LESS "3.1" AND MSVC AND
 117   CMAKE_C_LINKER_SUPPORTS_PDB)
 118   install(FILES "$<TARGET_PDB_FILE:jpeg>"
 119     DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
 120 endif()