scripts/kernel-doc

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0
   3
   4 use warnings;
   5 use strict;
   6
   7 ## Copyright (c) 1998 Michael Zucchi, All Rights Reserved        ##
   8 ## Copyright (C) 2000, 1  Tim Waugh <twaugh@redhat.com>          ##
   9 ## Copyright (C) 2001  Simon Huggins                             ##
  10 ## Copyright (C) 2005-2012  Randy Dunlap                         ##
  11 ## Copyright (C) 2012  Dan Luedtke                               ##
  12 ##                                                               ##
  13 ## #define enhancements by Armin Kuster <akuster@mvista.com>     ##
  14 ## Copyright (c) 2000 MontaVista Software, Inc.                  ##
  15 #
  16 # Copyright (C) 2022 Tomasz Warniełło (POD)
  17
  18 use Pod::Usage qw/pod2usage/;
  19
  20 =head1 NAME
  21
  22 kernel-doc - Print formatted kernel documentation to stdout
  23
  24 =head1 SYNOPSIS
  25
  26  kernel-doc [-h] [-v] [-Werror] [-Wall] [-Wreturn] [-Wshort-description] [-Wcontents-before-sections]
  27    [ -man |
  28      -rst [-sphinx-version VERSION] [-enable-lineno] |
  29      -none
  30    ]
  31    [
  32      -export |
  33      -internal |
  34      [-function NAME] ... |
  35      [-nosymbol NAME] ...
  36    ]
  37    [-no-doc-sections]
  38    [-export-file FILE] ...
  39    FILE ...
  40
  41 Run `kernel-doc -h` for details.
  42
  43 =head1 DESCRIPTION
  44
  45 Read C language source or header FILEs, extract embedded documentation comments,
  46 and print formatted documentation to standard output.
  47
  48 The documentation comments are identified by the "/**" opening comment mark.
  49
  50 See Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
  51
  52 =cut
  53
  54 # more perldoc at the end of the file
  55
  56 ## init lots of data
  57
  58 my $errors = 0;
  59 my $warnings = 0;
  60 my $anon_struct_union = 0;
  61
  62 # match expressions used to find embedded type information
  63 my $type_constant = '\b``([^\`]+)``\b';
  64 my $type_constant2 = '\%([-_\w]+)';
  65 my $type_func = '(\w+)\(\)';
  66 my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
  67 my $type_param_ref = '([\!~]?)\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
  68 my $type_fp_param = '\@(\w+)\(\)';  # Special RST handling for func ptr params
  69 my $type_fp_param2 = '\@(\w+->\S+)\(\)';  # Special RST handling for structs with func ptr params
  70 my $type_env = '(\$\w+)';
  71 my $type_enum = '\&(enum\s*([_\w]+))';
  72 my $type_struct = '\&(struct\s*([_\w]+))';
  73 my $type_typedef = '\&(typedef\s*([_\w]+))';
  74 my $type_union = '\&(union\s*([_\w]+))';
  75 my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
  76 my $type_fallback = '\&([_\w]+)';
  77 my $type_member_func = $type_member . '\(\)';
  78
  79 # Output conversion substitutions.
  80 #  One for each output format
  81
  82 # these are pretty rough
  83 my @highlights_man = (
  84                       [$type_constant, "\$1"],
  85                       [$type_constant2, "\$1"],
  86                       [$type_func, "\\\\fB\$1\\\\fP"],
  87                       [$type_enum, "\\\\fI\$1\\\\fP"],
  88                       [$type_struct, "\\\\fI\$1\\\\fP"],
  89                       [$type_typedef, "\\\\fI\$1\\\\fP"],
  90                       [$type_union, "\\\\fI\$1\\\\fP"],
  91                       [$type_param, "\\\\fI\$1\\\\fP"],
  92                       [$type_param_ref, "\\\\fI\$1\$2\\\\fP"],
  93                       [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
  94                       [$type_fallback, "\\\\fI\$1\\\\fP"]
  95                      );
  96 my $blankline_man = "";
  97
  98 # rst-mode
  99 my @highlights_rst = (
 100                        [$type_constant, "``\$1``"],
 101                        [$type_constant2, "``\$1``"],
 102                        # Note: need to escape () to avoid func matching later
 103                        [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
 104                        [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
 105                        [$type_fp_param, "**\$1\\\\(\\\\)**"],
 106                        [$type_fp_param2, "**\$1\\\\(\\\\)**"],
 107                        [$type_func, "\$1()"],
 108                        [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
 109                        [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
 110                        [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
 111                        [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
 112                        # in rst this can refer to any type
 113                        [$type_fallback, "\\:c\\:type\\:`\$1`"],
 114                        [$type_param_ref, "**\$1\$2**"]
 115                       );
 116 my $blankline_rst = "\n";
 117
 118 # read arguments
 119 if ($#ARGV == -1) {
 120         pod2usage(
 121                 -message => "No arguments!\n",
 122                 -exitval => 1,
 123                 -verbose => 99,
 124                 -sections => 'SYNOPSIS',
 125                 -output => \*STDERR,
 126         );
 127 }
 128
 129 my $kernelversion;
 130 my ($sphinx_major, $sphinx_minor, $sphinx_patch);
 131
 132 my $dohighlight = "";
 133
 134 my $verbose = 0;
 135 my $Werror = 0;
 136 my $Wreturn = 0;
 137 my $Wshort_desc = 0;
 138 my $Wcontents_before_sections = 0;
 139 my $output_mode = "rst";
 140 my $output_preformatted = 0;
 141 my $no_doc_sections = 0;
 142 my $enable_lineno = 0;
 143 my @highlights = @highlights_rst;
 144 my $blankline = $blankline_rst;
 145 my $modulename = "Kernel API";
 146
 147 use constant {
 148     OUTPUT_ALL          => 0, # output all symbols and doc sections
 149     OUTPUT_INCLUDE      => 1, # output only specified symbols
 150     OUTPUT_EXPORTED     => 2, # output exported symbols
 151     OUTPUT_INTERNAL     => 3, # output non-exported symbols
 152 };
 153 my $output_selection = OUTPUT_ALL;
 154 my $show_not_found = 0; # No longer used
 155
 156 my @export_file_list;
 157
 158 my @build_time;
 159 if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
 160     (my $seconds = `date -d"${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
 161     @build_time = gmtime($seconds);
 162 } else {
 163     @build_time = localtime;
 164 }
 165
 166 my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
 167                 'July', 'August', 'September', 'October',
 168                 'November', 'December')[$build_time[4]] .
 169   " " . ($build_time[5]+1900);
 170
 171 # Essentially these are globals.
 172 # They probably want to be tidied up, made more localised or something.
 173 # CAVEAT EMPTOR!  Some of the others I localised may not want to be, which
 174 # could cause "use of undefined value" or other bugs.
 175 my ($function, %function_table, %parametertypes, $declaration_purpose);
 176 my %nosymbol_table = ();
 177 my $declaration_start_line;
 178 my ($type, $declaration_name, $return_type);
 179 my ($newsection, $newcontents, $prototype, $brcount, %source_map);
 180
 181 if (defined($ENV{'KBUILD_VERBOSE'}) && $ENV{'KBUILD_VERBOSE'} =~ '1') {
 182         $verbose = 1;
 183 }
 184
 185 if (defined($ENV{'KCFLAGS'})) {
 186         my $kcflags = "$ENV{'KCFLAGS'}";
 187
 188         if ($kcflags =~ /Werror/) {
 189                 $Werror = 1;
 190         }
 191 }
 192
 193 # reading this variable is for backwards compat just in case
 194 # someone was calling it with the variable from outside the
 195 # kernel's build system
 196 if (defined($ENV{'KDOC_WERROR'})) {
 197         $Werror = "$ENV{'KDOC_WERROR'}";
 198 }
 199 # other environment variables are converted to command-line
 200 # arguments in cmd_checkdoc in the build system
 201
 202 # Generated docbook code is inserted in a template at a point where
 203 # docbook v3.1 requires a non-zero sequence of RefEntry's; see:
 204 # https://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
 205 # We keep track of number of generated entries and generate a dummy
 206 # if needs be to ensure the expanded template can be postprocessed
 207 # into html.
 208 my $section_counter = 0;
 209
 210 my $lineprefix="";
 211
 212 # Parser states
 213 use constant {
 214     STATE_NORMAL        => 0,        # normal code
 215     STATE_NAME          => 1,        # looking for function name
 216     STATE_BODY_MAYBE    => 2,        # body - or maybe more description
 217     STATE_BODY          => 3,        # the body of the comment
 218     STATE_BODY_WITH_BLANK_LINE => 4, # the body, which has a blank line
 219     STATE_PROTO         => 5,        # scanning prototype
 220     STATE_DOCBLOCK      => 6,        # documentation block
 221     STATE_INLINE        => 7,        # gathering doc outside main block
 222 };
 223 my $state;
 224 my $in_doc_sect;
 225 my $leading_space;
 226
 227 # Inline documentation state
 228 use constant {
 229     STATE_INLINE_NA     => 0, # not applicable ($state != STATE_INLINE)
 230     STATE_INLINE_NAME   => 1, # looking for member name (@foo:)
 231     STATE_INLINE_TEXT   => 2, # looking for member documentation
 232     STATE_INLINE_END    => 3, # done
 233     STATE_INLINE_ERROR  => 4, # error - Comment without header was found.
 234                               # Spit a warning as it's not
 235                               # proper kernel-doc and ignore the rest.
 236 };
 237 my $inline_doc_state;
 238
 239 #declaration types: can be
 240 # 'function', 'struct', 'union', 'enum', 'typedef'
 241 my $decl_type;
 242
 243 # Name of the kernel-doc identifier for non-DOC markups
 244 my $identifier;
 245
 246 my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
 247 my $doc_end = '\*/';
 248 my $doc_com = '\s*\*\s*';
 249 my $doc_com_body = '\s*\* ?';
 250 my $doc_decl = $doc_com . '(\w+)';
 251 # @params and a strictly limited set of supported section names
 252 # Specifically:
 253 #   Match @word:
 254 #         @...:
 255 #         @{section-name}:
 256 # while trying to not match literal block starts like "example::"
 257 #
 258 my $doc_sect = $doc_com .
 259     '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:([^:].*)?$';
 260 my $doc_content = $doc_com_body . '(.*)';
 261 my $doc_block = $doc_com . 'DOC:\s*(.*)?';
 262 my $doc_inline_start = '^\s*/\*\*\s*$';
 263 my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
 264 my $doc_inline_end = '^\s*\*/\s*$';
 265 my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
 266 my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
 267 my $export_symbol_ns = '^\s*EXPORT_SYMBOL_NS(_GPL)?\s*\(\s*(\w+)\s*,\s*\w+\)\s*;';
 268 my $function_pointer = qr{([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)};
 269 my $attribute = qr{__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)}i;
 270
 271 my %parameterdescs;
 272 my %parameterdesc_start_lines;
 273 my @parameterlist;
 274 my %sections;
 275 my @sectionlist;
 276 my %section_start_lines;
 277 my $sectcheck;
 278 my $struct_actual;
 279
 280 my $contents = "";
 281 my $new_start_line = 0;
 282
 283 # the canonical section names. see also $doc_sect above.
 284 my $section_default = "Description";    # default section
 285 my $section_intro = "Introduction";
 286 my $section = $section_default;
 287 my $section_context = "Context";
 288 my $section_return = "Return";
 289
 290 my $undescribed = "-- undescribed --";
 291
 292 reset_state();
 293
 294 while ($ARGV[0] =~ m/^--?(.*)/) {
 295     my $cmd = $1;
 296     shift @ARGV;
 297     if ($cmd eq "man") {
 298         $output_mode = "man";
 299         @highlights = @highlights_man;
 300         $blankline = $blankline_man;
 301     } elsif ($cmd eq "rst") {
 302         $output_mode = "rst";
 303         @highlights = @highlights_rst;
 304         $blankline = $blankline_rst;
 305     } elsif ($cmd eq "none") {
 306         $output_mode = "none";
 307     } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
 308         $modulename = shift @ARGV;
 309     } elsif ($cmd eq "function") { # to only output specific functions
 310         $output_selection = OUTPUT_INCLUDE;
 311         $function = shift @ARGV;
 312         $function_table{$function} = 1;
 313     } elsif ($cmd eq "nosymbol") { # Exclude specific symbols
 314         my $symbol = shift @ARGV;
 315         $nosymbol_table{$symbol} = 1;
 316     } elsif ($cmd eq "export") { # only exported symbols
 317         $output_selection = OUTPUT_EXPORTED;
 318         %function_table = ();
 319     } elsif ($cmd eq "internal") { # only non-exported symbols
 320         $output_selection = OUTPUT_INTERNAL;
 321         %function_table = ();
 322     } elsif ($cmd eq "export-file") {
 323         my $file = shift @ARGV;
 324         push(@export_file_list, $file);
 325     } elsif ($cmd eq "v") {
 326         $verbose = 1;
 327     } elsif ($cmd eq "Werror") {
 328         $Werror = 1;
 329     } elsif ($cmd eq "Wreturn") {
 330         $Wreturn = 1;
 331     } elsif ($cmd eq "Wshort-desc") {
 332         $Wshort_desc = 1;
 333     } elsif ($cmd eq "Wcontents-before-sections") {
 334         $Wcontents_before_sections = 1;
 335     } elsif ($cmd eq "Wall") {
 336         $Wreturn = 1;
 337         $Wshort_desc = 1;
 338         $Wcontents_before_sections = 1;
 339     } elsif (($cmd eq "h") || ($cmd eq "help")) {
 340                 pod2usage(-exitval => 0, -verbose => 2);
 341     } elsif ($cmd eq 'no-doc-sections') {
 342             $no_doc_sections = 1;
 343     } elsif ($cmd eq 'enable-lineno') {
 344             $enable_lineno = 1;
 345     } elsif ($cmd eq 'show-not-found') {
 346         $show_not_found = 1;  # A no-op but don't fail
 347     } elsif ($cmd eq "sphinx-version") {
 348         my $ver_string = shift @ARGV;
 349         if ($ver_string =~ m/^(\d+)(\.\d+)?(\.\d+)?/) {
 350             $sphinx_major = $1;
 351             if (defined($2)) {
 352                 $sphinx_minor = substr($2,1);
 353             } else {
 354                 $sphinx_minor = 0;
 355             }
 356             if (defined($3)) {
 357                 $sphinx_patch = substr($3,1)
 358             } else {
 359                 $sphinx_patch = 0;
 360             }
 361         } else {
 362             die "Sphinx version should either major.minor or major.minor.patch format\n";
 363         }
 364     } else {
 365         # Unknown argument
 366         pod2usage(
 367             -message => "Argument unknown!\n",
 368             -exitval => 1,
 369             -verbose => 99,
 370             -sections => 'SYNOPSIS',
 371             -output => \*STDERR,
 372             );
 373     }
 374     if ($#ARGV < 0){
 375         pod2usage(
 376             -message => "FILE argument missing\n",
 377             -exitval => 1,
 378             -verbose => 99,
 379             -sections => 'SYNOPSIS',
 380             -output => \*STDERR,
 381             );
 382     }
 383 }
 384
 385 # continue execution near EOF;
 386
 387 # The C domain dialect changed on Sphinx 3. So, we need to check the
 388 # version in order to produce the right tags.
 389 sub findprog($)
 390 {
 391         foreach(split(/:/, $ENV{PATH})) {
 392                 return "$_/$_[0]" if(-x "$_/$_[0]");
 393         }
 394 }
 395
 396 sub get_sphinx_version()
 397 {
 398         my $ver;
 399
 400         my $cmd = "sphinx-build";
 401         if (!findprog($cmd)) {
 402                 my $cmd = "sphinx-build3";
 403                 if (!findprog($cmd)) {
 404                         $sphinx_major = 1;
 405                         $sphinx_minor = 2;
 406                         $sphinx_patch = 0;
 407                         printf STDERR "Warning: Sphinx version not found. Using default (Sphinx version %d.%d.%d)\n",
 408                                $sphinx_major, $sphinx_minor, $sphinx_patch;
 409                         return;
 410                 }
 411         }
 412
 413         open IN, "$cmd --version 2>&1 |";
 414         while (<IN>) {
 415                 if (m/^\s*sphinx-build\s+([\d]+)\.([\d\.]+)(\+\/[\da-f]+)?$/) {
 416                         $sphinx_major = $1;
 417                         $sphinx_minor = $2;
 418                         $sphinx_patch = $3;
 419                         last;
 420                 }
 421                 # Sphinx 1.2.x uses a different format
 422                 if (m/^\s*Sphinx.*\s+([\d]+)\.([\d\.]+)$/) {
 423                         $sphinx_major = $1;
 424                         $sphinx_minor = $2;
 425                         $sphinx_patch = $3;
 426                         last;
 427                 }
 428         }
 429         close IN;
 430 }
 431
 432 # get kernel version from env
 433 sub get_kernel_version() {
 434     my $version = 'unknown kernel version';
 435
 436     if (defined($ENV{'KERNELVERSION'})) {
 437         $version = $ENV{'KERNELVERSION'};
 438     }
 439     return $version;
 440 }
 441
 442 #
 443 sub print_lineno {
 444     my $lineno = shift;
 445     if ($enable_lineno && defined($lineno)) {
 446         print ".. LINENO " . $lineno . "\n";
 447     }
 448 }
 449
 450 sub emit_warning {
 451     my $location = shift;
 452     my $msg = shift;
 453     print STDERR "$location: warning: $msg";
 454     ++$warnings;
 455 }
 456 ##
 457 # dumps section contents to arrays/hashes intended for that purpose.
 458 #
 459 sub dump_section {
 460     my $file = shift;
 461     my $name = shift;
 462     my $contents = join "\n", @_;
 463
 464     if ($name =~ m/$type_param/) {
 465         $name = $1;
 466         $parameterdescs{$name} = $contents;
 467         $sectcheck = $sectcheck . $name . " ";
 468         $parameterdesc_start_lines{$name} = $new_start_line;
 469         $new_start_line = 0;
 470     } elsif ($name eq "@\.\.\.") {
 471         $name = "...";
 472         $parameterdescs{$name} = $contents;
 473         $sectcheck = $sectcheck . $name . " ";
 474         $parameterdesc_start_lines{$name} = $new_start_line;
 475         $new_start_line = 0;
 476     } else {
 477         if (defined($sections{$name}) && ($sections{$name} ne "")) {
 478             # Only warn on user specified duplicate section names.
 479             if ($name ne $section_default) {
 480                 emit_warning("${file}:$.", "duplicate section name '$name'\n");
 481             }
 482             $sections{$name} .= $contents;
 483         } else {
 484             $sections{$name} = $contents;
 485             push @sectionlist, $name;
 486             $section_start_lines{$name} = $new_start_line;
 487             $new_start_line = 0;
 488         }
 489     }
 490 }
 491
 492 ##
 493 # dump DOC: section after checking that it should go out
 494 #
 495 sub dump_doc_section {
 496     my $file = shift;
 497     my $name = shift;
 498     my $contents = join "\n", @_;
 499
 500     if ($no_doc_sections) {
 501         return;
 502     }
 503
 504     return if (defined($nosymbol_table{$name}));
 505
 506     if (($output_selection == OUTPUT_ALL) ||
 507         (($output_selection == OUTPUT_INCLUDE) &&
 508          defined($function_table{$name})))
 509     {
 510         dump_section($file, $name, $contents);
 511         output_blockhead({'sectionlist' => \@sectionlist,
 512                           'sections' => \%sections,
 513                           'module' => $modulename,
 514                           'content-only' => ($output_selection != OUTPUT_ALL), });
 515     }
 516 }
 517
 518 ##
 519 # output function
 520 #
 521 # parameterdescs, a hash.
 522 #  function => "function name"
 523 #  parameterlist => @list of parameters
 524 #  parameterdescs => %parameter descriptions
 525 #  sectionlist => @list of sections
 526 #  sections => %section descriptions
 527 #
 528
 529 sub output_highlight {
 530     my $contents = join "\n",@_;
 531     my $line;
 532
 533 #   DEBUG
 534 #   if (!defined $contents) {
 535 #       use Carp;
 536 #       confess "output_highlight got called with no args?\n";
 537 #   }
 538
 539 #   print STDERR "contents b4:$contents\n";
 540     eval $dohighlight;
 541     die $@ if $@;
 542 #   print STDERR "contents af:$contents\n";
 543
 544     foreach $line (split "\n", $contents) {
 545         if (! $output_preformatted) {
 546             $line =~ s/^\s*//;
 547         }
 548         if ($line eq ""){
 549             if (! $output_preformatted) {
 550                 print $lineprefix, $blankline;
 551             }
 552         } else {
 553             if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
 554                 print "\\&$line";
 555             } else {
 556                 print $lineprefix, $line;
 557             }
 558         }
 559         print "\n";
 560     }
 561 }
 562
 563 ##
 564 # output function in man
 565 sub output_function_man(%) {
 566     my %args = %{$_[0]};
 567     my ($parameter, $section);
 568     my $count;
 569
 570     print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
 571
 572     print ".SH NAME\n";
 573     print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
 574
 575     print ".SH SYNOPSIS\n";
 576     if ($args{'functiontype'} ne "") {
 577         print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
 578     } else {
 579         print ".B \"" . $args{'function'} . "\n";
 580     }
 581     $count = 0;
 582     my $parenth = "(";
 583     my $post = ",";
 584     foreach my $parameter (@{$args{'parameterlist'}}) {
 585         if ($count == $#{$args{'parameterlist'}}) {
 586             $post = ");";
 587         }
 588         $type = $args{'parametertypes'}{$parameter};
 589         if ($type =~ m/$function_pointer/) {
 590             # pointer-to-function
 591             print ".BI \"" . $parenth . $1 . "\" " . " \") (" . $2 . ")" . $post . "\"\n";
 592         } else {
 593             $type =~ s/([^\*])$/$1 /;
 594             print ".BI \"" . $parenth . $type . "\" " . " \"" . $post . "\"\n";
 595         }
 596         $count++;
 597         $parenth = "";
 598     }
 599
 600     print ".SH ARGUMENTS\n";
 601     foreach $parameter (@{$args{'parameterlist'}}) {
 602         my $parameter_name = $parameter;
 603         $parameter_name =~ s/\[.*//;
 604
 605         print ".IP \"" . $parameter . "\" 12\n";
 606         output_highlight($args{'parameterdescs'}{$parameter_name});
 607     }
 608     foreach $section (@{$args{'sectionlist'}}) {
 609         print ".SH \"", uc $section, "\"\n";
 610         output_highlight($args{'sections'}{$section});
 611     }
 612 }
 613
 614 ##
 615 # output enum in man
 616 sub output_enum_man(%) {
 617     my %args = %{$_[0]};
 618     my ($parameter, $section);
 619     my $count;
 620
 621     print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
 622
 623     print ".SH NAME\n";
 624     print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
 625
 626     print ".SH SYNOPSIS\n";
 627     print "enum " . $args{'enum'} . " {\n";
 628     $count = 0;
 629     foreach my $parameter (@{$args{'parameterlist'}}) {
 630         print ".br\n.BI \"    $parameter\"\n";
 631         if ($count == $#{$args{'parameterlist'}}) {
 632             print "\n};\n";
 633             last;
 634         }
 635         else {
 636             print ", \n.br\n";
 637         }
 638         $count++;
 639     }
 640
 641     print ".SH Constants\n";
 642     foreach $parameter (@{$args{'parameterlist'}}) {
 643         my $parameter_name = $parameter;
 644         $parameter_name =~ s/\[.*//;
 645
 646         print ".IP \"" . $parameter . "\" 12\n";
 647         output_highlight($args{'parameterdescs'}{$parameter_name});
 648     }
 649     foreach $section (@{$args{'sectionlist'}}) {
 650         print ".SH \"$section\"\n";
 651         output_highlight($args{'sections'}{$section});
 652     }
 653 }
 654
 655 ##
 656 # output struct in man
 657 sub output_struct_man(%) {
 658     my %args = %{$_[0]};
 659     my ($parameter, $section);
 660
 661     print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
 662
 663     print ".SH NAME\n";
 664     print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
 665
 666     my $declaration = $args{'definition'};
 667     $declaration =~ s/\t/  /g;
 668     $declaration =~ s/\n/"\n.br\n.BI \"/g;
 669     print ".SH SYNOPSIS\n";
 670     print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
 671     print ".BI \"$declaration\n};\n.br\n\n";
 672
 673     print ".SH Members\n";
 674     foreach $parameter (@{$args{'parameterlist'}}) {
 675         ($parameter =~ /^#/) && next;
 676
 677         my $parameter_name = $parameter;
 678         $parameter_name =~ s/\[.*//;
 679
 680         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
 681         print ".IP \"" . $parameter . "\" 12\n";
 682         output_highlight($args{'parameterdescs'}{$parameter_name});
 683     }
 684     foreach $section (@{$args{'sectionlist'}}) {
 685         print ".SH \"$section\"\n";
 686         output_highlight($args{'sections'}{$section});
 687     }
 688 }
 689
 690 ##
 691 # output typedef in man
 692 sub output_typedef_man(%) {
 693     my %args = %{$_[0]};
 694     my ($parameter, $section);
 695
 696     print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
 697
 698     print ".SH NAME\n";
 699     print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
 700
 701     foreach $section (@{$args{'sectionlist'}}) {
 702         print ".SH \"$section\"\n";
 703         output_highlight($args{'sections'}{$section});
 704     }
 705 }
 706
 707 sub output_blockhead_man(%) {
 708     my %args = %{$_[0]};
 709     my ($parameter, $section);
 710     my $count;
 711
 712     print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
 713
 714     foreach $section (@{$args{'sectionlist'}}) {
 715         print ".SH \"$section\"\n";
 716         output_highlight($args{'sections'}{$section});
 717     }
 718 }
 719
 720 ##
 721 # output in restructured text
 722 #
 723
 724 #
 725 # This could use some work; it's used to output the DOC: sections, and
 726 # starts by putting out the name of the doc section itself, but that tends
 727 # to duplicate a header already in the template file.
 728 #
 729 sub output_blockhead_rst(%) {
 730     my %args = %{$_[0]};
 731     my ($parameter, $section);
 732
 733     foreach $section (@{$args{'sectionlist'}}) {
 734         next if (defined($nosymbol_table{$section}));
 735
 736         if ($output_selection != OUTPUT_INCLUDE) {
 737             print ".. _$section:\n\n";
 738             print "**$section**\n\n";
 739         }
 740         print_lineno($section_start_lines{$section});
 741         output_highlight_rst($args{'sections'}{$section});
 742         print "\n";
 743     }
 744 }
 745
 746 #
 747 # Apply the RST highlights to a sub-block of text.
 748 #
 749 sub highlight_block($) {
 750     # The dohighlight kludge requires the text be called $contents
 751     my $contents = shift;
 752     eval $dohighlight;
 753     die $@ if $@;
 754     return $contents;
 755 }
 756
 757 #
 758 # Regexes used only here.
 759 #
 760 my $sphinx_literal = '^[^.].*::$';
 761 my $sphinx_cblock = '^\.\.\ +code-block::';
 762
 763 sub output_highlight_rst {
 764     my $input = join "\n",@_;
 765     my $output = "";
 766     my $line;
 767     my $in_literal = 0;
 768     my $litprefix;
 769     my $block = "";
 770
 771     foreach $line (split "\n",$input) {
 772         #
 773         # If we're in a literal block, see if we should drop out
 774         # of it.  Otherwise pass the line straight through unmunged.
 775         #
 776         if ($in_literal) {
 777             if (! ($line =~ /^\s*$/)) {
 778                 #
 779                 # If this is the first non-blank line in a literal
 780                 # block we need to figure out what the proper indent is.
 781                 #
 782                 if ($litprefix eq "") {
 783                     $line =~ /^(\s*)/;
 784                     $litprefix = '^' . $1;
 785                     $output .= $line . "\n";
 786                 } elsif (! ($line =~ /$litprefix/)) {
 787                     $in_literal = 0;
 788                 } else {
 789                     $output .= $line . "\n";
 790                 }
 791             } else {
 792                 $output .= $line . "\n";
 793             }
 794         }
 795         #
 796         # Not in a literal block (or just dropped out)
 797         #
 798         if (! $in_literal) {
 799             $block .= $line . "\n";
 800             if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
 801                 $in_literal = 1;
 802                 $litprefix = "";
 803                 $output .= highlight_block($block);
 804                 $block = ""
 805             }
 806         }
 807     }
 808
 809     if ($block) {
 810         $output .= highlight_block($block);
 811     }
 812     foreach $line (split "\n", $output) {
 813         print $lineprefix . $line . "\n";
 814     }
 815 }
 816
 817 sub output_function_rst(%) {
 818     my %args = %{$_[0]};
 819     my ($parameter, $section);
 820     my $oldprefix = $lineprefix;
 821     my $start = "";
 822     my $is_macro = 0;
 823
 824     if ($sphinx_major < 3) {
 825         if ($args{'typedef'}) {
 826             print ".. c:type:: ". $args{'function'} . "\n\n";
 827             print_lineno($declaration_start_line);
 828             print "   **Typedef**: ";
 829             $lineprefix = "";
 830             output_highlight_rst($args{'purpose'});
 831             $start = "\n\n**Syntax**\n\n  ``";
 832             $is_macro = 1;
 833         } else {
 834             print ".. c:function:: ";
 835         }
 836     } else {
 837         if ($args{'typedef'} || $args{'functiontype'} eq "") {
 838             $is_macro = 1;
 839             print ".. c:macro:: ". $args{'function'} . "\n\n";
 840         } else {
 841             print ".. c:function:: ";
 842         }
 843
 844         if ($args{'typedef'}) {
 845             print_lineno($declaration_start_line);
 846             print "   **Typedef**: ";
 847             $lineprefix = "";
 848             output_highlight_rst($args{'purpose'});
 849             $start = "\n\n**Syntax**\n\n  ``";
 850         } else {
 851             print "``" if ($is_macro);
 852         }
 853     }
 854     if ($args{'functiontype'} ne "") {
 855         $start .= $args{'functiontype'} . " " . $args{'function'} . " (";
 856     } else {
 857         $start .= $args{'function'} . " (";
 858     }
 859     print $start;
 860
 861     my $count = 0;
 862     foreach my $parameter (@{$args{'parameterlist'}}) {
 863         if ($count ne 0) {
 864             print ", ";
 865         }
 866         $count++;
 867         $type = $args{'parametertypes'}{$parameter};
 868
 869         if ($type =~ m/$function_pointer/) {
 870             # pointer-to-function
 871             print $1 . $parameter . ") (" . $2 . ")";
 872         } else {
 873             print $type;
 874         }
 875     }
 876     if ($is_macro) {
 877         print ")``\n\n";
 878     } else {
 879         print ")\n\n";
 880     }
 881     if (!$args{'typedef'}) {
 882         print_lineno($declaration_start_line);
 883         $lineprefix = "   ";
 884         output_highlight_rst($args{'purpose'});
 885         print "\n";
 886     }
 887
 888     #
 889     # Put our descriptive text into a container (thus an HTML <div>) to help
 890     # set the function prototypes apart.
 891     #
 892     print ".. container:: kernelindent\n\n";
 893     $lineprefix = "  ";
 894     print $lineprefix . "**Parameters**\n\n";
 895     foreach $parameter (@{$args{'parameterlist'}}) {
 896         my $parameter_name = $parameter;
 897         $parameter_name =~ s/\[.*//;
 898         $type = $args{'parametertypes'}{$parameter};
 899
 900         if ($type ne "") {
 901             print $lineprefix . "``$type``\n";
 902         } else {
 903             print $lineprefix . "``$parameter``\n";
 904         }
 905
 906         print_lineno($parameterdesc_start_lines{$parameter_name});
 907
 908         $lineprefix = "    ";
 909         if (defined($args{'parameterdescs'}{$parameter_name}) &&
 910             $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
 911             output_highlight_rst($args{'parameterdescs'}{$parameter_name});
 912         } else {
 913             print $lineprefix . "*undescribed*\n";
 914         }
 915         $lineprefix = "  ";
 916         print "\n";
 917     }
 918
 919     output_section_rst(@_);
 920     $lineprefix = $oldprefix;
 921 }
 922
 923 sub output_section_rst(%) {
 924     my %args = %{$_[0]};
 925     my $section;
 926     my $oldprefix = $lineprefix;
 927
 928     foreach $section (@{$args{'sectionlist'}}) {
 929         print $lineprefix . "**$section**\n\n";
 930         print_lineno($section_start_lines{$section});
 931         output_highlight_rst($args{'sections'}{$section});
 932         print "\n";
 933     }
 934     print "\n";
 935 }
 936
 937 sub output_enum_rst(%) {
 938     my %args = %{$_[0]};
 939     my ($parameter);
 940     my $oldprefix = $lineprefix;
 941     my $count;
 942     my $outer;
 943
 944     if ($sphinx_major < 3) {
 945         my $name = "enum " . $args{'enum'};
 946         print "\n\n.. c:type:: " . $name . "\n\n";
 947     } else {
 948         my $name = $args{'enum'};
 949         print "\n\n.. c:enum:: " . $name . "\n\n";
 950     }
 951     print_lineno($declaration_start_line);
 952     $lineprefix = "  ";
 953     output_highlight_rst($args{'purpose'});
 954     print "\n";
 955
 956     print ".. container:: kernelindent\n\n";
 957     $outer = $lineprefix . "  ";
 958     $lineprefix = $outer . "  ";
 959     print $outer . "**Constants**\n\n";
 960     foreach $parameter (@{$args{'parameterlist'}}) {
 961         print $outer . "``$parameter``\n";
 962
 963         if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
 964             output_highlight_rst($args{'parameterdescs'}{$parameter});
 965         } else {
 966             print $lineprefix . "*undescribed*\n";
 967         }
 968         print "\n";
 969     }
 970     print "\n";
 971     $lineprefix = $oldprefix;
 972     output_section_rst(@_);
 973 }
 974
 975 sub output_typedef_rst(%) {
 976     my %args = %{$_[0]};
 977     my ($parameter);
 978     my $oldprefix = $lineprefix;
 979     my $name;
 980
 981     if ($sphinx_major < 3) {
 982         $name = "typedef " . $args{'typedef'};
 983     } else {
 984         $name = $args{'typedef'};
 985     }
 986     print "\n\n.. c:type:: " . $name . "\n\n";
 987     print_lineno($declaration_start_line);
 988     $lineprefix = "   ";
 989     output_highlight_rst($args{'purpose'});
 990     print "\n";
 991
 992     $lineprefix = $oldprefix;
 993     output_section_rst(@_);
 994 }
 995
 996 sub output_struct_rst(%) {
 997     my %args = %{$_[0]};
 998     my ($parameter);
 999     my $oldprefix = $lineprefix;
1000
1001     if ($sphinx_major < 3) {
1002         my $name = $args{'type'} . " " . $args{'struct'};
1003         print "\n\n.. c:type:: " . $name . "\n\n";
1004     } else {
1005         my $name = $args{'struct'};
1006         if ($args{'type'} eq 'union') {
1007             print "\n\n.. c:union:: " . $name . "\n\n";
1008         } else {
1009             print "\n\n.. c:struct:: " . $name . "\n\n";
1010         }
1011     }
1012     print_lineno($declaration_start_line);
1013     $lineprefix = "  ";
1014     output_highlight_rst($args{'purpose'});
1015     print "\n";
1016
1017     print ".. container:: kernelindent\n\n";
1018     print $lineprefix . "**Definition**::\n\n";
1019     my $declaration = $args{'definition'};
1020     $lineprefix = $lineprefix . "  ";
1021     $declaration =~ s/\t/$lineprefix/g;
1022     print $lineprefix . $args{'type'} . " " . $args{'struct'} . " {\n$declaration" . $lineprefix . "};\n\n";
1023
1024     $lineprefix = "  ";
1025     print $lineprefix . "**Members**\n\n";
1026     foreach $parameter (@{$args{'parameterlist'}}) {
1027         ($parameter =~ /^#/) && next;
1028
1029         my $parameter_name = $parameter;
1030         $parameter_name =~ s/\[.*//;
1031
1032         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
1033         $type = $args{'parametertypes'}{$parameter};
1034         print_lineno($parameterdesc_start_lines{$parameter_name});
1035         print $lineprefix . "``" . $parameter . "``\n";
1036         $lineprefix = "    ";
1037         output_highlight_rst($args{'parameterdescs'}{$parameter_name});
1038         $lineprefix = "  ";
1039         print "\n";
1040     }
1041     print "\n";
1042
1043     $lineprefix = $oldprefix;
1044     output_section_rst(@_);
1045 }
1046
1047 ## none mode output functions
1048
1049 sub output_function_none(%) {
1050 }
1051
1052 sub output_enum_none(%) {
1053 }
1054
1055 sub output_typedef_none(%) {
1056 }
1057
1058 sub output_struct_none(%) {
1059 }
1060
1061 sub output_blockhead_none(%) {
1062 }
1063
1064 ##
1065 # generic output function for all types (function, struct/union, typedef, enum);
1066 # calls the generated, variable output_ function name based on
1067 # functype and output_mode
1068 sub output_declaration {
1069     no strict 'refs';
1070     my $name = shift;
1071     my $functype = shift;
1072     my $func = "output_${functype}_$output_mode";
1073
1074     return if (defined($nosymbol_table{$name}));
1075
1076     if (($output_selection == OUTPUT_ALL) ||
1077         (($output_selection == OUTPUT_INCLUDE ||
1078           $output_selection == OUTPUT_EXPORTED) &&
1079          defined($function_table{$name})) ||
1080         ($output_selection == OUTPUT_INTERNAL &&
1081          !($functype eq "function" && defined($function_table{$name}))))
1082     {
1083         &$func(@_);
1084         $section_counter++;
1085     }
1086 }
1087
1088 ##
1089 # generic output function - calls the right one based on current output mode.
1090 sub output_blockhead {
1091     no strict 'refs';
1092     my $func = "output_blockhead_" . $output_mode;
1093     &$func(@_);
1094     $section_counter++;
1095 }
1096
1097 ##
1098 # takes a declaration (struct, union, enum, typedef) and
1099 # invokes the right handler. NOT called for functions.
1100 sub dump_declaration($$) {
1101     no strict 'refs';
1102     my ($prototype, $file) = @_;
1103     my $func = "dump_" . $decl_type;
1104     &$func(@_);
1105 }
1106
1107 sub dump_union($$) {
1108     dump_struct(@_);
1109 }
1110
1111 sub dump_struct($$) {
1112     my $x = shift;
1113     my $file = shift;
1114     my $decl_type;
1115     my $members;
1116     my $type = qr{struct|union};
1117     # For capturing struct/union definition body, i.e. "{members*}qualifiers*"
1118     my $qualifiers = qr{$attribute|__packed|__aligned|____cacheline_aligned_in_smp|____cacheline_aligned};
1119     my $definition_body = qr{\{(.*)\}\s*$qualifiers*};
1120     my $struct_members = qr{($type)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;};
1121
1122     if ($x =~ /($type)\s+(\w+)\s*$definition_body/) {
1123         $decl_type = $1;
1124         $declaration_name = $2;
1125         $members = $3;
1126     } elsif ($x =~ /typedef\s+($type)\s*$definition_body\s*(\w+)\s*;/) {
1127         $decl_type = $1;
1128         $declaration_name = $3;
1129         $members = $2;
1130     }
1131
1132     if ($members) {
1133         if ($identifier ne $declaration_name) {
1134             emit_warning("${file}:$.", "expecting prototype for $decl_type $identifier. Prototype was for $decl_type $declaration_name instead\n");
1135             return;
1136         }
1137
1138         # ignore members marked private:
1139         $members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1140         $members =~ s/\/\*\s*private:.*//gosi;
1141         # strip comments:
1142         $members =~ s/\/\*.*?\*\///gos;
1143         # strip attributes
1144         $members =~ s/\s*$attribute/ /gi;
1145         $members =~ s/\s*__aligned\s*\([^;]*\)/ /gos;
1146         $members =~ s/\s*__packed\s*/ /gos;
1147         $members =~ s/\s*CRYPTO_MINALIGN_ATTR/ /gos;
1148         $members =~ s/\s*____cacheline_aligned_in_smp/ /gos;
1149         $members =~ s/\s*____cacheline_aligned/ /gos;
1150         # unwrap struct_group():
1151         # - first eat non-declaration parameters and rewrite for final match
1152         # - then remove macro, outer parens, and trailing semicolon
1153         $members =~ s/\bstruct_group\s*\(([^,]*,)/STRUCT_GROUP(/gos;
1154         $members =~ s/\bstruct_group_(attr|tagged)\s*\(([^,]*,){2}/STRUCT_GROUP(/gos;
1155         $members =~ s/\b__struct_group\s*\(([^,]*,){3}/STRUCT_GROUP(/gos;
1156         $members =~ s/\bSTRUCT_GROUP(\(((?:(?>[^)(]+)|(?1))*)\))[^;]*;/$2/gos;
1157
1158         my $args = qr{([^,)]+)};
1159         # replace DECLARE_BITMAP
1160         $members =~ s/__ETHTOOL_DECLARE_LINK_MODE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, __ETHTOOL_LINK_MODE_MASK_NBITS)/gos;
1161         $members =~ s/DECLARE_PHY_INTERFACE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, PHY_INTERFACE_MODE_MAX)/gos;
1162         $members =~ s/DECLARE_BITMAP\s*\($args,\s*$args\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1163         # replace DECLARE_HASHTABLE
1164         $members =~ s/DECLARE_HASHTABLE\s*\($args,\s*$args\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1165         # replace DECLARE_KFIFO
1166         $members =~ s/DECLARE_KFIFO\s*\($args,\s*$args,\s*$args\)/$2 \*$1/gos;
1167         # replace DECLARE_KFIFO_PTR
1168         $members =~ s/DECLARE_KFIFO_PTR\s*\($args,\s*$args\)/$2 \*$1/gos;
1169         # replace DECLARE_FLEX_ARRAY
1170         $members =~ s/(?:__)?DECLARE_FLEX_ARRAY\s*\($args,\s*$args\)/$1 $2\[\]/gos;
1171         #replace DEFINE_DMA_UNMAP_ADDR
1172         $members =~ s/DEFINE_DMA_UNMAP_ADDR\s*\($args\)/dma_addr_t $1/gos;
1173         #replace DEFINE_DMA_UNMAP_LEN
1174         $members =~ s/DEFINE_DMA_UNMAP_LEN\s*\($args\)/__u32 $1/gos;
1175         my $declaration = $members;
1176
1177         # Split nested struct/union elements as newer ones
1178         while ($members =~ m/$struct_members/) {
1179                 my $newmember;
1180                 my $maintype = $1;
1181                 my $ids = $4;
1182                 my $content = $3;
1183                 foreach my $id(split /,/, $ids) {
1184                         $newmember .= "$maintype $id; ";
1185
1186                         $id =~ s/[:\[].*//;
1187                         $id =~ s/^\s*\**(\S+)\s*/$1/;
1188                         foreach my $arg (split /;/, $content) {
1189                                 next if ($arg =~ m/^\s*$/);
1190                                 if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1191                                         # pointer-to-function
1192                                         my $type = $1;
1193                                         my $name = $2;
1194                                         my $extra = $3;
1195                                         next if (!$name);
1196                                         if ($id =~ m/^\s*$/) {
1197                                                 # anonymous struct/union
1198                                                 $newmember .= "$type$name$extra; ";
1199                                         } else {
1200                                                 $newmember .= "$type$id.$name$extra; ";
1201                                         }
1202                                 } else {
1203                                         my $type;
1204                                         my $names;
1205                                         $arg =~ s/^\s+//;
1206                                         $arg =~ s/\s+$//;
1207                                         # Handle bitmaps
1208                                         $arg =~ s/:\s*\d+\s*//g;
1209                                         # Handle arrays
1210                                         $arg =~ s/\[.*\]//g;
1211                                         # The type may have multiple words,
1212                                         # and multiple IDs can be defined, like:
1213                                         #       const struct foo, *bar, foobar
1214                                         # So, we remove spaces when parsing the
1215                                         # names, in order to match just names
1216                                         # and commas for the names
1217                                         $arg =~ s/\s*,\s*/,/g;
1218                                         if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1219                                                 $type = $1;
1220                                                 $names = $2;
1221                                         } else {
1222                                                 $newmember .= "$arg; ";
1223                                                 next;
1224                                         }
1225                                         foreach my $name (split /,/, $names) {
1226                                                 $name =~ s/^\s*\**(\S+)\s*/$1/;
1227                                                 next if (($name =~ m/^\s*$/));
1228                                                 if ($id =~ m/^\s*$/) {
1229                                                         # anonymous struct/union
1230                                                         $newmember .= "$type $name; ";
1231                                                 } else {
1232                                                         $newmember .= "$type $id.$name; ";
1233                                                 }
1234                                         }
1235                                 }
1236                         }
1237                 }
1238                 $members =~ s/$struct_members/$newmember/;
1239         }
1240
1241         # Ignore other nested elements, like enums
1242         $members =~ s/(\{[^\{\}]*\})//g;
1243
1244         create_parameterlist($members, ';', $file, $declaration_name);
1245         check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1246
1247         # Adjust declaration for better display
1248         $declaration =~ s/([\{;])/$1\n/g;
1249         $declaration =~ s/\}\s+;/};/g;
1250         # Better handle inlined enums
1251         do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1252
1253         my @def_args = split /\n/, $declaration;
1254         my $level = 1;
1255         $declaration = "";
1256         foreach my $clause (@def_args) {
1257                 $clause =~ s/^\s+//;
1258                 $clause =~ s/\s+$//;
1259                 $clause =~ s/\s+/ /;
1260                 next if (!$clause);
1261                 $level-- if ($clause =~ m/(\})/ && $level > 1);
1262                 if (!($clause =~ m/^\s*#/)) {
1263                         $declaration .= "\t" x $level;
1264                 }
1265                 $declaration .= "\t" . $clause . "\n";
1266                 $level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1267         }
1268         output_declaration($declaration_name,
1269                            'struct',
1270                            {'struct' => $declaration_name,
1271                             'module' => $modulename,
1272                             'definition' => $declaration,
1273                             'parameterlist' => \@parameterlist,
1274                             'parameterdescs' => \%parameterdescs,
1275                             'parametertypes' => \%parametertypes,
1276                             'sectionlist' => \@sectionlist,
1277                             'sections' => \%sections,
1278                             'purpose' => $declaration_purpose,
1279                             'type' => $decl_type
1280                            });
1281     }
1282     else {
1283         print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1284         ++$errors;
1285     }
1286 }
1287
1288
1289 sub show_warnings($$) {
1290         my $functype = shift;
1291         my $name = shift;
1292
1293         return 0 if (defined($nosymbol_table{$name}));
1294
1295         return 1 if ($output_selection == OUTPUT_ALL);
1296
1297         if ($output_selection == OUTPUT_EXPORTED) {
1298                 if (defined($function_table{$name})) {
1299                         return 1;
1300                 } else {
1301                         return 0;
1302                 }
1303         }
1304         if ($output_selection == OUTPUT_INTERNAL) {
1305                 if (!($functype eq "function" && defined($function_table{$name}))) {
1306                         return 1;
1307                 } else {
1308                         return 0;
1309                 }
1310         }
1311         if ($output_selection == OUTPUT_INCLUDE) {
1312                 if (defined($function_table{$name})) {
1313                         return 1;
1314                 } else {
1315                         return 0;
1316                 }
1317         }
1318         die("Please add the new output type at show_warnings()");
1319 }
1320
1321 sub dump_enum($$) {
1322     my $x = shift;
1323     my $file = shift;
1324     my $members;
1325
1326     # ignore members marked private:
1327     $x =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1328     $x =~ s/\/\*\s*private:.*}/}/gosi;
1329
1330     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1331     # strip #define macros inside enums
1332     $x =~ s@#\s*((define|ifdef)\s+|endif)[^;]*;@@gos;
1333
1334     if ($x =~ /typedef\s+enum\s*\{(.*)\}\s*(\w*)\s*;/) {
1335         $declaration_name = $2;
1336         $members = $1;
1337     } elsif ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1338         $declaration_name = $1;
1339         $members = $2;
1340     }
1341
1342     if ($members) {
1343         if ($identifier ne $declaration_name) {
1344             if ($identifier eq "") {
1345                 emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n");
1346             } else {
1347                 emit_warning("${file}:$.", "expecting prototype for enum $identifier. Prototype was for enum $declaration_name instead\n");
1348             }
1349             return;
1350         }
1351         $declaration_name = "(anonymous)" if ($declaration_name eq "");
1352
1353         my %_members;
1354
1355         $members =~ s/\s+$//;
1356
1357         foreach my $arg (split ',', $members) {
1358             $arg =~ s/^\s*(\w+).*/$1/;
1359             push @parameterlist, $arg;
1360             if (!$parameterdescs{$arg}) {
1361                 $parameterdescs{$arg} = $undescribed;
1362                 if (show_warnings("enum", $declaration_name)) {
1363                         emit_warning("${file}:$.", "Enum value '$arg' not described in enum '$declaration_name'\n");
1364                 }
1365             }
1366             $_members{$arg} = 1;
1367         }
1368
1369         while (my ($k, $v) = each %parameterdescs) {
1370             if (!exists($_members{$k})) {
1371                 if (show_warnings("enum", $declaration_name)) {
1372                      emit_warning("${file}:$.", "Excess enum value '$k' description in '$declaration_name'\n");
1373                 }
1374             }
1375         }
1376
1377         output_declaration($declaration_name,
1378                            'enum',
1379                            {'enum' => $declaration_name,
1380                             'module' => $modulename,
1381                             'parameterlist' => \@parameterlist,
1382                             'parameterdescs' => \%parameterdescs,
1383                             'sectionlist' => \@sectionlist,
1384                             'sections' => \%sections,
1385                             'purpose' => $declaration_purpose
1386                            });
1387     } else {
1388         print STDERR "${file}:$.: error: Cannot parse enum!\n";
1389         ++$errors;
1390     }
1391 }
1392
1393 my $typedef_type = qr { ((?:\s+[\w\*]+\b){1,8})\s* }x;
1394 my $typedef_ident = qr { \*?\s*(\w\S+)\s* }x;
1395 my $typedef_args = qr { \s*\((.*)\); }x;
1396
1397 my $typedef1 = qr { typedef$typedef_type\($typedef_ident\)$typedef_args }x;
1398 my $typedef2 = qr { typedef$typedef_type$typedef_ident$typedef_args }x;
1399
1400 sub dump_typedef($$) {
1401     my $x = shift;
1402     my $file = shift;
1403
1404     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1405
1406     # Parse function typedef prototypes
1407     if ($x =~ $typedef1 || $x =~ $typedef2) {
1408         $return_type = $1;
1409         $declaration_name = $2;
1410         my $args = $3;
1411         $return_type =~ s/^\s+//;
1412
1413         if ($identifier ne $declaration_name) {
1414             emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1415             return;
1416         }
1417
1418         create_parameterlist($args, ',', $file, $declaration_name);
1419
1420         output_declaration($declaration_name,
1421                            'function',
1422                            {'function' => $declaration_name,
1423                             'typedef' => 1,
1424                             'module' => $modulename,
1425                             'functiontype' => $return_type,
1426                             'parameterlist' => \@parameterlist,
1427                             'parameterdescs' => \%parameterdescs,
1428                             'parametertypes' => \%parametertypes,
1429                             'sectionlist' => \@sectionlist,
1430                             'sections' => \%sections,
1431                             'purpose' => $declaration_purpose
1432                            });
1433         return;
1434     }
1435
1436     while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1437         $x =~ s/\(*.\)\s*;$/;/;
1438         $x =~ s/\[*.\]\s*;$/;/;
1439     }
1440
1441     if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1442         $declaration_name = $1;
1443
1444         if ($identifier ne $declaration_name) {
1445             emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1446             return;
1447         }
1448
1449         output_declaration($declaration_name,
1450                            'typedef',
1451                            {'typedef' => $declaration_name,
1452                             'module' => $modulename,
1453                             'sectionlist' => \@sectionlist,
1454                             'sections' => \%sections,
1455                             'purpose' => $declaration_purpose
1456                            });
1457     }
1458     else {
1459         print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1460         ++$errors;
1461     }
1462 }
1463
1464 sub save_struct_actual($) {
1465     my $actual = shift;
1466
1467     # strip all spaces from the actual param so that it looks like one string item
1468     $actual =~ s/\s*//g;
1469     $struct_actual = $struct_actual . $actual . " ";
1470 }
1471
1472 sub create_parameterlist($$$$) {
1473     my $args = shift;
1474     my $splitter = shift;
1475     my $file = shift;
1476     my $declaration_name = shift;
1477     my $type;
1478     my $param;
1479
1480     # temporarily replace commas inside function pointer definition
1481     my $arg_expr = qr{\([^\),]+};
1482     while ($args =~ /$arg_expr,/) {
1483         $args =~ s/($arg_expr),/$1#/g;
1484     }
1485
1486     foreach my $arg (split($splitter, $args)) {
1487         # strip comments
1488         $arg =~ s/\/\*.*\*\///;
1489         # ignore argument attributes
1490         $arg =~ s/\sPOS0?\s/ /;
1491         # strip leading/trailing spaces
1492         $arg =~ s/^\s*//;
1493         $arg =~ s/\s*$//;
1494         $arg =~ s/\s+/ /;
1495
1496         if ($arg =~ /^#/) {
1497             # Treat preprocessor directive as a typeless variable just to fill
1498             # corresponding data structures "correctly". Catch it later in
1499             # output_* subs.
1500             push_parameter($arg, "", "", $file);
1501         } elsif ($arg =~ m/\(.+\)\s*\(/) {
1502             # pointer-to-function
1503             $arg =~ tr/#/,/;
1504             $arg =~ m/[^\(]+\(\*?\s*([\w\[\]\.]*)\s*\)/;
1505             $param = $1;
1506             $type = $arg;
1507             $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1508             save_struct_actual($param);
1509             push_parameter($param, $type, $arg, $file, $declaration_name);
1510         } elsif ($arg) {
1511             $arg =~ s/\s*:\s*/:/g;
1512             $arg =~ s/\s*\[/\[/g;
1513
1514             my @args = split('\s*,\s*', $arg);
1515             if ($args[0] =~ m/\*/) {
1516                 $args[0] =~ s/(\*+)\s*/ $1/;
1517             }
1518
1519             my @first_arg;
1520             if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1521                     shift @args;
1522                     push(@first_arg, split('\s+', $1));
1523                     push(@first_arg, $2);
1524             } else {
1525                     @first_arg = split('\s+', shift @args);
1526             }
1527
1528             unshift(@args, pop @first_arg);
1529             $type = join " ", @first_arg;
1530
1531             foreach $param (@args) {
1532                 if ($param =~ m/^(\*+)\s*(.*)/) {
1533                     save_struct_actual($2);
1534
1535                     push_parameter($2, "$type $1", $arg, $file, $declaration_name);
1536                 }
1537                 elsif ($param =~ m/(.*?):(\d+)/) {
1538                     if ($type ne "") { # skip unnamed bit-fields
1539                         save_struct_actual($1);
1540                         push_parameter($1, "$type:$2", $arg, $file, $declaration_name)
1541                     }
1542                 }
1543                 else {
1544                     save_struct_actual($param);
1545                     push_parameter($param, $type, $arg, $file, $declaration_name);
1546                 }
1547             }
1548         }
1549     }
1550 }
1551
1552 sub push_parameter($$$$$) {
1553         my $param = shift;
1554         my $type = shift;
1555         my $org_arg = shift;
1556         my $file = shift;
1557         my $declaration_name = shift;
1558
1559         if (($anon_struct_union == 1) && ($type eq "") &&
1560             ($param eq "}")) {
1561                 return;         # ignore the ending }; from anon. struct/union
1562         }
1563
1564         $anon_struct_union = 0;
1565         $param =~ s/[\[\)].*//;
1566
1567         if ($type eq "" && $param =~ /\.\.\.$/)
1568         {
1569             if (!$param =~ /\w\.\.\.$/) {
1570               # handles unnamed variable parameters
1571               $param = "...";
1572             }
1573             elsif ($param =~ /\w\.\.\.$/) {
1574               # for named variable parameters of the form `x...`, remove the dots
1575               $param =~ s/\.\.\.$//;
1576             }
1577             if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1578                 $parameterdescs{$param} = "variable arguments";
1579             }
1580         }
1581         elsif ($type eq "" && ($param eq "" or $param eq "void"))
1582         {
1583             $param="void";
1584             $parameterdescs{void} = "no arguments";
1585         }
1586         elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1587         # handle unnamed (anonymous) union or struct:
1588         {
1589                 $type = $param;
1590                 $param = "{unnamed_" . $param . "}";
1591                 $parameterdescs{$param} = "anonymous\n";
1592                 $anon_struct_union = 1;
1593         }
1594
1595         # warn if parameter has no description
1596         # (but ignore ones starting with # as these are not parameters
1597         # but inline preprocessor statements);
1598         # Note: It will also ignore void params and unnamed structs/unions
1599         if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1600                 $parameterdescs{$param} = $undescribed;
1601
1602                 if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1603                         emit_warning("${file}:$.", "Function parameter or member '$param' not described in '$declaration_name'\n");
1604                 }
1605         }
1606
1607         # strip spaces from $param so that it is one continuous string
1608         # on @parameterlist;
1609         # this fixes a problem where check_sections() cannot find
1610         # a parameter like "addr[6 + 2]" because it actually appears
1611         # as "addr[6", "+", "2]" on the parameter list;
1612         # but it's better to maintain the param string unchanged for output,
1613         # so just weaken the string compare in check_sections() to ignore
1614         # "[blah" in a parameter string;
1615         ###$param =~ s/\s*//g;
1616         push @parameterlist, $param;
1617         $org_arg =~ s/\s\s+/ /g;
1618         $parametertypes{$param} = $org_arg;
1619 }
1620
1621 sub check_sections($$$$$) {
1622         my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1623         my @sects = split ' ', $sectcheck;
1624         my @prms = split ' ', $prmscheck;
1625         my $err;
1626         my ($px, $sx);
1627         my $prm_clean;          # strip trailing "[array size]" and/or beginning "*"
1628
1629         foreach $sx (0 .. $#sects) {
1630                 $err = 1;
1631                 foreach $px (0 .. $#prms) {
1632                         $prm_clean = $prms[$px];
1633                         $prm_clean =~ s/\[.*\]//;
1634                         $prm_clean =~ s/$attribute//i;
1635                         # ignore array size in a parameter string;
1636                         # however, the original param string may contain
1637                         # spaces, e.g.:  addr[6 + 2]
1638                         # and this appears in @prms as "addr[6" since the
1639                         # parameter list is split at spaces;
1640                         # hence just ignore "[..." for the sections check;
1641                         $prm_clean =~ s/\[.*//;
1642
1643                         ##$prm_clean =~ s/^\**//;
1644                         if ($prm_clean eq $sects[$sx]) {
1645                                 $err = 0;
1646                                 last;
1647                         }
1648                 }
1649                 if ($err) {
1650                         if ($decl_type eq "function") {
1651                                 emit_warning("${file}:$.",
1652                                         "Excess function parameter " .
1653                                         "'$sects[$sx]' " .
1654                                         "description in '$decl_name'\n");
1655                         }
1656                 }
1657         }
1658 }
1659
1660 ##
1661 # Checks the section describing the return value of a function.
1662 sub check_return_section {
1663         my $file = shift;
1664         my $declaration_name = shift;
1665         my $return_type = shift;
1666
1667         # Ignore an empty return type (It's a macro)
1668         # Ignore functions with a "void" return type. (But don't ignore "void *")
1669         if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1670                 return;
1671         }
1672
1673         if (!defined($sections{$section_return}) ||
1674             $sections{$section_return} eq "") {
1675                 emit_warning("${file}:$.",
1676                         "No description found for return value of " .
1677                         "'$declaration_name'\n");
1678         }
1679 }
1680
1681 ##
1682 # takes a function prototype and the name of the current file being
1683 # processed and spits out all the details stored in the global
1684 # arrays/hashes.
1685 sub dump_function($$) {
1686     my $prototype = shift;
1687     my $file = shift;
1688     my $noret = 0;
1689
1690     print_lineno($new_start_line);
1691
1692     $prototype =~ s/^static +//;
1693     $prototype =~ s/^extern +//;
1694     $prototype =~ s/^asmlinkage +//;
1695     $prototype =~ s/^inline +//;
1696     $prototype =~ s/^__inline__ +//;
1697     $prototype =~ s/^__inline +//;
1698     $prototype =~ s/^__always_inline +//;
1699     $prototype =~ s/^noinline +//;
1700     $prototype =~ s/^__FORTIFY_INLINE +//;
1701     $prototype =~ s/__init +//;
1702     $prototype =~ s/__init_or_module +//;
1703     $prototype =~ s/__deprecated +//;
1704     $prototype =~ s/__flatten +//;
1705     $prototype =~ s/__meminit +//;
1706     $prototype =~ s/__must_check +//;
1707     $prototype =~ s/__weak +//;
1708     $prototype =~ s/__sched +//;
1709     $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1710     $prototype =~ s/__(?:re)?alloc_size\s*\(\s*\d+\s*(?:,\s*\d+\s*)?\) +//;
1711     $prototype =~ s/__diagnose_as\s*\(\s*\S+\s*(?:,\s*\d+\s*)*\) +//;
1712     my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1713     $prototype =~ s/__attribute_const__ +//;
1714     $prototype =~ s/__attribute__\s*\(\(
1715             (?:
1716                  [\w\s]++          # attribute name
1717                  (?:\([^)]*+\))?   # attribute arguments
1718                  \s*+,?            # optional comma at the end
1719             )+
1720           \)\)\s+//x;
1721
1722     # Yes, this truly is vile.  We are looking for:
1723     # 1. Return type (may be nothing if we're looking at a macro)
1724     # 2. Function name
1725     # 3. Function parameters.
1726     #
1727     # All the while we have to watch out for function pointer parameters
1728     # (which IIRC is what the two sections are for), C types (these
1729     # regexps don't even start to express all the possibilities), and
1730     # so on.
1731     #
1732     # If you mess with these regexps, it's a good idea to check that
1733     # the following functions' documentation still comes out right:
1734     # - parport_register_device (function pointer parameters)
1735     # - atomic_set (macro)
1736     # - pci_match_device, __copy_to_user (long return type)
1737     my $name = qr{[a-zA-Z0-9_~:]+};
1738     my $prototype_end1 = qr{[^\(]*};
1739     my $prototype_end2 = qr{[^\{]*};
1740     my $prototype_end = qr{\(($prototype_end1|$prototype_end2)\)};
1741     my $type1 = qr{[\w\s]+};
1742     my $type2 = qr{$type1\*+};
1743
1744     if ($define && $prototype =~ m/^()($name)\s+/) {
1745         # This is an object-like macro, it has no return type and no parameter
1746         # list.
1747         # Function-like macros are not allowed to have spaces between
1748         # declaration_name and opening parenthesis (notice the \s+).
1749         $return_type = $1;
1750         $declaration_name = $2;
1751         $noret = 1;
1752     } elsif ($prototype =~ m/^()($name)\s*$prototype_end/ ||
1753         $prototype =~ m/^($type1)\s+($name)\s*$prototype_end/ ||
1754         $prototype =~ m/^($type2+)\s*($name)\s*$prototype_end/)  {
1755         $return_type = $1;
1756         $declaration_name = $2;
1757         my $args = $3;
1758
1759         create_parameterlist($args, ',', $file, $declaration_name);
1760     } else {
1761         emit_warning("${file}:$.", "cannot understand function prototype: '$prototype'\n");
1762         return;
1763     }
1764
1765     if ($identifier ne $declaration_name) {
1766         emit_warning("${file}:$.", "expecting prototype for $identifier(). Prototype was for $declaration_name() instead\n");
1767         return;
1768     }
1769
1770     my $prms = join " ", @parameterlist;
1771     check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1772
1773     # This check emits a lot of warnings at the moment, because many
1774     # functions don't have a 'Return' doc section. So until the number
1775     # of warnings goes sufficiently down, the check is only performed in
1776     # -Wreturn mode.
1777     # TODO: always perform the check.
1778     if ($Wreturn && !$noret) {
1779             check_return_section($file, $declaration_name, $return_type);
1780     }
1781
1782     # The function parser can be called with a typedef parameter.
1783     # Handle it.
1784     if ($return_type =~ /typedef/) {
1785         output_declaration($declaration_name,
1786                            'function',
1787                            {'function' => $declaration_name,
1788                             'typedef' => 1,
1789                             'module' => $modulename,
1790                             'functiontype' => $return_type,
1791                             'parameterlist' => \@parameterlist,
1792                             'parameterdescs' => \%parameterdescs,
1793                             'parametertypes' => \%parametertypes,
1794                             'sectionlist' => \@sectionlist,
1795                             'sections' => \%sections,
1796                             'purpose' => $declaration_purpose
1797                            });
1798     } else {
1799         output_declaration($declaration_name,
1800                            'function',
1801                            {'function' => $declaration_name,
1802                             'module' => $modulename,
1803                             'functiontype' => $return_type,
1804                             'parameterlist' => \@parameterlist,
1805                             'parameterdescs' => \%parameterdescs,
1806                             'parametertypes' => \%parametertypes,
1807                             'sectionlist' => \@sectionlist,
1808                             'sections' => \%sections,
1809                             'purpose' => $declaration_purpose
1810                            });
1811     }
1812 }
1813
1814 sub reset_state {
1815     $function = "";
1816     %parameterdescs = ();
1817     %parametertypes = ();
1818     @parameterlist = ();
1819     %sections = ();
1820     @sectionlist = ();
1821     $sectcheck = "";
1822     $struct_actual = "";
1823     $prototype = "";
1824
1825     $state = STATE_NORMAL;
1826     $inline_doc_state = STATE_INLINE_NA;
1827 }
1828
1829 sub tracepoint_munge($) {
1830         my $file = shift;
1831         my $tracepointname = 0;
1832         my $tracepointargs = 0;
1833
1834         if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1835                 $tracepointname = $1;
1836         }
1837         if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1838                 $tracepointname = $1;
1839         }
1840         if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1841                 $tracepointname = $2;
1842         }
1843         $tracepointname =~ s/^\s+//; #strip leading whitespace
1844         if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1845                 $tracepointargs = $1;
1846         }
1847         if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1848                 emit_warning("${file}:$.", "Unrecognized tracepoint format: \n".
1849                              "$prototype\n");
1850         } else {
1851                 $prototype = "static inline void trace_$tracepointname($tracepointargs)";
1852                 $identifier = "trace_$identifier";
1853         }
1854 }
1855
1856 sub syscall_munge() {
1857         my $void = 0;
1858
1859         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1860 ##      if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1861         if ($prototype =~ m/SYSCALL_DEFINE0/) {
1862                 $void = 1;
1863 ##              $prototype = "long sys_$1(void)";
1864         }
1865
1866         $prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1867         if ($prototype =~ m/long (sys_.*?),/) {
1868                 $prototype =~ s/,/\(/;
1869         } elsif ($void) {
1870                 $prototype =~ s/\)/\(void\)/;
1871         }
1872
1873         # now delete all of the odd-number commas in $prototype
1874         # so that arg types & arg names don't have a comma between them
1875         my $count = 0;
1876         my $len = length($prototype);
1877         if ($void) {
1878                 $len = 0;       # skip the for-loop
1879         }
1880         for (my $ix = 0; $ix < $len; $ix++) {
1881                 if (substr($prototype, $ix, 1) eq ',') {
1882                         $count++;
1883                         if ($count % 2 == 1) {
1884                                 substr($prototype, $ix, 1) = ' ';
1885                         }
1886                 }
1887         }
1888 }
1889
1890 sub process_proto_function($$) {
1891     my $x = shift;
1892     my $file = shift;
1893
1894     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1895
1896     if ($x =~ m#\s*/\*\s+MACDOC\s*#io || ($x =~ /^#/ && $x !~ /^#\s*define/)) {
1897         # do nothing
1898     }
1899     elsif ($x =~ /([^\{]*)/) {
1900         $prototype .= $1;
1901     }
1902
1903     if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1904         $prototype =~ s@/\*.*?\*/@@gos; # strip comments.
1905         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1906         $prototype =~ s@^\s+@@gos; # strip leading spaces
1907
1908          # Handle prototypes for function pointers like:
1909          # int (*pcs_config)(struct foo)
1910         $prototype =~ s@^(\S+\s+)\(\s*\*(\S+)\)@$1$2@gos;
1911
1912         if ($prototype =~ /SYSCALL_DEFINE/) {
1913                 syscall_munge();
1914         }
1915         if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
1916             $prototype =~ /DEFINE_SINGLE_EVENT/)
1917         {
1918                 tracepoint_munge($file);
1919         }
1920         dump_function($prototype, $file);
1921         reset_state();
1922     }
1923 }
1924
1925 sub process_proto_type($$) {
1926     my $x = shift;
1927     my $file = shift;
1928
1929     $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1930     $x =~ s@^\s+@@gos; # strip leading spaces
1931     $x =~ s@\s+$@@gos; # strip trailing spaces
1932     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1933
1934     if ($x =~ /^#/) {
1935         # To distinguish preprocessor directive from regular declaration later.
1936         $x .= ";";
1937     }
1938
1939     while (1) {
1940         if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
1941             if( length $prototype ) {
1942                 $prototype .= " "
1943             }
1944             $prototype .= $1 . $2;
1945             ($2 eq '{') && $brcount++;
1946             ($2 eq '}') && $brcount--;
1947             if (($2 eq ';') && ($brcount == 0)) {
1948                 dump_declaration($prototype, $file);
1949                 reset_state();
1950                 last;
1951             }
1952             $x = $3;
1953         } else {
1954             $prototype .= $x;
1955             last;
1956         }
1957     }
1958 }
1959
1960
1961 sub map_filename($) {
1962     my $file;
1963     my ($orig_file) = @_;
1964
1965     if (defined($ENV{'SRCTREE'})) {
1966         $file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
1967     } else {
1968         $file = $orig_file;
1969     }
1970
1971     if (defined($source_map{$file})) {
1972         $file = $source_map{$file};
1973     }
1974
1975     return $file;
1976 }
1977
1978 sub process_export_file($) {
1979     my ($orig_file) = @_;
1980     my $file = map_filename($orig_file);
1981
1982     if (!open(IN,"<$file")) {
1983         print STDERR "Error: Cannot open file $file\n";
1984         ++$errors;
1985         return;
1986     }
1987
1988     while (<IN>) {
1989         if (/$export_symbol/) {
1990             next if (defined($nosymbol_table{$2}));
1991             $function_table{$2} = 1;
1992         }
1993         if (/$export_symbol_ns/) {
1994             next if (defined($nosymbol_table{$2}));
1995             $function_table{$2} = 1;
1996         }
1997     }
1998
1999     close(IN);
2000 }
2001
2002 #
2003 # Parsers for the various processing states.
2004 #
2005 # STATE_NORMAL: looking for the /** to begin everything.
2006 #
2007 sub process_normal() {
2008     if (/$doc_start/o) {
2009         $state = STATE_NAME;    # next line is always the function name
2010         $in_doc_sect = 0;
2011         $declaration_start_line = $. + 1;
2012     }
2013 }
2014
2015 #
2016 # STATE_NAME: Looking for the "name - description" line
2017 #
2018 sub process_name($$) {
2019     my $file = shift;
2020     my $descr;
2021
2022     if (/$doc_block/o) {
2023         $state = STATE_DOCBLOCK;
2024         $contents = "";
2025         $new_start_line = $.;
2026
2027         if ( $1 eq "" ) {
2028             $section = $section_intro;
2029         } else {
2030             $section = $1;
2031         }
2032     } elsif (/$doc_decl/o) {
2033         $identifier = $1;
2034         my $is_kernel_comment = 0;
2035         my $decl_start = qr{$doc_com};
2036         # test for pointer declaration type, foo * bar() - desc
2037         my $fn_type = qr{\w+\s*\*\s*};
2038         my $parenthesis = qr{\(\w*\)};
2039         my $decl_end = qr{[-:].*};
2040         if (/^$decl_start([\w\s]+?)$parenthesis?\s*$decl_end?$/) {
2041             $identifier = $1;
2042         }
2043         if ($identifier =~ m/^(struct|union|enum|typedef)\b\s*(\S*)/) {
2044             $decl_type = $1;
2045             $identifier = $2;
2046             $is_kernel_comment = 1;
2047         }
2048         # Look for foo() or static void foo() - description; or misspelt
2049         # identifier
2050         elsif (/^$decl_start$fn_type?(\w+)\s*$parenthesis?\s*$decl_end?$/ ||
2051             /^$decl_start$fn_type?(\w+.*)$parenthesis?\s*$decl_end$/) {
2052             $identifier = $1;
2053             $decl_type = 'function';
2054             $identifier =~ s/^define\s+//;
2055             $is_kernel_comment = 1;
2056         }
2057         $identifier =~ s/\s+$//;
2058
2059         $state = STATE_BODY;
2060         # if there's no @param blocks need to set up default section
2061         # here
2062         $contents = "";
2063         $section = $section_default;
2064         $new_start_line = $. + 1;
2065         if (/[-:](.*)/) {
2066             # strip leading/trailing/multiple spaces
2067             $descr= $1;
2068             $descr =~ s/^\s*//;
2069             $descr =~ s/\s*$//;
2070             $descr =~ s/\s+/ /g;
2071             $declaration_purpose = $descr;
2072             $state = STATE_BODY_MAYBE;
2073         } else {
2074             $declaration_purpose = "";
2075         }
2076
2077         if (!$is_kernel_comment) {
2078             emit_warning("${file}:$.", "This comment starts with '/**', but isn't a kernel-doc comment. Refer Documentation/doc-guide/kernel-doc.rst\n$_");
2079             $state = STATE_NORMAL;
2080         }
2081
2082         if (($declaration_purpose eq "") && $Wshort_desc) {
2083             emit_warning("${file}:$.", "missing initial short description on line:\n$_");
2084         }
2085
2086         if ($identifier eq "" && $decl_type ne "enum") {
2087             emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n$_");
2088             $state = STATE_NORMAL;
2089         }
2090
2091         if ($verbose) {
2092             print STDERR "${file}:$.: info: Scanning doc for $decl_type $identifier\n";
2093         }
2094     } else {
2095         emit_warning("${file}:$.", "Cannot understand $_ on line $. - I thought it was a doc line\n");
2096         $state = STATE_NORMAL;
2097     }
2098 }
2099
2100
2101 #
2102 # STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
2103 #
2104 sub process_body($$) {
2105     my $file = shift;
2106
2107     if ($state == STATE_BODY_WITH_BLANK_LINE && /^\s*\*\s?\S/) {
2108         dump_section($file, $section, $contents);
2109         $section = $section_default;
2110         $new_start_line = $.;
2111         $contents = "";
2112     }
2113
2114     if (/$doc_sect/i) { # case insensitive for supported section names
2115         $newsection = $1;
2116         $newcontents = $2;
2117
2118         # map the supported section names to the canonical names
2119         if ($newsection =~ m/^description$/i) {
2120             $newsection = $section_default;
2121         } elsif ($newsection =~ m/^context$/i) {
2122             $newsection = $section_context;
2123         } elsif ($newsection =~ m/^returns?$/i) {
2124             $newsection = $section_return;
2125         } elsif ($newsection =~ m/^\@return$/) {
2126             # special: @return is a section, not a param description
2127             $newsection = $section_return;
2128         }
2129
2130         if (($contents ne "") && ($contents ne "\n")) {
2131             if (!$in_doc_sect && $Wcontents_before_sections) {
2132                 emit_warning("${file}:$.", "contents before sections\n");
2133             }
2134             dump_section($file, $section, $contents);
2135             $section = $section_default;
2136         }
2137
2138         $in_doc_sect = 1;
2139         $state = STATE_BODY;
2140         $contents = $newcontents;
2141         $new_start_line = $.;
2142         while (substr($contents, 0, 1) eq " ") {
2143             $contents = substr($contents, 1);
2144         }
2145         if ($contents ne "") {
2146             $contents .= "\n";
2147         }
2148         $section = $newsection;
2149         $leading_space = undef;
2150     } elsif (/$doc_end/) {
2151         if (($contents ne "") && ($contents ne "\n")) {
2152             dump_section($file, $section, $contents);
2153             $section = $section_default;
2154             $contents = "";
2155         }
2156         # look for doc_com + <text> + doc_end:
2157         if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
2158             emit_warning("${file}:$.", "suspicious ending line: $_");
2159         }
2160
2161         $prototype = "";
2162         $state = STATE_PROTO;
2163         $brcount = 0;
2164         $new_start_line = $. + 1;
2165     } elsif (/$doc_content/) {
2166         if ($1 eq "") {
2167             if ($section eq $section_context) {
2168                 dump_section($file, $section, $contents);
2169                 $section = $section_default;
2170                 $contents = "";
2171                 $new_start_line = $.;
2172                 $state = STATE_BODY;
2173             } else {
2174                 if ($section ne $section_default) {
2175                     $state = STATE_BODY_WITH_BLANK_LINE;
2176                 } else {
2177                     $state = STATE_BODY;
2178                 }
2179                 $contents .= "\n";
2180             }
2181         } elsif ($state == STATE_BODY_MAYBE) {
2182             # Continued declaration purpose
2183             chomp($declaration_purpose);
2184             $declaration_purpose .= " " . $1;
2185             $declaration_purpose =~ s/\s+/ /g;
2186         } else {
2187             my $cont = $1;
2188             if ($section =~ m/^@/ || $section eq $section_context) {
2189                 if (!defined $leading_space) {
2190                     if ($cont =~ m/^(\s+)/) {
2191                         $leading_space = $1;
2192                     } else {
2193                         $leading_space = "";
2194                     }
2195                 }
2196                 $cont =~ s/^$leading_space//;
2197             }
2198             $contents .= $cont . "\n";
2199         }
2200     } else {
2201         # i dont know - bad line?  ignore.
2202         emit_warning("${file}:$.", "bad line: $_");
2203     }
2204 }
2205
2206
2207 #
2208 # STATE_PROTO: reading a function/whatever prototype.
2209 #
2210 sub process_proto($$) {
2211     my $file = shift;
2212
2213     if (/$doc_inline_oneline/) {
2214         $section = $1;
2215         $contents = $2;
2216         if ($contents ne "") {
2217             $contents .= "\n";
2218             dump_section($file, $section, $contents);
2219             $section = $section_default;
2220             $contents = "";
2221         }
2222     } elsif (/$doc_inline_start/) {
2223         $state = STATE_INLINE;
2224         $inline_doc_state = STATE_INLINE_NAME;
2225     } elsif ($decl_type eq 'function') {
2226         process_proto_function($_, $file);
2227     } else {
2228         process_proto_type($_, $file);
2229     }
2230 }
2231
2232 #
2233 # STATE_DOCBLOCK: within a DOC: block.
2234 #
2235 sub process_docblock($$) {
2236     my $file = shift;
2237
2238     if (/$doc_end/) {
2239         dump_doc_section($file, $section, $contents);
2240         $section = $section_default;
2241         $contents = "";
2242         $function = "";
2243         %parameterdescs = ();
2244         %parametertypes = ();
2245         @parameterlist = ();
2246         %sections = ();
2247         @sectionlist = ();
2248         $prototype = "";
2249         $state = STATE_NORMAL;
2250     } elsif (/$doc_content/) {
2251         if ( $1 eq "" ) {
2252             $contents .= $blankline;
2253         } else {
2254             $contents .= $1 . "\n";
2255         }
2256     }
2257 }
2258
2259 #
2260 # STATE_INLINE: docbook comments within a prototype.
2261 #
2262 sub process_inline($$) {
2263     my $file = shift;
2264
2265     # First line (state 1) needs to be a @parameter
2266     if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2267         $section = $1;
2268         $contents = $2;
2269         $new_start_line = $.;
2270         if ($contents ne "") {
2271             while (substr($contents, 0, 1) eq " ") {
2272                 $contents = substr($contents, 1);
2273             }
2274             $contents .= "\n";
2275         }
2276         $inline_doc_state = STATE_INLINE_TEXT;
2277         # Documentation block end */
2278     } elsif (/$doc_inline_end/) {
2279         if (($contents ne "") && ($contents ne "\n")) {
2280             dump_section($file, $section, $contents);
2281             $section = $section_default;
2282             $contents = "";
2283         }
2284         $state = STATE_PROTO;
2285         $inline_doc_state = STATE_INLINE_NA;
2286         # Regular text
2287     } elsif (/$doc_content/) {
2288         if ($inline_doc_state == STATE_INLINE_TEXT) {
2289             $contents .= $1 . "\n";
2290             # nuke leading blank lines
2291             if ($contents =~ /^\s*$/) {
2292                 $contents = "";
2293             }
2294         } elsif ($inline_doc_state == STATE_INLINE_NAME) {
2295             $inline_doc_state = STATE_INLINE_ERROR;
2296             emit_warning("${file}:$.", "Incorrect use of kernel-doc format: $_");
2297         }
2298     }
2299 }
2300
2301
2302 sub process_file($) {
2303     my $file;
2304     my $initial_section_counter = $section_counter;
2305     my ($orig_file) = @_;
2306
2307     $file = map_filename($orig_file);
2308
2309     if (!open(IN_FILE,"<$file")) {
2310         print STDERR "Error: Cannot open file $file\n";
2311         ++$errors;
2312         return;
2313     }
2314
2315     $. = 1;
2316
2317     $section_counter = 0;
2318     while (<IN_FILE>) {
2319         while (s/\\\s*$//) {
2320             $_ .= <IN_FILE>;
2321         }
2322         # Replace tabs by spaces
2323         while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2324         # Hand this line to the appropriate state handler
2325         if ($state == STATE_NORMAL) {
2326             process_normal();
2327         } elsif ($state == STATE_NAME) {
2328             process_name($file, $_);
2329         } elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE ||
2330                  $state == STATE_BODY_WITH_BLANK_LINE) {
2331             process_body($file, $_);
2332         } elsif ($state == STATE_INLINE) { # scanning for inline parameters
2333             process_inline($file, $_);
2334         } elsif ($state == STATE_PROTO) {
2335             process_proto($file, $_);
2336         } elsif ($state == STATE_DOCBLOCK) {
2337             process_docblock($file, $_);
2338         }
2339     }
2340
2341     # Make sure we got something interesting.
2342     if ($initial_section_counter == $section_counter && $
2343         output_mode ne "none") {
2344         if ($output_selection == OUTPUT_INCLUDE) {
2345             emit_warning("${file}:1", "'$_' not found\n")
2346                 for keys %function_table;
2347         }
2348         else {
2349             emit_warning("${file}:1", "no structured comments found\n");
2350         }
2351     }
2352     close IN_FILE;
2353 }
2354
2355
2356 if ($output_mode eq "rst") {
2357         get_sphinx_version() if (!$sphinx_major);
2358 }
2359
2360 $kernelversion = get_kernel_version();
2361
2362 # generate a sequence of code that will splice in highlighting information
2363 # using the s// operator.
2364 for (my $k = 0; $k < @highlights; $k++) {
2365     my $pattern = $highlights[$k][0];
2366     my $result = $highlights[$k][1];
2367 #   print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2368     $dohighlight .=  "\$contents =~ s:$pattern:$result:gs;\n";
2369 }
2370
2371 # Read the file that maps relative names to absolute names for
2372 # separate source and object directories and for shadow trees.
2373 if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2374         my ($relname, $absname);
2375         while(<SOURCE_MAP>) {
2376                 chop();
2377                 ($relname, $absname) = (split())[0..1];
2378                 $relname =~ s:^/+::;
2379                 $source_map{$relname} = $absname;
2380         }
2381         close(SOURCE_MAP);
2382 }
2383
2384 if ($output_selection == OUTPUT_EXPORTED ||
2385     $output_selection == OUTPUT_INTERNAL) {
2386
2387     push(@export_file_list, @ARGV);
2388
2389     foreach (@export_file_list) {
2390         chomp;
2391         process_export_file($_);
2392     }
2393 }
2394
2395 foreach (@ARGV) {
2396     chomp;
2397     process_file($_);
2398 }
2399 if ($verbose && $errors) {
2400   print STDERR "$errors errors\n";
2401 }
2402 if ($verbose && $warnings) {
2403   print STDERR "$warnings warnings\n";
2404 }
2405
2406 if ($Werror && $warnings) {
2407     print STDERR "$warnings warnings as Errors\n";
2408     exit($warnings);
2409 } else {
2410     exit($output_mode eq "none" ? 0 : $errors)
2411 }
2412
2413 __END__
2414
2415 =head1 OPTIONS
2416
2417 =head2 Output format selection (mutually exclusive):
2418
2419 =over 8
2420
2421 =item -man
2422
2423 Output troff manual page format.
2424
2425 =item -rst
2426
2427 Output reStructuredText format. This is the default.
2428
2429 =item -none
2430
2431 Do not output documentation, only warnings.
2432
2433 =back
2434
2435 =head2 Output format modifiers
2436
2437 =head3 reStructuredText only
2438
2439 =over 8
2440
2441 =item -sphinx-version VERSION
2442
2443 Use the ReST C domain dialect compatible with a specific Sphinx Version.
2444
2445 If not specified, kernel-doc will auto-detect using the sphinx-build version
2446 found on PATH.
2447
2448 =back
2449
2450 =head2 Output selection (mutually exclusive):
2451
2452 =over 8
2453
2454 =item -export
2455
2456 Only output documentation for the symbols that have been exported using
2457 EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2458
2459 =item -internal
2460
2461 Only output documentation for the symbols that have NOT been exported using
2462 EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2463
2464 =item -function NAME
2465
2466 Only output documentation for the given function or DOC: section title.
2467 All other functions and DOC: sections are ignored.
2468
2469 May be specified multiple times.
2470
2471 =item -nosymbol NAME
2472
2473 Exclude the specified symbol from the output documentation.
2474
2475 May be specified multiple times.
2476
2477 =back
2478
2479 =head2 Output selection modifiers:
2480
2481 =over 8
2482
2483 =item -no-doc-sections
2484
2485 Do not output DOC: sections.
2486
2487 =item -export-file FILE
2488
2489 Specify an additional FILE in which to look for EXPORT_SYMBOL information.
2490
2491 To be used with -export or -internal.
2492
2493 May be specified multiple times.
2494
2495 =back
2496
2497 =head3 reStructuredText only
2498
2499 =over 8
2500
2501 =item -enable-lineno
2502
2503 Enable output of .. LINENO lines.
2504
2505 =back
2506
2507 =head2 Other parameters:
2508
2509 =over 8
2510
2511 =item -h, -help
2512
2513 Print this help.
2514
2515 =item -v
2516
2517 Verbose output, more warnings and other information.
2518
2519 =item -Werror
2520
2521 Treat warnings as errors.
2522
2523 =back
2524
2525 =cut