scripts/kernel-doc

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0
   3
   4 use warnings;
   5 use strict;
   6
   7 ## Copyright (c) 1998 Michael Zucchi, All Rights Reserved        ##
   8 ## Copyright (C) 2000, 1  Tim Waugh <twaugh@redhat.com>          ##
   9 ## Copyright (C) 2001  Simon Huggins                             ##
  10 ## Copyright (C) 2005-2012  Randy Dunlap                         ##
  11 ## Copyright (C) 2012  Dan Luedtke                               ##
  12 ##                                                               ##
  13 ## #define enhancements by Armin Kuster <akuster@mvista.com>     ##
  14 ## Copyright (c) 2000 MontaVista Software, Inc.                  ##
  15 ##                                                               ##
  16 ## This software falls under the GNU General Public License.     ##
  17 ## Please read the COPYING file for more information             ##
  18
  19 # 18/01/2001 -  Cleanups
  20 #               Functions prototyped as foo(void) same as foo()
  21 #               Stop eval'ing where we don't need to.
  22 # -- huggie@earth.li
  23
  24 # 27/06/2001 -  Allowed whitespace after initial "/**" and
  25 #               allowed comments before function declarations.
  26 # -- Christian Kreibich <ck@whoop.org>
  27
  28 # Still to do:
  29 #       - add perldoc documentation
  30 #       - Look more closely at some of the scarier bits :)
  31
  32 # 26/05/2001 -  Support for separate source and object trees.
  33 #               Return error code.
  34 #               Keith Owens <kaos@ocs.com.au>
  35
  36 # 23/09/2001 - Added support for typedefs, structs, enums and unions
  37 #              Support for Context section; can be terminated using empty line
  38 #              Small fixes (like spaces vs. \s in regex)
  39 # -- Tim Jansen <tim@tjansen.de>
  40
  41 # 25/07/2012 - Added support for HTML5
  42 # -- Dan Luedtke <mail@danrl.de>
  43
  44 sub usage {
  45     my $message = <<"EOF";
  46 Usage: $0 [OPTION ...] FILE ...
  47
  48 Read C language source or header FILEs, extract embedded documentation comments,
  49 and print formatted documentation to standard output.
  50
  51 The documentation comments are identified by "/**" opening comment mark. See
  52 Documentation/doc-guide/kernel-doc.rst for the documentation comment syntax.
  53
  54 Output format selection (mutually exclusive):
  55   -man                  Output troff manual page format. This is the default.
  56   -rst                  Output reStructuredText format.
  57   -none                 Do not output documentation, only warnings.
  58
  59 Output format selection modifier (affects only ReST output):
  60
  61   -sphinx-version       Use the ReST C domain dialect compatible with an
  62                         specific Sphinx Version.
  63                         If not specified, kernel-doc will auto-detect using
  64                         the sphinx-build version found on PATH.
  65
  66 Output selection (mutually exclusive):
  67   -export               Only output documentation for symbols that have been
  68                         exported using EXPORT_SYMBOL() or EXPORT_SYMBOL_GPL()
  69                         in any input FILE or -export-file FILE.
  70   -internal             Only output documentation for symbols that have NOT been
  71                         exported using EXPORT_SYMBOL() or EXPORT_SYMBOL_GPL()
  72                         in any input FILE or -export-file FILE.
  73   -function NAME        Only output documentation for the given function(s)
  74                         or DOC: section title(s). All other functions and DOC:
  75                         sections are ignored. May be specified multiple times.
  76   -nosymbol NAME        Exclude the specified symbols from the output
  77                         documentation. May be specified multiple times.
  78
  79 Output selection modifiers:
  80   -no-doc-sections      Do not output DOC: sections.
  81   -enable-lineno        Enable output of #define LINENO lines. Only works with
  82                         reStructuredText format.
  83   -export-file FILE     Specify an additional FILE in which to look for
  84                         EXPORT_SYMBOL() and EXPORT_SYMBOL_GPL(). To be used with
  85                         -export or -internal. May be specified multiple times.
  86
  87 Other parameters:
  88   -v                    Verbose output, more warnings and other information.
  89   -h                    Print this help.
  90   -Werror               Treat warnings as errors.
  91
  92 EOF
  93     print $message;
  94     exit 1;
  95 }
  96
  97 #
  98 # format of comments.
  99 # In the following table, (...)? signifies optional structure.
 100 #                         (...)* signifies 0 or more structure elements
 101 # /**
 102 #  * function_name(:)? (- short description)?
 103 # (* @parameterx: (description of parameter x)?)*
 104 # (* a blank line)?
 105 #  * (Description:)? (Description of function)?
 106 #  * (section header: (section description)? )*
 107 #  (*)?*/
 108 #
 109 # So .. the trivial example would be:
 110 #
 111 # /**
 112 #  * my_function
 113 #  */
 114 #
 115 # If the Description: header tag is omitted, then there must be a blank line
 116 # after the last parameter specification.
 117 # e.g.
 118 # /**
 119 #  * my_function - does my stuff
 120 #  * @my_arg: its mine damnit
 121 #  *
 122 #  * Does my stuff explained.
 123 #  */
 124 #
 125 #  or, could also use:
 126 # /**
 127 #  * my_function - does my stuff
 128 #  * @my_arg: its mine damnit
 129 #  * Description: Does my stuff explained.
 130 #  */
 131 # etc.
 132 #
 133 # Besides functions you can also write documentation for structs, unions,
 134 # enums and typedefs. Instead of the function name you must write the name
 135 # of the declaration;  the struct/union/enum/typedef must always precede
 136 # the name. Nesting of declarations is not supported.
 137 # Use the argument mechanism to document members or constants.
 138 # e.g.
 139 # /**
 140 #  * struct my_struct - short description
 141 #  * @a: first member
 142 #  * @b: second member
 143 #  *
 144 #  * Longer description
 145 #  */
 146 # struct my_struct {
 147 #     int a;
 148 #     int b;
 149 # /* private: */
 150 #     int c;
 151 # };
 152 #
 153 # All descriptions can be multiline, except the short function description.
 154 #
 155 # For really longs structs, you can also describe arguments inside the
 156 # body of the struct.
 157 # eg.
 158 # /**
 159 #  * struct my_struct - short description
 160 #  * @a: first member
 161 #  * @b: second member
 162 #  *
 163 #  * Longer description
 164 #  */
 165 # struct my_struct {
 166 #     int a;
 167 #     int b;
 168 #     /**
 169 #      * @c: This is longer description of C
 170 #      *
 171 #      * You can use paragraphs to describe arguments
 172 #      * using this method.
 173 #      */
 174 #     int c;
 175 # };
 176 #
 177 # This should be use only for struct/enum members.
 178 #
 179 # You can also add additional sections. When documenting kernel functions you
 180 # should document the "Context:" of the function, e.g. whether the functions
 181 # can be called form interrupts. Unlike other sections you can end it with an
 182 # empty line.
 183 # A non-void function should have a "Return:" section describing the return
 184 # value(s).
 185 # Example-sections should contain the string EXAMPLE so that they are marked
 186 # appropriately in DocBook.
 187 #
 188 # Example:
 189 # /**
 190 #  * user_function - function that can only be called in user context
 191 #  * @a: some argument
 192 #  * Context: !in_interrupt()
 193 #  *
 194 #  * Some description
 195 #  * Example:
 196 #  *    user_function(22);
 197 #  */
 198 # ...
 199 #
 200 #
 201 # All descriptive text is further processed, scanning for the following special
 202 # patterns, which are highlighted appropriately.
 203 #
 204 # 'funcname()' - function
 205 # '$ENVVAR' - environmental variable
 206 # '&struct_name' - name of a structure (up to two words including 'struct')
 207 # '&struct_name.member' - name of a structure member
 208 # '@parameter' - name of a parameter
 209 # '%CONST' - name of a constant.
 210 # '``LITERAL``' - literal string without any spaces on it.
 211
 212 ## init lots of data
 213
 214 my $errors = 0;
 215 my $warnings = 0;
 216 my $anon_struct_union = 0;
 217
 218 # match expressions used to find embedded type information
 219 my $type_constant = '\b``([^\`]+)``\b';
 220 my $type_constant2 = '\%([-_\w]+)';
 221 my $type_func = '(\w+)\(\)';
 222 my $type_param = '\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
 223 my $type_param_ref = '([\!]?)\@(\w*((\.\w+)|(->\w+))*(\.\.\.)?)';
 224 my $type_fp_param = '\@(\w+)\(\)';  # Special RST handling for func ptr params
 225 my $type_fp_param2 = '\@(\w+->\S+)\(\)';  # Special RST handling for structs with func ptr params
 226 my $type_env = '(\$\w+)';
 227 my $type_enum = '\&(enum\s*([_\w]+))';
 228 my $type_struct = '\&(struct\s*([_\w]+))';
 229 my $type_typedef = '\&(typedef\s*([_\w]+))';
 230 my $type_union = '\&(union\s*([_\w]+))';
 231 my $type_member = '\&([_\w]+)(\.|->)([_\w]+)';
 232 my $type_fallback = '\&([_\w]+)';
 233 my $type_member_func = $type_member . '\(\)';
 234
 235 # Output conversion substitutions.
 236 #  One for each output format
 237
 238 # these are pretty rough
 239 my @highlights_man = (
 240                       [$type_constant, "\$1"],
 241                       [$type_constant2, "\$1"],
 242                       [$type_func, "\\\\fB\$1\\\\fP"],
 243                       [$type_enum, "\\\\fI\$1\\\\fP"],
 244                       [$type_struct, "\\\\fI\$1\\\\fP"],
 245                       [$type_typedef, "\\\\fI\$1\\\\fP"],
 246                       [$type_union, "\\\\fI\$1\\\\fP"],
 247                       [$type_param, "\\\\fI\$1\\\\fP"],
 248                       [$type_param_ref, "\\\\fI\$1\$2\\\\fP"],
 249                       [$type_member, "\\\\fI\$1\$2\$3\\\\fP"],
 250                       [$type_fallback, "\\\\fI\$1\\\\fP"]
 251                      );
 252 my $blankline_man = "";
 253
 254 # rst-mode
 255 my @highlights_rst = (
 256                        [$type_constant, "``\$1``"],
 257                        [$type_constant2, "``\$1``"],
 258                        # Note: need to escape () to avoid func matching later
 259                        [$type_member_func, "\\:c\\:type\\:`\$1\$2\$3\\\\(\\\\) <\$1>`"],
 260                        [$type_member, "\\:c\\:type\\:`\$1\$2\$3 <\$1>`"],
 261                        [$type_fp_param, "**\$1\\\\(\\\\)**"],
 262                        [$type_fp_param2, "**\$1\\\\(\\\\)**"],
 263                        [$type_func, "\$1()"],
 264                        [$type_enum, "\\:c\\:type\\:`\$1 <\$2>`"],
 265                        [$type_struct, "\\:c\\:type\\:`\$1 <\$2>`"],
 266                        [$type_typedef, "\\:c\\:type\\:`\$1 <\$2>`"],
 267                        [$type_union, "\\:c\\:type\\:`\$1 <\$2>`"],
 268                        # in rst this can refer to any type
 269                        [$type_fallback, "\\:c\\:type\\:`\$1`"],
 270                        [$type_param_ref, "**\$1\$2**"]
 271                       );
 272 my $blankline_rst = "\n";
 273
 274 # read arguments
 275 if ($#ARGV == -1) {
 276     usage();
 277 }
 278
 279 my $kernelversion;
 280 my ($sphinx_major, $sphinx_minor, $sphinx_patch);
 281
 282 my $dohighlight = "";
 283
 284 my $verbose = 0;
 285 my $Werror = 0;
 286 my $output_mode = "rst";
 287 my $output_preformatted = 0;
 288 my $no_doc_sections = 0;
 289 my $enable_lineno = 0;
 290 my @highlights = @highlights_rst;
 291 my $blankline = $blankline_rst;
 292 my $modulename = "Kernel API";
 293
 294 use constant {
 295     OUTPUT_ALL          => 0, # output all symbols and doc sections
 296     OUTPUT_INCLUDE      => 1, # output only specified symbols
 297     OUTPUT_EXPORTED     => 2, # output exported symbols
 298     OUTPUT_INTERNAL     => 3, # output non-exported symbols
 299 };
 300 my $output_selection = OUTPUT_ALL;
 301 my $show_not_found = 0; # No longer used
 302
 303 my @export_file_list;
 304
 305 my @build_time;
 306 if (defined($ENV{'KBUILD_BUILD_TIMESTAMP'}) &&
 307     (my $seconds = `date -d"${ENV{'KBUILD_BUILD_TIMESTAMP'}}" +%s`) ne '') {
 308     @build_time = gmtime($seconds);
 309 } else {
 310     @build_time = localtime;
 311 }
 312
 313 my $man_date = ('January', 'February', 'March', 'April', 'May', 'June',
 314                 'July', 'August', 'September', 'October',
 315                 'November', 'December')[$build_time[4]] .
 316   " " . ($build_time[5]+1900);
 317
 318 # Essentially these are globals.
 319 # They probably want to be tidied up, made more localised or something.
 320 # CAVEAT EMPTOR!  Some of the others I localised may not want to be, which
 321 # could cause "use of undefined value" or other bugs.
 322 my ($function, %function_table, %parametertypes, $declaration_purpose);
 323 my %nosymbol_table = ();
 324 my $declaration_start_line;
 325 my ($type, $declaration_name, $return_type);
 326 my ($newsection, $newcontents, $prototype, $brcount, %source_map);
 327
 328 if (defined($ENV{'KBUILD_VERBOSE'})) {
 329         $verbose = "$ENV{'KBUILD_VERBOSE'}";
 330 }
 331
 332 if (defined($ENV{'KCFLAGS'})) {
 333         my $kcflags = "$ENV{'KCFLAGS'}";
 334
 335         if ($kcflags =~ /Werror/) {
 336                 $Werror = 1;
 337         }
 338 }
 339
 340 if (defined($ENV{'KDOC_WERROR'})) {
 341         $Werror = "$ENV{'KDOC_WERROR'}";
 342 }
 343
 344 # Generated docbook code is inserted in a template at a point where
 345 # docbook v3.1 requires a non-zero sequence of RefEntry's; see:
 346 # https://www.oasis-open.org/docbook/documentation/reference/html/refentry.html
 347 # We keep track of number of generated entries and generate a dummy
 348 # if needs be to ensure the expanded template can be postprocessed
 349 # into html.
 350 my $section_counter = 0;
 351
 352 my $lineprefix="";
 353
 354 # Parser states
 355 use constant {
 356     STATE_NORMAL        => 0,        # normal code
 357     STATE_NAME          => 1,        # looking for function name
 358     STATE_BODY_MAYBE    => 2,        # body - or maybe more description
 359     STATE_BODY          => 3,        # the body of the comment
 360     STATE_BODY_WITH_BLANK_LINE => 4, # the body, which has a blank line
 361     STATE_PROTO         => 5,        # scanning prototype
 362     STATE_DOCBLOCK      => 6,        # documentation block
 363     STATE_INLINE        => 7,        # gathering doc outside main block
 364 };
 365 my $state;
 366 my $in_doc_sect;
 367 my $leading_space;
 368
 369 # Inline documentation state
 370 use constant {
 371     STATE_INLINE_NA     => 0, # not applicable ($state != STATE_INLINE)
 372     STATE_INLINE_NAME   => 1, # looking for member name (@foo:)
 373     STATE_INLINE_TEXT   => 2, # looking for member documentation
 374     STATE_INLINE_END    => 3, # done
 375     STATE_INLINE_ERROR  => 4, # error - Comment without header was found.
 376                               # Spit a warning as it's not
 377                               # proper kernel-doc and ignore the rest.
 378 };
 379 my $inline_doc_state;
 380
 381 #declaration types: can be
 382 # 'function', 'struct', 'union', 'enum', 'typedef'
 383 my $decl_type;
 384
 385 # Name of the kernel-doc identifier for non-DOC markups
 386 my $identifier;
 387
 388 my $doc_start = '^/\*\*\s*$'; # Allow whitespace at end of comment start.
 389 my $doc_end = '\*/';
 390 my $doc_com = '\s*\*\s*';
 391 my $doc_com_body = '\s*\* ?';
 392 my $doc_decl = $doc_com . '(\w+)';
 393 # @params and a strictly limited set of supported section names
 394 # Specifically:
 395 #   Match @word:
 396 #         @...:
 397 #         @{section-name}:
 398 # while trying to not match literal block starts like "example::"
 399 #
 400 my $doc_sect = $doc_com .
 401     '\s*(\@[.\w]+|\@\.\.\.|description|context|returns?|notes?|examples?)\s*:([^:].*)?$';
 402 my $doc_content = $doc_com_body . '(.*)';
 403 my $doc_block = $doc_com . 'DOC:\s*(.*)?';
 404 my $doc_inline_start = '^\s*/\*\*\s*$';
 405 my $doc_inline_sect = '\s*\*\s*(@\s*[\w][\w\.]*\s*):(.*)';
 406 my $doc_inline_end = '^\s*\*/\s*$';
 407 my $doc_inline_oneline = '^\s*/\*\*\s*(@[\w\s]+):\s*(.*)\s*\*/\s*$';
 408 my $export_symbol = '^\s*EXPORT_SYMBOL(_GPL)?\s*\(\s*(\w+)\s*\)\s*;';
 409 my $function_pointer = qr{([^\(]*\(\*)\s*\)\s*\(([^\)]*)\)};
 410 my $attribute = qr{__attribute__\s*\(\([a-z0-9,_\*\s\(\)]*\)\)}i;
 411
 412 my %parameterdescs;
 413 my %parameterdesc_start_lines;
 414 my @parameterlist;
 415 my %sections;
 416 my @sectionlist;
 417 my %section_start_lines;
 418 my $sectcheck;
 419 my $struct_actual;
 420
 421 my $contents = "";
 422 my $new_start_line = 0;
 423
 424 # the canonical section names. see also $doc_sect above.
 425 my $section_default = "Description";    # default section
 426 my $section_intro = "Introduction";
 427 my $section = $section_default;
 428 my $section_context = "Context";
 429 my $section_return = "Return";
 430
 431 my $undescribed = "-- undescribed --";
 432
 433 reset_state();
 434
 435 while ($ARGV[0] =~ m/^--?(.*)/) {
 436     my $cmd = $1;
 437     shift @ARGV;
 438     if ($cmd eq "man") {
 439         $output_mode = "man";
 440         @highlights = @highlights_man;
 441         $blankline = $blankline_man;
 442     } elsif ($cmd eq "rst") {
 443         $output_mode = "rst";
 444         @highlights = @highlights_rst;
 445         $blankline = $blankline_rst;
 446     } elsif ($cmd eq "none") {
 447         $output_mode = "none";
 448     } elsif ($cmd eq "module") { # not needed for XML, inherits from calling document
 449         $modulename = shift @ARGV;
 450     } elsif ($cmd eq "function") { # to only output specific functions
 451         $output_selection = OUTPUT_INCLUDE;
 452         $function = shift @ARGV;
 453         $function_table{$function} = 1;
 454     } elsif ($cmd eq "nosymbol") { # Exclude specific symbols
 455         my $symbol = shift @ARGV;
 456         $nosymbol_table{$symbol} = 1;
 457     } elsif ($cmd eq "export") { # only exported symbols
 458         $output_selection = OUTPUT_EXPORTED;
 459         %function_table = ();
 460     } elsif ($cmd eq "internal") { # only non-exported symbols
 461         $output_selection = OUTPUT_INTERNAL;
 462         %function_table = ();
 463     } elsif ($cmd eq "export-file") {
 464         my $file = shift @ARGV;
 465         push(@export_file_list, $file);
 466     } elsif ($cmd eq "v") {
 467         $verbose = 1;
 468     } elsif ($cmd eq "Werror") {
 469         $Werror = 1;
 470     } elsif (($cmd eq "h") || ($cmd eq "help")) {
 471         usage();
 472     } elsif ($cmd eq 'no-doc-sections') {
 473             $no_doc_sections = 1;
 474     } elsif ($cmd eq 'enable-lineno') {
 475             $enable_lineno = 1;
 476     } elsif ($cmd eq 'show-not-found') {
 477         $show_not_found = 1;  # A no-op but don't fail
 478     } elsif ($cmd eq "sphinx-version") {
 479         my $ver_string = shift @ARGV;
 480         if ($ver_string =~ m/^(\d+)(\.\d+)?(\.\d+)?/) {
 481             $sphinx_major = $1;
 482             if (defined($2)) {
 483                 $sphinx_minor = substr($2,1);
 484             } else {
 485                 $sphinx_minor = 0;
 486             }
 487             if (defined($3)) {
 488                 $sphinx_patch = substr($3,1)
 489             } else {
 490                 $sphinx_patch = 0;
 491             }
 492         } else {
 493             die "Sphinx version should either major.minor or major.minor.patch format\n";
 494         }
 495     } else {
 496         # Unknown argument
 497         usage();
 498     }
 499 }
 500
 501 # continue execution near EOF;
 502
 503 # The C domain dialect changed on Sphinx 3. So, we need to check the
 504 # version in order to produce the right tags.
 505 sub findprog($)
 506 {
 507         foreach(split(/:/, $ENV{PATH})) {
 508                 return "$_/$_[0]" if(-x "$_/$_[0]");
 509         }
 510 }
 511
 512 sub get_sphinx_version()
 513 {
 514         my $ver;
 515
 516         my $cmd = "sphinx-build";
 517         if (!findprog($cmd)) {
 518                 my $cmd = "sphinx-build3";
 519                 if (!findprog($cmd)) {
 520                         $sphinx_major = 1;
 521                         $sphinx_minor = 2;
 522                         $sphinx_patch = 0;
 523                         printf STDERR "Warning: Sphinx version not found. Using default (Sphinx version %d.%d.%d)\n",
 524                                $sphinx_major, $sphinx_minor, $sphinx_patch;
 525                         return;
 526                 }
 527         }
 528
 529         open IN, "$cmd --version 2>&1 |";
 530         while (<IN>) {
 531                 if (m/^\s*sphinx-build\s+([\d]+)\.([\d\.]+)(\+\/[\da-f]+)?$/) {
 532                         $sphinx_major = $1;
 533                         $sphinx_minor = $2;
 534                         $sphinx_patch = $3;
 535                         last;
 536                 }
 537                 # Sphinx 1.2.x uses a different format
 538                 if (m/^\s*Sphinx.*\s+([\d]+)\.([\d\.]+)$/) {
 539                         $sphinx_major = $1;
 540                         $sphinx_minor = $2;
 541                         $sphinx_patch = $3;
 542                         last;
 543                 }
 544         }
 545         close IN;
 546 }
 547
 548 # get kernel version from env
 549 sub get_kernel_version() {
 550     my $version = 'unknown kernel version';
 551
 552     if (defined($ENV{'KERNELVERSION'})) {
 553         $version = $ENV{'KERNELVERSION'};
 554     }
 555     return $version;
 556 }
 557
 558 #
 559 sub print_lineno {
 560     my $lineno = shift;
 561     if ($enable_lineno && defined($lineno)) {
 562         print "#define LINENO " . $lineno . "\n";
 563     }
 564 }
 565 ##
 566 # dumps section contents to arrays/hashes intended for that purpose.
 567 #
 568 sub dump_section {
 569     my $file = shift;
 570     my $name = shift;
 571     my $contents = join "\n", @_;
 572
 573     if ($name =~ m/$type_param/) {
 574         $name = $1;
 575         $parameterdescs{$name} = $contents;
 576         $sectcheck = $sectcheck . $name . " ";
 577         $parameterdesc_start_lines{$name} = $new_start_line;
 578         $new_start_line = 0;
 579     } elsif ($name eq "@\.\.\.") {
 580         $name = "...";
 581         $parameterdescs{$name} = $contents;
 582         $sectcheck = $sectcheck . $name . " ";
 583         $parameterdesc_start_lines{$name} = $new_start_line;
 584         $new_start_line = 0;
 585     } else {
 586         if (defined($sections{$name}) && ($sections{$name} ne "")) {
 587             # Only warn on user specified duplicate section names.
 588             if ($name ne $section_default) {
 589                 print STDERR "${file}:$.: warning: duplicate section name '$name'\n";
 590                 ++$warnings;
 591             }
 592             $sections{$name} .= $contents;
 593         } else {
 594             $sections{$name} = $contents;
 595             push @sectionlist, $name;
 596             $section_start_lines{$name} = $new_start_line;
 597             $new_start_line = 0;
 598         }
 599     }
 600 }
 601
 602 ##
 603 # dump DOC: section after checking that it should go out
 604 #
 605 sub dump_doc_section {
 606     my $file = shift;
 607     my $name = shift;
 608     my $contents = join "\n", @_;
 609
 610     if ($no_doc_sections) {
 611         return;
 612     }
 613
 614     return if (defined($nosymbol_table{$name}));
 615
 616     if (($output_selection == OUTPUT_ALL) ||
 617         (($output_selection == OUTPUT_INCLUDE) &&
 618          defined($function_table{$name})))
 619     {
 620         dump_section($file, $name, $contents);
 621         output_blockhead({'sectionlist' => \@sectionlist,
 622                           'sections' => \%sections,
 623                           'module' => $modulename,
 624                           'content-only' => ($output_selection != OUTPUT_ALL), });
 625     }
 626 }
 627
 628 ##
 629 # output function
 630 #
 631 # parameterdescs, a hash.
 632 #  function => "function name"
 633 #  parameterlist => @list of parameters
 634 #  parameterdescs => %parameter descriptions
 635 #  sectionlist => @list of sections
 636 #  sections => %section descriptions
 637 #
 638
 639 sub output_highlight {
 640     my $contents = join "\n",@_;
 641     my $line;
 642
 643 #   DEBUG
 644 #   if (!defined $contents) {
 645 #       use Carp;
 646 #       confess "output_highlight got called with no args?\n";
 647 #   }
 648
 649 #   print STDERR "contents b4:$contents\n";
 650     eval $dohighlight;
 651     die $@ if $@;
 652 #   print STDERR "contents af:$contents\n";
 653
 654     foreach $line (split "\n", $contents) {
 655         if (! $output_preformatted) {
 656             $line =~ s/^\s*//;
 657         }
 658         if ($line eq ""){
 659             if (! $output_preformatted) {
 660                 print $lineprefix, $blankline;
 661             }
 662         } else {
 663             if ($output_mode eq "man" && substr($line, 0, 1) eq ".") {
 664                 print "\\&$line";
 665             } else {
 666                 print $lineprefix, $line;
 667             }
 668         }
 669         print "\n";
 670     }
 671 }
 672
 673 ##
 674 # output function in man
 675 sub output_function_man(%) {
 676     my %args = %{$_[0]};
 677     my ($parameter, $section);
 678     my $count;
 679
 680     print ".TH \"$args{'function'}\" 9 \"$args{'function'}\" \"$man_date\" \"Kernel Hacker's Manual\" LINUX\n";
 681
 682     print ".SH NAME\n";
 683     print $args{'function'} . " \\- " . $args{'purpose'} . "\n";
 684
 685     print ".SH SYNOPSIS\n";
 686     if ($args{'functiontype'} ne "") {
 687         print ".B \"" . $args{'functiontype'} . "\" " . $args{'function'} . "\n";
 688     } else {
 689         print ".B \"" . $args{'function'} . "\n";
 690     }
 691     $count = 0;
 692     my $parenth = "(";
 693     my $post = ",";
 694     foreach my $parameter (@{$args{'parameterlist'}}) {
 695         if ($count == $#{$args{'parameterlist'}}) {
 696             $post = ");";
 697         }
 698         $type = $args{'parametertypes'}{$parameter};
 699         if ($type =~ m/$function_pointer/) {
 700             # pointer-to-function
 701             print ".BI \"" . $parenth . $1 . "\" " . " \") (" . $2 . ")" . $post . "\"\n";
 702         } else {
 703             $type =~ s/([^\*])$/$1 /;
 704             print ".BI \"" . $parenth . $type . "\" " . " \"" . $post . "\"\n";
 705         }
 706         $count++;
 707         $parenth = "";
 708     }
 709
 710     print ".SH ARGUMENTS\n";
 711     foreach $parameter (@{$args{'parameterlist'}}) {
 712         my $parameter_name = $parameter;
 713         $parameter_name =~ s/\[.*//;
 714
 715         print ".IP \"" . $parameter . "\" 12\n";
 716         output_highlight($args{'parameterdescs'}{$parameter_name});
 717     }
 718     foreach $section (@{$args{'sectionlist'}}) {
 719         print ".SH \"", uc $section, "\"\n";
 720         output_highlight($args{'sections'}{$section});
 721     }
 722 }
 723
 724 ##
 725 # output enum in man
 726 sub output_enum_man(%) {
 727     my %args = %{$_[0]};
 728     my ($parameter, $section);
 729     my $count;
 730
 731     print ".TH \"$args{'module'}\" 9 \"enum $args{'enum'}\" \"$man_date\" \"API Manual\" LINUX\n";
 732
 733     print ".SH NAME\n";
 734     print "enum " . $args{'enum'} . " \\- " . $args{'purpose'} . "\n";
 735
 736     print ".SH SYNOPSIS\n";
 737     print "enum " . $args{'enum'} . " {\n";
 738     $count = 0;
 739     foreach my $parameter (@{$args{'parameterlist'}}) {
 740         print ".br\n.BI \"    $parameter\"\n";
 741         if ($count == $#{$args{'parameterlist'}}) {
 742             print "\n};\n";
 743             last;
 744         }
 745         else {
 746             print ", \n.br\n";
 747         }
 748         $count++;
 749     }
 750
 751     print ".SH Constants\n";
 752     foreach $parameter (@{$args{'parameterlist'}}) {
 753         my $parameter_name = $parameter;
 754         $parameter_name =~ s/\[.*//;
 755
 756         print ".IP \"" . $parameter . "\" 12\n";
 757         output_highlight($args{'parameterdescs'}{$parameter_name});
 758     }
 759     foreach $section (@{$args{'sectionlist'}}) {
 760         print ".SH \"$section\"\n";
 761         output_highlight($args{'sections'}{$section});
 762     }
 763 }
 764
 765 ##
 766 # output struct in man
 767 sub output_struct_man(%) {
 768     my %args = %{$_[0]};
 769     my ($parameter, $section);
 770
 771     print ".TH \"$args{'module'}\" 9 \"" . $args{'type'} . " " . $args{'struct'} . "\" \"$man_date\" \"API Manual\" LINUX\n";
 772
 773     print ".SH NAME\n";
 774     print $args{'type'} . " " . $args{'struct'} . " \\- " . $args{'purpose'} . "\n";
 775
 776     my $declaration = $args{'definition'};
 777     $declaration =~ s/\t/  /g;
 778     $declaration =~ s/\n/"\n.br\n.BI \"/g;
 779     print ".SH SYNOPSIS\n";
 780     print $args{'type'} . " " . $args{'struct'} . " {\n.br\n";
 781     print ".BI \"$declaration\n};\n.br\n\n";
 782
 783     print ".SH Members\n";
 784     foreach $parameter (@{$args{'parameterlist'}}) {
 785         ($parameter =~ /^#/) && next;
 786
 787         my $parameter_name = $parameter;
 788         $parameter_name =~ s/\[.*//;
 789
 790         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
 791         print ".IP \"" . $parameter . "\" 12\n";
 792         output_highlight($args{'parameterdescs'}{$parameter_name});
 793     }
 794     foreach $section (@{$args{'sectionlist'}}) {
 795         print ".SH \"$section\"\n";
 796         output_highlight($args{'sections'}{$section});
 797     }
 798 }
 799
 800 ##
 801 # output typedef in man
 802 sub output_typedef_man(%) {
 803     my %args = %{$_[0]};
 804     my ($parameter, $section);
 805
 806     print ".TH \"$args{'module'}\" 9 \"$args{'typedef'}\" \"$man_date\" \"API Manual\" LINUX\n";
 807
 808     print ".SH NAME\n";
 809     print "typedef " . $args{'typedef'} . " \\- " . $args{'purpose'} . "\n";
 810
 811     foreach $section (@{$args{'sectionlist'}}) {
 812         print ".SH \"$section\"\n";
 813         output_highlight($args{'sections'}{$section});
 814     }
 815 }
 816
 817 sub output_blockhead_man(%) {
 818     my %args = %{$_[0]};
 819     my ($parameter, $section);
 820     my $count;
 821
 822     print ".TH \"$args{'module'}\" 9 \"$args{'module'}\" \"$man_date\" \"API Manual\" LINUX\n";
 823
 824     foreach $section (@{$args{'sectionlist'}}) {
 825         print ".SH \"$section\"\n";
 826         output_highlight($args{'sections'}{$section});
 827     }
 828 }
 829
 830 ##
 831 # output in restructured text
 832 #
 833
 834 #
 835 # This could use some work; it's used to output the DOC: sections, and
 836 # starts by putting out the name of the doc section itself, but that tends
 837 # to duplicate a header already in the template file.
 838 #
 839 sub output_blockhead_rst(%) {
 840     my %args = %{$_[0]};
 841     my ($parameter, $section);
 842
 843     foreach $section (@{$args{'sectionlist'}}) {
 844         next if (defined($nosymbol_table{$section}));
 845
 846         if ($output_selection != OUTPUT_INCLUDE) {
 847             print ".. _$section:\n\n";
 848             print "**$section**\n\n";
 849         }
 850         print_lineno($section_start_lines{$section});
 851         output_highlight_rst($args{'sections'}{$section});
 852         print "\n";
 853     }
 854 }
 855
 856 #
 857 # Apply the RST highlights to a sub-block of text.
 858 #
 859 sub highlight_block($) {
 860     # The dohighlight kludge requires the text be called $contents
 861     my $contents = shift;
 862     eval $dohighlight;
 863     die $@ if $@;
 864     return $contents;
 865 }
 866
 867 #
 868 # Regexes used only here.
 869 #
 870 my $sphinx_literal = '^[^.].*::$';
 871 my $sphinx_cblock = '^\.\.\ +code-block::';
 872
 873 sub output_highlight_rst {
 874     my $input = join "\n",@_;
 875     my $output = "";
 876     my $line;
 877     my $in_literal = 0;
 878     my $litprefix;
 879     my $block = "";
 880
 881     foreach $line (split "\n",$input) {
 882         #
 883         # If we're in a literal block, see if we should drop out
 884         # of it.  Otherwise pass the line straight through unmunged.
 885         #
 886         if ($in_literal) {
 887             if (! ($line =~ /^\s*$/)) {
 888                 #
 889                 # If this is the first non-blank line in a literal
 890                 # block we need to figure out what the proper indent is.
 891                 #
 892                 if ($litprefix eq "") {
 893                     $line =~ /^(\s*)/;
 894                     $litprefix = '^' . $1;
 895                     $output .= $line . "\n";
 896                 } elsif (! ($line =~ /$litprefix/)) {
 897                     $in_literal = 0;
 898                 } else {
 899                     $output .= $line . "\n";
 900                 }
 901             } else {
 902                 $output .= $line . "\n";
 903             }
 904         }
 905         #
 906         # Not in a literal block (or just dropped out)
 907         #
 908         if (! $in_literal) {
 909             $block .= $line . "\n";
 910             if (($line =~ /$sphinx_literal/) || ($line =~ /$sphinx_cblock/)) {
 911                 $in_literal = 1;
 912                 $litprefix = "";
 913                 $output .= highlight_block($block);
 914                 $block = ""
 915             }
 916         }
 917     }
 918
 919     if ($block) {
 920         $output .= highlight_block($block);
 921     }
 922     foreach $line (split "\n", $output) {
 923         print $lineprefix . $line . "\n";
 924     }
 925 }
 926
 927 sub output_function_rst(%) {
 928     my %args = %{$_[0]};
 929     my ($parameter, $section);
 930     my $oldprefix = $lineprefix;
 931     my $start = "";
 932     my $is_macro = 0;
 933
 934     if ($sphinx_major < 3) {
 935         if ($args{'typedef'}) {
 936             print ".. c:type:: ". $args{'function'} . "\n\n";
 937             print_lineno($declaration_start_line);
 938             print "   **Typedef**: ";
 939             $lineprefix = "";
 940             output_highlight_rst($args{'purpose'});
 941             $start = "\n\n**Syntax**\n\n  ``";
 942             $is_macro = 1;
 943         } else {
 944             print ".. c:function:: ";
 945         }
 946     } else {
 947         if ($args{'typedef'} || $args{'functiontype'} eq "") {
 948             $is_macro = 1;
 949             print ".. c:macro:: ". $args{'function'} . "\n\n";
 950         } else {
 951             print ".. c:function:: ";
 952         }
 953
 954         if ($args{'typedef'}) {
 955             print_lineno($declaration_start_line);
 956             print "   **Typedef**: ";
 957             $lineprefix = "";
 958             output_highlight_rst($args{'purpose'});
 959             $start = "\n\n**Syntax**\n\n  ``";
 960         } else {
 961             print "``" if ($is_macro);
 962         }
 963     }
 964     if ($args{'functiontype'} ne "") {
 965         $start .= $args{'functiontype'} . " " . $args{'function'} . " (";
 966     } else {
 967         $start .= $args{'function'} . " (";
 968     }
 969     print $start;
 970
 971     my $count = 0;
 972     foreach my $parameter (@{$args{'parameterlist'}}) {
 973         if ($count ne 0) {
 974             print ", ";
 975         }
 976         $count++;
 977         $type = $args{'parametertypes'}{$parameter};
 978
 979         if ($type =~ m/$function_pointer/) {
 980             # pointer-to-function
 981             print $1 . $parameter . ") (" . $2 . ")";
 982         } else {
 983             print $type;
 984         }
 985     }
 986     if ($is_macro) {
 987         print ")``\n\n";
 988     } else {
 989         print ")\n\n";
 990     }
 991     if (!$args{'typedef'}) {
 992         print_lineno($declaration_start_line);
 993         $lineprefix = "   ";
 994         output_highlight_rst($args{'purpose'});
 995         print "\n";
 996     }
 997
 998     print "**Parameters**\n\n";
 999     $lineprefix = "  ";
1000     foreach $parameter (@{$args{'parameterlist'}}) {
1001         my $parameter_name = $parameter;
1002         $parameter_name =~ s/\[.*//;
1003         $type = $args{'parametertypes'}{$parameter};
1004
1005         if ($type ne "") {
1006             print "``$type``\n";
1007         } else {
1008             print "``$parameter``\n";
1009         }
1010
1011         print_lineno($parameterdesc_start_lines{$parameter_name});
1012
1013         if (defined($args{'parameterdescs'}{$parameter_name}) &&
1014             $args{'parameterdescs'}{$parameter_name} ne $undescribed) {
1015             output_highlight_rst($args{'parameterdescs'}{$parameter_name});
1016         } else {
1017             print "  *undescribed*\n";
1018         }
1019         print "\n";
1020     }
1021
1022     $lineprefix = $oldprefix;
1023     output_section_rst(@_);
1024 }
1025
1026 sub output_section_rst(%) {
1027     my %args = %{$_[0]};
1028     my $section;
1029     my $oldprefix = $lineprefix;
1030     $lineprefix = "";
1031
1032     foreach $section (@{$args{'sectionlist'}}) {
1033         print "**$section**\n\n";
1034         print_lineno($section_start_lines{$section});
1035         output_highlight_rst($args{'sections'}{$section});
1036         print "\n";
1037     }
1038     print "\n";
1039     $lineprefix = $oldprefix;
1040 }
1041
1042 sub output_enum_rst(%) {
1043     my %args = %{$_[0]};
1044     my ($parameter);
1045     my $oldprefix = $lineprefix;
1046     my $count;
1047
1048     if ($sphinx_major < 3) {
1049         my $name = "enum " . $args{'enum'};
1050         print "\n\n.. c:type:: " . $name . "\n\n";
1051     } else {
1052         my $name = $args{'enum'};
1053         print "\n\n.. c:enum:: " . $name . "\n\n";
1054     }
1055     print_lineno($declaration_start_line);
1056     $lineprefix = "   ";
1057     output_highlight_rst($args{'purpose'});
1058     print "\n";
1059
1060     print "**Constants**\n\n";
1061     $lineprefix = "  ";
1062     foreach $parameter (@{$args{'parameterlist'}}) {
1063         print "``$parameter``\n";
1064         if ($args{'parameterdescs'}{$parameter} ne $undescribed) {
1065             output_highlight_rst($args{'parameterdescs'}{$parameter});
1066         } else {
1067             print "  *undescribed*\n";
1068         }
1069         print "\n";
1070     }
1071
1072     $lineprefix = $oldprefix;
1073     output_section_rst(@_);
1074 }
1075
1076 sub output_typedef_rst(%) {
1077     my %args = %{$_[0]};
1078     my ($parameter);
1079     my $oldprefix = $lineprefix;
1080     my $name;
1081
1082     if ($sphinx_major < 3) {
1083         $name = "typedef " . $args{'typedef'};
1084     } else {
1085         $name = $args{'typedef'};
1086     }
1087     print "\n\n.. c:type:: " . $name . "\n\n";
1088     print_lineno($declaration_start_line);
1089     $lineprefix = "   ";
1090     output_highlight_rst($args{'purpose'});
1091     print "\n";
1092
1093     $lineprefix = $oldprefix;
1094     output_section_rst(@_);
1095 }
1096
1097 sub output_struct_rst(%) {
1098     my %args = %{$_[0]};
1099     my ($parameter);
1100     my $oldprefix = $lineprefix;
1101
1102     if ($sphinx_major < 3) {
1103         my $name = $args{'type'} . " " . $args{'struct'};
1104         print "\n\n.. c:type:: " . $name . "\n\n";
1105     } else {
1106         my $name = $args{'struct'};
1107         if ($args{'type'} eq 'union') {
1108             print "\n\n.. c:union:: " . $name . "\n\n";
1109         } else {
1110             print "\n\n.. c:struct:: " . $name . "\n\n";
1111         }
1112     }
1113     print_lineno($declaration_start_line);
1114     $lineprefix = "   ";
1115     output_highlight_rst($args{'purpose'});
1116     print "\n";
1117
1118     print "**Definition**\n\n";
1119     print "::\n\n";
1120     my $declaration = $args{'definition'};
1121     $declaration =~ s/\t/  /g;
1122     print "  " . $args{'type'} . " " . $args{'struct'} . " {\n$declaration  };\n\n";
1123
1124     print "**Members**\n\n";
1125     $lineprefix = "  ";
1126     foreach $parameter (@{$args{'parameterlist'}}) {
1127         ($parameter =~ /^#/) && next;
1128
1129         my $parameter_name = $parameter;
1130         $parameter_name =~ s/\[.*//;
1131
1132         ($args{'parameterdescs'}{$parameter_name} ne $undescribed) || next;
1133         $type = $args{'parametertypes'}{$parameter};
1134         print_lineno($parameterdesc_start_lines{$parameter_name});
1135         print "``" . $parameter . "``\n";
1136         output_highlight_rst($args{'parameterdescs'}{$parameter_name});
1137         print "\n";
1138     }
1139     print "\n";
1140
1141     $lineprefix = $oldprefix;
1142     output_section_rst(@_);
1143 }
1144
1145 ## none mode output functions
1146
1147 sub output_function_none(%) {
1148 }
1149
1150 sub output_enum_none(%) {
1151 }
1152
1153 sub output_typedef_none(%) {
1154 }
1155
1156 sub output_struct_none(%) {
1157 }
1158
1159 sub output_blockhead_none(%) {
1160 }
1161
1162 ##
1163 # generic output function for all types (function, struct/union, typedef, enum);
1164 # calls the generated, variable output_ function name based on
1165 # functype and output_mode
1166 sub output_declaration {
1167     no strict 'refs';
1168     my $name = shift;
1169     my $functype = shift;
1170     my $func = "output_${functype}_$output_mode";
1171
1172     return if (defined($nosymbol_table{$name}));
1173
1174     if (($output_selection == OUTPUT_ALL) ||
1175         (($output_selection == OUTPUT_INCLUDE ||
1176           $output_selection == OUTPUT_EXPORTED) &&
1177          defined($function_table{$name})) ||
1178         ($output_selection == OUTPUT_INTERNAL &&
1179          !($functype eq "function" && defined($function_table{$name}))))
1180     {
1181         &$func(@_);
1182         $section_counter++;
1183     }
1184 }
1185
1186 ##
1187 # generic output function - calls the right one based on current output mode.
1188 sub output_blockhead {
1189     no strict 'refs';
1190     my $func = "output_blockhead_" . $output_mode;
1191     &$func(@_);
1192     $section_counter++;
1193 }
1194
1195 ##
1196 # takes a declaration (struct, union, enum, typedef) and
1197 # invokes the right handler. NOT called for functions.
1198 sub dump_declaration($$) {
1199     no strict 'refs';
1200     my ($prototype, $file) = @_;
1201     my $func = "dump_" . $decl_type;
1202     &$func(@_);
1203 }
1204
1205 sub dump_union($$) {
1206     dump_struct(@_);
1207 }
1208
1209 sub dump_struct($$) {
1210     my $x = shift;
1211     my $file = shift;
1212     my $decl_type;
1213     my $members;
1214     my $type = qr{struct|union};
1215     # For capturing struct/union definition body, i.e. "{members*}qualifiers*"
1216     my $qualifiers = qr{$attribute|__packed|__aligned|____cacheline_aligned_in_smp|____cacheline_aligned};
1217     my $definition_body = qr{\{(.*)\}\s*$qualifiers*};
1218     my $struct_members = qr{($type)([^\{\};]+)\{([^\{\}]*)\}([^\{\}\;]*)\;};
1219
1220     if ($x =~ /($type)\s+(\w+)\s*$definition_body/) {
1221         $decl_type = $1;
1222         $declaration_name = $2;
1223         $members = $3;
1224     } elsif ($x =~ /typedef\s+($type)\s*$definition_body\s*(\w+)\s*;/) {
1225         $decl_type = $1;
1226         $declaration_name = $3;
1227         $members = $2;
1228     }
1229
1230     if ($members) {
1231         if ($identifier ne $declaration_name) {
1232             print STDERR "${file}:$.: warning: expecting prototype for $decl_type $identifier. Prototype was for $decl_type $declaration_name instead\n";
1233             return;
1234         }
1235
1236         # ignore members marked private:
1237         $members =~ s/\/\*\s*private:.*?\/\*\s*public:.*?\*\///gosi;
1238         $members =~ s/\/\*\s*private:.*//gosi;
1239         # strip comments:
1240         $members =~ s/\/\*.*?\*\///gos;
1241         # strip attributes
1242         $members =~ s/\s*$attribute/ /gi;
1243         $members =~ s/\s*__aligned\s*\([^;]*\)/ /gos;
1244         $members =~ s/\s*__packed\s*/ /gos;
1245         $members =~ s/\s*CRYPTO_MINALIGN_ATTR/ /gos;
1246         $members =~ s/\s*____cacheline_aligned_in_smp/ /gos;
1247         $members =~ s/\s*____cacheline_aligned/ /gos;
1248         # unwrap struct_group():
1249         # - first eat non-declaration parameters and rewrite for final match
1250         # - then remove macro, outer parens, and trailing semicolon
1251         $members =~ s/\bstruct_group\s*\(([^,]*,)/STRUCT_GROUP(/gos;
1252         $members =~ s/\bstruct_group_(attr|tagged)\s*\(([^,]*,){2}/STRUCT_GROUP(/gos;
1253         $members =~ s/\b__struct_group\s*\(([^,]*,){3}/STRUCT_GROUP(/gos;
1254         $members =~ s/\bSTRUCT_GROUP(\(((?:(?>[^)(]+)|(?1))*)\))[^;]*;/$2/gos;
1255
1256         my $args = qr{([^,)]+)};
1257         # replace DECLARE_BITMAP
1258         $members =~ s/__ETHTOOL_DECLARE_LINK_MODE_MASK\s*\(([^\)]+)\)/DECLARE_BITMAP($1, __ETHTOOL_LINK_MODE_MASK_NBITS)/gos;
1259         $members =~ s/DECLARE_BITMAP\s*\($args,\s*$args\)/unsigned long $1\[BITS_TO_LONGS($2)\]/gos;
1260         # replace DECLARE_HASHTABLE
1261         $members =~ s/DECLARE_HASHTABLE\s*\($args,\s*$args\)/unsigned long $1\[1 << (($2) - 1)\]/gos;
1262         # replace DECLARE_KFIFO
1263         $members =~ s/DECLARE_KFIFO\s*\($args,\s*$args,\s*$args\)/$2 \*$1/gos;
1264         # replace DECLARE_KFIFO_PTR
1265         $members =~ s/DECLARE_KFIFO_PTR\s*\($args,\s*$args\)/$2 \*$1/gos;
1266         # replace DECLARE_FLEX_ARRAY
1267         $members =~ s/(?:__)?DECLARE_FLEX_ARRAY\s*\($args,\s*$args\)/$1 $2\[\]/gos;
1268         my $declaration = $members;
1269
1270         # Split nested struct/union elements as newer ones
1271         while ($members =~ m/$struct_members/) {
1272                 my $newmember;
1273                 my $maintype = $1;
1274                 my $ids = $4;
1275                 my $content = $3;
1276                 foreach my $id(split /,/, $ids) {
1277                         $newmember .= "$maintype $id; ";
1278
1279                         $id =~ s/[:\[].*//;
1280                         $id =~ s/^\s*\**(\S+)\s*/$1/;
1281                         foreach my $arg (split /;/, $content) {
1282                                 next if ($arg =~ m/^\s*$/);
1283                                 if ($arg =~ m/^([^\(]+\(\*?\s*)([\w\.]*)(\s*\).*)/) {
1284                                         # pointer-to-function
1285                                         my $type = $1;
1286                                         my $name = $2;
1287                                         my $extra = $3;
1288                                         next if (!$name);
1289                                         if ($id =~ m/^\s*$/) {
1290                                                 # anonymous struct/union
1291                                                 $newmember .= "$type$name$extra; ";
1292                                         } else {
1293                                                 $newmember .= "$type$id.$name$extra; ";
1294                                         }
1295                                 } else {
1296                                         my $type;
1297                                         my $names;
1298                                         $arg =~ s/^\s+//;
1299                                         $arg =~ s/\s+$//;
1300                                         # Handle bitmaps
1301                                         $arg =~ s/:\s*\d+\s*//g;
1302                                         # Handle arrays
1303                                         $arg =~ s/\[.*\]//g;
1304                                         # The type may have multiple words,
1305                                         # and multiple IDs can be defined, like:
1306                                         #       const struct foo, *bar, foobar
1307                                         # So, we remove spaces when parsing the
1308                                         # names, in order to match just names
1309                                         # and commas for the names
1310                                         $arg =~ s/\s*,\s*/,/g;
1311                                         if ($arg =~ m/(.*)\s+([\S+,]+)/) {
1312                                                 $type = $1;
1313                                                 $names = $2;
1314                                         } else {
1315                                                 $newmember .= "$arg; ";
1316                                                 next;
1317                                         }
1318                                         foreach my $name (split /,/, $names) {
1319                                                 $name =~ s/^\s*\**(\S+)\s*/$1/;
1320                                                 next if (($name =~ m/^\s*$/));
1321                                                 if ($id =~ m/^\s*$/) {
1322                                                         # anonymous struct/union
1323                                                         $newmember .= "$type $name; ";
1324                                                 } else {
1325                                                         $newmember .= "$type $id.$name; ";
1326                                                 }
1327                                         }
1328                                 }
1329                         }
1330                 }
1331                 $members =~ s/$struct_members/$newmember/;
1332         }
1333
1334         # Ignore other nested elements, like enums
1335         $members =~ s/(\{[^\{\}]*\})//g;
1336
1337         create_parameterlist($members, ';', $file, $declaration_name);
1338         check_sections($file, $declaration_name, $decl_type, $sectcheck, $struct_actual);
1339
1340         # Adjust declaration for better display
1341         $declaration =~ s/([\{;])/$1\n/g;
1342         $declaration =~ s/\}\s+;/};/g;
1343         # Better handle inlined enums
1344         do {} while ($declaration =~ s/(enum\s+\{[^\}]+),([^\n])/$1,\n$2/);
1345
1346         my @def_args = split /\n/, $declaration;
1347         my $level = 1;
1348         $declaration = "";
1349         foreach my $clause (@def_args) {
1350                 $clause =~ s/^\s+//;
1351                 $clause =~ s/\s+$//;
1352                 $clause =~ s/\s+/ /;
1353                 next if (!$clause);
1354                 $level-- if ($clause =~ m/(\})/ && $level > 1);
1355                 if (!($clause =~ m/^\s*#/)) {
1356                         $declaration .= "\t" x $level;
1357                 }
1358                 $declaration .= "\t" . $clause . "\n";
1359                 $level++ if ($clause =~ m/(\{)/ && !($clause =~m/\}/));
1360         }
1361         output_declaration($declaration_name,
1362                            'struct',
1363                            {'struct' => $declaration_name,
1364                             'module' => $modulename,
1365                             'definition' => $declaration,
1366                             'parameterlist' => \@parameterlist,
1367                             'parameterdescs' => \%parameterdescs,
1368                             'parametertypes' => \%parametertypes,
1369                             'sectionlist' => \@sectionlist,
1370                             'sections' => \%sections,
1371                             'purpose' => $declaration_purpose,
1372                             'type' => $decl_type
1373                            });
1374     }
1375     else {
1376         print STDERR "${file}:$.: error: Cannot parse struct or union!\n";
1377         ++$errors;
1378     }
1379 }
1380
1381
1382 sub show_warnings($$) {
1383         my $functype = shift;
1384         my $name = shift;
1385
1386         return 0 if (defined($nosymbol_table{$name}));
1387
1388         return 1 if ($output_selection == OUTPUT_ALL);
1389
1390         if ($output_selection == OUTPUT_EXPORTED) {
1391                 if (defined($function_table{$name})) {
1392                         return 1;
1393                 } else {
1394                         return 0;
1395                 }
1396         }
1397         if ($output_selection == OUTPUT_INTERNAL) {
1398                 if (!($functype eq "function" && defined($function_table{$name}))) {
1399                         return 1;
1400                 } else {
1401                         return 0;
1402                 }
1403         }
1404         if ($output_selection == OUTPUT_INCLUDE) {
1405                 if (defined($function_table{$name})) {
1406                         return 1;
1407                 } else {
1408                         return 0;
1409                 }
1410         }
1411         die("Please add the new output type at show_warnings()");
1412 }
1413
1414 sub dump_enum($$) {
1415     my $x = shift;
1416     my $file = shift;
1417     my $members;
1418
1419
1420     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1421     # strip #define macros inside enums
1422     $x =~ s@#\s*((define|ifdef)\s+|endif)[^;]*;@@gos;
1423
1424     if ($x =~ /typedef\s+enum\s*\{(.*)\}\s*(\w*)\s*;/) {
1425         $declaration_name = $2;
1426         $members = $1;
1427     } elsif ($x =~ /enum\s+(\w*)\s*\{(.*)\}/) {
1428         $declaration_name = $1;
1429         $members = $2;
1430     }
1431
1432     if ($members) {
1433         if ($identifier ne $declaration_name) {
1434             if ($identifier eq "") {
1435                 print STDERR "${file}:$.: warning: wrong kernel-doc identifier on line:\n";
1436             } else {
1437                 print STDERR "${file}:$.: warning: expecting prototype for enum $identifier. Prototype was for enum $declaration_name instead\n";
1438             }
1439             return;
1440         }
1441         $declaration_name = "(anonymous)" if ($declaration_name eq "");
1442
1443         my %_members;
1444
1445         $members =~ s/\s+$//;
1446
1447         foreach my $arg (split ',', $members) {
1448             $arg =~ s/^\s*(\w+).*/$1/;
1449             push @parameterlist, $arg;
1450             if (!$parameterdescs{$arg}) {
1451                 $parameterdescs{$arg} = $undescribed;
1452                 if (show_warnings("enum", $declaration_name)) {
1453                         print STDERR "${file}:$.: warning: Enum value '$arg' not described in enum '$declaration_name'\n";
1454                 }
1455             }
1456             $_members{$arg} = 1;
1457         }
1458
1459         while (my ($k, $v) = each %parameterdescs) {
1460             if (!exists($_members{$k})) {
1461                 if (show_warnings("enum", $declaration_name)) {
1462                      print STDERR "${file}:$.: warning: Excess enum value '$k' description in '$declaration_name'\n";
1463                 }
1464             }
1465         }
1466
1467         output_declaration($declaration_name,
1468                            'enum',
1469                            {'enum' => $declaration_name,
1470                             'module' => $modulename,
1471                             'parameterlist' => \@parameterlist,
1472                             'parameterdescs' => \%parameterdescs,
1473                             'sectionlist' => \@sectionlist,
1474                             'sections' => \%sections,
1475                             'purpose' => $declaration_purpose
1476                            });
1477     } else {
1478         print STDERR "${file}:$.: error: Cannot parse enum!\n";
1479         ++$errors;
1480     }
1481 }
1482
1483 my $typedef_type = qr { ((?:\s+[\w\*]+\b){1,8})\s* }x;
1484 my $typedef_ident = qr { \*?\s*(\w\S+)\s* }x;
1485 my $typedef_args = qr { \s*\((.*)\); }x;
1486
1487 my $typedef1 = qr { typedef$typedef_type\($typedef_ident\)$typedef_args }x;
1488 my $typedef2 = qr { typedef$typedef_type$typedef_ident$typedef_args }x;
1489
1490 sub dump_typedef($$) {
1491     my $x = shift;
1492     my $file = shift;
1493
1494     $x =~ s@/\*.*?\*/@@gos;     # strip comments.
1495
1496     # Parse function typedef prototypes
1497     if ($x =~ $typedef1 || $x =~ $typedef2) {
1498         $return_type = $1;
1499         $declaration_name = $2;
1500         my $args = $3;
1501         $return_type =~ s/^\s+//;
1502
1503         if ($identifier ne $declaration_name) {
1504             print STDERR "${file}:$.: warning: expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n";
1505             return;
1506         }
1507
1508         create_parameterlist($args, ',', $file, $declaration_name);
1509
1510         output_declaration($declaration_name,
1511                            'function',
1512                            {'function' => $declaration_name,
1513                             'typedef' => 1,
1514                             'module' => $modulename,
1515                             'functiontype' => $return_type,
1516                             'parameterlist' => \@parameterlist,
1517                             'parameterdescs' => \%parameterdescs,
1518                             'parametertypes' => \%parametertypes,
1519                             'sectionlist' => \@sectionlist,
1520                             'sections' => \%sections,
1521                             'purpose' => $declaration_purpose
1522                            });
1523         return;
1524     }
1525
1526     while (($x =~ /\(*.\)\s*;$/) || ($x =~ /\[*.\]\s*;$/)) {
1527         $x =~ s/\(*.\)\s*;$/;/;
1528         $x =~ s/\[*.\]\s*;$/;/;
1529     }
1530
1531     if ($x =~ /typedef.*\s+(\w+)\s*;/) {
1532         $declaration_name = $1;
1533
1534         if ($identifier ne $declaration_name) {
1535             print STDERR "${file}:$.: warning: expecting prototype for typedef $identifier. Prototype was for typedef $declaration_name instead\n";
1536             return;
1537         }
1538
1539         output_declaration($declaration_name,
1540                            'typedef',
1541                            {'typedef' => $declaration_name,
1542                             'module' => $modulename,
1543                             'sectionlist' => \@sectionlist,
1544                             'sections' => \%sections,
1545                             'purpose' => $declaration_purpose
1546                            });
1547     }
1548     else {
1549         print STDERR "${file}:$.: error: Cannot parse typedef!\n";
1550         ++$errors;
1551     }
1552 }
1553
1554 sub save_struct_actual($) {
1555     my $actual = shift;
1556
1557     # strip all spaces from the actual param so that it looks like one string item
1558     $actual =~ s/\s*//g;
1559     $struct_actual = $struct_actual . $actual . " ";
1560 }
1561
1562 sub create_parameterlist($$$$) {
1563     my $args = shift;
1564     my $splitter = shift;
1565     my $file = shift;
1566     my $declaration_name = shift;
1567     my $type;
1568     my $param;
1569
1570     # temporarily replace commas inside function pointer definition
1571     my $arg_expr = qr{\([^\),]+};
1572     while ($args =~ /$arg_expr,/) {
1573         $args =~ s/($arg_expr),/$1#/g;
1574     }
1575
1576     foreach my $arg (split($splitter, $args)) {
1577         # strip comments
1578         $arg =~ s/\/\*.*\*\///;
1579         # strip leading/trailing spaces
1580         $arg =~ s/^\s*//;
1581         $arg =~ s/\s*$//;
1582         $arg =~ s/\s+/ /;
1583
1584         if ($arg =~ /^#/) {
1585             # Treat preprocessor directive as a typeless variable just to fill
1586             # corresponding data structures "correctly". Catch it later in
1587             # output_* subs.
1588             push_parameter($arg, "", "", $file);
1589         } elsif ($arg =~ m/\(.+\)\s*\(/) {
1590             # pointer-to-function
1591             $arg =~ tr/#/,/;
1592             $arg =~ m/[^\(]+\(\*?\s*([\w\[\]\.]*)\s*\)/;
1593             $param = $1;
1594             $type = $arg;
1595             $type =~ s/([^\(]+\(\*?)\s*$param/$1/;
1596             save_struct_actual($param);
1597             push_parameter($param, $type, $arg, $file, $declaration_name);
1598         } elsif ($arg) {
1599             $arg =~ s/\s*:\s*/:/g;
1600             $arg =~ s/\s*\[/\[/g;
1601
1602             my @args = split('\s*,\s*', $arg);
1603             if ($args[0] =~ m/\*/) {
1604                 $args[0] =~ s/(\*+)\s*/ $1/;
1605             }
1606
1607             my @first_arg;
1608             if ($args[0] =~ /^(.*\s+)(.*?\[.*\].*)$/) {
1609                     shift @args;
1610                     push(@first_arg, split('\s+', $1));
1611                     push(@first_arg, $2);
1612             } else {
1613                     @first_arg = split('\s+', shift @args);
1614             }
1615
1616             unshift(@args, pop @first_arg);
1617             $type = join " ", @first_arg;
1618
1619             foreach $param (@args) {
1620                 if ($param =~ m/^(\*+)\s*(.*)/) {
1621                     save_struct_actual($2);
1622
1623                     push_parameter($2, "$type $1", $arg, $file, $declaration_name);
1624                 }
1625                 elsif ($param =~ m/(.*?):(\d+)/) {
1626                     if ($type ne "") { # skip unnamed bit-fields
1627                         save_struct_actual($1);
1628                         push_parameter($1, "$type:$2", $arg, $file, $declaration_name)
1629                     }
1630                 }
1631                 else {
1632                     save_struct_actual($param);
1633                     push_parameter($param, $type, $arg, $file, $declaration_name);
1634                 }
1635             }
1636         }
1637     }
1638 }
1639
1640 sub push_parameter($$$$$) {
1641         my $param = shift;
1642         my $type = shift;
1643         my $org_arg = shift;
1644         my $file = shift;
1645         my $declaration_name = shift;
1646
1647         if (($anon_struct_union == 1) && ($type eq "") &&
1648             ($param eq "}")) {
1649                 return;         # ignore the ending }; from anon. struct/union
1650         }
1651
1652         $anon_struct_union = 0;
1653         $param =~ s/[\[\)].*//;
1654
1655         if ($type eq "" && $param =~ /\.\.\.$/)
1656         {
1657             if (!$param =~ /\w\.\.\.$/) {
1658               # handles unnamed variable parameters
1659               $param = "...";
1660             }
1661             elsif ($param =~ /\w\.\.\.$/) {
1662               # for named variable parameters of the form `x...`, remove the dots
1663               $param =~ s/\.\.\.$//;
1664             }
1665             if (!defined $parameterdescs{$param} || $parameterdescs{$param} eq "") {
1666                 $parameterdescs{$param} = "variable arguments";
1667             }
1668         }
1669         elsif ($type eq "" && ($param eq "" or $param eq "void"))
1670         {
1671             $param="void";
1672             $parameterdescs{void} = "no arguments";
1673         }
1674         elsif ($type eq "" && ($param eq "struct" or $param eq "union"))
1675         # handle unnamed (anonymous) union or struct:
1676         {
1677                 $type = $param;
1678                 $param = "{unnamed_" . $param . "}";
1679                 $parameterdescs{$param} = "anonymous\n";
1680                 $anon_struct_union = 1;
1681         }
1682
1683         # warn if parameter has no description
1684         # (but ignore ones starting with # as these are not parameters
1685         # but inline preprocessor statements);
1686         # Note: It will also ignore void params and unnamed structs/unions
1687         if (!defined $parameterdescs{$param} && $param !~ /^#/) {
1688                 $parameterdescs{$param} = $undescribed;
1689
1690                 if (show_warnings($type, $declaration_name) && $param !~ /\./) {
1691                         print STDERR
1692                               "${file}:$.: warning: Function parameter or member '$param' not described in '$declaration_name'\n";
1693                         ++$warnings;
1694                 }
1695         }
1696
1697         # strip spaces from $param so that it is one continuous string
1698         # on @parameterlist;
1699         # this fixes a problem where check_sections() cannot find
1700         # a parameter like "addr[6 + 2]" because it actually appears
1701         # as "addr[6", "+", "2]" on the parameter list;
1702         # but it's better to maintain the param string unchanged for output,
1703         # so just weaken the string compare in check_sections() to ignore
1704         # "[blah" in a parameter string;
1705         ###$param =~ s/\s*//g;
1706         push @parameterlist, $param;
1707         $org_arg =~ s/\s\s+/ /g;
1708         $parametertypes{$param} = $org_arg;
1709 }
1710
1711 sub check_sections($$$$$) {
1712         my ($file, $decl_name, $decl_type, $sectcheck, $prmscheck) = @_;
1713         my @sects = split ' ', $sectcheck;
1714         my @prms = split ' ', $prmscheck;
1715         my $err;
1716         my ($px, $sx);
1717         my $prm_clean;          # strip trailing "[array size]" and/or beginning "*"
1718
1719         foreach $sx (0 .. $#sects) {
1720                 $err = 1;
1721                 foreach $px (0 .. $#prms) {
1722                         $prm_clean = $prms[$px];
1723                         $prm_clean =~ s/\[.*\]//;
1724                         $prm_clean =~ s/$attribute//i;
1725                         # ignore array size in a parameter string;
1726                         # however, the original param string may contain
1727                         # spaces, e.g.:  addr[6 + 2]
1728                         # and this appears in @prms as "addr[6" since the
1729                         # parameter list is split at spaces;
1730                         # hence just ignore "[..." for the sections check;
1731                         $prm_clean =~ s/\[.*//;
1732
1733                         ##$prm_clean =~ s/^\**//;
1734                         if ($prm_clean eq $sects[$sx]) {
1735                                 $err = 0;
1736                                 last;
1737                         }
1738                 }
1739                 if ($err) {
1740                         if ($decl_type eq "function") {
1741                                 print STDERR "${file}:$.: warning: " .
1742                                         "Excess function parameter " .
1743                                         "'$sects[$sx]' " .
1744                                         "description in '$decl_name'\n";
1745                                 ++$warnings;
1746                         }
1747                 }
1748         }
1749 }
1750
1751 ##
1752 # Checks the section describing the return value of a function.
1753 sub check_return_section {
1754         my $file = shift;
1755         my $declaration_name = shift;
1756         my $return_type = shift;
1757
1758         # Ignore an empty return type (It's a macro)
1759         # Ignore functions with a "void" return type. (But don't ignore "void *")
1760         if (($return_type eq "") || ($return_type =~ /void\s*\w*\s*$/)) {
1761                 return;
1762         }
1763
1764         if (!defined($sections{$section_return}) ||
1765             $sections{$section_return} eq "") {
1766                 print STDERR "${file}:$.: warning: " .
1767                         "No description found for return value of " .
1768                         "'$declaration_name'\n";
1769                 ++$warnings;
1770         }
1771 }
1772
1773 ##
1774 # takes a function prototype and the name of the current file being
1775 # processed and spits out all the details stored in the global
1776 # arrays/hashes.
1777 sub dump_function($$) {
1778     my $prototype = shift;
1779     my $file = shift;
1780     my $noret = 0;
1781
1782     print_lineno($new_start_line);
1783
1784     $prototype =~ s/^static +//;
1785     $prototype =~ s/^extern +//;
1786     $prototype =~ s/^asmlinkage +//;
1787     $prototype =~ s/^inline +//;
1788     $prototype =~ s/^__inline__ +//;
1789     $prototype =~ s/^__inline +//;
1790     $prototype =~ s/^__always_inline +//;
1791     $prototype =~ s/^noinline +//;
1792     $prototype =~ s/__init +//;
1793     $prototype =~ s/__init_or_module +//;
1794     $prototype =~ s/__deprecated +//;
1795     $prototype =~ s/__flatten +//;
1796     $prototype =~ s/__meminit +//;
1797     $prototype =~ s/__must_check +//;
1798     $prototype =~ s/__weak +//;
1799     $prototype =~ s/__sched +//;
1800     $prototype =~ s/__printf\s*\(\s*\d*\s*,\s*\d*\s*\) +//;
1801     my $define = $prototype =~ s/^#\s*define\s+//; #ak added
1802     $prototype =~ s/__attribute_const__ +//;
1803     $prototype =~ s/__attribute__\s*\(\(
1804             (?:
1805                  [\w\s]++          # attribute name
1806                  (?:\([^)]*+\))?   # attribute arguments
1807                  \s*+,?            # optional comma at the end
1808             )+
1809           \)\)\s+//x;
1810
1811     # Yes, this truly is vile.  We are looking for:
1812     # 1. Return type (may be nothing if we're looking at a macro)
1813     # 2. Function name
1814     # 3. Function parameters.
1815     #
1816     # All the while we have to watch out for function pointer parameters
1817     # (which IIRC is what the two sections are for), C types (these
1818     # regexps don't even start to express all the possibilities), and
1819     # so on.
1820     #
1821     # If you mess with these regexps, it's a good idea to check that
1822     # the following functions' documentation still comes out right:
1823     # - parport_register_device (function pointer parameters)
1824     # - atomic_set (macro)
1825     # - pci_match_device, __copy_to_user (long return type)
1826     my $name = qr{[a-zA-Z0-9_~:]+};
1827     my $prototype_end1 = qr{[^\(]*};
1828     my $prototype_end2 = qr{[^\{]*};
1829     my $prototype_end = qr{\(($prototype_end1|$prototype_end2)\)};
1830     my $type1 = qr{[\w\s]+};
1831     my $type2 = qr{$type1\*+};
1832
1833     if ($define && $prototype =~ m/^()($name)\s+/) {
1834         # This is an object-like macro, it has no return type and no parameter
1835         # list.
1836         # Function-like macros are not allowed to have spaces between
1837         # declaration_name and opening parenthesis (notice the \s+).
1838         $return_type = $1;
1839         $declaration_name = $2;
1840         $noret = 1;
1841     } elsif ($prototype =~ m/^()($name)\s*$prototype_end/ ||
1842         $prototype =~ m/^($type1)\s+($name)\s*$prototype_end/ ||
1843         $prototype =~ m/^($type2+)\s*($name)\s*$prototype_end/)  {
1844         $return_type = $1;
1845         $declaration_name = $2;
1846         my $args = $3;
1847
1848         create_parameterlist($args, ',', $file, $declaration_name);
1849     } else {
1850         print STDERR "${file}:$.: warning: cannot understand function prototype: '$prototype'\n";
1851         return;
1852     }
1853
1854     if ($identifier ne $declaration_name) {
1855         print STDERR "${file}:$.: warning: expecting prototype for $identifier(). Prototype was for $declaration_name() instead\n";
1856         return;
1857     }
1858
1859     my $prms = join " ", @parameterlist;
1860     check_sections($file, $declaration_name, "function", $sectcheck, $prms);
1861
1862     # This check emits a lot of warnings at the moment, because many
1863     # functions don't have a 'Return' doc section. So until the number
1864     # of warnings goes sufficiently down, the check is only performed in
1865     # verbose mode.
1866     # TODO: always perform the check.
1867     if ($verbose && !$noret) {
1868             check_return_section($file, $declaration_name, $return_type);
1869     }
1870
1871     # The function parser can be called with a typedef parameter.
1872     # Handle it.
1873     if ($return_type =~ /typedef/) {
1874         output_declaration($declaration_name,
1875                            'function',
1876                            {'function' => $declaration_name,
1877                             'typedef' => 1,
1878                             'module' => $modulename,
1879                             'functiontype' => $return_type,
1880                             'parameterlist' => \@parameterlist,
1881                             'parameterdescs' => \%parameterdescs,
1882                             'parametertypes' => \%parametertypes,
1883                             'sectionlist' => \@sectionlist,
1884                             'sections' => \%sections,
1885                             'purpose' => $declaration_purpose
1886                            });
1887     } else {
1888         output_declaration($declaration_name,
1889                            'function',
1890                            {'function' => $declaration_name,
1891                             'module' => $modulename,
1892                             'functiontype' => $return_type,
1893                             'parameterlist' => \@parameterlist,
1894                             'parameterdescs' => \%parameterdescs,
1895                             'parametertypes' => \%parametertypes,
1896                             'sectionlist' => \@sectionlist,
1897                             'sections' => \%sections,
1898                             'purpose' => $declaration_purpose
1899                            });
1900     }
1901 }
1902
1903 sub reset_state {
1904     $function = "";
1905     %parameterdescs = ();
1906     %parametertypes = ();
1907     @parameterlist = ();
1908     %sections = ();
1909     @sectionlist = ();
1910     $sectcheck = "";
1911     $struct_actual = "";
1912     $prototype = "";
1913
1914     $state = STATE_NORMAL;
1915     $inline_doc_state = STATE_INLINE_NA;
1916 }
1917
1918 sub tracepoint_munge($) {
1919         my $file = shift;
1920         my $tracepointname = 0;
1921         my $tracepointargs = 0;
1922
1923         if ($prototype =~ m/TRACE_EVENT\((.*?),/) {
1924                 $tracepointname = $1;
1925         }
1926         if ($prototype =~ m/DEFINE_SINGLE_EVENT\((.*?),/) {
1927                 $tracepointname = $1;
1928         }
1929         if ($prototype =~ m/DEFINE_EVENT\((.*?),(.*?),/) {
1930                 $tracepointname = $2;
1931         }
1932         $tracepointname =~ s/^\s+//; #strip leading whitespace
1933         if ($prototype =~ m/TP_PROTO\((.*?)\)/) {
1934                 $tracepointargs = $1;
1935         }
1936         if (($tracepointname eq 0) || ($tracepointargs eq 0)) {
1937                 print STDERR "${file}:$.: warning: Unrecognized tracepoint format: \n".
1938                              "$prototype\n";
1939         } else {
1940                 $prototype = "static inline void trace_$tracepointname($tracepointargs)";
1941                 $identifier = "trace_$identifier";
1942         }
1943 }
1944
1945 sub syscall_munge() {
1946         my $void = 0;
1947
1948         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/CR's
1949 ##      if ($prototype =~ m/SYSCALL_DEFINE0\s*\(\s*(a-zA-Z0-9_)*\s*\)/) {
1950         if ($prototype =~ m/SYSCALL_DEFINE0/) {
1951                 $void = 1;
1952 ##              $prototype = "long sys_$1(void)";
1953         }
1954
1955         $prototype =~ s/SYSCALL_DEFINE.*\(/long sys_/; # fix return type & func name
1956         if ($prototype =~ m/long (sys_.*?),/) {
1957                 $prototype =~ s/,/\(/;
1958         } elsif ($void) {
1959                 $prototype =~ s/\)/\(void\)/;
1960         }
1961
1962         # now delete all of the odd-number commas in $prototype
1963         # so that arg types & arg names don't have a comma between them
1964         my $count = 0;
1965         my $len = length($prototype);
1966         if ($void) {
1967                 $len = 0;       # skip the for-loop
1968         }
1969         for (my $ix = 0; $ix < $len; $ix++) {
1970                 if (substr($prototype, $ix, 1) eq ',') {
1971                         $count++;
1972                         if ($count % 2 == 1) {
1973                                 substr($prototype, $ix, 1) = ' ';
1974                         }
1975                 }
1976         }
1977 }
1978
1979 sub process_proto_function($$) {
1980     my $x = shift;
1981     my $file = shift;
1982
1983     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
1984
1985     if ($x =~ m#\s*/\*\s+MACDOC\s*#io || ($x =~ /^#/ && $x !~ /^#\s*define/)) {
1986         # do nothing
1987     }
1988     elsif ($x =~ /([^\{]*)/) {
1989         $prototype .= $1;
1990     }
1991
1992     if (($x =~ /\{/) || ($x =~ /\#\s*define/) || ($x =~ /;/)) {
1993         $prototype =~ s@/\*.*?\*/@@gos; # strip comments.
1994         $prototype =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
1995         $prototype =~ s@^\s+@@gos; # strip leading spaces
1996
1997          # Handle prototypes for function pointers like:
1998          # int (*pcs_config)(struct foo)
1999         $prototype =~ s@^(\S+\s+)\(\s*\*(\S+)\)@$1$2@gos;
2000
2001         if ($prototype =~ /SYSCALL_DEFINE/) {
2002                 syscall_munge();
2003         }
2004         if ($prototype =~ /TRACE_EVENT/ || $prototype =~ /DEFINE_EVENT/ ||
2005             $prototype =~ /DEFINE_SINGLE_EVENT/)
2006         {
2007                 tracepoint_munge($file);
2008         }
2009         dump_function($prototype, $file);
2010         reset_state();
2011     }
2012 }
2013
2014 sub process_proto_type($$) {
2015     my $x = shift;
2016     my $file = shift;
2017
2018     $x =~ s@[\r\n]+@ @gos; # strip newlines/cr's.
2019     $x =~ s@^\s+@@gos; # strip leading spaces
2020     $x =~ s@\s+$@@gos; # strip trailing spaces
2021     $x =~ s@\/\/.*$@@gos; # strip C99-style comments to end of line
2022
2023     if ($x =~ /^#/) {
2024         # To distinguish preprocessor directive from regular declaration later.
2025         $x .= ";";
2026     }
2027
2028     while (1) {
2029         if ( $x =~ /([^\{\};]*)([\{\};])(.*)/ ) {
2030             if( length $prototype ) {
2031                 $prototype .= " "
2032             }
2033             $prototype .= $1 . $2;
2034             ($2 eq '{') && $brcount++;
2035             ($2 eq '}') && $brcount--;
2036             if (($2 eq ';') && ($brcount == 0)) {
2037                 dump_declaration($prototype, $file);
2038                 reset_state();
2039                 last;
2040             }
2041             $x = $3;
2042         } else {
2043             $prototype .= $x;
2044             last;
2045         }
2046     }
2047 }
2048
2049
2050 sub map_filename($) {
2051     my $file;
2052     my ($orig_file) = @_;
2053
2054     if (defined($ENV{'SRCTREE'})) {
2055         $file = "$ENV{'SRCTREE'}" . "/" . $orig_file;
2056     } else {
2057         $file = $orig_file;
2058     }
2059
2060     if (defined($source_map{$file})) {
2061         $file = $source_map{$file};
2062     }
2063
2064     return $file;
2065 }
2066
2067 sub process_export_file($) {
2068     my ($orig_file) = @_;
2069     my $file = map_filename($orig_file);
2070
2071     if (!open(IN,"<$file")) {
2072         print STDERR "Error: Cannot open file $file\n";
2073         ++$errors;
2074         return;
2075     }
2076
2077     while (<IN>) {
2078         if (/$export_symbol/) {
2079             next if (defined($nosymbol_table{$2}));
2080             $function_table{$2} = 1;
2081         }
2082     }
2083
2084     close(IN);
2085 }
2086
2087 #
2088 # Parsers for the various processing states.
2089 #
2090 # STATE_NORMAL: looking for the /** to begin everything.
2091 #
2092 sub process_normal() {
2093     if (/$doc_start/o) {
2094         $state = STATE_NAME;    # next line is always the function name
2095         $in_doc_sect = 0;
2096         $declaration_start_line = $. + 1;
2097     }
2098 }
2099
2100 #
2101 # STATE_NAME: Looking for the "name - description" line
2102 #
2103 sub process_name($$) {
2104     my $file = shift;
2105     my $descr;
2106
2107     if (/$doc_block/o) {
2108         $state = STATE_DOCBLOCK;
2109         $contents = "";
2110         $new_start_line = $.;
2111
2112         if ( $1 eq "" ) {
2113             $section = $section_intro;
2114         } else {
2115             $section = $1;
2116         }
2117     } elsif (/$doc_decl/o) {
2118         $identifier = $1;
2119         my $is_kernel_comment = 0;
2120         my $decl_start = qr{$doc_com};
2121         # test for pointer declaration type, foo * bar() - desc
2122         my $fn_type = qr{\w+\s*\*\s*};
2123         my $parenthesis = qr{\(\w*\)};
2124         my $decl_end = qr{[-:].*};
2125         if (/^$decl_start([\w\s]+?)$parenthesis?\s*$decl_end?$/) {
2126             $identifier = $1;
2127         }
2128         if ($identifier =~ m/^(struct|union|enum|typedef)\b\s*(\S*)/) {
2129             $decl_type = $1;
2130             $identifier = $2;
2131             $is_kernel_comment = 1;
2132         }
2133         # Look for foo() or static void foo() - description; or misspelt
2134         # identifier
2135         elsif (/^$decl_start$fn_type?(\w+)\s*$parenthesis?\s*$decl_end?$/ ||
2136             /^$decl_start$fn_type?(\w+.*)$parenthesis?\s*$decl_end$/) {
2137             $identifier = $1;
2138             $decl_type = 'function';
2139             $identifier =~ s/^define\s+//;
2140             $is_kernel_comment = 1;
2141         }
2142         $identifier =~ s/\s+$//;
2143
2144         $state = STATE_BODY;
2145         # if there's no @param blocks need to set up default section
2146         # here
2147         $contents = "";
2148         $section = $section_default;
2149         $new_start_line = $. + 1;
2150         if (/[-:](.*)/) {
2151             # strip leading/trailing/multiple spaces
2152             $descr= $1;
2153             $descr =~ s/^\s*//;
2154             $descr =~ s/\s*$//;
2155             $descr =~ s/\s+/ /g;
2156             $declaration_purpose = $descr;
2157             $state = STATE_BODY_MAYBE;
2158         } else {
2159             $declaration_purpose = "";
2160         }
2161
2162         if (!$is_kernel_comment) {
2163             print STDERR "${file}:$.: warning: This comment starts with '/**', but isn't a kernel-doc comment. Refer Documentation/doc-guide/kernel-doc.rst\n";
2164             print STDERR $_;
2165             ++$warnings;
2166             $state = STATE_NORMAL;
2167         }
2168
2169         if (($declaration_purpose eq "") && $verbose) {
2170             print STDERR "${file}:$.: warning: missing initial short description on line:\n";
2171             print STDERR $_;
2172             ++$warnings;
2173         }
2174
2175         if ($identifier eq "" && $decl_type ne "enum") {
2176             print STDERR "${file}:$.: warning: wrong kernel-doc identifier on line:\n";
2177             print STDERR $_;
2178             ++$warnings;
2179             $state = STATE_NORMAL;
2180         }
2181
2182         if ($verbose) {
2183             print STDERR "${file}:$.: info: Scanning doc for $decl_type $identifier\n";
2184         }
2185     } else {
2186         print STDERR "${file}:$.: warning: Cannot understand $_ on line $.",
2187             " - I thought it was a doc line\n";
2188         ++$warnings;
2189         $state = STATE_NORMAL;
2190     }
2191 }
2192
2193
2194 #
2195 # STATE_BODY and STATE_BODY_MAYBE: the bulk of a kerneldoc comment.
2196 #
2197 sub process_body($$) {
2198     my $file = shift;
2199
2200     # Until all named variable macro parameters are
2201     # documented using the bare name (`x`) rather than with
2202     # dots (`x...`), strip the dots:
2203     if ($section =~ /\w\.\.\.$/) {
2204         $section =~ s/\.\.\.$//;
2205
2206         if ($verbose) {
2207             print STDERR "${file}:$.: warning: Variable macro arguments should be documented without dots\n";
2208             ++$warnings;
2209         }
2210     }
2211
2212     if ($state == STATE_BODY_WITH_BLANK_LINE && /^\s*\*\s?\S/) {
2213         dump_section($file, $section, $contents);
2214         $section = $section_default;
2215         $new_start_line = $.;
2216         $contents = "";
2217     }
2218
2219     if (/$doc_sect/i) { # case insensitive for supported section names
2220         $newsection = $1;
2221         $newcontents = $2;
2222
2223         # map the supported section names to the canonical names
2224         if ($newsection =~ m/^description$/i) {
2225             $newsection = $section_default;
2226         } elsif ($newsection =~ m/^context$/i) {
2227             $newsection = $section_context;
2228         } elsif ($newsection =~ m/^returns?$/i) {
2229             $newsection = $section_return;
2230         } elsif ($newsection =~ m/^\@return$/) {
2231             # special: @return is a section, not a param description
2232             $newsection = $section_return;
2233         }
2234
2235         if (($contents ne "") && ($contents ne "\n")) {
2236             if (!$in_doc_sect && $verbose) {
2237                 print STDERR "${file}:$.: warning: contents before sections\n";
2238                 ++$warnings;
2239             }
2240             dump_section($file, $section, $contents);
2241             $section = $section_default;
2242         }
2243
2244         $in_doc_sect = 1;
2245         $state = STATE_BODY;
2246         $contents = $newcontents;
2247         $new_start_line = $.;
2248         while (substr($contents, 0, 1) eq " ") {
2249             $contents = substr($contents, 1);
2250         }
2251         if ($contents ne "") {
2252             $contents .= "\n";
2253         }
2254         $section = $newsection;
2255         $leading_space = undef;
2256     } elsif (/$doc_end/) {
2257         if (($contents ne "") && ($contents ne "\n")) {
2258             dump_section($file, $section, $contents);
2259             $section = $section_default;
2260             $contents = "";
2261         }
2262         # look for doc_com + <text> + doc_end:
2263         if ($_ =~ m'\s*\*\s*[a-zA-Z_0-9:\.]+\*/') {
2264             print STDERR "${file}:$.: warning: suspicious ending line: $_";
2265             ++$warnings;
2266         }
2267
2268         $prototype = "";
2269         $state = STATE_PROTO;
2270         $brcount = 0;
2271         $new_start_line = $. + 1;
2272     } elsif (/$doc_content/) {
2273         if ($1 eq "") {
2274             if ($section eq $section_context) {
2275                 dump_section($file, $section, $contents);
2276                 $section = $section_default;
2277                 $contents = "";
2278                 $new_start_line = $.;
2279                 $state = STATE_BODY;
2280             } else {
2281                 if ($section ne $section_default) {
2282                     $state = STATE_BODY_WITH_BLANK_LINE;
2283                 } else {
2284                     $state = STATE_BODY;
2285                 }
2286                 $contents .= "\n";
2287             }
2288         } elsif ($state == STATE_BODY_MAYBE) {
2289             # Continued declaration purpose
2290             chomp($declaration_purpose);
2291             $declaration_purpose .= " " . $1;
2292             $declaration_purpose =~ s/\s+/ /g;
2293         } else {
2294             my $cont = $1;
2295             if ($section =~ m/^@/ || $section eq $section_context) {
2296                 if (!defined $leading_space) {
2297                     if ($cont =~ m/^(\s+)/) {
2298                         $leading_space = $1;
2299                     } else {
2300                         $leading_space = "";
2301                     }
2302                 }
2303                 $cont =~ s/^$leading_space//;
2304             }
2305             $contents .= $cont . "\n";
2306         }
2307     } else {
2308         # i dont know - bad line?  ignore.
2309         print STDERR "${file}:$.: warning: bad line: $_";
2310         ++$warnings;
2311     }
2312 }
2313
2314
2315 #
2316 # STATE_PROTO: reading a function/whatever prototype.
2317 #
2318 sub process_proto($$) {
2319     my $file = shift;
2320
2321     if (/$doc_inline_oneline/) {
2322         $section = $1;
2323         $contents = $2;
2324         if ($contents ne "") {
2325             $contents .= "\n";
2326             dump_section($file, $section, $contents);
2327             $section = $section_default;
2328             $contents = "";
2329         }
2330     } elsif (/$doc_inline_start/) {
2331         $state = STATE_INLINE;
2332         $inline_doc_state = STATE_INLINE_NAME;
2333     } elsif ($decl_type eq 'function') {
2334         process_proto_function($_, $file);
2335     } else {
2336         process_proto_type($_, $file);
2337     }
2338 }
2339
2340 #
2341 # STATE_DOCBLOCK: within a DOC: block.
2342 #
2343 sub process_docblock($$) {
2344     my $file = shift;
2345
2346     if (/$doc_end/) {
2347         dump_doc_section($file, $section, $contents);
2348         $section = $section_default;
2349         $contents = "";
2350         $function = "";
2351         %parameterdescs = ();
2352         %parametertypes = ();
2353         @parameterlist = ();
2354         %sections = ();
2355         @sectionlist = ();
2356         $prototype = "";
2357         $state = STATE_NORMAL;
2358     } elsif (/$doc_content/) {
2359         if ( $1 eq "" ) {
2360             $contents .= $blankline;
2361         } else {
2362             $contents .= $1 . "\n";
2363         }
2364     }
2365 }
2366
2367 #
2368 # STATE_INLINE: docbook comments within a prototype.
2369 #
2370 sub process_inline($$) {
2371     my $file = shift;
2372
2373     # First line (state 1) needs to be a @parameter
2374     if ($inline_doc_state == STATE_INLINE_NAME && /$doc_inline_sect/o) {
2375         $section = $1;
2376         $contents = $2;
2377         $new_start_line = $.;
2378         if ($contents ne "") {
2379             while (substr($contents, 0, 1) eq " ") {
2380                 $contents = substr($contents, 1);
2381             }
2382             $contents .= "\n";
2383         }
2384         $inline_doc_state = STATE_INLINE_TEXT;
2385         # Documentation block end */
2386     } elsif (/$doc_inline_end/) {
2387         if (($contents ne "") && ($contents ne "\n")) {
2388             dump_section($file, $section, $contents);
2389             $section = $section_default;
2390             $contents = "";
2391         }
2392         $state = STATE_PROTO;
2393         $inline_doc_state = STATE_INLINE_NA;
2394         # Regular text
2395     } elsif (/$doc_content/) {
2396         if ($inline_doc_state == STATE_INLINE_TEXT) {
2397             $contents .= $1 . "\n";
2398             # nuke leading blank lines
2399             if ($contents =~ /^\s*$/) {
2400                 $contents = "";
2401             }
2402         } elsif ($inline_doc_state == STATE_INLINE_NAME) {
2403             $inline_doc_state = STATE_INLINE_ERROR;
2404             print STDERR "${file}:$.: warning: ";
2405             print STDERR "Incorrect use of kernel-doc format: $_";
2406             ++$warnings;
2407         }
2408     }
2409 }
2410
2411
2412 sub process_file($) {
2413     my $file;
2414     my $initial_section_counter = $section_counter;
2415     my ($orig_file) = @_;
2416
2417     $file = map_filename($orig_file);
2418
2419     if (!open(IN_FILE,"<$file")) {
2420         print STDERR "Error: Cannot open file $file\n";
2421         ++$errors;
2422         return;
2423     }
2424
2425     $. = 1;
2426
2427     $section_counter = 0;
2428     while (<IN_FILE>) {
2429         while (s/\\\s*$//) {
2430             $_ .= <IN_FILE>;
2431         }
2432         # Replace tabs by spaces
2433         while ($_ =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e) {};
2434         # Hand this line to the appropriate state handler
2435         if ($state == STATE_NORMAL) {
2436             process_normal();
2437         } elsif ($state == STATE_NAME) {
2438             process_name($file, $_);
2439         } elsif ($state == STATE_BODY || $state == STATE_BODY_MAYBE ||
2440                  $state == STATE_BODY_WITH_BLANK_LINE) {
2441             process_body($file, $_);
2442         } elsif ($state == STATE_INLINE) { # scanning for inline parameters
2443             process_inline($file, $_);
2444         } elsif ($state == STATE_PROTO) {
2445             process_proto($file, $_);
2446         } elsif ($state == STATE_DOCBLOCK) {
2447             process_docblock($file, $_);
2448         }
2449     }
2450
2451     # Make sure we got something interesting.
2452     if ($initial_section_counter == $section_counter && $
2453         output_mode ne "none") {
2454         if ($output_selection == OUTPUT_INCLUDE) {
2455             print STDERR "${file}:1: warning: '$_' not found\n"
2456                 for keys %function_table;
2457         }
2458         else {
2459             print STDERR "${file}:1: warning: no structured comments found\n";
2460         }
2461     }
2462     close IN_FILE;
2463 }
2464
2465
2466 if ($output_mode eq "rst") {
2467         get_sphinx_version() if (!$sphinx_major);
2468 }
2469
2470 $kernelversion = get_kernel_version();
2471
2472 # generate a sequence of code that will splice in highlighting information
2473 # using the s// operator.
2474 for (my $k = 0; $k < @highlights; $k++) {
2475     my $pattern = $highlights[$k][0];
2476     my $result = $highlights[$k][1];
2477 #   print STDERR "scanning pattern:$pattern, highlight:($result)\n";
2478     $dohighlight .=  "\$contents =~ s:$pattern:$result:gs;\n";
2479 }
2480
2481 # Read the file that maps relative names to absolute names for
2482 # separate source and object directories and for shadow trees.
2483 if (open(SOURCE_MAP, "<.tmp_filelist.txt")) {
2484         my ($relname, $absname);
2485         while(<SOURCE_MAP>) {
2486                 chop();
2487                 ($relname, $absname) = (split())[0..1];
2488                 $relname =~ s:^/+::;
2489                 $source_map{$relname} = $absname;
2490         }
2491         close(SOURCE_MAP);
2492 }
2493
2494 if ($output_selection == OUTPUT_EXPORTED ||
2495     $output_selection == OUTPUT_INTERNAL) {
2496
2497     push(@export_file_list, @ARGV);
2498
2499     foreach (@export_file_list) {
2500         chomp;
2501         process_export_file($_);
2502     }
2503 }
2504
2505 foreach (@ARGV) {
2506     chomp;
2507     process_file($_);
2508 }
2509 if ($verbose && $errors) {
2510   print STDERR "$errors errors\n";
2511 }
2512 if ($verbose && $warnings) {
2513   print STDERR "$warnings warnings\n";
2514 }
2515
2516 if ($Werror && $warnings) {
2517     print STDERR "$warnings warnings as Errors\n";
2518     exit($warnings);
2519 } else {
2520     exit($output_mode eq "none" ? 0 : $errors)
2521 }