scripts/recordmcount.pl

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0-only
   3 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use warnings;
 110 use strict;
 111
 112 my $P = $0;
 113 $P =~ s@.*/@@g;
 114
 115 my $V = '0.1';
 116
 117 if ($#ARGV != 11) {
 118         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 119         print "version: $V\n";
 120         exit(1);
 121 }
 122
 123 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 124     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 125
 126 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 127 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 128     exit(0);
 129 }
 130
 131 # Acceptable sections to record.
 132 my %text_sections = (
 133      ".text" => 1,
 134      ".init.text" => 1,
 135      ".ref.text" => 1,
 136      ".sched.text" => 1,
 137      ".spinlock.text" => 1,
 138      ".irqentry.text" => 1,
 139      ".softirqentry.text" => 1,
 140      ".kprobes.text" => 1,
 141      ".cpuidle.text" => 1,
 142      ".text.unlikely" => 1,
 143 );
 144
 145 # Acceptable section-prefixes to record.
 146 my %text_section_prefixes = (
 147      ".text." => 1,
 148 );
 149
 150 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 151 $objdump = 'objdump' if (!$objdump);
 152 $objcopy = 'objcopy' if (!$objcopy);
 153 $cc = 'gcc' if (!$cc);
 154 $ld = 'ld' if (!$ld);
 155 $nm = 'nm' if (!$nm);
 156 $rm = 'rm' if (!$rm);
 157 $mv = 'mv' if (!$mv);
 158
 159 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 160 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 161
 162 my %locals;             # List of local (static) functions
 163 my %weak;               # List of weak functions
 164 my %convert;            # List of local functions used that needs conversion
 165
 166 my $type;
 167 my $local_regex;        # Match a local function (return function)
 168 my $weak_regex;         # Match a weak function (return function)
 169 my $section_regex;      # Find the start of a section
 170 my $function_regex;     # Find the name of a function
 171                         #    (return offset and func name)
 172 my $mcount_regex;       # Find the call site to mcount (return offset)
 173 my $mcount_adjust;      # Address adjustment to mcount offset
 174 my $alignment;          # The .align value to use for $mcount_section
 175 my $section_type;       # Section header plus possible alignment command
 176
 177 if ($arch =~ /(x86(_64)?)|(i386)/) {
 178     if ($bits == 64) {
 179         $arch = "x86_64";
 180     } else {
 181         $arch = "i386";
 182     }
 183 }
 184
 185 #
 186 # We base the defaults off of i386, the other archs may
 187 # feel free to change them in the below if statements.
 188 #
 189 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 190 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 191 $section_regex = "Disassembly of section\\s+(\\S+):";
 192 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 193 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
 194 $section_type = '@progbits';
 195 $mcount_adjust = 0;
 196 $type = ".long";
 197
 198 if ($arch eq "x86_64") {
 199     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
 200     $type = ".quad";
 201     $alignment = 8;
 202     $mcount_adjust = -1;
 203
 204     # force flags for this arch
 205     $ld .= " -m elf_x86_64";
 206     $objdump .= " -M x86-64";
 207     $objcopy .= " -O elf64-x86-64";
 208     $cc .= " -m64";
 209
 210 } elsif ($arch eq "i386") {
 211     $alignment = 4;
 212     $mcount_adjust = -1;
 213
 214     # force flags for this arch
 215     $ld .= " -m elf_i386";
 216     $objdump .= " -M i386";
 217     $objcopy .= " -O elf32-i386";
 218     $cc .= " -m32";
 219
 220 } elsif ($arch eq "s390" && $bits == 64) {
 221     if ($cc =~ /-DCC_USING_HOTPATCH/) {
 222         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*brcl\\s*0,[0-9a-f]+ <([^\+]*)>\$";
 223         $mcount_adjust = 0;
 224     }
 225     $alignment = 8;
 226     $type = ".quad";
 227     $ld .= " -m elf64_s390";
 228     $cc .= " -m64";
 229
 230 } elsif ($arch eq "sh") {
 231     $alignment = 2;
 232
 233     # force flags for this arch
 234     $ld .= " -m shlelf_linux";
 235     if ($endian eq "big") {
 236         $objcopy .= " -O elf32-shbig-linux";
 237     } else {
 238         $objcopy .= " -O elf32-sh-linux";
 239     }
 240
 241 } elsif ($arch eq "powerpc") {
 242     my $ldemulation;
 243
 244     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 245     # See comment in the sparc64 section for why we use '\w'.
 246     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?\\w*?)>:";
 247     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 248
 249     if ($endian eq "big") {
 250             $cc .= " -mbig-endian ";
 251             $ld .= " -EB ";
 252             $ldemulation = "ppc"
 253     } else {
 254             $cc .= " -mlittle-endian ";
 255             $ld .= " -EL ";
 256             $ldemulation = "lppc"
 257     }
 258     if ($bits == 64) {
 259         $type = ".quad";
 260         $cc .= " -m64 ";
 261         $ld .= " -m elf64".$ldemulation." ";
 262     } else {
 263         $cc .= " -m32 ";
 264         $ld .= " -m elf32".$ldemulation." ";
 265     }
 266
 267 } elsif ($arch eq "arm") {
 268     $alignment = 2;
 269     $section_type = '%progbits';
 270     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 271                         "\\s+(__gnu_mcount_nc|mcount)\$";
 272
 273 } elsif ($arch eq "arm64") {
 274     $alignment = 3;
 275     $section_type = '%progbits';
 276     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
 277     $type = ".quad";
 278 } elsif ($arch eq "ia64") {
 279     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 280     $type = "data8";
 281
 282     if ($is_module eq "0") {
 283         $cc .= " -mconstant-gp";
 284     }
 285 } elsif ($arch eq "sparc64") {
 286     # In the objdump output there are giblets like:
 287     # 0000000000000000 <igmp_net_exit-0x18>:
 288     # As there's some data blobs that get emitted into the
 289     # text section before the first instructions and the first
 290     # real symbols.  We don't want to match that, so to combat
 291     # this we use '\w' so we'll match just plain symbol names,
 292     # and not those that also include hex offsets inside of the
 293     # '<>' brackets.  Actually the generic function_regex setting
 294     # could safely use this too.
 295     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 296
 297     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 298     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 299
 300     $alignment = 8;
 301     $type = ".xword";
 302     $ld .= " -m elf64_sparc";
 303     $cc .= " -m64";
 304     $objcopy .= " -O elf64-sparc";
 305 } elsif ($arch eq "mips") {
 306     # To enable module support, we need to enable the -mlong-calls option
 307     # of gcc for module, after using this option, we can not get the real
 308     # offset of the calling to _mcount, but the offset of the lui
 309     # instruction or the addiu one. herein, we record the address of the
 310     # first one, and then we can replace this instruction by a branch
 311     # instruction to jump over the profiling function to filter the
 312     # indicated functions, or switch back to the lui instruction to trace
 313     # them, which means dynamic tracing.
 314     #
 315     #       c:  3c030000        lui     v1,0x0
 316     #                   c: R_MIPS_HI16  _mcount
 317     #                   c: R_MIPS_NONE  *ABS*
 318     #                   c: R_MIPS_NONE  *ABS*
 319     #      10:  64630000        daddiu  v1,v1,0
 320     #                   10: R_MIPS_LO16 _mcount
 321     #                   10: R_MIPS_NONE *ABS*
 322     #                   10: R_MIPS_NONE *ABS*
 323     #      14:  03e0082d        move    at,ra
 324     #      18:  0060f809        jalr    v1
 325     #
 326     # for the kernel:
 327     #
 328     #     10:   03e0082d        move    at,ra
 329     #     14:   0c000000        jal     0 <loongson_halt>
 330     #                    14: R_MIPS_26   _mcount
 331     #                    14: R_MIPS_NONE *ABS*
 332     #                    14: R_MIPS_NONE *ABS*
 333     #    18:   00020021        nop
 334     if ($is_module eq "0") {
 335             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 336     } else {
 337             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 338     }
 339     $objdump .= " -Melf-trad".$endian."mips ";
 340
 341     if ($endian eq "big") {
 342             $endian = " -EB ";
 343             $ld .= " -melf".$bits."btsmip";
 344     } else {
 345             $endian = " -EL ";
 346             $ld .= " -melf".$bits."ltsmip";
 347     }
 348
 349     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 350     $ld .= $endian;
 351
 352     if ($bits == 64) {
 353             $function_regex =
 354                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 355             $type = ".dword";
 356     }
 357 } elsif ($arch eq "microblaze") {
 358     # Microblaze calls '_mcount' instead of plain 'mcount'.
 359     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 360 } elsif ($arch eq "riscv") {
 361     $function_regex = "^([0-9a-fA-F]+)\\s+<([^.0-9][0-9a-zA-Z_\\.]+)>:";
 362     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\sR_RISCV_CALL(_PLT)?\\s_?mcount\$";
 363     $type = ".quad";
 364     $alignment = 2;
 365 } elsif ($arch eq "nds32") {
 366     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_NDS32_HI20_RELA\\s+_mcount\$";
 367     $alignment = 2;
 368 } elsif ($arch eq "csky") {
 369     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_CKCORE_PCREL_JSR_IMM26BY2\\s+_mcount\$";
 370     $alignment = 2;
 371 } else {
 372     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 373 }
 374
 375 my $text_found = 0;
 376 my $read_function = 0;
 377 my $opened = 0;
 378 my $mcount_section = "__mcount_loc";
 379
 380 my $dirname;
 381 my $filename;
 382 my $prefix;
 383 my $ext;
 384
 385 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 386     $dirname = $1;
 387     $filename = $2;
 388 } else {
 389     $dirname = ".";
 390     $filename = $inputfile;
 391 }
 392
 393 if ($filename =~ m,^(.*)(\.\S),) {
 394     $prefix = $1;
 395     $ext = $2;
 396 } else {
 397     $prefix = $filename;
 398     $ext = "";
 399 }
 400
 401 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 402 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 403
 404 #
 405 # Step 1: find all the local (static functions) and weak symbols.
 406 #         't' is local, 'w/W' is weak
 407 #
 408 open (IN, "$nm $inputfile|") || die "error running $nm";
 409 while (<IN>) {
 410     if (/$local_regex/) {
 411         $locals{$1} = 1;
 412     } elsif (/$weak_regex/) {
 413         $weak{$2} = $1;
 414     }
 415 }
 416 close(IN);
 417
 418 my @offsets;            # Array of offsets of mcount callers
 419 my $ref_func;           # reference function to use for offsets
 420 my $offset = 0;         # offset of ref_func to section beginning
 421
 422 ##
 423 # update_funcs - print out the current mcount callers
 424 #
 425 #  Go through the list of offsets to callers and write them to
 426 #  the output file in a format that can be read by an assembler.
 427 #
 428 sub update_funcs
 429 {
 430     return unless ($ref_func and @offsets);
 431
 432     # Sanity check on weak function. A weak function may be overwritten by
 433     # another function of the same name, making all these offsets incorrect.
 434     if (defined $weak{$ref_func}) {
 435         die "$inputfile: ERROR: referencing weak function" .
 436             " $ref_func for mcount\n";
 437     }
 438
 439     # is this function static? If so, note this fact.
 440     if (defined $locals{$ref_func}) {
 441         $convert{$ref_func} = 1;
 442     }
 443
 444     # Loop through all the mcount caller offsets and print a reference
 445     # to the caller based from the ref_func.
 446     if (!$opened) {
 447         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 448         $opened = 1;
 449         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 450         print FILE "\t.align $alignment\n" if (defined($alignment));
 451     }
 452     foreach my $cur_offset (@offsets) {
 453         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 454     }
 455 }
 456
 457 #
 458 # Step 2: find the sections and mcount call sites
 459 #
 460 open(IN, "LC_ALL=C $objdump -hdr $inputfile|") || die "error running $objdump";
 461
 462 my $text;
 463
 464
 465 # read headers first
 466 my $read_headers = 1;
 467
 468 while (<IN>) {
 469
 470     if ($read_headers && /$mcount_section/) {
 471         #
 472         # Somehow the make process can execute this script on an
 473         # object twice. If it does, we would duplicate the mcount
 474         # section and it will cause the function tracer self test
 475         # to fail. Check if the mcount section exists, and if it does,
 476         # warn and exit.
 477         #
 478         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 479             "\tThis may be an indication that your build is corrupted.\n" .
 480             "\tDelete $inputfile and try again. If the same object file\n" .
 481             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 482         exit(-1);
 483     }
 484
 485     # is it a section?
 486     if (/$section_regex/) {
 487         $read_headers = 0;
 488
 489         # Only record text sections that we know are safe
 490         $read_function = defined($text_sections{$1});
 491         if (!$read_function) {
 492             foreach my $prefix (keys %text_section_prefixes) {
 493                 if (substr($1, 0, length $prefix) eq $prefix) {
 494                     $read_function = 1;
 495                     last;
 496                 }
 497             }
 498         }
 499         # print out any recorded offsets
 500         update_funcs();
 501
 502         # reset all markers and arrays
 503         $text_found = 0;
 504         undef($ref_func);
 505         undef(@offsets);
 506
 507     # section found, now is this a start of a function?
 508     } elsif ($read_function && /$function_regex/) {
 509         $text_found = 1;
 510         $text = $2;
 511
 512         # if this is either a local function or a weak function
 513         # keep looking for functions that are global that
 514         # we can use safely.
 515         if (!defined($locals{$text}) && !defined($weak{$text})) {
 516             $ref_func = $text;
 517             $read_function = 0;
 518             $offset = hex $1;
 519         } else {
 520             # if we already have a function, and this is weak, skip it
 521             if (!defined($ref_func) && !defined($weak{$text}) &&
 522                  # PPC64 can have symbols that start with .L and
 523                  # gcc considers these special. Don't use them!
 524                  $text !~ /^\.L/) {
 525                 $ref_func = $text;
 526                 $offset = hex $1;
 527             }
 528         }
 529     }
 530     # is this a call site to mcount? If so, record it to print later
 531     if ($text_found && /$mcount_regex/) {
 532         push(@offsets, (hex $1) + $mcount_adjust);
 533     }
 534 }
 535
 536 # dump out anymore offsets that may have been found
 537 update_funcs();
 538
 539 # If we did not find any mcount callers, we are done (do nothing).
 540 if (!$opened) {
 541     exit(0);
 542 }
 543
 544 close(FILE);
 545
 546 #
 547 # Step 3: Compile the file that holds the list of call sites to mcount.
 548 #
 549 `$cc -o $mcount_o -c $mcount_s`;
 550
 551 my @converts = keys %convert;
 552
 553 #
 554 # Step 4: Do we have sections that started with local functions?
 555 #
 556 if ($#converts >= 0) {
 557     my $globallist = "";
 558     my $locallist = "";
 559
 560     foreach my $con (@converts) {
 561         $globallist .= " --globalize-symbol $con";
 562         $locallist .= " --localize-symbol $con";
 563     }
 564
 565     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 566     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 567
 568     #
 569     # Step 5: set up each local function as a global
 570     #
 571     `$objcopy $globallist $inputfile $globalobj`;
 572
 573     #
 574     # Step 6: Link the global version to our list.
 575     #
 576     `$ld -r $globalobj $mcount_o -o $globalmix`;
 577
 578     #
 579     # Step 7: Convert the local functions back into local symbols
 580     #
 581     `$objcopy $locallist $globalmix $inputfile`;
 582
 583     # Remove the temp files
 584     `$rm $globalobj $globalmix`;
 585
 586 } else {
 587
 588     my $mix = $dirname . "/.tmp_mx_" . $filename;
 589
 590     #
 591     # Step 8: Link the object with our list of call sites object.
 592     #
 593     `$ld -r $inputfile $mcount_o -o $mix`;
 594
 595     #
 596     # Step 9: Move the result back to the original object.
 597     #
 598     `$mv $mix $inputfile`;
 599 }
 600
 601 # Clean up the temp files
 602 `$rm $mcount_o $mcount_s`;
 603
 604 exit(0);
 605
 606 # vim: softtabstop=4