scripts/abilist.awk

   1 # This awk script processes the output of objdump --dynamic-syms
   2 # into a simple format that should not change when the ABI is not changing.
   3
   4 # Normalize columns.
   5 /^[0-9a-fA-F]+      / { sub(/      /, "  -   ") }
   6
   7 # Skip undefineds.
   8 $4 == "*UND*" { next }
   9
  10 # Skip locals.
  11 $2 == "l" { next }
  12
  13 $2 == "g" || $2 == "w" && NF == 7 {
  14   weak = $2;
  15   type = $3;
  16   size = $5;
  17   sub(/^0*/, "", size);
  18   size = " 0x" size;
  19   version = $6;
  20   symbol = $7;
  21   gsub(/[()]/, "", version);
  22
  23   if (version == "GLIBC_PRIVATE") next;
  24
  25   if (type == "D" && $4 == ".tbss") {
  26     type = "T";
  27   }
  28   else if (type == "D" && $4 == ".opd") {
  29     type = "O";
  30     size = "";
  31   }
  32   else if (type == "DO" && $4 == "*ABS*") {
  33     type = "A";
  34     size = "";
  35   }
  36   else if (type == "DO") {
  37     type = "D";
  38   }
  39   else if (type == "DF") {
  40     type = "F";
  41     size = "";
  42   }
  43   else {
  44     print symbol, version, weak, "?", type, $4, $5;
  45     next;
  46   }
  47
  48   desc = " " symbol " " (weak == "w" ? tolower(type) : type) size;
  49
  50   if (version in versions) {
  51     versions[version] = versions[version] "\n" desc;
  52   }
  53   else {
  54     versions[version] = desc;
  55   }
  56   next;
  57 }
  58
  59 # Header crapola.
  60 NF == 0 || /DYNAMIC SYMBOL TABLE/ || /file format/ { next }
  61
  62 {
  63   print "Don't grok this line:", $0
  64 }
  65
  66 END {
  67   nverlist = 0;
  68   for (version in versions) {
  69     if (nverslist == 0) {
  70       verslist = version;
  71       nverslist = 1;
  72       continue;
  73     }
  74     split(verslist, s, "\n");
  75     if (version < s[1]) {
  76       verslist = version;
  77       for (i = 1; i <= nverslist; ++i) {
  78         verslist = verslist "\n" s[i];
  79       }
  80     }
  81     else {
  82       verslist = s[1];
  83       for (i = 2; i <= nverslist; ++i) {
  84         if (version < s[i]) break;
  85         verslist = verslist "\n" s[i];
  86       }
  87       verslist = verslist "\n" version;
  88       for (; i <= nverslist; ++i) {
  89         verslist = verslist "\n" s[i];
  90       }
  91     }
  92     ++nverslist;
  93   }
  94
  95   split(verslist, order, "\n");
  96   for (i = 1; i <= nverslist; ++i) {
  97     version = order[i];
  98
  99     print version;
 100     outpipe = "sort";
 101     print versions[version] | outpipe;
 102     close(outpipe);
 103   }
 104 }