scripts/abilist.awk

   1 # This awk script processes the output of objdump --dynamic-syms
   2 # into a simple format that should not change when the ABI is not changing.
   3
   4 BEGIN {
   5   if (combine_fullname)
   6     combine = 1;
   7   if (combine)
   8     parse_names = 1;
   9 }
  10
  11 # Per-file header.
  12 /[^ :]+\.so\.[0-9]+:[   ]+.file format .*$/ {
  13   if (parse_names && soname != "")
  14     emit(1);
  15
  16   sofullname = $1;
  17   sub(/:$/, "", sofullname);
  18   soname = sofullname;
  19   sub(/^.*\//, "", soname);
  20   sub(/\.so\.[0-9]+$/, "", soname);
  21
  22   next
  23 }
  24
  25 # Normalize columns.
  26 /^[0-9a-fA-F]+      / { sub(/      /, "  -   ") }
  27
  28 # Skip undefineds.
  29 $4 == "*UND*" { next }
  30
  31 # Skip locals.
  32 $2 == "l" { next }
  33
  34 $2 == "g" || $2 == "w" && NF == 7 {
  35   weak = $2;
  36   type = $3;
  37   size = $5;
  38   sub(/^0*/, "", size);
  39   size = " 0x" size;
  40   version = $6;
  41   symbol = $7;
  42   gsub(/[()]/, "", version);
  43
  44   if (version == "GLIBC_PRIVATE") next;
  45
  46   desc = "";
  47   if (type == "D" && $4 == ".tbss") {
  48     type = "T";
  49   }
  50   else if (type == "D" && $4 == ".opd") {
  51     type = "O";
  52     size = "";
  53   }
  54   else if ($4 == "*ABS*") {
  55     type = "A";
  56     size = "";
  57   }
  58   else if (type == "DO") {
  59     type = "D";
  60   }
  61   else if (type == "DF") {
  62     type = "F";
  63     size = "";
  64   }
  65   else {
  66     desc = symbol " " version " " weak " ? " type " " $4 " " $5;
  67   }
  68   if (size == " 0x") {
  69     desc = symbol " " version " " weak " ? " type " " $4 " " $5;
  70   }
  71
  72   # Disabled -- weakness should not matter to shared library ABIs any more.
  73   #if (weak == "w") type = tolower(type);
  74   if (desc == "")
  75     desc = " " symbol " " type size;
  76
  77   if (version in versions) {
  78     versions[version] = versions[version] "\n" desc;
  79   }
  80   else {
  81     versions[version] = desc;
  82   }
  83   next;
  84 }
  85
  86 # Header crapola.
  87 NF == 0 || /DYNAMIC SYMBOL TABLE/ || /file format/ { next }
  88
  89 {
  90   print "Don't grok this line:", $0
  91 }
  92
  93 function emit(tofile) {
  94   nverslist = 0;
  95   for (version in versions) {
  96     if (nverslist == 0) {
  97       verslist = version;
  98       nverslist = 1;
  99       continue;
 100     }
 101     split(verslist, s, "\n");
 102     if (version < s[1]) {
 103       verslist = version;
 104       for (i = 1; i <= nverslist; ++i) {
 105         verslist = verslist "\n" s[i];
 106       }
 107     }
 108     else {
 109       verslist = s[1];
 110       for (i = 2; i <= nverslist; ++i) {
 111         if (version < s[i]) break;
 112         verslist = verslist "\n" s[i];
 113       }
 114       verslist = verslist "\n" version;
 115       for (; i <= nverslist; ++i) {
 116         verslist = verslist "\n" s[i];
 117       }
 118     }
 119     ++nverslist;
 120   }
 121
 122   if (combine)
 123     tofile = 0;
 124
 125   if (tofile) {
 126     out = prefix soname ".symlist";
 127     if (soname in outfiles)
 128       out = out "." ++outfiles[soname];
 129     else
 130       outfiles[soname] = 1;
 131     printf "" > out;
 132   }
 133
 134   split(verslist, order, "\n");
 135   for (i = 1; i <= nverslist; ++i) {
 136     version = order[i];
 137
 138     if (tofile) {
 139       print version >> out;
 140       close(out);
 141       outpipe = "sort >> " out;
 142     }
 143     else {
 144       if (combine_fullname)
 145         print prefix soname, version, sofullname;
 146       else if (combine)
 147         print prefix soname, version;
 148       else
 149         print version;
 150       outpipe = "sort";
 151     }
 152     print versions[version] | outpipe;
 153     close(outpipe);
 154
 155     delete versions[version];
 156   }
 157   for (version in versions)
 158     delete versions[version];
 159
 160   if (tofile)
 161     print "wrote", out, "for", sofullname;
 162 }
 163
 164 END {
 165   if (! parse_names)
 166     emit(0);
 167   else if (soname != "") {
 168     emit(1);
 169   }
 170 }