scripts/recordmcount.pl

   1 #!/usr/bin/env perl
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use warnings;
 110 use strict;
 111
 112 my $P = $0;
 113 $P =~ s@.*/@@g;
 114
 115 my $V = '0.1';
 116
 117 if ($#ARGV != 11) {
 118         print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 119         print "version: $V\n";
 120         exit(1);
 121 }
 122
 123 my ($arch, $endian, $bits, $objdump, $objcopy, $cc,
 124     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 125
 126 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 127 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 128     exit(0);
 129 }
 130
 131 # Acceptable sections to record.
 132 my %text_sections = (
 133      ".text" => 1,
 134      ".init.text" => 1,
 135      ".ref.text" => 1,
 136      ".sched.text" => 1,
 137      ".spinlock.text" => 1,
 138      ".irqentry.text" => 1,
 139      ".softirqentry.text" => 1,
 140      ".kprobes.text" => 1,
 141      ".cpuidle.text" => 1,
 142      ".text.unlikely" => 1,
 143 );
 144
 145 # Acceptable section-prefixes to record.
 146 my %text_section_prefixes = (
 147      ".text." => 1,
 148 );
 149
 150 # Note: we are nice to C-programmers here, thus we skip the '||='-idiom.
 151 $objdump = 'objdump' if (!$objdump);
 152 $objcopy = 'objcopy' if (!$objcopy);
 153 $cc = 'gcc' if (!$cc);
 154 $ld = 'ld' if (!$ld);
 155 $nm = 'nm' if (!$nm);
 156 $rm = 'rm' if (!$rm);
 157 $mv = 'mv' if (!$mv);
 158
 159 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 160 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 161
 162 my %locals;             # List of local (static) functions
 163 my %weak;               # List of weak functions
 164 my %convert;            # List of local functions used that needs conversion
 165
 166 my $type;
 167 my $local_regex;        # Match a local function (return function)
 168 my $weak_regex;         # Match a weak function (return function)
 169 my $section_regex;      # Find the start of a section
 170 my $function_regex;     # Find the name of a function
 171                         #    (return offset and func name)
 172 my $mcount_regex;       # Find the call site to mcount (return offset)
 173 my $mcount_adjust;      # Address adjustment to mcount offset
 174 my $alignment;          # The .align value to use for $mcount_section
 175 my $section_type;       # Section header plus possible alignment command
 176 my $can_use_local = 0;  # If we can use local function references
 177
 178 # Shut up recordmcount if user has older objcopy
 179 my $quiet_recordmcount = ".tmp_quiet_recordmcount";
 180 my $print_warning = 1;
 181 $print_warning = 0 if ( -f $quiet_recordmcount);
 182
 183 ##
 184 # check_objcopy - whether objcopy supports --globalize-symbols
 185 #
 186 #  --globalize-symbols came out in 2.17, we must test the version
 187 #  of objcopy, and if it is less than 2.17, then we can not
 188 #  record local functions.
 189 sub check_objcopy
 190 {
 191     open (IN, "$objcopy --version |") or die "error running $objcopy";
 192     while (<IN>) {
 193         if (/objcopy.*\s(\d+)\.(\d+)/) {
 194             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 195             last;
 196         }
 197     }
 198     close (IN);
 199
 200     if (!$can_use_local && $print_warning) {
 201         print STDERR "WARNING: could not find objcopy version or version " .
 202             "is less than 2.17.\n" .
 203             "\tLocal function references are disabled.\n";
 204         open (QUIET, ">$quiet_recordmcount");
 205         printf QUIET "Disables the warning from recordmcount.pl\n";
 206         close QUIET;
 207     }
 208 }
 209
 210 if ($arch =~ /(x86(_64)?)|(i386)/) {
 211     if ($bits == 64) {
 212         $arch = "x86_64";
 213     } else {
 214         $arch = "i386";
 215     }
 216 }
 217
 218 #
 219 # We base the defaults off of i386, the other archs may
 220 # feel free to change them in the below if statements.
 221 #
 222 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 223 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 224 $section_regex = "Disassembly of section\\s+(\\S+):";
 225 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 226 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$";
 227 $section_type = '@progbits';
 228 $mcount_adjust = 0;
 229 $type = ".long";
 230
 231 if ($arch eq "x86_64") {
 232     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$";
 233     $type = ".quad";
 234     $alignment = 8;
 235     $mcount_adjust = -1;
 236
 237     # force flags for this arch
 238     $ld .= " -m elf_x86_64";
 239     $objdump .= " -M x86-64";
 240     $objcopy .= " -O elf64-x86-64";
 241     $cc .= " -m64";
 242
 243 } elsif ($arch eq "i386") {
 244     $alignment = 4;
 245     $mcount_adjust = -1;
 246
 247     # force flags for this arch
 248     $ld .= " -m elf_i386";
 249     $objdump .= " -M i386";
 250     $objcopy .= " -O elf32-i386";
 251     $cc .= " -m32";
 252
 253 } elsif ($arch eq "s390" && $bits == 64) {
 254     if ($cc =~ /-DCC_USING_HOTPATCH/) {
 255         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*brcl\\s*0,[0-9a-f]+ <([^\+]*)>\$";
 256         $mcount_adjust = 0;
 257     } else {
 258         $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 259         $mcount_adjust = -14;
 260     }
 261     $alignment = 8;
 262     $type = ".quad";
 263     $ld .= " -m elf64_s390";
 264     $cc .= " -m64";
 265
 266 } elsif ($arch eq "sh") {
 267     $alignment = 2;
 268
 269     # force flags for this arch
 270     $ld .= " -m shlelf_linux";
 271     $objcopy .= " -O elf32-sh-linux";
 272
 273 } elsif ($arch eq "powerpc") {
 274     my $ldemulation;
 275
 276     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 277     # See comment in the sparc64 section for why we use '\w'.
 278     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?\\w*?)>:";
 279     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 280
 281     if ($endian eq "big") {
 282             $cc .= " -mbig-endian ";
 283             $ld .= " -EB ";
 284             $ldemulation = "ppc"
 285     } else {
 286             $cc .= " -mlittle-endian ";
 287             $ld .= " -EL ";
 288             $ldemulation = "lppc"
 289     }
 290     if ($bits == 64) {
 291         $type = ".quad";
 292         $cc .= " -m64 ";
 293         $ld .= " -m elf64".$ldemulation." ";
 294     } else {
 295         $cc .= " -m32 ";
 296         $ld .= " -m elf32".$ldemulation." ";
 297     }
 298
 299 } elsif ($arch eq "arm") {
 300     $alignment = 2;
 301     $section_type = '%progbits';
 302     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" .
 303                         "\\s+(__gnu_mcount_nc|mcount)\$";
 304
 305 } elsif ($arch eq "arm64") {
 306     $alignment = 3;
 307     $section_type = '%progbits';
 308     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$";
 309     $type = ".quad";
 310 } elsif ($arch eq "ia64") {
 311     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 312     $type = "data8";
 313
 314     if ($is_module eq "0") {
 315         $cc .= " -mconstant-gp";
 316     }
 317 } elsif ($arch eq "sparc64") {
 318     # In the objdump output there are giblets like:
 319     # 0000000000000000 <igmp_net_exit-0x18>:
 320     # As there's some data blobs that get emitted into the
 321     # text section before the first instructions and the first
 322     # real symbols.  We don't want to match that, so to combat
 323     # this we use '\w' so we'll match just plain symbol names,
 324     # and not those that also include hex offsets inside of the
 325     # '<>' brackets.  Actually the generic function_regex setting
 326     # could safely use this too.
 327     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 328
 329     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 330     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 331
 332     $alignment = 8;
 333     $type = ".xword";
 334     $ld .= " -m elf64_sparc";
 335     $cc .= " -m64";
 336     $objcopy .= " -O elf64-sparc";
 337 } elsif ($arch eq "mips") {
 338     # To enable module support, we need to enable the -mlong-calls option
 339     # of gcc for module, after using this option, we can not get the real
 340     # offset of the calling to _mcount, but the offset of the lui
 341     # instruction or the addiu one. herein, we record the address of the
 342     # first one, and then we can replace this instruction by a branch
 343     # instruction to jump over the profiling function to filter the
 344     # indicated functions, or switch back to the lui instruction to trace
 345     # them, which means dynamic tracing.
 346     #
 347     #       c:  3c030000        lui     v1,0x0
 348     #                   c: R_MIPS_HI16  _mcount
 349     #                   c: R_MIPS_NONE  *ABS*
 350     #                   c: R_MIPS_NONE  *ABS*
 351     #      10:  64630000        daddiu  v1,v1,0
 352     #                   10: R_MIPS_LO16 _mcount
 353     #                   10: R_MIPS_NONE *ABS*
 354     #                   10: R_MIPS_NONE *ABS*
 355     #      14:  03e0082d        move    at,ra
 356     #      18:  0060f809        jalr    v1
 357     #
 358     # for the kernel:
 359     #
 360     #     10:   03e0082d        move    at,ra
 361     #     14:   0c000000        jal     0 <loongson_halt>
 362     #                    14: R_MIPS_26   _mcount
 363     #                    14: R_MIPS_NONE *ABS*
 364     #                    14: R_MIPS_NONE *ABS*
 365     #    18:   00020021        nop
 366     if ($is_module eq "0") {
 367             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$";
 368     } else {
 369             $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$";
 370     }
 371     $objdump .= " -Melf-trad".$endian."mips ";
 372
 373     if ($endian eq "big") {
 374             $endian = " -EB ";
 375             $ld .= " -melf".$bits."btsmip";
 376     } else {
 377             $endian = " -EL ";
 378             $ld .= " -melf".$bits."ltsmip";
 379     }
 380
 381     $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian;
 382     $ld .= $endian;
 383
 384     if ($bits == 64) {
 385             $function_regex =
 386                 "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:";
 387             $type = ".dword";
 388     }
 389 } elsif ($arch eq "microblaze") {
 390     # Microblaze calls '_mcount' instead of plain 'mcount'.
 391     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 392 } elsif ($arch eq "riscv") {
 393     $function_regex = "^([0-9a-fA-F]+)\\s+<([^.0-9][0-9a-zA-Z_\\.]+)>:";
 394     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\sR_RISCV_CALL\\s_mcount\$";
 395     $type = ".quad";
 396     $alignment = 2;
 397 } elsif ($arch eq "nds32") {
 398     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_NDS32_HI20_RELA\\s+_mcount\$";
 399     $alignment = 2;
 400 } else {
 401     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 402 }
 403
 404 my $text_found = 0;
 405 my $read_function = 0;
 406 my $opened = 0;
 407 my $mcount_section = "__mcount_loc";
 408
 409 my $dirname;
 410 my $filename;
 411 my $prefix;
 412 my $ext;
 413
 414 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 415     $dirname = $1;
 416     $filename = $2;
 417 } else {
 418     $dirname = ".";
 419     $filename = $inputfile;
 420 }
 421
 422 if ($filename =~ m,^(.*)(\.\S),) {
 423     $prefix = $1;
 424     $ext = $2;
 425 } else {
 426     $prefix = $filename;
 427     $ext = "";
 428 }
 429
 430 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 431 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 432
 433 check_objcopy();
 434
 435 #
 436 # Step 1: find all the local (static functions) and weak symbols.
 437 #         't' is local, 'w/W' is weak
 438 #
 439 open (IN, "$nm $inputfile|") || die "error running $nm";
 440 while (<IN>) {
 441     if (/$local_regex/) {
 442         $locals{$1} = 1;
 443     } elsif (/$weak_regex/) {
 444         $weak{$2} = $1;
 445     }
 446 }
 447 close(IN);
 448
 449 my @offsets;            # Array of offsets of mcount callers
 450 my $ref_func;           # reference function to use for offsets
 451 my $offset = 0;         # offset of ref_func to section beginning
 452
 453 ##
 454 # update_funcs - print out the current mcount callers
 455 #
 456 #  Go through the list of offsets to callers and write them to
 457 #  the output file in a format that can be read by an assembler.
 458 #
 459 sub update_funcs
 460 {
 461     return unless ($ref_func and @offsets);
 462
 463     # Sanity check on weak function. A weak function may be overwritten by
 464     # another function of the same name, making all these offsets incorrect.
 465     if (defined $weak{$ref_func}) {
 466         die "$inputfile: ERROR: referencing weak function" .
 467             " $ref_func for mcount\n";
 468     }
 469
 470     # is this function static? If so, note this fact.
 471     if (defined $locals{$ref_func}) {
 472
 473         # only use locals if objcopy supports globalize-symbols
 474         if (!$can_use_local) {
 475             return;
 476         }
 477         $convert{$ref_func} = 1;
 478     }
 479
 480     # Loop through all the mcount caller offsets and print a reference
 481     # to the caller based from the ref_func.
 482     if (!$opened) {
 483         open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 484         $opened = 1;
 485         print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 486         print FILE "\t.align $alignment\n" if (defined($alignment));
 487     }
 488     foreach my $cur_offset (@offsets) {
 489         printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset;
 490     }
 491 }
 492
 493 #
 494 # Step 2: find the sections and mcount call sites
 495 #
 496 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 497
 498 my $text;
 499
 500
 501 # read headers first
 502 my $read_headers = 1;
 503
 504 while (<IN>) {
 505
 506     if ($read_headers && /$mcount_section/) {
 507         #
 508         # Somehow the make process can execute this script on an
 509         # object twice. If it does, we would duplicate the mcount
 510         # section and it will cause the function tracer self test
 511         # to fail. Check if the mcount section exists, and if it does,
 512         # warn and exit.
 513         #
 514         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 515             "\tThis may be an indication that your build is corrupted.\n" .
 516             "\tDelete $inputfile and try again. If the same object file\n" .
 517             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 518         exit(-1);
 519     }
 520
 521     # is it a section?
 522     if (/$section_regex/) {
 523         $read_headers = 0;
 524
 525         # Only record text sections that we know are safe
 526         $read_function = defined($text_sections{$1});
 527         if (!$read_function) {
 528             foreach my $prefix (keys %text_section_prefixes) {
 529                 if (substr($1, 0, length $prefix) eq $prefix) {
 530                     $read_function = 1;
 531                     last;
 532                 }
 533             }
 534         }
 535         # print out any recorded offsets
 536         update_funcs();
 537
 538         # reset all markers and arrays
 539         $text_found = 0;
 540         undef($ref_func);
 541         undef(@offsets);
 542
 543     # section found, now is this a start of a function?
 544     } elsif ($read_function && /$function_regex/) {
 545         $text_found = 1;
 546         $text = $2;
 547
 548         # if this is either a local function or a weak function
 549         # keep looking for functions that are global that
 550         # we can use safely.
 551         if (!defined($locals{$text}) && !defined($weak{$text})) {
 552             $ref_func = $text;
 553             $read_function = 0;
 554             $offset = hex $1;
 555         } else {
 556             # if we already have a function, and this is weak, skip it
 557             if (!defined($ref_func) && !defined($weak{$text}) &&
 558                  # PPC64 can have symbols that start with .L and
 559                  # gcc considers these special. Don't use them!
 560                  $text !~ /^\.L/) {
 561                 $ref_func = $text;
 562                 $offset = hex $1;
 563             }
 564         }
 565     }
 566     # is this a call site to mcount? If so, record it to print later
 567     if ($text_found && /$mcount_regex/) {
 568         push(@offsets, (hex $1) + $mcount_adjust);
 569     }
 570 }
 571
 572 # dump out anymore offsets that may have been found
 573 update_funcs();
 574
 575 # If we did not find any mcount callers, we are done (do nothing).
 576 if (!$opened) {
 577     exit(0);
 578 }
 579
 580 close(FILE);
 581
 582 #
 583 # Step 3: Compile the file that holds the list of call sites to mcount.
 584 #
 585 `$cc -o $mcount_o -c $mcount_s`;
 586
 587 my @converts = keys %convert;
 588
 589 #
 590 # Step 4: Do we have sections that started with local functions?
 591 #
 592 if ($#converts >= 0) {
 593     my $globallist = "";
 594     my $locallist = "";
 595
 596     foreach my $con (@converts) {
 597         $globallist .= " --globalize-symbol $con";
 598         $locallist .= " --localize-symbol $con";
 599     }
 600
 601     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 602     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 603
 604     #
 605     # Step 5: set up each local function as a global
 606     #
 607     `$objcopy $globallist $inputfile $globalobj`;
 608
 609     #
 610     # Step 6: Link the global version to our list.
 611     #
 612     `$ld -r $globalobj $mcount_o -o $globalmix`;
 613
 614     #
 615     # Step 7: Convert the local functions back into local symbols
 616     #
 617     `$objcopy $locallist $globalmix $inputfile`;
 618
 619     # Remove the temp files
 620     `$rm $globalobj $globalmix`;
 621
 622 } else {
 623
 624     my $mix = $dirname . "/.tmp_mx_" . $filename;
 625
 626     #
 627     # Step 8: Link the object with our list of call sites object.
 628     #
 629     `$ld -r $inputfile $mcount_o -o $mix`;
 630
 631     #
 632     # Step 9: Move the result back to the original object.
 633     #
 634     `$mv $mix $inputfile`;
 635 }
 636
 637 # Clean up the temp files
 638 `$rm $mcount_o $mcount_s`;
 639
 640 exit(0);