scripts/abilist.awk

   1 # This awk script processes the output of objdump --dynamic-syms
   2 # into a simple format that should not change when the ABI is not changing.
   3
   4 # Normalize columns.
   5 /^[0-9a-fA-F]+      / { sub(/      /, "  -   ") }
   6
   7 # Skip undefineds.
   8 $4 == "*UND*" { next }
   9
  10 # Skip locals.
  11 $2 == "l" { next }
  12
  13 $2 == "g" || $2 == "w" && NF == 7 {
  14   weak = $2;
  15   type = $3;
  16   size = $5;
  17   sub(/^0*/, "", size);
  18   size = " 0x" size;
  19   version = $6;
  20   symbol = $7;
  21   gsub(/[()]/, "", version);
  22
  23   if (version == "GLIBC_PRIVATE") next;
  24
  25   if (type == "D" && $4 == ".tbss") {
  26     type = "T";
  27   }
  28   else if (type == "D" && $4 == ".opd") {
  29     type = "O";
  30     size = "";
  31   }
  32   else if (type == "DO" && $4 == "*ABS*") {
  33     type = "A";
  34     size = "";
  35   }
  36   else if (type == "DO") {
  37     type = "D";
  38   }
  39   else if (type == "DF") {
  40     type = "F";
  41     size = "";
  42   }
  43   else {
  44     print symbol, version, weak, "?", type, $4, $5;
  45     next;
  46   }
  47   if (size == " 0x") {
  48     print symbol, version, weak, "?", type, $4, $5;
  49     next;
  50   }
  51
  52   # Disabled -- weakness should not matter to shared library ABIs any more.
  53   #if (weak == "w") type = tolower(type);
  54   desc = " " symbol " " type size;
  55
  56   if (version in versions) {
  57     versions[version] = versions[version] "\n" desc;
  58   }
  59   else {
  60     versions[version] = desc;
  61   }
  62   next;
  63 }
  64
  65 # Header crapola.
  66 NF == 0 || /DYNAMIC SYMBOL TABLE/ || /file format/ { next }
  67
  68 {
  69   print "Don't grok this line:", $0
  70 }
  71
  72 END {
  73   nverlist = 0;
  74   for (version in versions) {
  75     if (nverslist == 0) {
  76       verslist = version;
  77       nverslist = 1;
  78       continue;
  79     }
  80     split(verslist, s, "\n");
  81     if (version < s[1]) {
  82       verslist = version;
  83       for (i = 1; i <= nverslist; ++i) {
  84         verslist = verslist "\n" s[i];
  85       }
  86     }
  87     else {
  88       verslist = s[1];
  89       for (i = 2; i <= nverslist; ++i) {
  90         if (version < s[i]) break;
  91         verslist = verslist "\n" s[i];
  92       }
  93       verslist = verslist "\n" version;
  94       for (; i <= nverslist; ++i) {
  95         verslist = verslist "\n" s[i];
  96       }
  97     }
  98     ++nverslist;
  99   }
 100
 101   split(verslist, order, "\n");
 102   for (i = 1; i <= nverslist; ++i) {
 103     version = order[i];
 104
 105     print version;
 106     outpipe = "sort";
 107     print versions[version] | outpipe;
 108     close(outpipe);
 109   }
 110 }