scripts/sphinx-pre-install

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0-or-later
   3 use strict;
   4
   5 # Copyright (c) 2017-2020 Mauro Carvalho Chehab <mchehab@kernel.org>
   6 #
   7
   8 my $prefix = "./";
   9 $prefix = "$ENV{'srctree'}/" if ($ENV{'srctree'});
  10
  11 my $conf = $prefix . "Documentation/conf.py";
  12 my $requirement_file = $prefix . "Documentation/sphinx/requirements.txt";
  13 my $virtenv_prefix = "sphinx_";
  14
  15 #
  16 # Static vars
  17 #
  18
  19 my %missing;
  20 my $system_release;
  21 my $need = 0;
  22 my $optional = 0;
  23 my $need_symlink = 0;
  24 my $need_sphinx = 0;
  25 my $need_pip = 0;
  26 my $need_virtualenv = 0;
  27 my $rec_sphinx_upgrade = 0;
  28 my $install = "";
  29 my $virtenv_dir = "";
  30 my $python_cmd = "";
  31 my $activate_cmd;
  32 my $min_version;
  33 my $cur_version;
  34 my $rec_version = "1.7.9";      # PDF won't build here
  35 my $min_pdf_version = "2.4.4";  # Min version where pdf builds
  36 my $latest_avail_ver;
  37
  38 #
  39 # Command line arguments
  40 #
  41
  42 my $pdf = 1;
  43 my $virtualenv = 1;
  44 my $version_check = 0;
  45
  46 #
  47 # List of required texlive packages on Fedora and OpenSuse
  48 #
  49
  50 my %texlive = (
  51         'amsfonts.sty'       => 'texlive-amsfonts',
  52         'amsmath.sty'        => 'texlive-amsmath',
  53         'amssymb.sty'        => 'texlive-amsfonts',
  54         'amsthm.sty'         => 'texlive-amscls',
  55         'anyfontsize.sty'    => 'texlive-anyfontsize',
  56         'atbegshi.sty'       => 'texlive-oberdiek',
  57         'bm.sty'             => 'texlive-tools',
  58         'capt-of.sty'        => 'texlive-capt-of',
  59         'cmap.sty'           => 'texlive-cmap',
  60         'ecrm1000.tfm'       => 'texlive-ec',
  61         'eqparbox.sty'       => 'texlive-eqparbox',
  62         'eu1enc.def'         => 'texlive-euenc',
  63         'fancybox.sty'       => 'texlive-fancybox',
  64         'fancyvrb.sty'       => 'texlive-fancyvrb',
  65         'float.sty'          => 'texlive-float',
  66         'fncychap.sty'       => 'texlive-fncychap',
  67         'footnote.sty'       => 'texlive-mdwtools',
  68         'framed.sty'         => 'texlive-framed',
  69         'luatex85.sty'       => 'texlive-luatex85',
  70         'multirow.sty'       => 'texlive-multirow',
  71         'needspace.sty'      => 'texlive-needspace',
  72         'palatino.sty'       => 'texlive-psnfss',
  73         'parskip.sty'        => 'texlive-parskip',
  74         'polyglossia.sty'    => 'texlive-polyglossia',
  75         'tabulary.sty'       => 'texlive-tabulary',
  76         'threeparttable.sty' => 'texlive-threeparttable',
  77         'titlesec.sty'       => 'texlive-titlesec',
  78         'ucs.sty'            => 'texlive-ucs',
  79         'upquote.sty'        => 'texlive-upquote',
  80         'wrapfig.sty'        => 'texlive-wrapfig',
  81         'ctexhook.sty'       => 'texlive-ctex',
  82 );
  83
  84 #
  85 # Subroutines that checks if a feature exists
  86 #
  87
  88 sub check_missing(%)
  89 {
  90         my %map = %{$_[0]};
  91
  92         foreach my $prog (sort keys %missing) {
  93                 my $is_optional = $missing{$prog};
  94
  95                 # At least on some LTS distros like CentOS 7, texlive doesn't
  96                 # provide all packages we need. When such distros are
  97                 # detected, we have to disable PDF output.
  98                 #
  99                 # So, we need to ignore the packages that distros would
 100                 # need for LaTeX to work
 101                 if ($is_optional == 2 && !$pdf) {
 102                         $optional--;
 103                         next;
 104                 }
 105
 106                 if ($is_optional) {
 107                         print "Warning: better to also install \"$prog\".\n";
 108                 } else {
 109                         print "ERROR: please install \"$prog\", otherwise, build won't work.\n";
 110                 }
 111                 if (defined($map{$prog})) {
 112                         $install .= " " . $map{$prog};
 113                 } else {
 114                         $install .= " " . $prog;
 115                 }
 116         }
 117
 118         $install =~ s/^\s//;
 119 }
 120
 121 sub add_package($$)
 122 {
 123         my $package = shift;
 124         my $is_optional = shift;
 125
 126         $missing{$package} = $is_optional;
 127         if ($is_optional) {
 128                 $optional++;
 129         } else {
 130                 $need++;
 131         }
 132 }
 133
 134 sub check_missing_file($$$)
 135 {
 136         my $files = shift;
 137         my $package = shift;
 138         my $is_optional = shift;
 139
 140         for (@$files) {
 141                 return if(-e $_);
 142         }
 143
 144         add_package($package, $is_optional);
 145 }
 146
 147 sub findprog($)
 148 {
 149         foreach(split(/:/, $ENV{PATH})) {
 150                 return "$_/$_[0]" if(-x "$_/$_[0]");
 151         }
 152 }
 153
 154 sub find_python_no_venv()
 155 {
 156         my $prog = shift;
 157
 158         my $cur_dir = qx(pwd);
 159         $cur_dir =~ s/\s+$//;
 160
 161         foreach my $dir (split(/:/, $ENV{PATH})) {
 162                 next if ($dir =~ m,($cur_dir)/sphinx,);
 163                 return "$dir/python3" if(-x "$dir/python3");
 164         }
 165         foreach my $dir (split(/:/, $ENV{PATH})) {
 166                 next if ($dir =~ m,($cur_dir)/sphinx,);
 167                 return "$dir/python" if(-x "$dir/python");
 168         }
 169         return "python";
 170 }
 171
 172 sub check_program($$)
 173 {
 174         my $prog = shift;
 175         my $is_optional = shift;
 176
 177         return $prog if findprog($prog);
 178
 179         add_package($prog, $is_optional);
 180 }
 181
 182 sub check_perl_module($$)
 183 {
 184         my $prog = shift;
 185         my $is_optional = shift;
 186
 187         my $err = system("perl -M$prog -e 1 2>/dev/null /dev/null");
 188         return if ($err == 0);
 189
 190         add_package($prog, $is_optional);
 191 }
 192
 193 sub check_python_module($$)
 194 {
 195         my $prog = shift;
 196         my $is_optional = shift;
 197
 198         return if (!$python_cmd);
 199
 200         my $err = system("$python_cmd -c 'import $prog' 2>/dev/null /dev/null");
 201         return if ($err == 0);
 202
 203         add_package($prog, $is_optional);
 204 }
 205
 206 sub check_rpm_missing($$)
 207 {
 208         my @pkgs = @{$_[0]};
 209         my $is_optional = $_[1];
 210
 211         foreach my $prog(@pkgs) {
 212                 my $err = system("rpm -q '$prog' 2>/dev/null >/dev/null");
 213                 add_package($prog, $is_optional) if ($err);
 214         }
 215 }
 216
 217 sub check_pacman_missing($$)
 218 {
 219         my @pkgs = @{$_[0]};
 220         my $is_optional = $_[1];
 221
 222         foreach my $prog(@pkgs) {
 223                 my $err = system("pacman -Q '$prog' 2>/dev/null >/dev/null");
 224                 add_package($prog, $is_optional) if ($err);
 225         }
 226 }
 227
 228 sub check_missing_tex($)
 229 {
 230         my $is_optional = shift;
 231         my $kpsewhich = findprog("kpsewhich");
 232
 233         foreach my $prog(keys %texlive) {
 234                 my $package = $texlive{$prog};
 235                 if (!$kpsewhich) {
 236                         add_package($package, $is_optional);
 237                         next;
 238                 }
 239                 my $file = qx($kpsewhich $prog);
 240                 add_package($package, $is_optional) if ($file =~ /^\s*$/);
 241         }
 242 }
 243
 244 sub get_sphinx_fname()
 245 {
 246         my $fname = "sphinx-build";
 247         return $fname if findprog($fname);
 248
 249         $fname = "sphinx-build-3";
 250         if (findprog($fname)) {
 251                 $need_symlink = 1;
 252                 return $fname;
 253         }
 254
 255         return "";
 256 }
 257
 258 sub get_sphinx_version($)
 259 {
 260         my $cmd = shift;
 261         my $ver;
 262
 263         open IN, "$cmd --version 2>&1 |";
 264         while (<IN>) {
 265                 if (m/^\s*sphinx-build\s+([\d\.]+)((\+\/[\da-f]+)|(b\d+))?$/) {
 266                         $ver=$1;
 267                         last;
 268                 }
 269                 # Sphinx 1.2.x uses a different format
 270                 if (m/^\s*Sphinx.*\s+([\d\.]+)$/) {
 271                         $ver=$1;
 272                         last;
 273                 }
 274         }
 275         close IN;
 276         return $ver;
 277 }
 278
 279 sub check_sphinx()
 280 {
 281         my $default_version;
 282
 283         open IN, $conf or die "Can't open $conf";
 284         while (<IN>) {
 285                 if (m/^\s*needs_sphinx\s*=\s*[\'\"]([\d\.]+)[\'\"]/) {
 286                         $min_version=$1;
 287                         last;
 288                 }
 289         }
 290         close IN;
 291
 292         die "Can't get needs_sphinx version from $conf" if (!$min_version);
 293
 294         open IN, $requirement_file or die "Can't open $requirement_file";
 295         while (<IN>) {
 296                 if (m/^\s*Sphinx\s*==\s*([\d\.]+)$/) {
 297                         $default_version=$1;
 298                         last;
 299                 }
 300         }
 301         close IN;
 302
 303         die "Can't get default sphinx version from $requirement_file" if (!$default_version);
 304
 305         $virtenv_dir = $virtenv_prefix . $default_version;
 306
 307         my $sphinx = get_sphinx_fname();
 308         if ($sphinx eq "") {
 309                 $need_sphinx = 1;
 310                 return;
 311         }
 312
 313         $cur_version = get_sphinx_version($sphinx);
 314         die ("$sphinx returned an error") if (!$cur_version);
 315
 316         die "$sphinx didn't return its version" if (!$cur_version);
 317
 318         if ($cur_version lt $min_version) {
 319                 printf "ERROR: Sphinx version is %s. It should be >= %s (recommended >= %s)\n",
 320                        $cur_version, $min_version, $default_version;
 321                 $need_sphinx = 1;
 322                 return;
 323         }
 324
 325         return if ($cur_version lt $rec_version);
 326
 327         # On version check mode, just assume Sphinx has all mandatory deps
 328         exit (0) if ($version_check);
 329 }
 330
 331 #
 332 # Ancillary subroutines
 333 #
 334
 335 sub catcheck($)
 336 {
 337   my $res = "";
 338   $res = qx(cat $_[0]) if (-r $_[0]);
 339   return $res;
 340 }
 341
 342 sub which($)
 343 {
 344         my $file = shift;
 345         my @path = split ":", $ENV{PATH};
 346
 347         foreach my $dir(@path) {
 348                 my $name = $dir.'/'.$file;
 349                 return $name if (-x $name );
 350         }
 351         return undef;
 352 }
 353
 354 #
 355 # Subroutines that check distro-specific hints
 356 #
 357
 358 sub give_debian_hints()
 359 {
 360         my %map = (
 361                 "python-sphinx"         => "python3-sphinx",
 362                 "sphinx_rtd_theme"      => "python3-sphinx-rtd-theme",
 363                 "ensurepip"             => "python3-venv",
 364                 "virtualenv"            => "virtualenv",
 365                 "dot"                   => "graphviz",
 366                 "convert"               => "imagemagick",
 367                 "Pod::Usage"            => "perl-modules",
 368                 "xelatex"               => "texlive-xetex",
 369                 "rsvg-convert"          => "librsvg2-bin",
 370         );
 371
 372         if ($pdf) {
 373                 check_missing_file(["/usr/share/texlive/texmf-dist/tex/latex/ctex/ctexhook.sty"],
 374                                    "texlive-lang-chinese", 2);
 375
 376                 check_missing_file(["/usr/share/fonts/truetype/dejavu/DejaVuSans.ttf"],
 377                                    "fonts-dejavu", 2);
 378
 379                 check_missing_file(["/usr/share/fonts/noto-cjk/NotoSansCJK-Regular.ttc",
 380                                     "/usr/share/fonts/opentype/noto/NotoSansCJK-Regular.ttc",
 381                                     "/usr/share/fonts/opentype/noto/NotoSerifCJK-Regular.ttc"],
 382                                    "fonts-noto-cjk", 2);
 383         }
 384
 385         check_program("dvipng", 2) if ($pdf);
 386         check_missing(\%map);
 387
 388         return if (!$need && !$optional);
 389         printf("You should run:\n\n\tsudo apt-get install $install\n");
 390 }
 391
 392 sub give_redhat_hints()
 393 {
 394         my %map = (
 395                 "python-sphinx"         => "python3-sphinx",
 396                 "sphinx_rtd_theme"      => "python3-sphinx_rtd_theme",
 397                 "virtualenv"            => "python3-virtualenv",
 398                 "dot"                   => "graphviz",
 399                 "convert"               => "ImageMagick",
 400                 "Pod::Usage"            => "perl-Pod-Usage",
 401                 "xelatex"               => "texlive-xetex-bin",
 402                 "rsvg-convert"          => "librsvg2-tools",
 403         );
 404
 405         my @fedora26_opt_pkgs = (
 406                 "graphviz-gd",          # Fedora 26: needed for PDF support
 407         );
 408
 409         my @fedora_tex_pkgs = (
 410                 "texlive-collection-fontsrecommended",
 411                 "texlive-collection-latex",
 412                 "texlive-xecjk",
 413                 "dejavu-sans-fonts",
 414                 "dejavu-serif-fonts",
 415                 "dejavu-sans-mono-fonts",
 416         );
 417
 418         #
 419         # Checks valid for RHEL/CentOS version 7.x.
 420         #
 421         my $old = 0;
 422         my $rel;
 423         $rel = $1 if ($system_release =~ /release\s+(\d+)/);
 424
 425         if (!($system_release =~ /Fedora/)) {
 426                 $map{"virtualenv"} = "python-virtualenv";
 427
 428                 if ($rel && $rel < 8) {
 429                         $old = 1;
 430                         $pdf = 0;
 431
 432                         printf("Note: texlive packages on RHEL/CENTOS <= 7 are incomplete. Can't support PDF output\n");
 433                         printf("If you want to build PDF, please read:\n");
 434                         printf("\thttps://www.systutorials.com/241660/how-to-install-tex-live-on-centos-7-linux/\n");
 435                 }
 436         } else {
 437                 if ($rel && $rel < 26) {
 438                         $old = 1;
 439                 }
 440         }
 441         if (!$rel) {
 442                 printf("Couldn't identify release number\n");
 443                 $old = 1;
 444                 $pdf = 0;
 445         }
 446
 447         if ($pdf) {
 448                 check_missing_file(["/usr/share/fonts/google-noto-cjk/NotoSansCJK-Regular.ttc"],
 449                                    "google-noto-sans-cjk-ttc-fonts", 2);
 450         }
 451
 452         check_rpm_missing(\@fedora26_opt_pkgs, 2) if ($pdf && !$old);
 453         check_rpm_missing(\@fedora_tex_pkgs, 2) if ($pdf);
 454         check_missing_tex(2) if ($pdf);
 455         check_missing(\%map);
 456
 457         return if (!$need && !$optional);
 458
 459         if (!$old) {
 460                 # dnf, for Fedora 18+
 461                 printf("You should run:\n\n\tsudo dnf install -y $install\n");
 462         } else {
 463                 # yum, for RHEL (and clones) or Fedora version < 18
 464                 printf("You should run:\n\n\tsudo yum install -y $install\n");
 465         }
 466 }
 467
 468 sub give_opensuse_hints()
 469 {
 470         my %map = (
 471                 "python-sphinx"         => "python3-sphinx",
 472                 "sphinx_rtd_theme"      => "python3-sphinx_rtd_theme",
 473                 "virtualenv"            => "python3-virtualenv",
 474                 "dot"                   => "graphviz",
 475                 "convert"               => "ImageMagick",
 476                 "Pod::Usage"            => "perl-Pod-Usage",
 477                 "xelatex"               => "texlive-xetex-bin",
 478         );
 479
 480         # On Tumbleweed, this package is also named rsvg-convert
 481         $map{"rsvg-convert"} = "rsvg-view" if (!($system_release =~ /Tumbleweed/));
 482
 483         my @suse_tex_pkgs = (
 484                 "texlive-babel-english",
 485                 "texlive-caption",
 486                 "texlive-colortbl",
 487                 "texlive-courier",
 488                 "texlive-dvips",
 489                 "texlive-helvetic",
 490                 "texlive-makeindex",
 491                 "texlive-metafont",
 492                 "texlive-metapost",
 493                 "texlive-palatino",
 494                 "texlive-preview",
 495                 "texlive-times",
 496                 "texlive-zapfchan",
 497                 "texlive-zapfding",
 498         );
 499
 500         $map{"latexmk"} = "texlive-latexmk-bin";
 501
 502         # FIXME: add support for installing CJK fonts
 503         #
 504         # I tried hard, but was unable to find a way to install
 505         # "Noto Sans CJK SC" on openSUSE
 506
 507         check_rpm_missing(\@suse_tex_pkgs, 2) if ($pdf);
 508         check_missing_tex(2) if ($pdf);
 509         check_missing(\%map);
 510
 511         return if (!$need && !$optional);
 512         printf("You should run:\n\n\tsudo zypper install --no-recommends $install\n");
 513 }
 514
 515 sub give_mageia_hints()
 516 {
 517         my %map = (
 518                 "python-sphinx"         => "python3-sphinx",
 519                 "sphinx_rtd_theme"      => "python3-sphinx_rtd_theme",
 520                 "virtualenv"            => "python3-virtualenv",
 521                 "dot"                   => "graphviz",
 522                 "convert"               => "ImageMagick",
 523                 "Pod::Usage"            => "perl-Pod-Usage",
 524                 "xelatex"               => "texlive",
 525                 "rsvg-convert"          => "librsvg2",
 526         );
 527
 528         my @tex_pkgs = (
 529                 "texlive-fontsextra",
 530         );
 531
 532         $map{"latexmk"} = "texlive-collection-basic";
 533
 534         my $packager_cmd;
 535         my $noto_sans;
 536         if ($system_release =~ /OpenMandriva/) {
 537                 $packager_cmd = "dnf install";
 538                 $noto_sans = "noto-sans-cjk-fonts";
 539                 @tex_pkgs = ( "texlive-collection-fontsextra" );
 540         } else {
 541                 $packager_cmd = "urpmi";
 542                 $noto_sans = "google-noto-sans-cjk-ttc-fonts";
 543         }
 544
 545
 546         if ($pdf) {
 547                 check_missing_file(["/usr/share/fonts/google-noto-cjk/NotoSansCJK-Regular.ttc",
 548                                     "/usr/share/fonts/TTF/NotoSans-Regular.ttf"],
 549                                    $noto_sans, 2);
 550         }
 551
 552         check_rpm_missing(\@tex_pkgs, 2) if ($pdf);
 553         check_missing(\%map);
 554
 555         return if (!$need && !$optional);
 556         printf("You should run:\n\n\tsudo $packager_cmd $install\n");
 557 }
 558
 559 sub give_arch_linux_hints()
 560 {
 561         my %map = (
 562                 "sphinx_rtd_theme"      => "python-sphinx_rtd_theme",
 563                 "virtualenv"            => "python-virtualenv",
 564                 "dot"                   => "graphviz",
 565                 "convert"               => "imagemagick",
 566                 "xelatex"               => "texlive-bin",
 567                 "latexmk"               => "texlive-core",
 568                 "rsvg-convert"          => "extra/librsvg",
 569         );
 570
 571         my @archlinux_tex_pkgs = (
 572                 "texlive-core",
 573                 "texlive-latexextra",
 574                 "ttf-dejavu",
 575         );
 576         check_pacman_missing(\@archlinux_tex_pkgs, 2) if ($pdf);
 577
 578         if ($pdf) {
 579                 check_missing_file(["/usr/share/fonts/noto-cjk/NotoSansCJK-Regular.ttc"],
 580                                    "noto-fonts-cjk", 2);
 581         }
 582
 583         check_missing(\%map);
 584
 585         return if (!$need && !$optional);
 586         printf("You should run:\n\n\tsudo pacman -S $install\n");
 587 }
 588
 589 sub give_gentoo_hints()
 590 {
 591         my %map = (
 592                 "sphinx_rtd_theme"      => "dev-python/sphinx_rtd_theme",
 593                 "virtualenv"            => "dev-python/virtualenv",
 594                 "dot"                   => "media-gfx/graphviz",
 595                 "convert"               => "media-gfx/imagemagick",
 596                 "xelatex"               => "dev-texlive/texlive-xetex media-fonts/dejavu",
 597                 "rsvg-convert"          => "gnome-base/librsvg",
 598         );
 599
 600         check_missing_file(["/usr/share/fonts/dejavu/DejaVuSans.ttf"],
 601                            "media-fonts/dejavu", 2) if ($pdf);
 602
 603         if ($pdf) {
 604                 check_missing_file(["/usr/share/fonts/noto-cjk/NotoSansCJKsc-Regular.otf",
 605                                     "/usr/share/fonts/noto-cjk/NotoSerifCJK-Regular.ttc"],
 606                                    "media-fonts/noto-cjk", 2);
 607         }
 608
 609         check_missing(\%map);
 610
 611         return if (!$need && !$optional);
 612
 613         printf("You should run:\n\n");
 614
 615         my $imagemagick = "media-gfx/imagemagick svg png";
 616         my $cairo = "media-gfx/graphviz cairo pdf";
 617         my $portage_imagemagick = "/etc/portage/package.use/imagemagick";
 618         my $portage_cairo = "/etc/portage/package.use/graphviz";
 619
 620         if (qx(grep imagemagick $portage_imagemagick 2>/dev/null) eq "") {
 621                 printf("\tsudo su -c 'echo \"$imagemagick\" > $portage_imagemagick'\n")
 622         }
 623         if (qx(grep graphviz $portage_cairo 2>/dev/null) eq  "") {
 624                 printf("\tsudo su -c 'echo \"$cairo\" > $portage_cairo'\n");
 625         }
 626
 627         printf("\tsudo emerge --ask $install\n");
 628
 629 }
 630
 631 sub check_distros()
 632 {
 633         # Distro-specific hints
 634         if ($system_release =~ /Red Hat Enterprise Linux/) {
 635                 give_redhat_hints;
 636                 return;
 637         }
 638         if ($system_release =~ /CentOS/) {
 639                 give_redhat_hints;
 640                 return;
 641         }
 642         if ($system_release =~ /Scientific Linux/) {
 643                 give_redhat_hints;
 644                 return;
 645         }
 646         if ($system_release =~ /Oracle Linux Server/) {
 647                 give_redhat_hints;
 648                 return;
 649         }
 650         if ($system_release =~ /Fedora/) {
 651                 give_redhat_hints;
 652                 return;
 653         }
 654         if ($system_release =~ /Ubuntu/) {
 655                 give_debian_hints;
 656                 return;
 657         }
 658         if ($system_release =~ /Debian/) {
 659                 give_debian_hints;
 660                 return;
 661         }
 662         if ($system_release =~ /openSUSE/) {
 663                 give_opensuse_hints;
 664                 return;
 665         }
 666         if ($system_release =~ /Mageia/) {
 667                 give_mageia_hints;
 668                 return;
 669         }
 670         if ($system_release =~ /OpenMandriva/) {
 671                 give_mageia_hints;
 672                 return;
 673         }
 674         if ($system_release =~ /Arch Linux/) {
 675                 give_arch_linux_hints;
 676                 return;
 677         }
 678         if ($system_release =~ /Gentoo/) {
 679                 give_gentoo_hints;
 680                 return;
 681         }
 682
 683         #
 684         # Fall-back to generic hint code for other distros
 685         # That's far from ideal, specially for LaTeX dependencies.
 686         #
 687         my %map = (
 688                 "sphinx-build" => "sphinx"
 689         );
 690         check_missing_tex(2) if ($pdf);
 691         check_missing(\%map);
 692         print "I don't know distro $system_release.\n";
 693         print "So, I can't provide you a hint with the install procedure.\n";
 694         print "There are likely missing dependencies.\n";
 695 }
 696
 697 #
 698 # Common dependencies
 699 #
 700
 701 sub deactivate_help()
 702 {
 703         printf "\nIf you want to exit the virtualenv, you can use:\n";
 704         printf "\tdeactivate\n";
 705 }
 706
 707 sub get_virtenv()
 708 {
 709         my $ver;
 710         my $min_activate = "$ENV{'PWD'}/${virtenv_prefix}${min_version}/bin/activate";
 711         my @activates = glob "$ENV{'PWD'}/${virtenv_prefix}*/bin/activate";
 712
 713         @activates = sort {$b cmp $a} @activates;
 714
 715         foreach my $f (@activates) {
 716                 next if ($f lt $min_activate);
 717
 718                 my $sphinx_cmd = $f;
 719                 $sphinx_cmd =~ s/activate/sphinx-build/;
 720                 next if (! -f $sphinx_cmd);
 721
 722                 my $ver = get_sphinx_version($sphinx_cmd);
 723                 if ($need_sphinx && ($ver ge $min_version)) {
 724                         return ($f, $ver);
 725                 } elsif ($ver gt $cur_version) {
 726                         return ($f, $ver);
 727                 }
 728         }
 729         return ("", "");
 730 }
 731
 732 sub recommend_sphinx_upgrade()
 733 {
 734         my $venv_ver;
 735
 736         # Avoid running sphinx-builds from venv if $cur_version is good
 737         if ($cur_version && ($cur_version ge $rec_version)) {
 738                 $latest_avail_ver = $cur_version;
 739                 return;
 740         }
 741
 742         # Get the highest version from sphinx_*/bin/sphinx-build and the
 743         # corresponding command to activate the venv/virtenv
 744         $activate_cmd = get_virtenv();
 745
 746         # Store the highest version from Sphinx existing virtualenvs
 747         if (($activate_cmd ne "") && ($venv_ver gt $cur_version)) {
 748                 $latest_avail_ver = $venv_ver;
 749         } else {
 750                 $latest_avail_ver = $cur_version if ($cur_version);
 751         }
 752
 753         # As we don't know package version of Sphinx, and there's no
 754         # virtual environments, don't check if upgrades are needed
 755         if (!$virtualenv) {
 756                 return if (!$latest_avail_ver);
 757         }
 758
 759         # Either there are already a virtual env or a new one should be created
 760         $need_pip = 1;
 761
 762         # Return if the reason is due to an upgrade or not
 763         if ($latest_avail_ver lt $rec_version) {
 764                 $rec_sphinx_upgrade = 1;
 765         }
 766 }
 767
 768 #
 769 # The logic here is complex, as it have to deal with different versions:
 770 #       - minimal supported version;
 771 #       - minimal PDF version;
 772 #       - recommended version.
 773 # It also needs to work fine with both distro's package and venv/virtualenv
 774 sub recommend_sphinx_version($)
 775 {
 776         my $virtualenv_cmd = shift;
 777
 778         if ($latest_avail_ver lt $min_pdf_version) {
 779                 print "note: If you want pdf, you need at least Sphinx $min_pdf_version.\n";
 780         }
 781
 782         # Version is OK. Nothing to do.
 783         return if ($cur_version && ($cur_version ge $rec_version));
 784
 785         if (!$need_sphinx) {
 786                 # sphinx-build is present and its version is >= $min_version
 787
 788                 #only recommend enabling a newer virtenv version if makes sense.
 789                 if ($latest_avail_ver gt $cur_version) {
 790                         printf "\nYou may also use the newer Sphinx version $latest_avail_ver with:\n";
 791                         printf "\tdeactivate\n"  if ($ENV{'PWD'} =~ /${virtenv_prefix}/);
 792                         printf "\t. $activate_cmd\n";
 793                         deactivate_help();
 794
 795                         return;
 796                 }
 797                 return if ($latest_avail_ver ge $rec_version);
 798         }
 799
 800         if (!$virtualenv) {
 801                 # No sphinx either via package or via virtenv. As we can't
 802                 # Compare the versions here, just return, recommending the
 803                 # user to install it from the package distro.
 804                 return if (!$latest_avail_ver);
 805
 806                 # User doesn't want a virtenv recommendation, but he already
 807                 # installed one via virtenv with a newer version.
 808                 # So, print commands to enable it
 809                 if ($latest_avail_ver gt $cur_version) {
 810                         printf "\nYou may also use the Sphinx virtualenv version $latest_avail_ver with:\n";
 811                         printf "\tdeactivate\n"  if ($ENV{'PWD'} =~ /${virtenv_prefix}/);
 812                         printf "\t. $activate_cmd\n";
 813                         deactivate_help();
 814
 815                         return;
 816                 }
 817                 print "\n";
 818         } else {
 819                 $need++ if ($need_sphinx);
 820         }
 821
 822         # Suggest newer versions if current ones are too old
 823         if ($latest_avail_ver && $cur_version ge $min_version) {
 824                 # If there's a good enough version, ask the user to enable it
 825                 if ($latest_avail_ver ge $rec_version) {
 826                         printf "\nNeed to activate Sphinx (version $latest_avail_ver) on virtualenv with:\n";
 827                         printf "\t. $activate_cmd\n";
 828                         deactivate_help();
 829
 830                         return;
 831                 }
 832
 833                 # Version is above the minimal required one, but may be
 834                 # below the recommended one. So, print warnings/notes
 835
 836                 if ($latest_avail_ver lt $rec_version) {
 837                         print "Warning: It is recommended at least Sphinx version $rec_version.\n";
 838                 }
 839         }
 840
 841         # At this point, either it needs Sphinx or upgrade is recommended,
 842         # both via pip
 843
 844         if ($rec_sphinx_upgrade) {
 845                 if (!$virtualenv) {
 846                         print "Instead of install/upgrade Python Sphinx pkg, you could use pip/pypi with:\n\n";
 847                 } else {
 848                         print "To upgrade Sphinx, use:\n\n";
 849                 }
 850         } else {
 851                 print "Sphinx needs to be installed either as a package or via pip/pypi with:\n";
 852         }
 853
 854         $python_cmd = find_python_no_venv();
 855
 856         printf "\t$virtualenv_cmd $virtenv_dir\n";
 857
 858         printf "\t. $virtenv_dir/bin/activate\n";
 859         printf "\tpip install -r $requirement_file\n";
 860         deactivate_help();
 861 }
 862
 863 sub check_needs()
 864 {
 865         # Check if Sphinx is already accessible from current environment
 866         check_sphinx();
 867
 868         if ($system_release) {
 869                 print "Detected OS: $system_release.\n";
 870         } else {
 871                 print "Unknown OS\n";
 872         }
 873         printf "Sphinx version: %s\n\n", $cur_version if ($cur_version);
 874
 875         # Check python command line, trying first python3
 876         $python_cmd = findprog("python3");
 877         $python_cmd = check_program("python", 0) if (!$python_cmd);
 878
 879         # Check the type of virtual env, depending on Python version
 880         if ($python_cmd) {
 881                 if ($virtualenv) {
 882                         my $tmp = qx($python_cmd --version 2>&1);
 883                         if ($tmp =~ m/(\d+\.)(\d+\.)/) {
 884                                 if ($1 < 3) {
 885                                         # Fail if it finds python2 (or worse)
 886                                         die "Python 3 is required to build the kernel docs\n";
 887                                 }
 888                                 if ($1 == 3 && $2 < 3) {
 889                                         # Need Python 3.3 or upper for venv
 890                                         $need_virtualenv = 1;
 891                                 }
 892                         } else {
 893                                 die "Warning: couldn't identify $python_cmd version!";
 894                         }
 895                 } else {
 896                         add_package("python-sphinx", 0);
 897                 }
 898         }
 899
 900         recommend_sphinx_upgrade();
 901
 902         my $virtualenv_cmd;
 903
 904         if ($need_pip) {
 905                 # Set virtualenv command line, if python < 3.3
 906                 if ($need_virtualenv) {
 907                         $virtualenv_cmd = findprog("virtualenv-3");
 908                         $virtualenv_cmd = findprog("virtualenv-3.5") if (!$virtualenv_cmd);
 909                         if (!$virtualenv_cmd) {
 910                                 check_program("virtualenv", 0);
 911                                 $virtualenv_cmd = "virtualenv";
 912                         }
 913                 } else {
 914                         $virtualenv_cmd = "$python_cmd -m venv";
 915                         check_python_module("ensurepip", 0);
 916                 }
 917         }
 918
 919         # Check for needed programs/tools
 920         check_perl_module("Pod::Usage", 0);
 921         check_program("make", 0);
 922         check_program("gcc", 0);
 923         check_python_module("sphinx_rtd_theme", 1) if (!$virtualenv);
 924         check_program("dot", 1);
 925         check_program("convert", 1);
 926
 927         # Extra PDF files - should use 2 for is_optional
 928         check_program("xelatex", 2) if ($pdf);
 929         check_program("rsvg-convert", 2) if ($pdf);
 930         check_program("latexmk", 2) if ($pdf);
 931
 932         # Do distro-specific checks and output distro-install commands
 933         check_distros();
 934
 935         if (!$python_cmd) {
 936                 if ($need == 1) {
 937                         die "Can't build as $need mandatory dependency is missing";
 938                 } elsif ($need) {
 939                         die "Can't build as $need mandatory dependencies are missing";
 940                 }
 941         }
 942
 943         # Check if sphinx-build is called sphinx-build-3
 944         if ($need_symlink) {
 945                 printf "\tsudo ln -sf %s /usr/bin/sphinx-build\n\n",
 946                        which("sphinx-build-3");
 947         }
 948
 949         recommend_sphinx_version($virtualenv_cmd);
 950         printf "\n";
 951
 952         print "All optional dependencies are met.\n" if (!$optional);
 953
 954         if ($need == 1) {
 955                 die "Can't build as $need mandatory dependency is missing";
 956         } elsif ($need) {
 957                 die "Can't build as $need mandatory dependencies are missing";
 958         }
 959
 960         print "Needed package dependencies are met.\n";
 961 }
 962
 963 #
 964 # Main
 965 #
 966
 967 while (@ARGV) {
 968         my $arg = shift(@ARGV);
 969
 970         if ($arg eq "--no-virtualenv") {
 971                 $virtualenv = 0;
 972         } elsif ($arg eq "--no-pdf"){
 973                 $pdf = 0;
 974         } elsif ($arg eq "--version-check"){
 975                 $version_check = 1;
 976         } else {
 977                 print "Usage:\n\t$0 <--no-virtualenv> <--no-pdf> <--version-check>\n\n";
 978                 print "Where:\n";
 979                 print "\t--no-virtualenv\t- Recommend installing Sphinx instead of using a virtualenv\n";
 980                 print "\t--version-check\t- if version is compatible, don't check for missing dependencies\n";
 981                 print "\t--no-pdf\t- don't check for dependencies required to build PDF docs\n\n";
 982                 exit -1;
 983         }
 984 }
 985
 986 #
 987 # Determine the system type. There's no standard unique way that would
 988 # work with all distros with a minimal package install. So, several
 989 # methods are used here.
 990 #
 991 # By default, it will use lsb_release function. If not available, it will
 992 # fail back to reading the known different places where the distro name
 993 # is stored
 994 #
 995
 996 $system_release = qx(lsb_release -d) if which("lsb_release");
 997 $system_release =~ s/Description:\s*// if ($system_release);
 998 $system_release = catcheck("/etc/system-release") if !$system_release;
 999 $system_release = catcheck("/etc/redhat-release") if !$system_release;
1000 $system_release = catcheck("/etc/lsb-release") if !$system_release;
1001 $system_release = catcheck("/etc/gentoo-release") if !$system_release;
1002
1003 # This seems more common than LSB these days
1004 if (!$system_release) {
1005         my %os_var;
1006         if (open IN, "cat /etc/os-release|") {
1007                 while (<IN>) {
1008                         if (m/^([\w\d\_]+)=\"?([^\"]*)\"?\n/) {
1009                                 $os_var{$1}=$2;
1010                         }
1011                 }
1012                 $system_release = $os_var{"NAME"};
1013                 if (defined($os_var{"VERSION_ID"})) {
1014                         $system_release .= " " . $os_var{"VERSION_ID"} if (defined($os_var{"VERSION_ID"}));
1015                 } else {
1016                         $system_release .= " " . $os_var{"VERSION"};
1017                 }
1018         }
1019 }
1020 $system_release = catcheck("/etc/issue") if !$system_release;
1021 $system_release =~ s/\s+$//;
1022
1023 check_needs;