scripts/checkstack.pl

   1 #!/usr/bin/env perl
   2 # SPDX-License-Identifier: GPL-2.0
   3
   4 #       Check the stack usage of functions
   5 #
   6 #       Copyright Joern Engel <joern@lazybastard.org>
   7 #       Inspired by Linus Torvalds
   8 #       Original idea maybe from Keith Owens
   9 #       s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
  10 #       Mips port by Juan Quintela <quintela@mandrakesoft.com>
  11 #       IA64 port via Andreas Dilger
  12 #       Arm port by Holger Schurig
  13 #       sh64 port by Paul Mundt
  14 #       Random bits by Matt Mackall <mpm@selenic.com>
  15 #       M68k port by Geert Uytterhoeven and Andreas Schwab
  16 #       AArch64, PARISC ports by Kyle McMartin
  17 #       sparc port by Martin Habets <errandir_news@mph.eclipse.co.uk>
  18 #
  19 #       Usage:
  20 #       objdump -d vmlinux | scripts/checkstack.pl [arch]
  21 #
  22 #       TODO :  Port to all architectures (one regex per arch)
  23
  24 use strict;
  25
  26 # check for arch
  27 #
  28 # $re is used for two matches:
  29 # $& (whole re) matches the complete objdump line with the stack growth
  30 # $1 (first bracket) matches the size of the stack growth
  31 #
  32 # $dre is similar, but for dynamic stack redutions:
  33 # $& (whole re) matches the complete objdump line with the stack growth
  34 # $1 (first bracket) matches the dynamic amount of the stack growth
  35 #
  36 # use anything else and feel the pain ;)
  37 my (@stack, $re, $dre, $x, $xs, $funcre);
  38 {
  39         my $arch = shift;
  40         if ($arch eq "") {
  41                 $arch = `uname -m`;
  42                 chomp($arch);
  43         }
  44
  45         $x      = "[0-9a-f]";   # hex character
  46         $xs     = "[0-9a-f ]";  # hex character or space
  47         $funcre = qr/^$x* <(.*)>:$/;
  48         if ($arch eq 'aarch64') {
  49                 #ffffffc0006325cc:       a9bb7bfd        stp     x29, x30, [sp,#-80]!
  50                 $re = qr/^.*stp.*sp,\#-([0-9]{1,8})\]\!/o;
  51         } elsif ($arch eq 'arm') {
  52                 #c0008ffc:      e24dd064        sub     sp, sp, #100    ; 0x64
  53                 $re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
  54         } elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
  55                 #c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
  56                 # or
  57                 #    2f60:    48 81 ec e8 05 00 00       sub    $0x5e8,%rsp
  58                 $re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%(e|r)sp$/o;
  59                 $dre = qr/^.*[as][du][db]    (%.*),\%(e|r)sp$/o;
  60         } elsif ($arch eq 'ia64') {
  61                 #e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
  62                 $re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
  63         } elsif ($arch eq 'm68k') {
  64                 #    2b6c:       4e56 fb70       linkw %fp,#-1168
  65                 #  1df770:       defc ffe4       addaw #-28,%sp
  66                 $re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
  67         } elsif ($arch eq 'metag') {
  68                 #400026fc:       40 00 00 82     ADD       A0StP,A0StP,#0x8
  69                 $re = qr/.*ADD.*A0StP,A0StP,\#(0x$x{1,8})/o;
  70                 $funcre = qr/^$x* <[^\$](.*)>:$/;
  71         } elsif ($arch eq 'mips64') {
  72                 #8800402c:       67bdfff0        daddiu  sp,sp,-16
  73                 $re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  74         } elsif ($arch eq 'mips') {
  75                 #88003254:       27bdffe0        addiu   sp,sp,-32
  76                 $re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  77         } elsif ($arch eq 'nios2') {
  78                 #25a8:  defffb04        addi    sp,sp,-20
  79                 $re = qr/.*addi.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  80         } elsif ($arch eq 'openrisc') {
  81                 # c000043c:       9c 21 fe f0     l.addi r1,r1,-272
  82                 $re = qr/.*l\.addi.*r1,r1,-(([0-9]{2}|[3-9])[0-9]{2})/o;
  83         } elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
  84                 $re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
  85         } elsif ($arch eq 'ppc') {
  86                 #c00029f4:       94 21 ff 30     stwu    r1,-208(r1)
  87                 $re = qr/.*stwu.*r1,-($x{1,8})\(r1\)/o;
  88         } elsif ($arch eq 'ppc64') {
  89                 #XXX
  90                 $re = qr/.*stdu.*r1,-($x{1,8})\(r1\)/o;
  91         } elsif ($arch eq 'powerpc') {
  92                 $re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
  93         } elsif ($arch =~ /^s390x?$/) {
  94                 #   11160:       a7 fb ff 60             aghi   %r15,-160
  95                 # or
  96                 #  100092:       e3 f0 ff c8 ff 71       lay     %r15,-56(%r15)
  97                 $re = qr/.*(?:lay|ag?hi).*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})
  98                       (?:\(\%r15\))?$/ox;
  99         } elsif ($arch =~ /^sh64$/) {
 100                 #XXX: we only check for the immediate case presently,
 101                 #     though we will want to check for the movi/sub
 102                 #     pair for larger users. -- PFM.
 103                 #a00048e0:       d4fc40f0        addi.l  r15,-240,r15
 104                 $re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
 105         } elsif ($arch =~ /^blackfin$/) {
 106                 #   0:   00 e8 38 01     LINK 0x4e0;
 107                 $re = qr/.*[[:space:]]LINK[[:space:]]*(0x$x{1,8})/o;
 108         } elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
 109                 # f0019d10:       9d e3 bf 90     save  %sp, -112, %sp
 110                 $re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o;
 111         } else {
 112                 print("wrong or unknown architecture \"$arch\"\n");
 113                 exit
 114         }
 115 }
 116
 117 #
 118 # main()
 119 #
 120 my ($func, $file, $lastslash);
 121
 122 while (my $line = <STDIN>) {
 123         if ($line =~ m/$funcre/) {
 124                 $func = $1;
 125         }
 126         elsif ($line =~ m/(.*):\s*file format/) {
 127                 $file = $1;
 128                 $file =~ s/\.ko//;
 129                 $lastslash = rindex($file, "/");
 130                 if ($lastslash != -1) {
 131                         $file = substr($file, $lastslash + 1);
 132                 }
 133         }
 134         elsif ($line =~ m/$re/) {
 135                 my $size = $1;
 136                 $size = hex($size) if ($size =~ /^0x/);
 137
 138                 if ($size > 0xf0000000) {
 139                         $size = - $size;
 140                         $size += 0x80000000;
 141                         $size += 0x80000000;
 142                 }
 143                 next if ($size > 0x10000000);
 144
 145                 next if $line !~ m/^($xs*)/;
 146                 my $addr = $1;
 147                 $addr =~ s/ /0/g;
 148                 $addr = "0x$addr";
 149
 150                 my $intro = "$addr $func [$file]:";
 151                 my $padlen = 56 - length($intro);
 152                 while ($padlen > 0) {
 153                         $intro .= '     ';
 154                         $padlen -= 8;
 155                 }
 156                 next if ($size < 100);
 157                 push @stack, "$intro$size\n";
 158         }
 159         elsif (defined $dre && $line =~ m/$dre/) {
 160                 my $size = "Dynamic ($1)";
 161
 162                 next if $line !~ m/^($xs*)/;
 163                 my $addr = $1;
 164                 $addr =~ s/ /0/g;
 165                 $addr = "0x$addr";
 166
 167                 my $intro = "$addr $func [$file]:";
 168                 my $padlen = 56 - length($intro);
 169                 while ($padlen > 0) {
 170                         $intro .= '     ';
 171                         $padlen -= 8;
 172                 }
 173                 push @stack, "$intro$size\n";
 174         }
 175 }
 176
 177 # Sort output by size (last field)
 178 print sort { ($b =~ /:\t*(\d+)$/)[0] <=> ($a =~ /:\t*(\d+)$/)[0] } @stack;