scripts/checkstack.pl

   1 #!/usr/bin/env perl
   2
   3 #       Check the stack usage of functions
   4 #
   5 #       Copyright Joern Engel <joern@lazybastard.org>
   6 #       Inspired by Linus Torvalds
   7 #       Original idea maybe from Keith Owens
   8 #       s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
   9 #       Mips port by Juan Quintela <quintela@mandrakesoft.com>
  10 #       IA64 port via Andreas Dilger
  11 #       Arm port by Holger Schurig
  12 #       sh64 port by Paul Mundt
  13 #       Random bits by Matt Mackall <mpm@selenic.com>
  14 #       M68k port by Geert Uytterhoeven and Andreas Schwab
  15 #       AArch64, PARISC ports by Kyle McMartin
  16 #       sparc port by Martin Habets <errandir_news@mph.eclipse.co.uk>
  17 #
  18 #       Usage:
  19 #       objdump -d vmlinux | scripts/checkstack.pl [arch]
  20 #
  21 #       TODO :  Port to all architectures (one regex per arch)
  22
  23 use strict;
  24
  25 # check for arch
  26 #
  27 # $re is used for two matches:
  28 # $& (whole re) matches the complete objdump line with the stack growth
  29 # $1 (first bracket) matches the size of the stack growth
  30 #
  31 # $dre is similar, but for dynamic stack redutions:
  32 # $& (whole re) matches the complete objdump line with the stack growth
  33 # $1 (first bracket) matches the dynamic amount of the stack growth
  34 #
  35 # use anything else and feel the pain ;)
  36 my (@stack, $re, $dre, $x, $xs, $funcre);
  37 {
  38         my $arch = shift;
  39         if ($arch eq "") {
  40                 $arch = `uname -m`;
  41                 chomp($arch);
  42         }
  43
  44         $x      = "[0-9a-f]";   # hex character
  45         $xs     = "[0-9a-f ]";  # hex character or space
  46         $funcre = qr/^$x* <(.*)>:$/;
  47         if ($arch eq 'aarch64') {
  48                 #ffffffc0006325cc:       a9bb7bfd        stp     x29, x30, [sp,#-80]!
  49                 $re = qr/^.*stp.*sp,\#-([0-9]{1,8})\]\!/o;
  50         } elsif ($arch eq 'arm') {
  51                 #c0008ffc:      e24dd064        sub     sp, sp, #100    ; 0x64
  52                 $re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
  53         } elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
  54                 #c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
  55                 # or
  56                 #    2f60:    48 81 ec e8 05 00 00       sub    $0x5e8,%rsp
  57                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%(e|r)sp$/o;
  58                 $dre = qr/^.*[as][du][db]    (%.*),\%(e|r)sp$/o;
  59         } elsif ($arch eq 'ia64') {
  60                 #e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
  61                 $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
  62         } elsif ($arch eq 'm68k') {
  63                 #    2b6c:       4e56 fb70       linkw %fp,#-1168
  64                 #  1df770:       defc ffe4       addaw #-28,%sp
  65                 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
  66         } elsif ($arch eq 'metag') {
  67                 #400026fc:       40 00 00 82     ADD       A0StP,A0StP,#0x8
  68                 $re = qr/.*ADD.*A0StP,A0StP,\#(0x$x{1,8})/o;
  69                 $funcre = qr/^$x* <[^\$](.*)>:$/;
  70         } elsif ($arch eq 'mips64') {
  71                 #8800402c:       67bdfff0        daddiu  sp,sp,-16
  72                 $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  73         } elsif ($arch eq 'mips') {
  74                 #88003254:       27bdffe0        addiu   sp,sp,-32
  75                 $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  76         } elsif ($arch eq 'nios2') {
  77                 #25a8:  defffb04        addi    sp,sp,-20
  78                 $re = qr/.*addi.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  79         } elsif ($arch eq 'openrisc') {
  80                 # c000043c:       9c 21 fe f0     l.addi r1,r1,-272
  81                 $re = qr/.*l\.addi.*r1,r1,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  82         } elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
  83                 $re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
  84         } elsif ($arch eq 'ppc') {
  85                 #c00029f4:       94 21 ff 30     stwu    r1,-208(r1)
  86                 $re = qr/.*stwu.*r1,-($x{1,8})\(r1\)/o;
  87         } elsif ($arch eq 'ppc64') {
  88                 #XXX
  89                 $re = qr/.*stdu.*r1,-($x{1,8})\(r1\)/o;
  90         } elsif ($arch eq 'powerpc') {
  91                 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
  92         } elsif ($arch =~ /^s390x?$/) {
  93                 #   11160:       a7 fb ff 60             aghi   %r15,-160
  94                 # or
  95                 #  100092:       e3 f0 ff c8 ff 71       lay     %r15,-56(%r15)
  96                 $re = qr/.*(?:lay|ag?hi).*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})
  97                       (?:\(\%r15\))?$/ox;
  98         } elsif ($arch =~ /^sh64$/) {
  99                 #XXX: we only check for the immediate case presently,
 100                 #     though we will want to check for the movi/sub
 101                 #     pair for larger users. -- PFM.
 102                 #a00048e0:       d4fc40f0        addi.l  r15,-240,r15
 103                 $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
 104         } elsif ($arch =~ /^blackfin$/) {
 105                 #   0:   00 e8 38 01     LINK 0x4e0;
 106                 $re = qr/.*[[:space:]]LINK[[:space:]]*(0x$x{1,8})/o;
 107         } elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
 108                 # f0019d10:       9d e3 bf 90     save  %sp, -112, %sp
 109                 $re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o;
 110         } else {
 111                 print("wrong or unknown architecture \"$arch\"\n");
 112                 exit
 113         }
 114 }
 115
 116 #
 117 # main()
 118 #
 119 my ($func, $file, $lastslash);
 120
 121 while (my $line = <STDIN>) {
 122         if ($line =~ m/$funcre/) {
 123                 $func = $1;
 124         }
 125         elsif ($line =~ m/(.*):\s*file format/) {
 126                 $file = $1;
 127                 $file =~ s/\.ko//;
 128                 $lastslash = rindex($file, "/");
 129                 if ($lastslash != -1) {
 130                         $file = substr($file, $lastslash + 1);
 131                 }
 132         }
 133         elsif ($line =~ m/$re/) {
 134                 my $size = $1;
 135                 $size = hex($size) if ($size =~ /^0x/);
 136
 137                 if ($size > 0xf0000000) {
 138                         $size = - $size;
 139                         $size += 0x80000000;
 140                         $size += 0x80000000;
 141                 }
 142                 next if ($size > 0x10000000);
 143
 144                 next if $line !~ m/^($xs*)/;
 145                 my $addr = $1;
 146                 $addr =~ s/ /0/g;
 147                 $addr = "0x$addr";
 148
 149                 my $intro = "$addr $func [$file]:";
 150                 my $padlen = 56 - length($intro);
 151                 while ($padlen > 0) {
 152                         $intro .= '     ';
 153                         $padlen -= 8;
 154                 }
 155                 next if ($size < 100);
 156                 push @stack, "$intro$size\n";
 157         }
 158         elsif (defined $dre && $line =~ m/$dre/) {
 159                 my $size = "Dynamic ($1)";
 160
 161                 next if $line !~ m/^($xs*)/;
 162                 my $addr = $1;
 163                 $addr =~ s/ /0/g;
 164                 $addr = "0x$addr";
 165
 166                 my $intro = "$addr $func [$file]:";
 167                 my $padlen = 56 - length($intro);
 168                 while ($padlen > 0) {
 169                         $intro .= '     ';
 170                         $padlen -= 8;
 171                 }
 172                 push @stack, "$intro$size\n";
 173         }
 174 }
 175
 176 # Sort output by size (last field)
 177 print sort { ($b =~ /:\t*(\d+)$/)[0] <=> ($a =~ /:\t*(\d+)$/)[0] } @stack;