scripts/recordmcount.pl

   1 #!/usr/bin/env perl
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use warnings;
 110 use strict;
 111
 112 my $P = $0;
 113 $P =~ s@.*/@@g;
 114
 115 my $V = '0.1';
 116
 117 if ($#ARGV != 11) {
 118         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 119         print "version: $V\n";
 120         exit(1);
 121 }
 122
 123 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 124     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 125
 126 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 127 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 128     exit(0);
 129 }
 130
 131 # Acceptable sections to record.
 132 my %text_sections = (
 133      ".text" => 1,
 134      ".init.text" => 1,
 135      ".ref.text" => 1,
 136      ".sched.text" => 1,
 137      ".spinlock.text" => 1,
 138      ".irqentry.text" => 1,
 139      ".softirqentry.text" => 1,
 140      ".kprobes.text" => 1,
 141      ".cpuidle.text" => 1,
 142      ".text.unlikely" => 1,
 143 );
 144
 145 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 146 $objdump = 'objdump' if (!$objdump);
 147 $objcopy = 'objcopy' if (!$objcopy);
 148 $cc = 'gcc' if (!$cc);
 149 $ld = 'ld' if (!$ld);
 150 $nm = 'nm' if (!$nm);
 151 $rm = 'rm' if (!$rm);
 152 $mv = 'mv' if (!$mv);
 153
 154 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 155 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 156
 157 my %locals;             # List of local (static) functions
 158 my %weak;               # List of weak functions
 159 my %convert;            # List of local functions used that needs conversion
 160
 161 my $type;
 162 my $local_regex;        # Match a local function (return function)
 163 my $weak_regex;         # Match a weak function (return function)
 164 my $section_regex;      # Find the start of a section
 165 my $function_regex;     # Find the name of a function
 166                         #    (return offset and func name)
 167 my $mcount_regex;       # Find the call site to mcount (return offset)
 168 my $mcount_adjust;      # Address adjustment to mcount offset
 169 my $alignment;          # The .align value to use for $mcount_section
 170 my $section_type;       # Section header plus possible alignment command
 171 my $can_use_local = 0;  # If we can use local function references
 172
 173 # Shut up recordmcount if user has older objcopy
 174 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 175 my $print_warning = 1;
 176 $print_warning = 0 if ( -f $quiet_recordmcount);
 177
 178 ##
 179 # check_objcopy - whether objcopy supports --globalize-symbols
 180 #
 181 #  --globalize-symbols came out in 2.17, we must test the version
 182 #  of objcopy, and if it is less than 2.17, then we can not
 183 #  record local functions.
 184 sub check_objcopy
 185 {
 186     open (IN, "$objcopy --version |") or die "error running $objcopy";
 187     while (<IN>) {
 188         if (/objcopy.*\s(\d+)\.(\d+)/) {
 189             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 190             last;
 191         }
 192     }
 193     close (IN);
 194
 195     if (!$can_use_local && $print_warning) {
 196         print STDERR "WARNING: could not find objcopy version or version " .
 197             "is less than 2.17.\n" .
 198             "\tLocal function references are disabled.\n";
 199         open (QUIET, ">$quiet_recordmcount");
 200         printf QUIET "Disables the warning from recordmcount.pl\n";
 201         close QUIET;
 202     }
 203 }
 204
 205 if ($arch =~ /(x86(_64)?)|(i386)/) {
 206     if ($bits == 64) {
 207         $arch = "x86_64";
 208     } else {
 209         $arch = "i386";
 210     }
 211 }
 212
 213 #
 214 # We base the defaults off of i386, the other archs may
 215 # feel free to change them in the below if statements.
 216 #
 217 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 218 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 219 $section_regex = "Disassembly of section\\s+(\\S+):";
 220 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 221 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
 222 $section_type = '@progbits';
 223 $mcount_adjust = 0;
 224 $type = ".long";
 225
 226 if ($arch eq "x86_64") {
 227     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
 228     $type = ".quad";
 229     $alignment = 8;
 230     $mcount_adjust = -1;
 231
 232     # force flags for this arch
 233     $ld .= " -m elf_x86_64";
 234     $objdump .= " -M x86-64";
 235     $objcopy .= " -O elf64-x86-64";
 236     $cc .= " -m64";
 237
 238 } elsif ($arch eq "i386") {
 239     $alignment = 4;
 240     $mcount_adjust = -1;
 241
 242     # force flags for this arch
 243     $ld .= " -m elf_i386";
 244     $objdump .= " -M i386";
 245     $objcopy .= " -O elf32-i386";
 246     $cc .= " -m32";
 247
 248 } elsif ($arch eq "s390" && $bits == 64) {
 249     if ($cc =~ /-DCC_USING_HOTPATCH/) {
 250         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*brcl\\s*0,[0-9a-f]+ <([^\+]*)>\$";
 251         $mcount_adjust = 0;
 252     } else {
 253         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 254         $mcount_adjust = -14;
 255     }
 256     $alignment = 8;
 257     $type = ".quad";
 258     $ld .= " -m elf64_s390";
 259     $cc .= " -m64";
 260
 261 } elsif ($arch eq "sh") {
 262     $alignment = 2;
 263
 264     # force flags for this arch
 265     $ld .= " -m shlelf_linux";
 266     $objcopy .= " -O elf32-sh-linux";
 267
 268 } elsif ($arch eq "powerpc") {
 269     my $ldemulation;
 270
 271     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 272     # See comment in the sparc64 section for why we use '\w'.
 273     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?\\w*?)>:";
 274     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 275
 276     if ($endian eq "big") {
 277             $cc .= " -mbig-endian ";
 278             $ld .= " -EB ";
 279             $ldemulation = "ppc"
 280     } else {
 281             $cc .= " -mlittle-endian ";
 282             $ld .= " -EL ";
 283             $ldemulation = "lppc"
 284     }
 285     if ($bits == 64) {
 286         $type = ".quad";
 287         $cc .= " -m64 ";
 288         $ld .= " -m elf64".$ldemulation." ";
 289     } else {
 290         $cc .= " -m32 ";
 291         $ld .= " -m elf32".$ldemulation." ";
 292     }
 293
 294 } elsif ($arch eq "arm") {
 295     $alignment = 2;
 296     $section_type = '%progbits';
 297     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 298                         "\\s+(__gnu_mcount_nc|mcount)\$";
 299
 300 } elsif ($arch eq "arm64") {
 301     $alignment = 3;
 302     $section_type = '%progbits';
 303     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
 304     $type = ".quad";
 305 } elsif ($arch eq "ia64") {
 306     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 307     $type = "data8";
 308
 309     if ($is_module eq "0") {
 310         $cc .= " -mconstant-gp";
 311     }
 312 } elsif ($arch eq "sparc64") {
 313     # In the objdump output there are giblets like:
 314     # 0000000000000000 <igmp_net_exit-0x18>:
 315     # As there's some data blobs that get emitted into the
 316     # text section before the first instructions and the first
 317     # real symbols.  We don't want to match that, so to combat
 318     # this we use '\w' so we'll match just plain symbol names,
 319     # and not those that also include hex offsets inside of the
 320     # '<>' brackets.  Actually the generic function_regex setting
 321     # could safely use this too.
 322     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 323
 324     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 325     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 326
 327     $alignment = 8;
 328     $type = ".xword";
 329     $ld .= " -m elf64_sparc";
 330     $cc .= " -m64";
 331     $objcopy .= " -O elf64-sparc";
 332 } elsif ($arch eq "mips") {
 333     # To enable module support, we need to enable the -mlong-calls option
 334     # of gcc for module, after using this option, we can not get the real
 335     # offset of the calling to _mcount, but the offset of the lui
 336     # instruction or the addiu one. herein, we record the address of the
 337     # first one, and then we can replace this instruction by a branch
 338     # instruction to jump over the profiling function to filter the
 339     # indicated functions, or switch back to the lui instruction to trace
 340     # them, which means dynamic tracing.
 341     #
 342     #       c:  3c030000        lui     v1,0x0
 343     #                   c: R_MIPS_HI16  _mcount
 344     #                   c: R_MIPS_NONE  *ABS*
 345     #                   c: R_MIPS_NONE  *ABS*
 346     #      10:  64630000        daddiu  v1,v1,0
 347     #                   10: R_MIPS_LO16 _mcount
 348     #                   10: R_MIPS_NONE *ABS*
 349     #                   10: R_MIPS_NONE *ABS*
 350     #      14:  03e0082d        move    at,ra
 351     #      18:  0060f809        jalr    v1
 352     #
 353     # for the kernel:
 354     #
 355     #     10:   03e0082d        move    at,ra
 356     #     14:   0c000000        jal     0 <loongson_halt>
 357     #                    14: R_MIPS_26   _mcount
 358     #                    14: R_MIPS_NONE *ABS*
 359     #                    14: R_MIPS_NONE *ABS*
 360     #    18:   00020021        nop
 361     if ($is_module eq "0") {
 362             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 363     } else {
 364             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 365     }
 366     $objdump .= " -Melf-trad".$endian."mips ";
 367
 368     if ($endian eq "big") {
 369             $endian = " -EB ";
 370             $ld .= " -melf".$bits."btsmip";
 371     } else {
 372             $endian = " -EL ";
 373             $ld .= " -melf".$bits."ltsmip";
 374     }
 375
 376     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 377     $ld .= $endian;
 378
 379     if ($bits == 64) {
 380             $function_regex =
 381                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 382             $type = ".dword";
 383     }
 384 } elsif ($arch eq "microblaze") {
 385     # Microblaze calls '_mcount' instead of plain 'mcount'.
 386     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 387 } elsif ($arch eq "riscv") {
 388     $function_regex = "^([0-9a-fA-F]+)\\s+<([^.0-9][0-9a-zA-Z_\\.]+)>:";
 389     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\sR_RISCV_CALL\\s_mcount\$";
 390     $type = ".quad";
 391     $alignment = 2;
 392 } elsif ($arch eq "nds32") {
 393     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_NDS32_HI20_RELA\\s+_mcount\$";
 394     $alignment = 2;
 395 } else {
 396     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 397 }
 398
 399 my $text_found = 0;
 400 my $read_function = 0;
 401 my $opened = 0;
 402 my $mcount_section = "__mcount_loc";
 403
 404 my $dirname;
 405 my $filename;
 406 my $prefix;
 407 my $ext;
 408
 409 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 410     $dirname = $1;
 411     $filename = $2;
 412 } else {
 413     $dirname = ".";
 414     $filename = $inputfile;
 415 }
 416
 417 if ($filename =~ m,^(.*)(\.\S),) {
 418     $prefix = $1;
 419     $ext = $2;
 420 } else {
 421     $prefix = $filename;
 422     $ext = "";
 423 }
 424
 425 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 426 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 427
 428 check_objcopy();
 429
 430 #
 431 # Step 1: find all the local (static functions) and weak symbols.
 432 #         't' is local, 'w/W' is weak
 433 #
 434 open (IN, "$nm $inputfile|") || die "error running $nm";
 435 while (<IN>) {
 436     if (/$local_regex/) {
 437         $locals{$1} = 1;
 438     } elsif (/$weak_regex/) {
 439         $weak{$2} = $1;
 440     }
 441 }
 442 close(IN);
 443
 444 my @offsets;            # Array of offsets of mcount callers
 445 my $ref_func;           # reference function to use for offsets
 446 my $offset = 0;         # offset of ref_func to section beginning
 447
 448 ##
 449 # update_funcs - print out the current mcount callers
 450 #
 451 #  Go through the list of offsets to callers and write them to
 452 #  the output file in a format that can be read by an assembler.
 453 #
 454 sub update_funcs
 455 {
 456     return unless ($ref_func and @offsets);
 457
 458     # Sanity check on weak function. A weak function may be overwritten by
 459     # another function of the same name, making all these offsets incorrect.
 460     if (defined $weak{$ref_func}) {
 461         die "$inputfile: ERROR: referencing weak function" .
 462             " $ref_func for mcount\n";
 463     }
 464
 465     # is this function static? If so, note this fact.
 466     if (defined $locals{$ref_func}) {
 467
 468         # only use locals if objcopy supports globalize-symbols
 469         if (!$can_use_local) {
 470             return;
 471         }
 472         $convert{$ref_func} = 1;
 473     }
 474
 475     # Loop through all the mcount caller offsets and print a reference
 476     # to the caller based from the ref_func.
 477     if (!$opened) {
 478         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 479         $opened = 1;
 480         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 481         print FILE "\t.align $alignment\n" if (defined($alignment));
 482     }
 483     foreach my $cur_offset (@offsets) {
 484         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 485     }
 486 }
 487
 488 #
 489 # Step 2: find the sections and mcount call sites
 490 #
 491 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 492
 493 my $text;
 494
 495
 496 # read headers first
 497 my $read_headers = 1;
 498
 499 while (<IN>) {
 500
 501     if ($read_headers && /$mcount_section/) {
 502         #
 503         # Somehow the make process can execute this script on an
 504         # object twice. If it does, we would duplicate the mcount
 505         # section and it will cause the function tracer self test
 506         # to fail. Check if the mcount section exists, and if it does,
 507         # warn and exit.
 508         #
 509         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 510             "\tThis may be an indication that your build is corrupted.\n" .
 511             "\tDelete $inputfile and try again. If the same object file\n" .
 512             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 513         exit(-1);
 514     }
 515
 516     # is it a section?
 517     if (/$section_regex/) {
 518         $read_headers = 0;
 519
 520         # Only record text sections that we know are safe
 521         $read_function = defined($text_sections{$1});
 522         # print out any recorded offsets
 523         update_funcs();
 524
 525         # reset all markers and arrays
 526         $text_found = 0;
 527         undef($ref_func);
 528         undef(@offsets);
 529
 530     # section found, now is this a start of a function?
 531     } elsif ($read_function && /$function_regex/) {
 532         $text_found = 1;
 533         $text = $2;
 534
 535         # if this is either a local function or a weak function
 536         # keep looking for functions that are global that
 537         # we can use safely.
 538         if (!defined($locals{$text}) && !defined($weak{$text})) {
 539             $ref_func = $text;
 540             $read_function = 0;
 541             $offset = hex $1;
 542         } else {
 543             # if we already have a function, and this is weak, skip it
 544             if (!defined($ref_func) && !defined($weak{$text}) &&
 545                  # PPC64 can have symbols that start with .L and
 546                  # gcc considers these special. Don't use them!
 547                  $text !~ /^\.L/) {
 548                 $ref_func = $text;
 549                 $offset = hex $1;
 550             }
 551         }
 552     }
 553     # is this a call site to mcount? If so, record it to print later
 554     if ($text_found && /$mcount_regex/) {
 555         push(@offsets, (hex $1) + $mcount_adjust);
 556     }
 557 }
 558
 559 # dump out anymore offsets that may have been found
 560 update_funcs();
 561
 562 # If we did not find any mcount callers, we are done (do nothing).
 563 if (!$opened) {
 564     exit(0);
 565 }
 566
 567 close(FILE);
 568
 569 #
 570 # Step 3: Compile the file that holds the list of call sites to mcount.
 571 #
 572 `$cc -o $mcount_o -c $mcount_s`;
 573
 574 my @converts = keys %convert;
 575
 576 #
 577 # Step 4: Do we have sections that started with local functions?
 578 #
 579 if ($#converts >= 0) {
 580     my $globallist = "";
 581     my $locallist = "";
 582
 583     foreach my $con (@converts) {
 584         $globallist .= " --globalize-symbol $con";
 585         $locallist .= " --localize-symbol $con";
 586     }
 587
 588     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 589     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 590
 591     #
 592     # Step 5: set up each local function as a global
 593     #
 594     `$objcopy $globallist $inputfile $globalobj`;
 595
 596     #
 597     # Step 6: Link the global version to our list.
 598     #
 599     `$ld -r $globalobj $mcount_o -o $globalmix`;
 600
 601     #
 602     # Step 7: Convert the local functions back into local symbols
 603     #
 604     `$objcopy $locallist $globalmix $inputfile`;
 605
 606     # Remove the temp files
 607     `$rm $globalobj $globalmix`;
 608
 609 } else {
 610
 611     my $mix = $dirname . "/.tmp_mx_" . $filename;
 612
 613     #
 614     # Step 8: Link the object with our list of call sites object.
 615     #
 616     `$ld -r $inputfile $mcount_o -o $mix`;
 617
 618     #
 619     # Step 9: Move the result back to the original object.
 620     #
 621     `$mv $mix $inputfile`;
 622 }
 623
 624 # Clean up the temp files
 625 `$rm $mcount_o $mcount_s`;
 626
 627 exit(0);