scripts/kernel-doc

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0
   3
   4 use warnings;
   5 use strict;
   6
   7 ## Copyright (c) 1998 Michael Zucchi, All Rights Reserved        ##
   8 ## Copyright (C) 2000, 1  Tim Waugh <twaugh@redhat.com>          ##
   9 ## Copyright (C) 2001  Simon Huggins                             ##
  10 ## Copyright (C) 2005-2012  Randy Dunlap                         ##
  11 ## Copyright (C) 2012  Dan Luedtke                               ##
  12 ##                                                               ##
  13 ## #define enhancements by Armin Kuster <akuster@mvista.com>     ##
  14 ## Copyright (c) 2000 MontaVista Software, Inc.                  ##
  15 #
  16 # Copyright (C) 2022 Tomasz Warniełło (POD)
  17
  18 use Pod::Usage qw/pod2usage/;
  19
  20 =head1 NAME
  21
  22 kernel-doc - Print formatted kernel documentation to stdout
  23
  24 =head1 SYNOPSIS
  25
  26  kernel-doc [-h] [-v] [-Werror] [-Wall] [-Wreturn] [-Wshort-description] [-Wcontents-before-sections]
  27    [ -man |
  28      -rst [-sphinx-version VERSION] [-enable-lineno] |
  29      -none
  30    ]
  31    [
  32      -export |
  33      -internal |
  34      [-function NAME] ... |
  35      [-nosymbol NAME] ...
  36    ]
  37    [-no-doc-sections]
  38    [-export-file FILE] ...
  39    FILE ...
  40
  41 Run `kernel-doc -h` for details.
  42
  43 =head1 DESCRIPTION
  44
  45 Read C language source or header FILEs, extract embedded documentation comments,
  46 and print formatted documentation to standard output.
  47
  48 The documentation comments are identified by the "/**" opening comment mark.
  49
  50 See Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
  51
  52 =cut
  53
  54 # more perldoc at the end of the file
  55
  56 ## init lots of data
  57
  58 my $errors = 0;
  59 my $warnings = 0;
  60 my $anon_struct_union = 0;
  61
  62 # match expressions used to find embedded type information
  63 my $type_constant = '\b``([^\`]+)``\b';
  64 my $type_constant2 = '\%([-_\w]+)';
  65 my $type_func = '(\w+)\(\)';
  66 my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
  67 my $type_param_ref = '([\!~]?)\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
  68 my $type_fp_param = '\@(\w+)\(\)';  # Special RST handling for func ptr params
  69 my $type_fp_param2 = '\@(\w+->\S+)\(\)';  # Special RST handling for structs with func ptr params
  70 my $type_env = '(\$\w+)';
  71 my $type_enum = '\&(enum\s*([_\w]+))';
  72 my $type_struct = '\&(struct\s*([_\w]+))';
  73 my $type_typedef = '\&(typedef\s*([_\w]+))';
  74 my $type_union = '\&(union\s*([_\w]+))';
  75 my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
  76 my $type_fallback = '\&([_\w]+)';
  77 my $type_member_func = $type_member . '\(\)';
  78
  79 # Output conversion substitutions.
  80 #  One for each output format
  81
  82 # these are pretty rough
  83 my @highlights_man = (
  84                       [$type_constant, "\$1"],
  85                       [$type_constant2, "\$1"],
  86                       [$type_func, "\\\\fB\$1\\\\fP"],
  87                       [$type_enum, "\\\\fI\$1\\\\fP"],
  88                       [$type_struct, "\\\\fI\$1\\\\fP"],
  89                       [$type_typedef, "\\\\fI\$1\\\\fP"],
  90                       [$type_union, "\\\\fI\$1\\\\fP"],
  91                       [$type_param, "\\\\fI\$1\\\\fP"],
  92                       [$type_param_ref, "\\\\fI\$1\$2\\\\fP"],
  93                       [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
  94                       [$type_fallback, "\\\\fI\$1\\\\fP"]
  95                      );
  96 my $blankline_man = "";
  97
  98 # rst-mode
  99 my @highlights_rst = (
 100                        [$type_constant, "``\$1``"],
 101                        [$type_constant2, "``\$1``"],
 102                        # Note: need to escape () to avoid func matching later
 103                        [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
 104                        [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
 105                        [$type_fp_param, "**\$1\\\\(\\\\)**"],
 106                        [$type_fp_param2, "**\$1\\\\(\\\\)**"],
 107                        [$type_func, "\$1()"],
 108                        [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
 109                        [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
 110                        [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
 111                        [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
 112                        # in rst this can refer to any type
 113                        [$type_fallback, "\\:c\\:type\\:`\$1`"],
 114                        [$type_param_ref, "**\$1\$2**"]
 115                       );
 116 my $blankline_rst = "\n";
 117
 118 # read arguments
 119 if ($#ARGV == -1) {
 120         pod2usage(
 121                 -message => "No arguments!\n",
 122                 -exitval => 1,
 123                 -verbose => 99,
 124                 -sections => 'SYNOPSIS',
 125                 -output => \*STDERR,
 126         );
 127 }
 128
 129 my $kernelversion;
 130 my ($sphinx_major, $sphinx_minor, $sphinx_patch);
 131
 132 my $dohighlight = "";
 133
 134 my $verbose = 0;
 135 my $Werror = 0;
 136 my $Wreturn = 0;
 137 my $Wshort_desc = 0;
 138 my $Wcontents_before_sections = 0;
 139 my $output_mode = "rst";
 140 my $output_preformatted = 0;
 141 my $no_doc_sections = 0;
 142 my $enable_lineno = 0;
 143 my @highlights = @highlights_rst;
 144 my $blankline = $blankline_rst;
 145 my $modulename = "Kernel API";
 146
 147 use constant {
 148     OUTPUT_ALL          => 0, # output all symbols and doc sections
 149     OUTPUT_INCLUDE      => 1, # output only specified symbols
 150     OUTPUT_EXPORTED     => 2, # output exported symbols
 151     OUTPUT_INTERNAL     => 3, # output non-exported symbols
 152 };
 153 my $output_selection = OUTPUT_ALL;
 154 my $show_not_found = 0; # No longer used
 155
 156 my @export_file_list;
 157
 158 my @build_time;
 159 if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
 160     (my $seconds = `date -d"${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
 161     @build_time = gmtime($seconds);
 162 } else {
 163     @build_time = localtime;
 164 }
 165
 166 my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
 167                 'July', 'August', 'September', 'October',
 168                 'November', 'December')[$build_time[4]] .
 169   " " . ($build_time[5]+1900);
 170
 171 # Essentially these are globals.
 172 # They probably want to be tidied up, made more localised or something.
 173 # CAVEAT EMPTOR!  Some of the others I localised may not want to be, which
 174 # could cause "use of undefined value" or other bugs.
 175 my ($function, %function_table, %parametertypes, $declaration_purpose);
 176 my %nosymbol_table = ();
 177 my $declaration_start_line;
 178 my ($type, $declaration_name, $return_type);
 179 my ($newsection, $newcontents, $prototype, $brcount, %source_map);
 180
 181 if (defined($ENV{'KBUILD_VERBOSE'}) && $ENV{'KBUILD_VERBOSE'} =~ '1') {
 182         $verbose = 1;
 183 }
 184
 185 if (defined($ENV{'KCFLAGS'})) {
 186         my $kcflags = "$ENV{'KCFLAGS'}";
 187
 188         if ($kcflags =~ /Werror/) {
 189                 $Werror = 1;
 190         }
 191 }
 192
 193 # reading this variable is for backwards compat just in case
 194 # someone was calling it with the variable from outside the
 195 # kernel's build system
 196 if (defined($ENV{'KDOC_WERROR'})) {
 197         $Werror = "$ENV{'KDOC_WERROR'}";
 198 }
 199 # other environment variables are converted to command-line
 200 # arguments in cmd_checkdoc in the build system
 201
 202 # Generated docbook code is inserted in a template at a point where
 203 # docbook v3.1 requires a non-zero sequence of RefEntry's; see:
 204 # https://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
 205 # We keep track of number of generated entries and generate a dummy
 206 # if needs be to ensure the expanded template can be postprocessed
 207 # into html.
 208 my $section_counter = 0;
 209
 210 my $lineprefix="";
 211
 212 # Parser states
 213 use constant {
 214     STATE_NORMAL        => 0,        # normal code
 215     STATE_NAME          => 1,        # looking for function name
 216     STATE_BODY_MAYBE    => 2,        # body - or maybe more description
 217     STATE_BODY          => 3,        # the body of the comment
 218     STATE_BODY_WITH_BLANK_LINE => 4, # the body, which has a blank line
 219     STATE_PROTO         => 5,        # scanning prototype
 220     STATE_DOCBLOCK      => 6,        # documentation block
 221     STATE_INLINE        => 7,        # gathering doc outside main block
 222 };
 223 my $state;
 224 my $in_doc_sect;
 225 my $leading_space;
 226
 227 # Inline documentation state
 228 use constant {
 229     STATE_INLINE_NA     => 0, # not applicable ($state != STATE_INLINE)
 230     STATE_INLINE_NAME   => 1, # looking for member name (@foo:)
 231     STATE_INLINE_TEXT   => 2, # looking for member documentation
 232     STATE_INLINE_END    => 3, # done
 233     STATE_INLINE_ERROR  => 4, # error - Comment without header was found.
 234                               # Spit a warning as it's not
 235                               # proper kernel-doc and ignore the rest.
 236 };
 237 my $inline_doc_state;
 238
 239 #declaration types: can be
 240 # 'function', 'struct', 'union', 'enum', 'typedef'
 241 my $decl_type;
 242
 243 # Name of the kernel-doc identifier for non-DOC markups
 244 my $identifier;
 245
 246 my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
 247 my $doc_end = '\*/';
 248 my $doc_com = '\s*\*\s*';
 249 my $doc_com_body = '\s*\* ?';
 250 my $doc_decl = $doc_com . '(\w+)';
 251 # @params and a strictly limited set of supported section names
 252 # Specifically:
 253 #   Match @word:
 254 #         @...:
 255 #         @{section-name}:
 256 # while trying to not match literal block starts like "example::"
 257 #
 258 my $doc_sect = $doc_com .
 259     '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:([^:].*)?$';
 260 my $doc_content = $doc_com_body . '(.*)';
 261 my $doc_block = $doc_com . 'DOC:\s*(.*)?';
 262 my $doc_inline_start = '^\s*/\*\*\s*$';
 263 my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
 264 my $doc_inline_end = '^\s*\*/\s*$';
 265 my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
 266 my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
 267 my $export_symbol_ns = '^\s*EXPORT_SYMBOL_NS(_GPL)?\s*\(\s*(\w+)\s*,\s*\w+\)\s*;';
 268 my $function_pointer = qr{([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)};
 269 my $attribute = qr{__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)}i;
 270
 271 my %parameterdescs;
 272 my %parameterdesc_start_lines;
 273 my @parameterlist;
 274 my %sections;
 275 my @sectionlist;
 276 my %section_start_lines;
 277 my $sectcheck;
 278 my $struct_actual;
 279
 280 my $contents = "";
 281 my $new_start_line = 0;
 282
 283 # the canonical section names. see also $doc_sect above.
 284 my $section_default = "Description";    # default section
 285 my $section_intro = "Introduction";
 286 my $section = $section_default;
 287 my $section_context = "Context";
 288 my $section_return = "Return";
 289
 290 my $undescribed = "-- undescribed --";
 291
 292 reset_state();
 293
 294 while ($ARGV[0] =~ m/^--?(.*)/) {
 295     my $cmd = $1;
 296     shift @ARGV;
 297     if ($cmd eq "man") {
 298         $output_mode = "man";
 299         @highlights = @highlights_man;
 300         $blankline = $blankline_man;
 301     } elsif ($cmd eq "rst") {
 302         $output_mode = "rst";
 303         @highlights = @highlights_rst;
 304         $blankline = $blankline_rst;
 305     } elsif ($cmd eq "none") {
 306         $output_mode = "none";
 307     } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
 308         $modulename = shift @ARGV;
 309     } elsif ($cmd eq "function") { # to only output specific functions
 310         $output_selection = OUTPUT_INCLUDE;
 311         $function = shift @ARGV;
 312         $function_table{$function} = 1;
 313     } elsif ($cmd eq "nosymbol") { # Exclude specific symbols
 314         my $symbol = shift @ARGV;
 315         $nosymbol_table{$symbol} = 1;
 316     } elsif ($cmd eq "export") { # only exported symbols
 317         $output_selection = OUTPUT_EXPORTED;
 318         %function_table = ();
 319     } elsif ($cmd eq "internal") { # only non-exported symbols
 320         $output_selection = OUTPUT_INTERNAL;
 321         %function_table = ();
 322     } elsif ($cmd eq "export-file") {
 323         my $file = shift @ARGV;
 324         push(@export_file_list, $file);
 325     } elsif ($cmd eq "v") {
 326         $verbose = 1;
 327     } elsif ($cmd eq "Werror") {
 328         $Werror = 1;
 329     } elsif ($cmd eq "Wreturn") {
 330         $Wreturn = 1;
 331     } elsif ($cmd eq "Wshort-desc") {
 332         $Wshort_desc = 1;
 333     } elsif ($cmd eq "Wcontents-before-sections") {
 334         $Wcontents_before_sections = 1;
 335     } elsif ($cmd eq "Wall") {
 336         $Wreturn = 1;
 337         $Wshort_desc = 1;
 338         $Wcontents_before_sections = 1;
 339     } elsif (($cmd eq "h") || ($cmd eq "help")) {
 340                 pod2usage(-exitval => 0, -verbose => 2);
 341     } elsif ($cmd eq 'no-doc-sections') {
 342             $no_doc_sections = 1;
 343     } elsif ($cmd eq 'enable-lineno') {
 344             $enable_lineno = 1;
 345     } elsif ($cmd eq 'show-not-found') {
 346         $show_not_found = 1;  # A no-op but don't fail
 347     } elsif ($cmd eq "sphinx-version") {
 348         my $ver_string = shift @ARGV;
 349         if ($ver_string =~ m/^(\d+)(\.\d+)?(\.\d+)?/) {
 350             $sphinx_major = $1;
 351             if (defined($2)) {
 352                 $sphinx_minor = substr($2,1);
 353             } else {
 354                 $sphinx_minor = 0;
 355             }
 356             if (defined($3)) {
 357                 $sphinx_patch = substr($3,1)
 358             } else {
 359                 $sphinx_patch = 0;
 360             }
 361         } else {
 362             die "Sphinx version should either major.minor or major.minor.patch format\n";
 363         }
 364     } else {
 365         # Unknown argument
 366         pod2usage(
 367             -message => "Argument unknown!\n",
 368             -exitval => 1,
 369             -verbose => 99,
 370             -sections => 'SYNOPSIS',
 371             -output => \*STDERR,
 372             );
 373     }
 374     if ($#ARGV < 0){
 375         pod2usage(
 376             -message => "FILE argument missing\n",
 377             -exitval => 1,
 378             -verbose => 99,
 379             -sections => 'SYNOPSIS',
 380             -output => \*STDERR,
 381             );
 382     }
 383 }
 384
 385 # continue execution near EOF;
 386
 387 # The C domain dialect changed on Sphinx 3. So, we need to check the
 388 # version in order to produce the right tags.
 389 sub findprog($)
 390 {
 391         foreach(split(/:/, $ENV{PATH})) {
 392                 return "$_/$_[0]" if(-x "$_/$_[0]");
 393         }
 394 }
 395
 396 sub get_sphinx_version()
 397 {
 398         my $ver;
 399
 400         my $cmd = "sphinx-build";
 401         if (!findprog($cmd)) {
 402                 my $cmd = "sphinx-build3";
 403                 if (!findprog($cmd)) {
 404                         $sphinx_major = 1;
 405                         $sphinx_minor = 2;
 406                         $sphinx_patch = 0;
 407                         printf STDERR "Warning: Sphinx version not found. Using default (Sphinx version %d.%d.%d)\n",
 408                                $sphinx_major, $sphinx_minor, $sphinx_patch;
 409                         return;
 410                 }
 411         }
 412
 413         open IN, "$cmd --version 2>&1 |";
 414         while (<IN>) {
 415                 if (m/^\s*sphinx-build\s+([\d]+)\.([\d\.]+)(\+\/[\da-f]+)?$/) {
 416                         $sphinx_major = $1;
 417                         $sphinx_minor = $2;
 418                         $sphinx_patch = $3;
 419                         last;
 420                 }
 421                 # Sphinx 1.2.x uses a different format
 422                 if (m/^\s*Sphinx.*\s+([\d]+)\.([\d\.]+)$/) {
 423                         $sphinx_major = $1;
 424                         $sphinx_minor = $2;
 425                         $sphinx_patch = $3;
 426                         last;
 427                 }
 428         }
 429         close IN;
 430 }
 431
 432 # get kernel version from env
 433 sub get_kernel_version() {
 434     my $version = 'unknown kernel version';
 435
 436     if (defined($ENV{'KERNELVERSION'})) {
 437         $version = $ENV{'KERNELVERSION'};
 438     }
 439     return $version;
 440 }
 441
 442 #
 443 sub print_lineno {
 444     my $lineno = shift;
 445     if ($enable_lineno && defined($lineno)) {
 446         print ".. LINENO " . $lineno . "\n";
 447     }
 448 }
 449
 450 sub emit_warning {
 451     my $location = shift;
 452     my $msg = shift;
 453     print STDERR "$location: warning: $msg";
 454     ++$warnings;
 455 }
 456 ##
 457 # dumps section contents to arrays/hashes intended for that purpose.
 458 #
 459 sub dump_section {
 460     my $file = shift;
 461     my $name = shift;
 462     my $contents = join "\n", @_;
 463
 464     if ($name =~ m/$type_param/) {
 465         $name = $1;
 466         $parameterdescs{$name} = $contents;
 467         $sectcheck = $sectcheck . $name . " ";
 468         $parameterdesc_start_lines{$name} = $new_start_line;
 469         $new_start_line = 0;
 470     } elsif ($name eq "@\.\.\.") {
 471         $name = "...";
 472         $parameterdescs{$name} = $contents;
 473         $sectcheck = $sectcheck . $name . " ";
 474         $parameterdesc_start_lines{$name} = $new_start_line;
 475         $new_start_line = 0;
 476     } else {
 477         if (defined($sections{$name}) && ($sections{$name} ne "")) {
 478             # Only warn on user specified duplicate section names.
 479             if ($name ne $section_default) {
 480                 emit_warning("${file}:$.", "duplicate section name '$name'\n");
 481             }
 482             $sections{$name} .= $contents;
 483         } else {
 484             $sections{$name} = $contents;
 485             push @sectionlist, $name;
 486             $section_start_lines{$name} = $new_start_line;
 487             $new_start_line = 0;
 488         }
 489     }
 490 }
 491
 492 ##
 493 # dump DOC: section after checking that it should go out
 494 #
 495 sub dump_doc_section {
 496     my $file = shift;
 497     my $name = shift;
 498     my $contents = join "\n", @_;
 499
 500     if ($no_doc_sections) {
 501         return;
 502     }
 503
 504     return if (defined($nosymbol_table{$name}));
 505
 506     if (($output_selection == OUTPUT_ALL) ||
 507         (($output_selection == OUTPUT_INCLUDE) &&
 508          defined($function_table{$name})))
 509     {
 510         dump_section($file, $name, $contents);
 511         output_blockhead({'sectionlist' => \@sectionlist,
 512                           'sections' => \%sections,
 513                           'module' => $modulename,
 514                           'content-only' => ($output_selection != OUTPUT_ALL), });
 515     }
 516 }
 517
 518 ##
 519 # output function
 520 #
 521 # parameterdescs, a hash.
 522 #  function => "function name"
 523 #  parameterlist => @list of parameters
 524 #  parameterdescs => %parameter descriptions
 525 #  sectionlist => @list of sections
 526 #  sections => %section descriptions
 527 #
 528
 529 sub output_highlight {
 530     my $contents = join "\n",@_;
 531     my $line;
 532
 533 #   DEBUG
 534 #   if (!defined $contents) {
 535 #       use Carp;
 536 #       confess "output_highlight got called with no args?\n";
 537 #   }
 538
 539 #   print STDERR "contents b4:$contents\n";
 540     eval $dohighlight;
 541     die $@ if $@;
 542 #   print STDERR "contents af:$contents\n";
 543
 544     foreach $line (split "\n", $contents) {
 545         if (! $output_preformatted) {
 546             $line =~ s/^\s*//;
 547         }
 548         if ($line eq ""){
 549             if (! $output_preformatted) {
 550                 print $lineprefix, $blankline;
 551             }
 552         } else {
 553             if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
 554                 print "\\&$line";
 555             } else {
 556                 print $lineprefix, $line;
 557             }
 558         }
 559         print "\n";
 560     }
 561 }
 562
 563 ##
 564 # output function in man
 565 sub output_function_man(%) {
 566     my %args = %{$_[0]};
 567     my ($parameter, $section);
 568     my $count;
 569
 570     print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
 571
 572     print ".SH NAME\n";
 573     print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
 574
 575     print ".SH SYNOPSIS\n";
 576     if ($args{'functiontype'} ne "") {
 577         print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
 578     } else {
 579         print ".B \"" . $args{'function'} . "\n";
 580     }
 581     $count = 0;
 582     my $parenth = "(";
 583     my $post = ",";
 584     foreach my $parameter (@{$args{'parameterlist'}}) {
 585         if ($count == $#{$args{'parameterlist'}}) {
 586             $post = ");";
 587         }
 588         $type = $args{'parametertypes'}{$parameter};
 589         if ($type =~ m/$function_pointer/) {
 590             # pointer-to-function
 591             print ".BI \"" . $parenth . $1 . "\" " . " \") (" . $2 . ")" . $post . "\"\n";
 592         } else {
 593             $type =~ s/([^\*])$/$1 /;
 594             print ".BI \"" . $parenth . $type . "\" " . " \"" . $post . "\"\n";
 595         }
 596         $count++;
 597         $parenth = "";
 598     }
 599
 600     print ".SH ARGUMENTS\n";
 601     foreach $parameter (@{$args{'parameterlist'}}) {
 602         my $parameter_name = $parameter;
 603         $parameter_name =~ s/\[.*//;
 604
 605         print ".IP \"" . $parameter . "\" 12\n";
 606         output_highlight($args{'parameterdescs'}{$parameter_name});
 607     }
 608     foreach $section (@{$args{'sectionlist'}}) {
 609         print ".SH \"", uc $section, "\"\n";
 610         output_highlight($args{'sections'}{$section});
 611     }
 612 }
 613
 614 ##
 615 # output enum in man
 616 sub output_enum_man(%) {
 617     my %args = %{$_[0]};
 618     my ($parameter, $section);
 619     my $count;
 620
 621     print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
 622
 623     print ".SH NAME\n";
 624     print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
 625
 626     print ".SH SYNOPSIS\n";
 627     print "enum " . $args{'enum'} . " {\n";
 628     $count = 0;
 629     foreach my $parameter (@{$args{'parameterlist'}}) {
 630         print ".br\n.BI \"    $parameter\"\n";
 631         if ($count == $#{$args{'parameterlist'}}) {
 632             print "\n};\n";
 633             last;
 634         }
 635         else {
 636             print ", \n.br\n";
 637         }
 638         $count++;
 639     }
 640
 641     print ".SH Constants\n";
 642     foreach $parameter (@{$args{'parameterlist'}}) {
 643         my $parameter_name = $parameter;
 644         $parameter_name =~ s/\[.*//;
 645
 646         print ".IP \"" . $parameter . "\" 12\n";
 647         output_highlight($args{'parameterdescs'}{$parameter_name});
 648     }
 649     foreach $section (@{$args{'sectionlist'}}) {
 650         print ".SH \"$section\"\n";
 651         output_highlight($args{'sections'}{$section});
 652     }
 653 }
 654
 655 ##
 656 # output struct in man
 657 sub output_struct_man(%) {
 658     my %args = %{$_[0]};
 659     my ($parameter, $section);
 660
 661     print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
 662
 663     print ".SH NAME\n";
 664     print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
 665
 666     my $declaration = $args{'definition'};
 667     $declaration =~ s/\t/  /g;
 668     $declaration =~ s/\n/"\n.br\n.BI \"/g;
 669     print ".SH SYNOPSIS\n";
 670     print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
 671     print ".BI \"$declaration\n};\n.br\n\n";
 672
 673     print ".SH Members\n";
 674     foreach $parameter (@{$args{'parameterlist'}}) {
 675         ($parameter =~ /^#/) && next;
 676
 677         my $parameter_name = $parameter;
 678         $parameter_name =~ s/\[.*//;
 679
 680         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
 681         print ".IP \"" . $parameter . "\" 12\n";
 682         output_highlight($args{'parameterdescs'}{$parameter_name});
 683     }
 684     foreach $section (@{$args{'sectionlist'}}) {
 685         print ".SH \"$section\"\n";
 686         output_highlight($args{'sections'}{$section});
 687     }
 688 }
 689
 690 ##
 691 # output typedef in man
 692 sub output_typedef_man(%) {
 693     my %args = %{$_[0]};
 694     my ($parameter, $section);
 695
 696     print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
 697
 698     print ".SH NAME\n";
 699     print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
 700
 701     foreach $section (@{$args{'sectionlist'}}) {
 702         print ".SH \"$section\"\n";
 703         output_highlight($args{'sections'}{$section});
 704     }
 705 }
 706
 707 sub output_blockhead_man(%) {
 708     my %args = %{$_[0]};
 709     my ($parameter, $section);
 710     my $count;
 711
 712     print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
 713
 714     foreach $section (@{$args{'sectionlist'}}) {
 715         print ".SH \"$section\"\n";
 716         output_highlight($args{'sections'}{$section});
 717     }
 718 }
 719
 720 ##
 721 # output in restructured text
 722 #
 723
 724 #
 725 # This could use some work; it's used to output the DOC: sections, and
 726 # starts by putting out the name of the doc section itself, but that tends
 727 # to duplicate a header already in the template file.
 728 #
 729 sub output_blockhead_rst(%) {
 730     my %args = %{$_[0]};
 731     my ($parameter, $section);
 732
 733     foreach $section (@{$args{'sectionlist'}}) {
 734         next if (defined($nosymbol_table{$section}));
 735
 736         if ($output_selection != OUTPUT_INCLUDE) {
 737             print ".. _$section:\n\n";
 738             print "**$section**\n\n";
 739         }
 740         print_lineno($section_start_lines{$section});
 741         output_highlight_rst($args{'sections'}{$section});
 742         print "\n";
 743     }
 744 }
 745
 746 #
 747 # Apply the RST highlights to a sub-block of text.
 748 #
 749 sub highlight_block($) {
 750     # The dohighlight kludge requires the text be called $contents
 751     my $contents = shift;
 752     eval $dohighlight;
 753     die $@ if $@;
 754     return $contents;
 755 }
 756
 757 #
 758 # Regexes used only here.
 759 #
 760 my $sphinx_literal = '^[^.].*::$';
 761 my $sphinx_cblock = '^\.\.\ +code-block::';
 762
 763 sub output_highlight_rst {
 764     my $input = join "\n",@_;
 765     my $output = "";
 766     my $line;
 767     my $in_literal = 0;
 768     my $litprefix;
 769     my $block = "";
 770
 771     foreach $line (split "\n",$input) {
 772         #
 773         # If we're in a literal block, see if we should drop out
 774         # of it.  Otherwise pass the line straight through unmunged.
 775         #
 776         if ($in_literal) {
 777             if (! ($line =~ /^\s*$/)) {
 778                 #
 779                 # If this is the first non-blank line in a literal
 780                 # block we need to figure out what the proper indent is.
 781                 #
 782                 if ($litprefix eq "") {
 783                     $line =~ /^(\s*)/;
 784                     $litprefix = '^' . $1;
 785                     $output .= $line . "\n";
 786                 } elsif (! ($line =~ /$litprefix/)) {
 787                     $in_literal = 0;
 788                 } else {
 789                     $output .= $line . "\n";
 790                 }
 791             } else {
 792                 $output .= $line . "\n";
 793             }
 794         }
 795         #
 796         # Not in a literal block (or just dropped out)
 797         #
 798         if (! $in_literal) {
 799             $block .= $line . "\n";
 800             if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
 801                 $in_literal = 1;
 802                 $litprefix = "";
 803                 $output .= highlight_block($block);
 804                 $block = ""
 805             }
 806         }
 807     }
 808
 809     if ($block) {
 810         $output .= highlight_block($block);
 811     }
 812     foreach $line (split "\n", $output) {
 813         print $lineprefix . $line . "\n";
 814     }
 815 }
 816
 817 sub output_function_rst(%) {
 818     my %args = %{$_[0]};
 819     my ($parameter, $section);
 820     my $oldprefix = $lineprefix;
 821     my $start = "";
 822     my $is_macro = 0;
 823
 824     if ($sphinx_major < 3) {
 825         if ($args{'typedef'}) {
 826             print ".. c:type:: ". $args{'function'} . "\n\n";
 827             print_lineno($declaration_start_line);
 828             print "   **Typedef**: ";
 829             $lineprefix = "";
 830             output_highlight_rst($args{'purpose'});
 831             $start = "\n\n**Syntax**\n\n  ``";
 832             $is_macro = 1;
 833         } else {
 834             print ".. c:function:: ";
 835         }
 836     } else {
 837         if ($args{'typedef'} || $args{'functiontype'} eq "") {
 838             $is_macro = 1;
 839             print ".. c:macro:: ". $args{'function'} . "\n\n";
 840         } else {
 841             print ".. c:function:: ";
 842         }
 843
 844         if ($args{'typedef'}) {
 845             print_lineno($declaration_start_line);
 846             print "   **Typedef**: ";
 847             $lineprefix = "";
 848             output_highlight_rst($args{'purpose'});
 849             $start = "\n\n**Syntax**\n\n  ``";
 850         } else {
 851             print "``" if ($is_macro);
 852         }
 853     }
 854     if ($args{'functiontype'} ne "") {
 855         $start .= $args{'functiontype'} . " " . $args{'function'} . " (";
 856     } else {
 857         $start .= $args{'function'} . " (";
 858     }
 859     print $start;
 860
 861     my $count = 0;
 862     foreach my $parameter (@{$args{'parameterlist'}}) {
 863         if ($count ne 0) {
 864             print ", ";
 865         }
 866         $count++;
 867         $type = $args{'parametertypes'}{$parameter};
 868
 869         if ($type =~ m/$function_pointer/) {
 870             # pointer-to-function
 871             print $1 . $parameter . ") (" . $2 . ")";
 872         } else {
 873             print $type;
 874         }
 875     }
 876     if ($is_macro) {
 877         print ")``\n\n";
 878     } else {
 879         print ")\n\n";
 880     }
 881     if (!$args{'typedef'}) {
 882         print_lineno($declaration_start_line);
 883         $lineprefix = "   ";
 884         output_highlight_rst($args{'purpose'});
 885         print "\n";
 886     }
 887
 888     #
 889     # Put our descriptive text into a container (thus an HTML <div>) to help
 890     # set the function prototypes apart.
 891     #
 892     print ".. container:: kernelindent\n\n";
 893     $lineprefix = "  ";
 894     print $lineprefix . "**Parameters**\n\n";
 895     foreach $parameter (@{$args{'parameterlist'}}) {
 896         my $parameter_name = $parameter;
 897         $parameter_name =~ s/\[.*//;
 898         $type = $args{'parametertypes'}{$parameter};
 899
 900         if ($type ne "") {
 901             print $lineprefix . "``$type``\n";
 902         } else {
 903             print $lineprefix . "``$parameter``\n";
 904         }
 905
 906         print_lineno($parameterdesc_start_lines{$parameter_name});
 907
 908         $lineprefix = "    ";
 909         if (defined($args{'parameterdescs'}{$parameter_name}) &&
 910             $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
 911             output_highlight_rst($args{'parameterdescs'}{$parameter_name});
 912         } else {
 913             print $lineprefix . "*undescribed*\n";
 914         }
 915         $lineprefix = "  ";
 916         print "\n";
 917     }
 918
 919     output_section_rst(@_);
 920     $lineprefix = $oldprefix;
 921 }
 922
 923 sub output_section_rst(%) {
 924     my %args = %{$_[0]};
 925     my $section;
 926     my $oldprefix = $lineprefix;
 927
 928     foreach $section (@{$args{'sectionlist'}}) {
 929         print $lineprefix . "**$section**\n\n";
 930         print_lineno($section_start_lines{$section});
 931         output_highlight_rst($args{'sections'}{$section});
 932         print "\n";
 933     }
 934     print "\n";
 935 }
 936
 937 sub output_enum_rst(%) {
 938     my %args = %{$_[0]};
 939     my ($parameter);
 940     my $oldprefix = $lineprefix;
 941     my $count;
 942     my $outer;
 943
 944     if ($sphinx_major < 3) {
 945         my $name = "enum " . $args{'enum'};
 946         print "\n\n.. c:type:: " . $name . "\n\n";
 947     } else {
 948         my $name = $args{'enum'};
 949         print "\n\n.. c:enum:: " . $name . "\n\n";
 950     }
 951     print_lineno($declaration_start_line);
 952     $lineprefix = "  ";
 953     output_highlight_rst($args{'purpose'});
 954     print "\n";
 955
 956     print ".. container:: kernelindent\n\n";
 957     $outer = $lineprefix . "  ";
 958     $lineprefix = $outer . "  ";
 959     print $outer . "**Constants**\n\n";
 960     foreach $parameter (@{$args{'parameterlist'}}) {
 961         print $outer . "``$parameter``\n";
 962
 963         if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
 964             output_highlight_rst($args{'parameterdescs'}{$parameter});
 965         } else {
 966             print $lineprefix . "*undescribed*\n";
 967         }
 968         print "\n";
 969     }
 970     print "\n";
 971     $lineprefix = $oldprefix;
 972     output_section_rst(@_);
 973 }
 974
 975 sub output_typedef_rst(%) {
 976     my %args = %{$_[0]};
 977     my ($parameter);
 978     my $oldprefix = $lineprefix;
 979     my $name;
 980
 981     if ($sphinx_major < 3) {
 982         $name = "typedef " . $args{'typedef'};
 983     } else {
 984         $name = $args{'typedef'};
 985     }
 986     print "\n\n.. c:type:: " . $name . "\n\n";
 987     print_lineno($declaration_start_line);
 988     $lineprefix = "   ";
 989     output_highlight_rst($args{'purpose'});
 990     print "\n";
 991
 992     $lineprefix = $oldprefix;
 993     output_section_rst(@_);
 994 }
 995
 996 sub output_struct_rst(%) {
 997     my %args = %{$_[0]};
 998     my ($parameter);
 999     my $oldprefix = $lineprefix;
1000
1001     if ($sphinx_major < 3) {
1002         my $name = $args{'type'} . " " . $args{'struct'};
1003         print "\n\n.. c:type:: " . $name . "\n\n";
1004     } else {
1005         my $name = $args{'struct'};
1006         if ($args{'type'} eq 'union') {
1007             print "\n\n.. c:union:: " . $name . "\n\n";
1008         } else {
1009             print "\n\n.. c:struct:: " . $name . "\n\n";
1010         }
1011     }
1012     print_lineno($declaration_start_line);
1013     $lineprefix = "  ";
1014     output_highlight_rst($args{'purpose'});
1015     print "\n";
1016
1017     print ".. container:: kernelindent\n\n";
1018     print $lineprefix . "**Definition**::\n\n";
1019     my $declaration = $args{'definition'};
1020     $lineprefix = $lineprefix . "  ";
1021     $declaration =~ s/\t/$lineprefix/g;
1022     print $lineprefix . $args{'type'} . " " . $args{'struct'} . " {\n$declaration" . $lineprefix . "};\n\n";
1023
1024     $lineprefix = "  ";
1025     print $lineprefix . "**Members**\n\n";
1026     foreach $parameter (@{$args{'parameterlist'}}) {
1027         ($parameter =~ /^#/) && next;
1028
1029         my $parameter_name = $parameter;
1030         $parameter_name =~ s/\[.*//;
1031
1032         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
1033         $type = $args{'parametertypes'}{$parameter};
1034         print_lineno($parameterdesc_start_lines{$parameter_name});
1035         print $lineprefix . "``" . $parameter . "``\n";
1036         $lineprefix = "    ";
1037         output_highlight_rst($args{'parameterdescs'}{$parameter_name});
1038         $lineprefix = "  ";
1039         print "\n";
1040     }
1041     print "\n";
1042
1043     $lineprefix = $oldprefix;
1044     output_section_rst(@_);
1045 }
1046
1047 ## none mode output functions
1048
1049 sub output_function_none(%) {
1050 }
1051
1052 sub output_enum_none(%) {
1053 }
1054
1055 sub output_typedef_none(%) {
1056 }
1057
1058 sub output_struct_none(%) {
1059 }
1060
1061 sub output_blockhead_none(%) {
1062 }
1063
1064 ##
1065 # generic output function for all types (function, struct/union, typedef, enum);
1066 # calls the generated, variable output_ function name based on
1067 # functype and output_mode
1068 sub output_declaration {
1069     no strict 'refs';
1070     my $name = shift;
1071     my $functype = shift;
1072     my $func = "output_${functype}_$output_mode";
1073
1074     return if (defined($nosymbol_table{$name}));
1075
1076     if (($output_selection == OUTPUT_ALL) ||
1077         (($output_selection == OUTPUT_INCLUDE ||
1078           $output_selection == OUTPUT_EXPORTED) &&
1079          defined($function_table{$name})) ||
1080         ($output_selection == OUTPUT_INTERNAL &&
1081          !($functype eq "function" && defined($function_table{$name}))))
1082     {
1083         &$func(@_);
1084         $section_counter++;
1085     }
1086 }
1087
1088 ##
1089 # generic output function - calls the right one based on current output mode.
1090 sub output_blockhead {
1091     no strict 'refs';
1092     my $func = "output_blockhead_" . $output_mode;
1093     &$func(@_);
1094     $section_counter++;
1095 }
1096
1097 ##
1098 # takes a declaration (struct, union, enum, typedef) and
1099 # invokes the right handler. NOT called for functions.
1100 sub dump_declaration($$) {
1101     no strict 'refs';
1102     my ($prototype, $file) = @_;
1103     my $func = "dump_" . $decl_type;
1104     &$func(@_);
1105 }
1106
1107 sub dump_union($$) {
1108     dump_struct(@_);
1109 }
1110
1111 sub dump_struct($$) {
1112     my $x = shift;
1113     my $file = shift;
1114     my $decl_type;
1115     my $members;
1116     my $type = qr{struct|union};
1117     # For capturing struct/union definition body, i.e. "{members*}qualifiers*"
1118     my $qualifiers = qr{$attribute|__packed|__aligned|____cacheline_aligned_in_smp|____cacheline_aligned};
1119     my $definition_body = qr{\{(.*)\}\s*$qualifiers*};
1120     my $struct_members = qr{($type)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;};
1121
1122     if ($x =~ /($type)\s+(\w+)\s*$definition_body/) {
1123         $decl_type = $1;
1124         $declaration_name = $2;
1125         $members = $3;
1126     } elsif ($x =~ /typedef\s+($type)\s*$definition_body\s*(\w+)\s*;/) {
1127         $decl_type = $1;
1128         $declaration_name = $3;
1129         $members = $2;
1130     }
1131
1132     if ($members) {
1133         if ($identifier ne $declaration_name) {
1134             emit_warning("${file}:$.", "expecting prototype for $decl_type $identifier. Prototype was for $decl_type $declaration_name instead\n");
1135             return;
1136         }
1137
1138         # ignore members marked private:
1139         $members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1140         $members =~ s/\/\*\s*private:.*//gosi;
1141         # strip comments:
1142         $members =~ s/\/\*.*?\*\///gos;
1143         # strip attributes
1144         $members =~ s/\s*$attribute/ /gi;
1145         $members =~ s/\s*__aligned\s*\([^;]*\)/ /gos;
1146         $members =~ s/\s*__packed\s*/ /gos;
1147         $members =~ s/\s*CRYPTO_MINALIGN_ATTR/ /gos;
1148         $members =~ s/\s*____cacheline_aligned_in_smp/ /gos;
1149         $members =~ s/\s*____cacheline_aligned/ /gos;
1150         # unwrap struct_group():
1151         # - first eat non-declaration parameters and rewrite for final match
1152         # - then remove macro, outer parens, and trailing semicolon
1153         $members =~ s/\bstruct_group\s*\(([^,]*,)/STRUCT_GROUP(/gos;
1154         $members =~ s/\bstruct_group_(attr|tagged)\s*\(([^,]*,){2}/STRUCT_GROUP(/gos;
1155         $members =~ s/\b__struct_group\s*\(([^,]*,){3}/STRUCT_GROUP(/gos;
1156         $members =~ s/\bSTRUCT_GROUP(\(((?:(?>[^)(]+)|(?1))*)\))[^;]*;/$2/gos;
1157
1158         my $args = qr{([^,)]+)};
1159         # replace DECLARE_BITMAP
1160         $members =~ s/__ETHTOOL_DECLARE_LINK_MODE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, __ETHTOOL_LINK_MODE_MASK_NBITS)/gos;
1161         $members =~ s/DECLARE_PHY_INTERFACE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, PHY_INTERFACE_MODE_MAX)/gos;
1162         $members =~ s/DECLARE_BITMAP\s*\($args,\s*$args\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1163         # replace DECLARE_HASHTABLE
1164         $members =~ s/DECLARE_HASHTABLE\s*\($args,\s*$args\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1165         # replace DECLARE_KFIFO
1166         $members =~ s/DECLARE_KFIFO\s*\($args,\s*$args,\s*$args\)/$2 \*$1/gos;
1167         # replace DECLARE_KFIFO_PTR
1168         $members =~ s/DECLARE_KFIFO_PTR\s*\($args,\s*$args\)/$2 \*$1/gos;
1169         # replace DECLARE_FLEX_ARRAY
1170         $members =~ s/(?:__)?DECLARE_FLEX_ARRAY\s*\($args,\s*$args\)/$1 $2\[\]/gos;
1171         my $declaration = $members;
1172
1173         # Split nested struct/union elements as newer ones
1174         while ($members =~ m/$struct_members/) {
1175                 my $newmember;
1176                 my $maintype = $1;
1177                 my $ids = $4;
1178                 my $content = $3;
1179                 foreach my $id(split /,/, $ids) {
1180                         $newmember .= "$maintype $id; ";
1181
1182                         $id =~ s/[:\[].*//;
1183                         $id =~ s/^\s*\**(\S+)\s*/$1/;
1184                         foreach my $arg (split /;/, $content) {
1185                                 next if ($arg =~ m/^\s*$/);
1186                                 if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1187                                         # pointer-to-function
1188                                         my $type = $1;
1189                                         my $name = $2;
1190                                         my $extra = $3;
1191                                         next if (!$name);
1192                                         if ($id =~ m/^\s*$/) {
1193                                                 # anonymous struct/union
1194                                                 $newmember .= "$type$name$extra; ";
1195                                         } else {
1196                                                 $newmember .= "$type$id.$name$extra; ";
1197                                         }
1198                                 } else {
1199                                         my $type;
1200                                         my $names;
1201                                         $arg =~ s/^\s+//;
1202                                         $arg =~ s/\s+$//;
1203                                         # Handle bitmaps
1204                                         $arg =~ s/:\s*\d+\s*//g;
1205                                         # Handle arrays
1206                                         $arg =~ s/\[.*\]//g;
1207                                         # The type may have multiple words,
1208                                         # and multiple IDs can be defined, like:
1209                                         #       const struct foo, *bar, foobar
1210                                         # So, we remove spaces when parsing the
1211                                         # names, in order to match just names
1212                                         # and commas for the names
1213                                         $arg =~ s/\s*,\s*/,/g;
1214                                         if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1215                                                 $type = $1;
1216                                                 $names = $2;
1217                                         } else {
1218                                                 $newmember .= "$arg; ";
1219                                                 next;
1220                                         }
1221                                         foreach my $name (split /,/, $names) {
1222                                                 $name =~ s/^\s*\**(\S+)\s*/$1/;
1223                                                 next if (($name =~ m/^\s*$/));
1224                                                 if ($id =~ m/^\s*$/) {
1225                                                         # anonymous struct/union
1226                                                         $newmember .= "$type $name; ";
1227                                                 } else {
1228                                                         $newmember .= "$type $id.$name; ";
1229                                                 }
1230                                         }
1231                                 }
1232                         }
1233                 }
1234                 $members =~ s/$struct_members/$newmember/;
1235         }
1236
1237         # Ignore other nested elements, like enums
1238         $members =~ s/(\{[^\{\}]*\})//g;
1239
1240         create_parameterlist($members, ';', $file, $declaration_name);
1241         check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1242
1243         # Adjust declaration for better display
1244         $declaration =~ s/([\{;])/$1\n/g;
1245         $declaration =~ s/\}\s+;/};/g;
1246         # Better handle inlined enums
1247         do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1248
1249         my @def_args = split /\n/, $declaration;
1250         my $level = 1;
1251         $declaration = "";
1252         foreach my $clause (@def_args) {
1253                 $clause =~ s/^\s+//;
1254                 $clause =~ s/\s+$//;
1255                 $clause =~ s/\s+/ /;
1256                 next if (!$clause);
1257                 $level-- if ($clause =~ m/(\})/ && $level > 1);
1258                 if (!($clause =~ m/^\s*#/)) {
1259                         $declaration .= "\t" x $level;
1260                 }
1261                 $declaration .= "\t" . $clause . "\n";
1262                 $level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1263         }
1264         output_declaration($declaration_name,
1265                            'struct',
1266                            {'struct' => $declaration_name,
1267                             'module' => $modulename,
1268                             'definition' => $declaration,
1269                             'parameterlist' => \@parameterlist,
1270                             'parameterdescs' => \%parameterdescs,
1271                             'parametertypes' => \%parametertypes,
1272                             'sectionlist' => \@sectionlist,
1273                             'sections' => \%sections,
1274                             'purpose' => $declaration_purpose,
1275                             'type' => $decl_type
1276                            });
1277     }
1278     else {
1279         print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1280         ++$errors;
1281     }
1282 }
1283
1284
1285 sub show_warnings($$) {
1286         my $functype = shift;
1287         my $name = shift;
1288
1289         return 0 if (defined($nosymbol_table{$name}));
1290
1291         return 1 if ($output_selection == OUTPUT_ALL);
1292
1293         if ($output_selection == OUTPUT_EXPORTED) {
1294                 if (defined($function_table{$name})) {
1295                         return 1;
1296                 } else {
1297                         return 0;
1298                 }
1299         }
1300         if ($output_selection == OUTPUT_INTERNAL) {
1301                 if (!($functype eq "function" && defined($function_table{$name}))) {
1302                         return 1;
1303                 } else {
1304                         return 0;
1305                 }
1306         }
1307         if ($output_selection == OUTPUT_INCLUDE) {
1308                 if (defined($function_table{$name})) {
1309                         return 1;
1310                 } else {
1311                         return 0;
1312                 }
1313         }
1314         die("Please add the new output type at show_warnings()");
1315 }
1316
1317 sub dump_enum($$) {
1318     my $x = shift;
1319     my $file = shift;
1320     my $members;
1321
1322
1323     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1324     # strip #define macros inside enums
1325     $x =~ s@#\s*((define|ifdef)\s+|endif)[^;]*;@@gos;
1326
1327     if ($x =~ /typedef\s+enum\s*\{(.*)\}\s*(\w*)\s*;/) {
1328         $declaration_name = $2;
1329         $members = $1;
1330     } elsif ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1331         $declaration_name = $1;
1332         $members = $2;
1333     }
1334
1335     if ($members) {
1336         if ($identifier ne $declaration_name) {
1337             if ($identifier eq "") {
1338                 emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n");
1339             } else {
1340                 emit_warning("${file}:$.", "expecting prototype for enum $identifier. Prototype was for enum $declaration_name instead\n");
1341             }
1342             return;
1343         }
1344         $declaration_name = "(anonymous)" if ($declaration_name eq "");
1345
1346         my %_members;
1347
1348         $members =~ s/\s+$//;
1349
1350         foreach my $arg (split ',', $members) {
1351             $arg =~ s/^\s*(\w+).*/$1/;
1352             push @parameterlist, $arg;
1353             if (!$parameterdescs{$arg}) {
1354                 $parameterdescs{$arg} = $undescribed;
1355                 if (show_warnings("enum", $declaration_name)) {
1356                         emit_warning("${file}:$.", "Enum value '$arg' not described in enum '$declaration_name'\n");
1357                 }
1358             }
1359             $_members{$arg} = 1;
1360         }
1361
1362         while (my ($k, $v) = each %parameterdescs) {
1363             if (!exists($_members{$k})) {
1364                 if (show_warnings("enum", $declaration_name)) {
1365                      emit_warning("${file}:$.", "Excess enum value '$k' description in '$declaration_name'\n");
1366                 }
1367             }
1368         }
1369
1370         output_declaration($declaration_name,
1371                            'enum',
1372                            {'enum' => $declaration_name,
1373                             'module' => $modulename,
1374                             'parameterlist' => \@parameterlist,
1375                             'parameterdescs' => \%parameterdescs,
1376                             'sectionlist' => \@sectionlist,
1377                             'sections' => \%sections,
1378                             'purpose' => $declaration_purpose
1379                            });
1380     } else {
1381         print STDERR "${file}:$.: error: Cannot parse enum!\n";
1382         ++$errors;
1383     }
1384 }
1385
1386 my $typedef_type = qr { ((?:\s+[\w\*]+\b){1,8})\s* }x;
1387 my $typedef_ident = qr { \*?\s*(\w\S+)\s* }x;
1388 my $typedef_args = qr { \s*\((.*)\); }x;
1389
1390 my $typedef1 = qr { typedef$typedef_type\($typedef_ident\)$typedef_args }x;
1391 my $typedef2 = qr { typedef$typedef_type$typedef_ident$typedef_args }x;
1392
1393 sub dump_typedef($$) {
1394     my $x = shift;
1395     my $file = shift;
1396
1397     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1398
1399     # Parse function typedef prototypes
1400     if ($x =~ $typedef1 || $x =~ $typedef2) {
1401         $return_type = $1;
1402         $declaration_name = $2;
1403         my $args = $3;
1404         $return_type =~ s/^\s+//;
1405
1406         if ($identifier ne $declaration_name) {
1407             emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1408             return;
1409         }
1410
1411         create_parameterlist($args, ',', $file, $declaration_name);
1412
1413         output_declaration($declaration_name,
1414                            'function',
1415                            {'function' => $declaration_name,
1416                             'typedef' => 1,
1417                             'module' => $modulename,
1418                             'functiontype' => $return_type,
1419                             'parameterlist' => \@parameterlist,
1420                             'parameterdescs' => \%parameterdescs,
1421                             'parametertypes' => \%parametertypes,
1422                             'sectionlist' => \@sectionlist,
1423                             'sections' => \%sections,
1424                             'purpose' => $declaration_purpose
1425                            });
1426         return;
1427     }
1428
1429     while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1430         $x =~ s/\(*.\)\s*;$/;/;
1431         $x =~ s/\[*.\]\s*;$/;/;
1432     }
1433
1434     if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1435         $declaration_name = $1;
1436
1437         if ($identifier ne $declaration_name) {
1438             emit_warning("${file}:$.", "expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n");
1439             return;
1440         }
1441
1442         output_declaration($declaration_name,
1443                            'typedef',
1444                            {'typedef' => $declaration_name,
1445                             'module' => $modulename,
1446                             'sectionlist' => \@sectionlist,
1447                             'sections' => \%sections,
1448                             'purpose' => $declaration_purpose
1449                            });
1450     }
1451     else {
1452         print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1453         ++$errors;
1454     }
1455 }
1456
1457 sub save_struct_actual($) {
1458     my $actual = shift;
1459
1460     # strip all spaces from the actual param so that it looks like one string item
1461     $actual =~ s/\s*//g;
1462     $struct_actual = $struct_actual . $actual . " ";
1463 }
1464
1465 sub create_parameterlist($$$$) {
1466     my $args = shift;
1467     my $splitter = shift;
1468     my $file = shift;
1469     my $declaration_name = shift;
1470     my $type;
1471     my $param;
1472
1473     # temporarily replace commas inside function pointer definition
1474     my $arg_expr = qr{\([^\),]+};
1475     while ($args =~ /$arg_expr,/) {
1476         $args =~ s/($arg_expr),/$1#/g;
1477     }
1478
1479     foreach my $arg (split($splitter, $args)) {
1480         # strip comments
1481         $arg =~ s/\/\*.*\*\///;
1482         # ignore argument attributes
1483         $arg =~ s/\sPOS0?\s/ /;
1484         # strip leading/trailing spaces
1485         $arg =~ s/^\s*//;
1486         $arg =~ s/\s*$//;
1487         $arg =~ s/\s+/ /;
1488
1489         if ($arg =~ /^#/) {
1490             # Treat preprocessor directive as a typeless variable just to fill
1491             # corresponding data structures "correctly". Catch it later in
1492             # output_* subs.
1493             push_parameter($arg, "", "", $file);
1494         } elsif ($arg =~ m/\(.+\)\s*\(/) {
1495             # pointer-to-function
1496             $arg =~ tr/#/,/;
1497             $arg =~ m/[^\(]+\(\*?\s*([\w\[\]\.]*)\s*\)/;
1498             $param = $1;
1499             $type = $arg;
1500             $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1501             save_struct_actual($param);
1502             push_parameter($param, $type, $arg, $file, $declaration_name);
1503         } elsif ($arg) {
1504             $arg =~ s/\s*:\s*/:/g;
1505             $arg =~ s/\s*\[/\[/g;
1506
1507             my @args = split('\s*,\s*', $arg);
1508             if ($args[0] =~ m/\*/) {
1509                 $args[0] =~ s/(\*+)\s*/ $1/;
1510             }
1511
1512             my @first_arg;
1513             if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1514                     shift @args;
1515                     push(@first_arg, split('\s+', $1));
1516                     push(@first_arg, $2);
1517             } else {
1518                     @first_arg = split('\s+', shift @args);
1519             }
1520
1521             unshift(@args, pop @first_arg);
1522             $type = join " ", @first_arg;
1523
1524             foreach $param (@args) {
1525                 if ($param =~ m/^(\*+)\s*(.*)/) {
1526                     save_struct_actual($2);
1527
1528                     push_parameter($2, "$type $1", $arg, $file, $declaration_name);
1529                 }
1530                 elsif ($param =~ m/(.*?):(\d+)/) {
1531                     if ($type ne "") { # skip unnamed bit-fields
1532                         save_struct_actual($1);
1533                         push_parameter($1, "$type:$2", $arg, $file, $declaration_name)
1534                     }
1535                 }
1536                 else {
1537                     save_struct_actual($param);
1538                     push_parameter($param, $type, $arg, $file, $declaration_name);
1539                 }
1540             }
1541         }
1542     }
1543 }
1544
1545 sub push_parameter($$$$$) {
1546         my $param = shift;
1547         my $type = shift;
1548         my $org_arg = shift;
1549         my $file = shift;
1550         my $declaration_name = shift;
1551
1552         if (($anon_struct_union == 1) && ($type eq "") &&
1553             ($param eq "}")) {
1554                 return;         # ignore the ending }; from anon. struct/union
1555         }
1556
1557         $anon_struct_union = 0;
1558         $param =~ s/[\[\)].*//;
1559
1560         if ($type eq "" && $param =~ /\.\.\.$/)
1561         {
1562             if (!$param =~ /\w\.\.\.$/) {
1563               # handles unnamed variable parameters
1564               $param = "...";
1565             }
1566             elsif ($param =~ /\w\.\.\.$/) {
1567               # for named variable parameters of the form `x...`, remove the dots
1568               $param =~ s/\.\.\.$//;
1569             }
1570             if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1571                 $parameterdescs{$param} = "variable arguments";
1572             }
1573         }
1574         elsif ($type eq "" && ($param eq "" or $param eq "void"))
1575         {
1576             $param="void";
1577             $parameterdescs{void} = "no arguments";
1578         }
1579         elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1580         # handle unnamed (anonymous) union or struct:
1581         {
1582                 $type = $param;
1583                 $param = "{unnamed_" . $param . "}";
1584                 $parameterdescs{$param} = "anonymous\n";
1585                 $anon_struct_union = 1;
1586         }
1587
1588         # warn if parameter has no description
1589         # (but ignore ones starting with # as these are not parameters
1590         # but inline preprocessor statements);
1591         # Note: It will also ignore void params and unnamed structs/unions
1592         if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1593                 $parameterdescs{$param} = $undescribed;
1594
1595                 if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1596                         emit_warning("${file}:$.", "Function parameter or member '$param' not described in '$declaration_name'\n");
1597                 }
1598         }
1599
1600         # strip spaces from $param so that it is one continuous string
1601         # on @parameterlist;
1602         # this fixes a problem where check_sections() cannot find
1603         # a parameter like "addr[6 + 2]" because it actually appears
1604         # as "addr[6", "+", "2]" on the parameter list;
1605         # but it's better to maintain the param string unchanged for output,
1606         # so just weaken the string compare in check_sections() to ignore
1607         # "[blah" in a parameter string;
1608         ###$param =~ s/\s*//g;
1609         push @parameterlist, $param;
1610         $org_arg =~ s/\s\s+/ /g;
1611         $parametertypes{$param} = $org_arg;
1612 }
1613
1614 sub check_sections($$$$$) {
1615         my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1616         my @sects = split ' ', $sectcheck;
1617         my @prms = split ' ', $prmscheck;
1618         my $err;
1619         my ($px, $sx);
1620         my $prm_clean;          # strip trailing "[array size]" and/or beginning "*"
1621
1622         foreach $sx (0 .. $#sects) {
1623                 $err = 1;
1624                 foreach $px (0 .. $#prms) {
1625                         $prm_clean = $prms[$px];
1626                         $prm_clean =~ s/\[.*\]//;
1627                         $prm_clean =~ s/$attribute//i;
1628                         # ignore array size in a parameter string;
1629                         # however, the original param string may contain
1630                         # spaces, e.g.:  addr[6 + 2]
1631                         # and this appears in @prms as "addr[6" since the
1632                         # parameter list is split at spaces;
1633                         # hence just ignore "[..." for the sections check;
1634                         $prm_clean =~ s/\[.*//;
1635
1636                         ##$prm_clean =~ s/^\**//;
1637                         if ($prm_clean eq $sects[$sx]) {
1638                                 $err = 0;
1639                                 last;
1640                         }
1641                 }
1642                 if ($err) {
1643                         if ($decl_type eq "function") {
1644                                 emit_warning("${file}:$.",
1645                                         "Excess function parameter " .
1646                                         "'$sects[$sx]' " .
1647                                         "description in '$decl_name'\n");
1648                         }
1649                 }
1650         }
1651 }
1652
1653 ##
1654 # Checks the section describing the return value of a function.
1655 sub check_return_section {
1656         my $file = shift;
1657         my $declaration_name = shift;
1658         my $return_type = shift;
1659
1660         # Ignore an empty return type (It's a macro)
1661         # Ignore functions with a "void" return type. (But don't ignore "void *")
1662         if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1663                 return;
1664         }
1665
1666         if (!defined($sections{$section_return}) ||
1667             $sections{$section_return} eq "") {
1668                 emit_warning("${file}:$.",
1669                         "No description found for return value of " .
1670                         "'$declaration_name'\n");
1671         }
1672 }
1673
1674 ##
1675 # takes a function prototype and the name of the current file being
1676 # processed and spits out all the details stored in the global
1677 # arrays/hashes.
1678 sub dump_function($$) {
1679     my $prototype = shift;
1680     my $file = shift;
1681     my $noret = 0;
1682
1683     print_lineno($new_start_line);
1684
1685     $prototype =~ s/^static +//;
1686     $prototype =~ s/^extern +//;
1687     $prototype =~ s/^asmlinkage +//;
1688     $prototype =~ s/^inline +//;
1689     $prototype =~ s/^__inline__ +//;
1690     $prototype =~ s/^__inline +//;
1691     $prototype =~ s/^__always_inline +//;
1692     $prototype =~ s/^noinline +//;
1693     $prototype =~ s/^__FORTIFY_INLINE +//;
1694     $prototype =~ s/__init +//;
1695     $prototype =~ s/__init_or_module +//;
1696     $prototype =~ s/__deprecated +//;
1697     $prototype =~ s/__flatten +//;
1698     $prototype =~ s/__meminit +//;
1699     $prototype =~ s/__must_check +//;
1700     $prototype =~ s/__weak +//;
1701     $prototype =~ s/__sched +//;
1702     $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1703     $prototype =~ s/__(?:re)?alloc_size\s*\(\s*\d+\s*(?:,\s*\d+\s*)?\) +//;
1704     $prototype =~ s/__diagnose_as\s*\(\s*\S+\s*(?:,\s*\d+\s*)*\) +//;
1705     my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1706     $prototype =~ s/__attribute_const__ +//;
1707     $prototype =~ s/__attribute__\s*\(\(
1708             (?:
1709                  [\w\s]++          # attribute name
1710                  (?:\([^)]*+\))?   # attribute arguments
1711                  \s*+,?            # optional comma at the end
1712             )+
1713           \)\)\s+//x;
1714
1715     # Yes, this truly is vile.  We are looking for:
1716     # 1. Return type (may be nothing if we're looking at a macro)
1717     # 2. Function name
1718     # 3. Function parameters.
1719     #
1720     # All the while we have to watch out for function pointer parameters
1721     # (which IIRC is what the two sections are for), C types (these
1722     # regexps don't even start to express all the possibilities), and
1723     # so on.
1724     #
1725     # If you mess with these regexps, it's a good idea to check that
1726     # the following functions' documentation still comes out right:
1727     # - parport_register_device (function pointer parameters)
1728     # - atomic_set (macro)
1729     # - pci_match_device, __copy_to_user (long return type)
1730     my $name = qr{[a-zA-Z0-9_~:]+};
1731     my $prototype_end1 = qr{[^\(]*};
1732     my $prototype_end2 = qr{[^\{]*};
1733     my $prototype_end = qr{\(($prototype_end1|$prototype_end2)\)};
1734     my $type1 = qr{[\w\s]+};
1735     my $type2 = qr{$type1\*+};
1736
1737     if ($define && $prototype =~ m/^()($name)\s+/) {
1738         # This is an object-like macro, it has no return type and no parameter
1739         # list.
1740         # Function-like macros are not allowed to have spaces between
1741         # declaration_name and opening parenthesis (notice the \s+).
1742         $return_type = $1;
1743         $declaration_name = $2;
1744         $noret = 1;
1745     } elsif ($prototype =~ m/^()($name)\s*$prototype_end/ ||
1746         $prototype =~ m/^($type1)\s+($name)\s*$prototype_end/ ||
1747         $prototype =~ m/^($type2+)\s*($name)\s*$prototype_end/)  {
1748         $return_type = $1;
1749         $declaration_name = $2;
1750         my $args = $3;
1751
1752         create_parameterlist($args, ',', $file, $declaration_name);
1753     } else {
1754         emit_warning("${file}:$.", "cannot understand function prototype: '$prototype'\n");
1755         return;
1756     }
1757
1758     if ($identifier ne $declaration_name) {
1759         emit_warning("${file}:$.", "expecting prototype for $identifier(). Prototype was for $declaration_name() instead\n");
1760         return;
1761     }
1762
1763     my $prms = join " ", @parameterlist;
1764     check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1765
1766     # This check emits a lot of warnings at the moment, because many
1767     # functions don't have a 'Return' doc section. So until the number
1768     # of warnings goes sufficiently down, the check is only performed in
1769     # -Wreturn mode.
1770     # TODO: always perform the check.
1771     if ($Wreturn && !$noret) {
1772             check_return_section($file, $declaration_name, $return_type);
1773     }
1774
1775     # The function parser can be called with a typedef parameter.
1776     # Handle it.
1777     if ($return_type =~ /typedef/) {
1778         output_declaration($declaration_name,
1779                            'function',
1780                            {'function' => $declaration_name,
1781                             'typedef' => 1,
1782                             'module' => $modulename,
1783                             'functiontype' => $return_type,
1784                             'parameterlist' => \@parameterlist,
1785                             'parameterdescs' => \%parameterdescs,
1786                             'parametertypes' => \%parametertypes,
1787                             'sectionlist' => \@sectionlist,
1788                             'sections' => \%sections,
1789                             'purpose' => $declaration_purpose
1790                            });
1791     } else {
1792         output_declaration($declaration_name,
1793                            'function',
1794                            {'function' => $declaration_name,
1795                             'module' => $modulename,
1796                             'functiontype' => $return_type,
1797                             'parameterlist' => \@parameterlist,
1798                             'parameterdescs' => \%parameterdescs,
1799                             'parametertypes' => \%parametertypes,
1800                             'sectionlist' => \@sectionlist,
1801                             'sections' => \%sections,
1802                             'purpose' => $declaration_purpose
1803                            });
1804     }
1805 }
1806
1807 sub reset_state {
1808     $function = "";
1809     %parameterdescs = ();
1810     %parametertypes = ();
1811     @parameterlist = ();
1812     %sections = ();
1813     @sectionlist = ();
1814     $sectcheck = "";
1815     $struct_actual = "";
1816     $prototype = "";
1817
1818     $state = STATE_NORMAL;
1819     $inline_doc_state = STATE_INLINE_NA;
1820 }
1821
1822 sub tracepoint_munge($) {
1823         my $file = shift;
1824         my $tracepointname = 0;
1825         my $tracepointargs = 0;
1826
1827         if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1828                 $tracepointname = $1;
1829         }
1830         if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1831                 $tracepointname = $1;
1832         }
1833         if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1834                 $tracepointname = $2;
1835         }
1836         $tracepointname =~ s/^\s+//; #strip leading whitespace
1837         if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1838                 $tracepointargs = $1;
1839         }
1840         if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1841                 emit_warning("${file}:$.", "Unrecognized tracepoint format: \n".
1842                              "$prototype\n");
1843         } else {
1844                 $prototype = "static inline void trace_$tracepointname($tracepointargs)";
1845                 $identifier = "trace_$identifier";
1846         }
1847 }
1848
1849 sub syscall_munge() {
1850         my $void = 0;
1851
1852         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1853 ##      if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1854         if ($prototype =~ m/SYSCALL_DEFINE0/) {
1855                 $void = 1;
1856 ##              $prototype = "long sys_$1(void)";
1857         }
1858
1859         $prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1860         if ($prototype =~ m/long (sys_.*?),/) {
1861                 $prototype =~ s/,/\(/;
1862         } elsif ($void) {
1863                 $prototype =~ s/\)/\(void\)/;
1864         }
1865
1866         # now delete all of the odd-number commas in $prototype
1867         # so that arg types & arg names don't have a comma between them
1868         my $count = 0;
1869         my $len = length($prototype);
1870         if ($void) {
1871                 $len = 0;       # skip the for-loop
1872         }
1873         for (my $ix = 0; $ix < $len; $ix++) {
1874                 if (substr($prototype, $ix, 1) eq ',') {
1875                         $count++;
1876                         if ($count % 2 == 1) {
1877                                 substr($prototype, $ix, 1) = ' ';
1878                         }
1879                 }
1880         }
1881 }
1882
1883 sub process_proto_function($$) {
1884     my $x = shift;
1885     my $file = shift;
1886
1887     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1888
1889     if ($x =~ m#\s*/\*\s+MACDOC\s*#io || ($x =~ /^#/ && $x !~ /^#\s*define/)) {
1890         # do nothing
1891     }
1892     elsif ($x =~ /([^\{]*)/) {
1893         $prototype .= $1;
1894     }
1895
1896     if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1897         $prototype =~ s@/\*.*?\*/@@gos; # strip comments.
1898         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1899         $prototype =~ s@^\s+@@gos; # strip leading spaces
1900
1901          # Handle prototypes for function pointers like:
1902          # int (*pcs_config)(struct foo)
1903         $prototype =~ s@^(\S+\s+)\(\s*\*(\S+)\)@$1$2@gos;
1904
1905         if ($prototype =~ /SYSCALL_DEFINE/) {
1906                 syscall_munge();
1907         }
1908         if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
1909             $prototype =~ /DEFINE_SINGLE_EVENT/)
1910         {
1911                 tracepoint_munge($file);
1912         }
1913         dump_function($prototype, $file);
1914         reset_state();
1915     }
1916 }
1917
1918 sub process_proto_type($$) {
1919     my $x = shift;
1920     my $file = shift;
1921
1922     $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1923     $x =~ s@^\s+@@gos; # strip leading spaces
1924     $x =~ s@\s+$@@gos; # strip trailing spaces
1925     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1926
1927     if ($x =~ /^#/) {
1928         # To distinguish preprocessor directive from regular declaration later.
1929         $x .= ";";
1930     }
1931
1932     while (1) {
1933         if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
1934             if( length $prototype ) {
1935                 $prototype .= " "
1936             }
1937             $prototype .= $1 . $2;
1938             ($2 eq '{') && $brcount++;
1939             ($2 eq '}') && $brcount--;
1940             if (($2 eq ';') && ($brcount == 0)) {
1941                 dump_declaration($prototype, $file);
1942                 reset_state();
1943                 last;
1944             }
1945             $x = $3;
1946         } else {
1947             $prototype .= $x;
1948             last;
1949         }
1950     }
1951 }
1952
1953
1954 sub map_filename($) {
1955     my $file;
1956     my ($orig_file) = @_;
1957
1958     if (defined($ENV{'SRCTREE'})) {
1959         $file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
1960     } else {
1961         $file = $orig_file;
1962     }
1963
1964     if (defined($source_map{$file})) {
1965         $file = $source_map{$file};
1966     }
1967
1968     return $file;
1969 }
1970
1971 sub process_export_file($) {
1972     my ($orig_file) = @_;
1973     my $file = map_filename($orig_file);
1974
1975     if (!open(IN,"<$file")) {
1976         print STDERR "Error: Cannot open file $file\n";
1977         ++$errors;
1978         return;
1979     }
1980
1981     while (<IN>) {
1982         if (/$export_symbol/) {
1983             next if (defined($nosymbol_table{$2}));
1984             $function_table{$2} = 1;
1985         }
1986         if (/$export_symbol_ns/) {
1987             next if (defined($nosymbol_table{$2}));
1988             $function_table{$2} = 1;
1989         }
1990     }
1991
1992     close(IN);
1993 }
1994
1995 #
1996 # Parsers for the various processing states.
1997 #
1998 # STATE_NORMAL: looking for the /** to begin everything.
1999 #
2000 sub process_normal() {
2001     if (/$doc_start/o) {
2002         $state = STATE_NAME;    # next line is always the function name
2003         $in_doc_sect = 0;
2004         $declaration_start_line = $. + 1;
2005     }
2006 }
2007
2008 #
2009 # STATE_NAME: Looking for the "name - description" line
2010 #
2011 sub process_name($$) {
2012     my $file = shift;
2013     my $descr;
2014
2015     if (/$doc_block/o) {
2016         $state = STATE_DOCBLOCK;
2017         $contents = "";
2018         $new_start_line = $.;
2019
2020         if ( $1 eq "" ) {
2021             $section = $section_intro;
2022         } else {
2023             $section = $1;
2024         }
2025     } elsif (/$doc_decl/o) {
2026         $identifier = $1;
2027         my $is_kernel_comment = 0;
2028         my $decl_start = qr{$doc_com};
2029         # test for pointer declaration type, foo * bar() - desc
2030         my $fn_type = qr{\w+\s*\*\s*};
2031         my $parenthesis = qr{\(\w*\)};
2032         my $decl_end = qr{[-:].*};
2033         if (/^$decl_start([\w\s]+?)$parenthesis?\s*$decl_end?$/) {
2034             $identifier = $1;
2035         }
2036         if ($identifier =~ m/^(struct|union|enum|typedef)\b\s*(\S*)/) {
2037             $decl_type = $1;
2038             $identifier = $2;
2039             $is_kernel_comment = 1;
2040         }
2041         # Look for foo() or static void foo() - description; or misspelt
2042         # identifier
2043         elsif (/^$decl_start$fn_type?(\w+)\s*$parenthesis?\s*$decl_end?$/ ||
2044             /^$decl_start$fn_type?(\w+.*)$parenthesis?\s*$decl_end$/) {
2045             $identifier = $1;
2046             $decl_type = 'function';
2047             $identifier =~ s/^define\s+//;
2048             $is_kernel_comment = 1;
2049         }
2050         $identifier =~ s/\s+$//;
2051
2052         $state = STATE_BODY;
2053         # if there's no @param blocks need to set up default section
2054         # here
2055         $contents = "";
2056         $section = $section_default;
2057         $new_start_line = $. + 1;
2058         if (/[-:](.*)/) {
2059             # strip leading/trailing/multiple spaces
2060             $descr= $1;
2061             $descr =~ s/^\s*//;
2062             $descr =~ s/\s*$//;
2063             $descr =~ s/\s+/ /g;
2064             $declaration_purpose = $descr;
2065             $state = STATE_BODY_MAYBE;
2066         } else {
2067             $declaration_purpose = "";
2068         }
2069
2070         if (!$is_kernel_comment) {
2071             emit_warning("${file}:$.", "This comment starts with '/**', but isn't a kernel-doc comment. Refer Documentation/doc-guide/kernel-doc.rst\n$_");
2072             $state = STATE_NORMAL;
2073         }
2074
2075         if (($declaration_purpose eq "") && $Wshort_desc) {
2076             emit_warning("${file}:$.", "missing initial short description on line:\n$_");
2077         }
2078
2079         if ($identifier eq "" && $decl_type ne "enum") {
2080             emit_warning("${file}:$.", "wrong kernel-doc identifier on line:\n$_");
2081             $state = STATE_NORMAL;
2082         }
2083
2084         if ($verbose) {
2085             print STDERR "${file}:$.: info: Scanning doc for $decl_type $identifier\n";
2086         }
2087     } else {
2088         emit_warning("${file}:$.", "Cannot understand $_ on line $. - I thought it was a doc line\n");
2089         $state = STATE_NORMAL;
2090     }
2091 }
2092
2093
2094 #
2095 # STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
2096 #
2097 sub process_body($$) {
2098     my $file = shift;
2099
2100     if ($state == STATE_BODY_WITH_BLANK_LINE && /^\s*\*\s?\S/) {
2101         dump_section($file, $section, $contents);
2102         $section = $section_default;
2103         $new_start_line = $.;
2104         $contents = "";
2105     }
2106
2107     if (/$doc_sect/i) { # case insensitive for supported section names
2108         $newsection = $1;
2109         $newcontents = $2;
2110
2111         # map the supported section names to the canonical names
2112         if ($newsection =~ m/^description$/i) {
2113             $newsection = $section_default;
2114         } elsif ($newsection =~ m/^context$/i) {
2115             $newsection = $section_context;
2116         } elsif ($newsection =~ m/^returns?$/i) {
2117             $newsection = $section_return;
2118         } elsif ($newsection =~ m/^\@return$/) {
2119             # special: @return is a section, not a param description
2120             $newsection = $section_return;
2121         }
2122
2123         if (($contents ne "") && ($contents ne "\n")) {
2124             if (!$in_doc_sect && $Wcontents_before_sections) {
2125                 emit_warning("${file}:$.", "contents before sections\n");
2126             }
2127             dump_section($file, $section, $contents);
2128             $section = $section_default;
2129         }
2130
2131         $in_doc_sect = 1;
2132         $state = STATE_BODY;
2133         $contents = $newcontents;
2134         $new_start_line = $.;
2135         while (substr($contents, 0, 1) eq " ") {
2136             $contents = substr($contents, 1);
2137         }
2138         if ($contents ne "") {
2139             $contents .= "\n";
2140         }
2141         $section = $newsection;
2142         $leading_space = undef;
2143     } elsif (/$doc_end/) {
2144         if (($contents ne "") && ($contents ne "\n")) {
2145             dump_section($file, $section, $contents);
2146             $section = $section_default;
2147             $contents = "";
2148         }
2149         # look for doc_com + <text> + doc_end:
2150         if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
2151             emit_warning("${file}:$.", "suspicious ending line: $_");
2152         }
2153
2154         $prototype = "";
2155         $state = STATE_PROTO;
2156         $brcount = 0;
2157         $new_start_line = $. + 1;
2158     } elsif (/$doc_content/) {
2159         if ($1 eq "") {
2160             if ($section eq $section_context) {
2161                 dump_section($file, $section, $contents);
2162                 $section = $section_default;
2163                 $contents = "";
2164                 $new_start_line = $.;
2165                 $state = STATE_BODY;
2166             } else {
2167                 if ($section ne $section_default) {
2168                     $state = STATE_BODY_WITH_BLANK_LINE;
2169                 } else {
2170                     $state = STATE_BODY;
2171                 }
2172                 $contents .= "\n";
2173             }
2174         } elsif ($state == STATE_BODY_MAYBE) {
2175             # Continued declaration purpose
2176             chomp($declaration_purpose);
2177             $declaration_purpose .= " " . $1;
2178             $declaration_purpose =~ s/\s+/ /g;
2179         } else {
2180             my $cont = $1;
2181             if ($section =~ m/^@/ || $section eq $section_context) {
2182                 if (!defined $leading_space) {
2183                     if ($cont =~ m/^(\s+)/) {
2184                         $leading_space = $1;
2185                     } else {
2186                         $leading_space = "";
2187                     }
2188                 }
2189                 $cont =~ s/^$leading_space//;
2190             }
2191             $contents .= $cont . "\n";
2192         }
2193     } else {
2194         # i dont know - bad line?  ignore.
2195         emit_warning("${file}:$.", "bad line: $_");
2196     }
2197 }
2198
2199
2200 #
2201 # STATE_PROTO: reading a function/whatever prototype.
2202 #
2203 sub process_proto($$) {
2204     my $file = shift;
2205
2206     if (/$doc_inline_oneline/) {
2207         $section = $1;
2208         $contents = $2;
2209         if ($contents ne "") {
2210             $contents .= "\n";
2211             dump_section($file, $section, $contents);
2212             $section = $section_default;
2213             $contents = "";
2214         }
2215     } elsif (/$doc_inline_start/) {
2216         $state = STATE_INLINE;
2217         $inline_doc_state = STATE_INLINE_NAME;
2218     } elsif ($decl_type eq 'function') {
2219         process_proto_function($_, $file);
2220     } else {
2221         process_proto_type($_, $file);
2222     }
2223 }
2224
2225 #
2226 # STATE_DOCBLOCK: within a DOC: block.
2227 #
2228 sub process_docblock($$) {
2229     my $file = shift;
2230
2231     if (/$doc_end/) {
2232         dump_doc_section($file, $section, $contents);
2233         $section = $section_default;
2234         $contents = "";
2235         $function = "";
2236         %parameterdescs = ();
2237         %parametertypes = ();
2238         @parameterlist = ();
2239         %sections = ();
2240         @sectionlist = ();
2241         $prototype = "";
2242         $state = STATE_NORMAL;
2243     } elsif (/$doc_content/) {
2244         if ( $1 eq "" ) {
2245             $contents .= $blankline;
2246         } else {
2247             $contents .= $1 . "\n";
2248         }
2249     }
2250 }
2251
2252 #
2253 # STATE_INLINE: docbook comments within a prototype.
2254 #
2255 sub process_inline($$) {
2256     my $file = shift;
2257
2258     # First line (state 1) needs to be a @parameter
2259     if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2260         $section = $1;
2261         $contents = $2;
2262         $new_start_line = $.;
2263         if ($contents ne "") {
2264             while (substr($contents, 0, 1) eq " ") {
2265                 $contents = substr($contents, 1);
2266             }
2267             $contents .= "\n";
2268         }
2269         $inline_doc_state = STATE_INLINE_TEXT;
2270         # Documentation block end */
2271     } elsif (/$doc_inline_end/) {
2272         if (($contents ne "") && ($contents ne "\n")) {
2273             dump_section($file, $section, $contents);
2274             $section = $section_default;
2275             $contents = "";
2276         }
2277         $state = STATE_PROTO;
2278         $inline_doc_state = STATE_INLINE_NA;
2279         # Regular text
2280     } elsif (/$doc_content/) {
2281         if ($inline_doc_state == STATE_INLINE_TEXT) {
2282             $contents .= $1 . "\n";
2283             # nuke leading blank lines
2284             if ($contents =~ /^\s*$/) {
2285                 $contents = "";
2286             }
2287         } elsif ($inline_doc_state == STATE_INLINE_NAME) {
2288             $inline_doc_state = STATE_INLINE_ERROR;
2289             emit_warning("${file}:$.", "Incorrect use of kernel-doc format: $_");
2290         }
2291     }
2292 }
2293
2294
2295 sub process_file($) {
2296     my $file;
2297     my $initial_section_counter = $section_counter;
2298     my ($orig_file) = @_;
2299
2300     $file = map_filename($orig_file);
2301
2302     if (!open(IN_FILE,"<$file")) {
2303         print STDERR "Error: Cannot open file $file\n";
2304         ++$errors;
2305         return;
2306     }
2307
2308     $. = 1;
2309
2310     $section_counter = 0;
2311     while (<IN_FILE>) {
2312         while (s/\\\s*$//) {
2313             $_ .= <IN_FILE>;
2314         }
2315         # Replace tabs by spaces
2316         while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2317         # Hand this line to the appropriate state handler
2318         if ($state == STATE_NORMAL) {
2319             process_normal();
2320         } elsif ($state == STATE_NAME) {
2321             process_name($file, $_);
2322         } elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE ||
2323                  $state == STATE_BODY_WITH_BLANK_LINE) {
2324             process_body($file, $_);
2325         } elsif ($state == STATE_INLINE) { # scanning for inline parameters
2326             process_inline($file, $_);
2327         } elsif ($state == STATE_PROTO) {
2328             process_proto($file, $_);
2329         } elsif ($state == STATE_DOCBLOCK) {
2330             process_docblock($file, $_);
2331         }
2332     }
2333
2334     # Make sure we got something interesting.
2335     if ($initial_section_counter == $section_counter && $
2336         output_mode ne "none") {
2337         if ($output_selection == OUTPUT_INCLUDE) {
2338             emit_warning("${file}:1", "'$_' not found\n")
2339                 for keys %function_table;
2340         }
2341         else {
2342             emit_warning("${file}:1", "no structured comments found\n");
2343         }
2344     }
2345     close IN_FILE;
2346 }
2347
2348
2349 if ($output_mode eq "rst") {
2350         get_sphinx_version() if (!$sphinx_major);
2351 }
2352
2353 $kernelversion = get_kernel_version();
2354
2355 # generate a sequence of code that will splice in highlighting information
2356 # using the s// operator.
2357 for (my $k = 0; $k < @highlights; $k++) {
2358     my $pattern = $highlights[$k][0];
2359     my $result = $highlights[$k][1];
2360 #   print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2361     $dohighlight .=  "\$contents =~ s:$pattern:$result:gs;\n";
2362 }
2363
2364 # Read the file that maps relative names to absolute names for
2365 # separate source and object directories and for shadow trees.
2366 if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2367         my ($relname, $absname);
2368         while(<SOURCE_MAP>) {
2369                 chop();
2370                 ($relname, $absname) = (split())[0..1];
2371                 $relname =~ s:^/+::;
2372                 $source_map{$relname} = $absname;
2373         }
2374         close(SOURCE_MAP);
2375 }
2376
2377 if ($output_selection == OUTPUT_EXPORTED ||
2378     $output_selection == OUTPUT_INTERNAL) {
2379
2380     push(@export_file_list, @ARGV);
2381
2382     foreach (@export_file_list) {
2383         chomp;
2384         process_export_file($_);
2385     }
2386 }
2387
2388 foreach (@ARGV) {
2389     chomp;
2390     process_file($_);
2391 }
2392 if ($verbose && $errors) {
2393   print STDERR "$errors errors\n";
2394 }
2395 if ($verbose && $warnings) {
2396   print STDERR "$warnings warnings\n";
2397 }
2398
2399 if ($Werror && $warnings) {
2400     print STDERR "$warnings warnings as Errors\n";
2401     exit($warnings);
2402 } else {
2403     exit($output_mode eq "none" ? 0 : $errors)
2404 }
2405
2406 __END__
2407
2408 =head1 OPTIONS
2409
2410 =head2 Output format selection (mutually exclusive):
2411
2412 =over 8
2413
2414 =item -man
2415
2416 Output troff manual page format.
2417
2418 =item -rst
2419
2420 Output reStructuredText format. This is the default.
2421
2422 =item -none
2423
2424 Do not output documentation, only warnings.
2425
2426 =back
2427
2428 =head2 Output format modifiers
2429
2430 =head3 reStructuredText only
2431
2432 =over 8
2433
2434 =item -sphinx-version VERSION
2435
2436 Use the ReST C domain dialect compatible with a specific Sphinx Version.
2437
2438 If not specified, kernel-doc will auto-detect using the sphinx-build version
2439 found on PATH.
2440
2441 =back
2442
2443 =head2 Output selection (mutually exclusive):
2444
2445 =over 8
2446
2447 =item -export
2448
2449 Only output documentation for the symbols that have been exported using
2450 EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2451
2452 =item -internal
2453
2454 Only output documentation for the symbols that have NOT been exported using
2455 EXPORT_SYMBOL() and related macros in any input FILE or -export-file FILE.
2456
2457 =item -function NAME
2458
2459 Only output documentation for the given function or DOC: section title.
2460 All other functions and DOC: sections are ignored.
2461
2462 May be specified multiple times.
2463
2464 =item -nosymbol NAME
2465
2466 Exclude the specified symbol from the output documentation.
2467
2468 May be specified multiple times.
2469
2470 =back
2471
2472 =head2 Output selection modifiers:
2473
2474 =over 8
2475
2476 =item -no-doc-sections
2477
2478 Do not output DOC: sections.
2479
2480 =item -export-file FILE
2481
2482 Specify an additional FILE in which to look for EXPORT_SYMBOL information.
2483
2484 To be used with -export or -internal.
2485
2486 May be specified multiple times.
2487
2488 =back
2489
2490 =head3 reStructuredText only
2491
2492 =over 8
2493
2494 =item -enable-lineno
2495
2496 Enable output of .. LINENO lines.
2497
2498 =back
2499
2500 =head2 Other parameters:
2501
2502 =over 8
2503
2504 =item -h, -help
2505
2506 Print this help.
2507
2508 =item -v
2509
2510 Verbose output, more warnings and other information.
2511
2512 =item -Werror
2513
2514 Treat warnings as errors.
2515
2516 =back
2517
2518 =cut