scripts/recordmcount.pl

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0-only
   3 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use warnings;
 110 use strict;
 111
 112 my $P = $0;
 113 $P =~ s@.*/@@g;
 114
 115 my $V = '0.1';
 116
 117 if ($#ARGV != 11) {
 118         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 119         print "version: $V\n";
 120         exit(1);
 121 }
 122
 123 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 124     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 125
 126 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 127 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 128     exit(0);
 129 }
 130
 131 # Acceptable sections to record.
 132 my %text_sections = (
 133      ".text" => 1,
 134      ".init.text" => 1,
 135      ".ref.text" => 1,
 136      ".sched.text" => 1,
 137      ".spinlock.text" => 1,
 138      ".irqentry.text" => 1,
 139      ".softirqentry.text" => 1,
 140      ".kprobes.text" => 1,
 141      ".cpuidle.text" => 1,
 142      ".text.unlikely" => 1,
 143 );
 144
 145 # Acceptable section-prefixes to record.
 146 my %text_section_prefixes = (
 147      ".text." => 1,
 148 );
 149
 150 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 151 $objdump = 'objdump' if (!$objdump);
 152 $objcopy = 'objcopy' if (!$objcopy);
 153 $cc = 'gcc' if (!$cc);
 154 $ld = 'ld' if (!$ld);
 155 $nm = 'nm' if (!$nm);
 156 $rm = 'rm' if (!$rm);
 157 $mv = 'mv' if (!$mv);
 158
 159 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 160 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 161
 162 my %locals;             # List of local (static) functions
 163 my %weak;               # List of weak functions
 164 my %convert;            # List of local functions used that needs conversion
 165
 166 my $type;
 167 my $local_regex;        # Match a local function (return function)
 168 my $weak_regex;         # Match a weak function (return function)
 169 my $section_regex;      # Find the start of a section
 170 my $function_regex;     # Find the name of a function
 171                         #    (return offset and func name)
 172 my $mcount_regex;       # Find the call site to mcount (return offset)
 173 my $mcount_adjust;      # Address adjustment to mcount offset
 174 my $alignment;          # The .align value to use for $mcount_section
 175 my $section_type;       # Section header plus possible alignment command
 176 my $can_use_local = 0;  # If we can use local function references
 177
 178 # Shut up recordmcount if user has older objcopy
 179 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 180 my $print_warning = 1;
 181 $print_warning = 0 if ( -f $quiet_recordmcount);
 182
 183 ##
 184 # check_objcopy - whether objcopy supports --globalize-symbols
 185 #
 186 #  --globalize-symbols came out in 2.17, we must test the version
 187 #  of objcopy, and if it is less than 2.17, then we can not
 188 #  record local functions.
 189 sub check_objcopy
 190 {
 191     open (IN, "$objcopy --version |") or die "error running $objcopy";
 192     while (<IN>) {
 193         if (/objcopy.*\s(\d+)\.(\d+)/) {
 194             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 195             last;
 196         }
 197     }
 198     close (IN);
 199
 200     if (!$can_use_local && $print_warning) {
 201         print STDERR "WARNING: could not find objcopy version or version " .
 202             "is less than 2.17.\n" .
 203             "\tLocal function references are disabled.\n";
 204         open (QUIET, ">$quiet_recordmcount");
 205         printf QUIET "Disables the warning from recordmcount.pl\n";
 206         close QUIET;
 207     }
 208 }
 209
 210 if ($arch =~ /(x86(_64)?)|(i386)/) {
 211     if ($bits == 64) {
 212         $arch = "x86_64";
 213     } else {
 214         $arch = "i386";
 215     }
 216 }
 217
 218 #
 219 # We base the defaults off of i386, the other archs may
 220 # feel free to change them in the below if statements.
 221 #
 222 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 223 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 224 $section_regex = "Disassembly of section\\s+(\\S+):";
 225 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 226 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
 227 $section_type = '@progbits';
 228 $mcount_adjust = 0;
 229 $type = ".long";
 230
 231 if ($arch eq "x86_64") {
 232     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
 233     $type = ".quad";
 234     $alignment = 8;
 235     $mcount_adjust = -1;
 236
 237     # force flags for this arch
 238     $ld .= " -m elf_x86_64";
 239     $objdump .= " -M x86-64";
 240     $objcopy .= " -O elf64-x86-64";
 241     $cc .= " -m64";
 242
 243 } elsif ($arch eq "i386") {
 244     $alignment = 4;
 245     $mcount_adjust = -1;
 246
 247     # force flags for this arch
 248     $ld .= " -m elf_i386";
 249     $objdump .= " -M i386";
 250     $objcopy .= " -O elf32-i386";
 251     $cc .= " -m32";
 252
 253 } elsif ($arch eq "s390" && $bits == 64) {
 254     if ($cc =~ /-DCC_USING_HOTPATCH/) {
 255         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*brcl\\s*0,[0-9a-f]+ <([^\+]*)>\$";
 256         $mcount_adjust = 0;
 257     }
 258     $alignment = 8;
 259     $type = ".quad";
 260     $ld .= " -m elf64_s390";
 261     $cc .= " -m64";
 262
 263 } elsif ($arch eq "sh") {
 264     $alignment = 2;
 265
 266     # force flags for this arch
 267     $ld .= " -m shlelf_linux";
 268     if ($endian eq "big") {
 269         $objcopy .= " -O elf32-shbig-linux";
 270     } else {
 271         $objcopy .= " -O elf32-sh-linux";
 272     }
 273
 274 } elsif ($arch eq "powerpc") {
 275     my $ldemulation;
 276
 277     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 278     # See comment in the sparc64 section for why we use '\w'.
 279     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?\\w*?)>:";
 280     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 281
 282     if ($endian eq "big") {
 283             $cc .= " -mbig-endian ";
 284             $ld .= " -EB ";
 285             $ldemulation = "ppc"
 286     } else {
 287             $cc .= " -mlittle-endian ";
 288             $ld .= " -EL ";
 289             $ldemulation = "lppc"
 290     }
 291     if ($bits == 64) {
 292         $type = ".quad";
 293         $cc .= " -m64 ";
 294         $ld .= " -m elf64".$ldemulation." ";
 295     } else {
 296         $cc .= " -m32 ";
 297         $ld .= " -m elf32".$ldemulation." ";
 298     }
 299
 300 } elsif ($arch eq "arm") {
 301     $alignment = 2;
 302     $section_type = '%progbits';
 303     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 304                         "\\s+(__gnu_mcount_nc|mcount)\$";
 305
 306 } elsif ($arch eq "arm64") {
 307     $alignment = 3;
 308     $section_type = '%progbits';
 309     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
 310     $type = ".quad";
 311 } elsif ($arch eq "ia64") {
 312     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 313     $type = "data8";
 314
 315     if ($is_module eq "0") {
 316         $cc .= " -mconstant-gp";
 317     }
 318 } elsif ($arch eq "sparc64") {
 319     # In the objdump output there are giblets like:
 320     # 0000000000000000 <igmp_net_exit-0x18>:
 321     # As there's some data blobs that get emitted into the
 322     # text section before the first instructions and the first
 323     # real symbols.  We don't want to match that, so to combat
 324     # this we use '\w' so we'll match just plain symbol names,
 325     # and not those that also include hex offsets inside of the
 326     # '<>' brackets.  Actually the generic function_regex setting
 327     # could safely use this too.
 328     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 329
 330     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 331     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 332
 333     $alignment = 8;
 334     $type = ".xword";
 335     $ld .= " -m elf64_sparc";
 336     $cc .= " -m64";
 337     $objcopy .= " -O elf64-sparc";
 338 } elsif ($arch eq "mips") {
 339     # To enable module support, we need to enable the -mlong-calls option
 340     # of gcc for module, after using this option, we can not get the real
 341     # offset of the calling to _mcount, but the offset of the lui
 342     # instruction or the addiu one. herein, we record the address of the
 343     # first one, and then we can replace this instruction by a branch
 344     # instruction to jump over the profiling function to filter the
 345     # indicated functions, or switch back to the lui instruction to trace
 346     # them, which means dynamic tracing.
 347     #
 348     #       c:  3c030000        lui     v1,0x0
 349     #                   c: R_MIPS_HI16  _mcount
 350     #                   c: R_MIPS_NONE  *ABS*
 351     #                   c: R_MIPS_NONE  *ABS*
 352     #      10:  64630000        daddiu  v1,v1,0
 353     #                   10: R_MIPS_LO16 _mcount
 354     #                   10: R_MIPS_NONE *ABS*
 355     #                   10: R_MIPS_NONE *ABS*
 356     #      14:  03e0082d        move    at,ra
 357     #      18:  0060f809        jalr    v1
 358     #
 359     # for the kernel:
 360     #
 361     #     10:   03e0082d        move    at,ra
 362     #     14:   0c000000        jal     0 <loongson_halt>
 363     #                    14: R_MIPS_26   _mcount
 364     #                    14: R_MIPS_NONE *ABS*
 365     #                    14: R_MIPS_NONE *ABS*
 366     #    18:   00020021        nop
 367     if ($is_module eq "0") {
 368             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 369     } else {
 370             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 371     }
 372     $objdump .= " -Melf-trad".$endian."mips ";
 373
 374     if ($endian eq "big") {
 375             $endian = " -EB ";
 376             $ld .= " -melf".$bits."btsmip";
 377     } else {
 378             $endian = " -EL ";
 379             $ld .= " -melf".$bits."ltsmip";
 380     }
 381
 382     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 383     $ld .= $endian;
 384
 385     if ($bits == 64) {
 386             $function_regex =
 387                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 388             $type = ".dword";
 389     }
 390 } elsif ($arch eq "microblaze") {
 391     # Microblaze calls '_mcount' instead of plain 'mcount'.
 392     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 393 } elsif ($arch eq "riscv") {
 394     $function_regex = "^([0-9a-fA-F]+)\\s+<([^.0-9][0-9a-zA-Z_\\.]+)>:";
 395     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\sR_RISCV_CALL\\s_mcount\$";
 396     $type = ".quad";
 397     $alignment = 2;
 398 } elsif ($arch eq "nds32") {
 399     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_NDS32_HI20_RELA\\s+_mcount\$";
 400     $alignment = 2;
 401 } elsif ($arch eq "csky") {
 402     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_CKCORE_PCREL_JSR_IMM26BY2\\s+_mcount\$";
 403     $alignment = 2;
 404 } else {
 405     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 406 }
 407
 408 my $text_found = 0;
 409 my $read_function = 0;
 410 my $opened = 0;
 411 my $mcount_section = "__mcount_loc";
 412
 413 my $dirname;
 414 my $filename;
 415 my $prefix;
 416 my $ext;
 417
 418 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 419     $dirname = $1;
 420     $filename = $2;
 421 } else {
 422     $dirname = ".";
 423     $filename = $inputfile;
 424 }
 425
 426 if ($filename =~ m,^(.*)(\.\S),) {
 427     $prefix = $1;
 428     $ext = $2;
 429 } else {
 430     $prefix = $filename;
 431     $ext = "";
 432 }
 433
 434 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 435 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 436
 437 check_objcopy();
 438
 439 #
 440 # Step 1: find all the local (static functions) and weak symbols.
 441 #         't' is local, 'w/W' is weak
 442 #
 443 open (IN, "$nm $inputfile|") || die "error running $nm";
 444 while (<IN>) {
 445     if (/$local_regex/) {
 446         $locals{$1} = 1;
 447     } elsif (/$weak_regex/) {
 448         $weak{$2} = $1;
 449     }
 450 }
 451 close(IN);
 452
 453 my @offsets;            # Array of offsets of mcount callers
 454 my $ref_func;           # reference function to use for offsets
 455 my $offset = 0;         # offset of ref_func to section beginning
 456
 457 ##
 458 # update_funcs - print out the current mcount callers
 459 #
 460 #  Go through the list of offsets to callers and write them to
 461 #  the output file in a format that can be read by an assembler.
 462 #
 463 sub update_funcs
 464 {
 465     return unless ($ref_func and @offsets);
 466
 467     # Sanity check on weak function. A weak function may be overwritten by
 468     # another function of the same name, making all these offsets incorrect.
 469     if (defined $weak{$ref_func}) {
 470         die "$inputfile: ERROR: referencing weak function" .
 471             " $ref_func for mcount\n";
 472     }
 473
 474     # is this function static? If so, note this fact.
 475     if (defined $locals{$ref_func}) {
 476
 477         # only use locals if objcopy supports globalize-symbols
 478         if (!$can_use_local) {
 479             return;
 480         }
 481         $convert{$ref_func} = 1;
 482     }
 483
 484     # Loop through all the mcount caller offsets and print a reference
 485     # to the caller based from the ref_func.
 486     if (!$opened) {
 487         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 488         $opened = 1;
 489         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 490         print FILE "\t.align $alignment\n" if (defined($alignment));
 491     }
 492     foreach my $cur_offset (@offsets) {
 493         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 494     }
 495 }
 496
 497 #
 498 # Step 2: find the sections and mcount call sites
 499 #
 500 open(IN, "LANG=C $objdump -hdr $inputfile|") || die "error running $objdump";
 501
 502 my $text;
 503
 504
 505 # read headers first
 506 my $read_headers = 1;
 507
 508 while (<IN>) {
 509
 510     if ($read_headers && /$mcount_section/) {
 511         #
 512         # Somehow the make process can execute this script on an
 513         # object twice. If it does, we would duplicate the mcount
 514         # section and it will cause the function tracer self test
 515         # to fail. Check if the mcount section exists, and if it does,
 516         # warn and exit.
 517         #
 518         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 519             "\tThis may be an indication that your build is corrupted.\n" .
 520             "\tDelete $inputfile and try again. If the same object file\n" .
 521             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 522         exit(-1);
 523     }
 524
 525     # is it a section?
 526     if (/$section_regex/) {
 527         $read_headers = 0;
 528
 529         # Only record text sections that we know are safe
 530         $read_function = defined($text_sections{$1});
 531         if (!$read_function) {
 532             foreach my $prefix (keys %text_section_prefixes) {
 533                 if (substr($1, 0, length $prefix) eq $prefix) {
 534                     $read_function = 1;
 535                     last;
 536                 }
 537             }
 538         }
 539         # print out any recorded offsets
 540         update_funcs();
 541
 542         # reset all markers and arrays
 543         $text_found = 0;
 544         undef($ref_func);
 545         undef(@offsets);
 546
 547     # section found, now is this a start of a function?
 548     } elsif ($read_function && /$function_regex/) {
 549         $text_found = 1;
 550         $text = $2;
 551
 552         # if this is either a local function or a weak function
 553         # keep looking for functions that are global that
 554         # we can use safely.
 555         if (!defined($locals{$text}) && !defined($weak{$text})) {
 556             $ref_func = $text;
 557             $read_function = 0;
 558             $offset = hex $1;
 559         } else {
 560             # if we already have a function, and this is weak, skip it
 561             if (!defined($ref_func) && !defined($weak{$text}) &&
 562                  # PPC64 can have symbols that start with .L and
 563                  # gcc considers these special. Don't use them!
 564                  $text !~ /^\.L/) {
 565                 $ref_func = $text;
 566                 $offset = hex $1;
 567             }
 568         }
 569     }
 570     # is this a call site to mcount? If so, record it to print later
 571     if ($text_found && /$mcount_regex/) {
 572         push(@offsets, (hex $1) + $mcount_adjust);
 573     }
 574 }
 575
 576 # dump out anymore offsets that may have been found
 577 update_funcs();
 578
 579 # If we did not find any mcount callers, we are done (do nothing).
 580 if (!$opened) {
 581     exit(0);
 582 }
 583
 584 close(FILE);
 585
 586 #
 587 # Step 3: Compile the file that holds the list of call sites to mcount.
 588 #
 589 `$cc -o $mcount_o -c $mcount_s`;
 590
 591 my @converts = keys %convert;
 592
 593 #
 594 # Step 4: Do we have sections that started with local functions?
 595 #
 596 if ($#converts >= 0) {
 597     my $globallist = "";
 598     my $locallist = "";
 599
 600     foreach my $con (@converts) {
 601         $globallist .= " --globalize-symbol $con";
 602         $locallist .= " --localize-symbol $con";
 603     }
 604
 605     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 606     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 607
 608     #
 609     # Step 5: set up each local function as a global
 610     #
 611     `$objcopy $globallist $inputfile $globalobj`;
 612
 613     #
 614     # Step 6: Link the global version to our list.
 615     #
 616     `$ld -r $globalobj $mcount_o -o $globalmix`;
 617
 618     #
 619     # Step 7: Convert the local functions back into local symbols
 620     #
 621     `$objcopy $locallist $globalmix $inputfile`;
 622
 623     # Remove the temp files
 624     `$rm $globalobj $globalmix`;
 625
 626 } else {
 627
 628     my $mix = $dirname . "/.tmp_mx_" . $filename;
 629
 630     #
 631     # Step 8: Link the object with our list of call sites object.
 632     #
 633     `$ld -r $inputfile $mcount_o -o $mix`;
 634
 635     #
 636     # Step 9: Move the result back to the original object.
 637     #
 638     `$mv $mix $inputfile`;
 639 }
 640
 641 # Clean up the temp files
 642 `$rm $mcount_o $mcount_s`;
 643
 644 exit(0);