scripts/abilist.awk

   1 # This awk script processes the output of objdump --dynamic-syms
   2 # into a simple format that should not change when the ABI is not changing.
   3
   4 BEGIN {
   5   if (combine_fullname)
   6     combine = 1;
   7   if (combine)
   8     parse_names = 1;
   9 }
  10
  11 # Per-file header.
  12 /[^ :]+\.so\.[0-9]+:[   ]+.file format .*$/ {
  13   emit(0);
  14
  15   sofullname = $1;
  16   sub(/:$/, "", sofullname);
  17   soname = sofullname;
  18   sub(/^.*\//, "", soname);
  19   sub(/\.so\.[0-9]+$/, "", soname);
  20
  21   suppress = ((filename_regexp != "" && sofullname !~ filename_regexp) \
  22               || (libname_regexp != "" && soname !~ libname_regexp));
  23
  24   next
  25 }
  26
  27 suppress { next }
  28
  29 # Normalize columns.
  30 /^[0-9a-fA-F]+      / { sub(/      /, "  -   ") }
  31
  32 # Skip undefineds.
  33 $4 == "*UND*" { next }
  34
  35 # Skip locals.
  36 $2 == "l" { next }
  37
  38 $2 == "g" || $2 == "w" && NF == 7 {
  39   weak = $2;
  40   type = $3;
  41   size = $5;
  42   sub(/^0*/, "", size);
  43   size = " 0x" size;
  44   version = $6;
  45   symbol = $7;
  46   gsub(/[()]/, "", version);
  47
  48   if (version == "GLIBC_PRIVATE") next;
  49
  50   desc = "";
  51   if (type == "D" && $4 == ".tbss") {
  52     type = "T";
  53   }
  54   else if (type == "D" && $4 == ".opd") {
  55     type = "O";
  56     size = "";
  57   }
  58   else if ($4 == "*ABS*") {
  59     type = "A";
  60     size = "";
  61   }
  62   else if (type == "DO") {
  63     type = "D";
  64   }
  65   else if (type == "DF") {
  66     type = "F";
  67     size = "";
  68   }
  69   else {
  70     desc = symbol " " version " " weak " ? " type " " $4 " " $5;
  71   }
  72   if (size == " 0x") {
  73     desc = symbol " " version " " weak " ? " type " " $4 " " $5;
  74   }
  75
  76   # Disabled -- weakness should not matter to shared library ABIs any more.
  77   #if (weak == "w") type = tolower(type);
  78   if (desc == "")
  79     desc = " " symbol " " type size;
  80
  81   if (combine)
  82     version = soname " " version (combine_fullname ? " " sofullname : "");
  83
  84   if (version in versions) {
  85     versions[version] = versions[version] "\n" desc;
  86   }
  87   else {
  88     versions[version] = desc;
  89   }
  90   next;
  91 }
  92
  93 # Header crapola.
  94 NF == 0 || /DYNAMIC SYMBOL TABLE/ || /file format/ { next }
  95
  96 {
  97   print "Don't grok this line:", $0
  98 }
  99
 100 function emit(end) {
 101   if (! parse_names || soname == "")
 102     return;
 103   if (combine && !end)
 104     return;
 105   tofile = !combine;
 106
 107   nverslist = 0;
 108   for (version in versions) {
 109     if (nverslist == 0) {
 110       verslist = version;
 111       nverslist = 1;
 112       continue;
 113     }
 114     split(verslist, s, "\n");
 115     if (version < s[1]) {
 116       verslist = version;
 117       for (i = 1; i <= nverslist; ++i) {
 118         verslist = verslist "\n" s[i];
 119       }
 120     }
 121     else {
 122       verslist = s[1];
 123       for (i = 2; i <= nverslist; ++i) {
 124         if (version < s[i]) break;
 125         verslist = verslist "\n" s[i];
 126       }
 127       verslist = verslist "\n" version;
 128       for (; i <= nverslist; ++i) {
 129         verslist = verslist "\n" s[i];
 130       }
 131     }
 132     ++nverslist;
 133   }
 134
 135   if (tofile) {
 136     out = prefix soname ".symlist";
 137     if (soname in outfiles)
 138       out = out "." ++outfiles[soname];
 139     else
 140       outfiles[soname] = 1;
 141     printf "" > out;
 142   }
 143
 144   split(verslist, order, "\n");
 145   for (i = 1; i <= nverslist; ++i) {
 146     version = order[i];
 147
 148     if (tofile) {
 149       print version >> out;
 150       close(out);
 151       outpipe = "sort >> " out;
 152     }
 153     else {
 154       if (combine)
 155         print "";
 156       print prefix version;
 157       outpipe = "sort";
 158     }
 159     print versions[version] | outpipe;
 160     close(outpipe);
 161
 162     delete versions[version];
 163   }
 164   for (version in versions)
 165     delete versions[version];
 166
 167   if (tofile)
 168     print "wrote", out, "for", sofullname;
 169 }
 170
 171 END {
 172   emit(1);
 173 }