scripts/abilist.awk

   1 # This awk script processes the output of objdump --dynamic-syms
   2 # into a simple format that should not change when the ABI is not changing.
   3
   4 # Normalize columns.
   5 /^[0-9a-fA-F]+      / { sub(/      /, "  -   ") }
   6
   7 # Skip undefineds.
   8 $4 == "*UND*" { next }
   9
  10 # Skip locals.
  11 $2 == "l" { next }
  12
  13 $2 == "g" || $2 == "w" && NF == 7 {
  14   weak = $2;
  15   type = $3;
  16   size = $5;
  17   sub(/^0*/, "", size);
  18   size = " 0x" size;
  19   version = $6;
  20   symbol = $7;
  21   gsub(/[()]/, "", version);
  22
  23   if (version == "GLIBC_PRIVATE") next;
  24
  25   if (type == "D" && $4 == ".tbss") {
  26     type = "T";
  27   }
  28   else if (type == "D" && $4 == ".opd") {
  29     type = "O";
  30     size = "";
  31   }
  32   else if (type == "DO" && $4 == "*ABS*") {
  33     type = "A";
  34     size = "";
  35   }
  36   else if (type == "DO") {
  37     type = "D";
  38   }
  39   else if (type == "DF") {
  40     type = "F";
  41     size = "";
  42   }
  43   else {
  44     print symbol, version, weak, "?", type, $4, $5;
  45     next;
  46   }
  47
  48   # Disabled -- weakness should not matter to shared library ABIs any more.
  49   #if (weak == "w") type = tolower(type);
  50   desc = " " symbol " " type size;
  51
  52   if (version in versions) {
  53     versions[version] = versions[version] "\n" desc;
  54   }
  55   else {
  56     versions[version] = desc;
  57   }
  58   next;
  59 }
  60
  61 # Header crapola.
  62 NF == 0 || /DYNAMIC SYMBOL TABLE/ || /file format/ { next }
  63
  64 {
  65   print "Don't grok this line:", $0
  66 }
  67
  68 END {
  69   nverlist = 0;
  70   for (version in versions) {
  71     if (nverslist == 0) {
  72       verslist = version;
  73       nverslist = 1;
  74       continue;
  75     }
  76     split(verslist, s, "\n");
  77     if (version < s[1]) {
  78       verslist = version;
  79       for (i = 1; i <= nverslist; ++i) {
  80         verslist = verslist "\n" s[i];
  81       }
  82     }
  83     else {
  84       verslist = s[1];
  85       for (i = 2; i <= nverslist; ++i) {
  86         if (version < s[i]) break;
  87         verslist = verslist "\n" s[i];
  88       }
  89       verslist = verslist "\n" version;
  90       for (; i <= nverslist; ++i) {
  91         verslist = verslist "\n" s[i];
  92       }
  93     }
  94     ++nverslist;
  95   }
  96
  97   split(verslist, order, "\n");
  98   for (i = 1; i <= nverslist; ++i) {
  99     version = order[i];
 100
 101     print version;
 102     outpipe = "sort";
 103     print versions[version] | outpipe;
 104     close(outpipe);
 105   }
 106 }