scripts/abilist.awk

   1 # This awk script processes the output of objdump --dynamic-syms
   2 # into a simple format that should not change when the ABI is not changing.
   3
   4 BEGIN {
   5   if (parse_names)
   6     defout = "/dev/stderr";
   7   else
   8     defout = "/dev/stdout";
   9 }
  10
  11 # Per-file header.
  12 /[^ :]+\.so\.[0-9]+:[   ]+.file format .*$/ {
  13   if (parse_names && soname != "")
  14     emit(1);
  15
  16   sofullname = $1;
  17   sub(/:$/, "", sofullname);
  18   soname = sofullname;
  19   sub(/^.*\//, "", soname);
  20   sub(/\.so\.[0-9]+$/, "", soname);
  21
  22   next
  23 }
  24
  25 # Normalize columns.
  26 /^[0-9a-fA-F]+      / { sub(/      /, "  -   ") }
  27
  28 # Skip undefineds.
  29 $4 == "*UND*" { next }
  30
  31 # Skip locals.
  32 $2 == "l" { next }
  33
  34 $2 == "g" || $2 == "w" && NF == 7 {
  35   weak = $2;
  36   type = $3;
  37   size = $5;
  38   sub(/^0*/, "", size);
  39   size = " 0x" size;
  40   version = $6;
  41   symbol = $7;
  42   gsub(/[()]/, "", version);
  43
  44   if (version == "GLIBC_PRIVATE") next;
  45
  46   if (type == "D" && $4 == ".tbss") {
  47     type = "T";
  48   }
  49   else if (type == "D" && $4 == ".opd") {
  50     type = "O";
  51     size = "";
  52   }
  53   else if (type == "DO" && $4 == "*ABS*") {
  54     type = "A";
  55     size = "";
  56   }
  57   else if (type == "DO") {
  58     type = "D";
  59   }
  60   else if (type == "DF") {
  61     type = "F";
  62     size = "";
  63   }
  64   else {
  65     print symbol, version, weak, "?", type, $4, $5 > defout;
  66     next;
  67   }
  68   if (size == " 0x") {
  69     print symbol, version, weak, "?", type, $4, $5 > defout;
  70     next;
  71   }
  72
  73   # Disabled -- weakness should not matter to shared library ABIs any more.
  74   #if (weak == "w") type = tolower(type);
  75   desc = " " symbol " " type size;
  76
  77   if (version in versions) {
  78     versions[version] = versions[version] "\n" desc;
  79   }
  80   else {
  81     versions[version] = desc;
  82   }
  83   next;
  84 }
  85
  86 # Header crapola.
  87 NF == 0 || /DYNAMIC SYMBOL TABLE/ || /file format/ { next }
  88
  89 {
  90   print "Don't grok this line:", $0 > defout
  91 }
  92
  93 function emit(tofile) {
  94   nverlist = 0;
  95   for (version in versions) {
  96     if (nverslist == 0) {
  97       verslist = version;
  98       nverslist = 1;
  99       continue;
 100     }
 101     split(verslist, s, "\n");
 102     if (version < s[1]) {
 103       verslist = version;
 104       for (i = 1; i <= nverslist; ++i) {
 105         verslist = verslist "\n" s[i];
 106       }
 107     }
 108     else {
 109       verslist = s[1];
 110       for (i = 2; i <= nverslist; ++i) {
 111         if (version < s[i]) break;
 112         verslist = verslist "\n" s[i];
 113       }
 114       verslist = verslist "\n" version;
 115       for (; i <= nverslist; ++i) {
 116         verslist = verslist "\n" s[i];
 117       }
 118     }
 119     ++nverslist;
 120   }
 121
 122   if (tofile) {
 123     out = prefix soname ".symlist";
 124     if (soname in outfiles)
 125       out = out "." ++outfiles[soname];
 126     else
 127       outfiles[soname] = 1;
 128     printf "" > out;
 129   }
 130
 131   split(verslist, order, "\n");
 132   for (i = 1; i <= nverslist; ++i) {
 133     version = order[i];
 134
 135     if (tofile) {
 136       print version >> out;
 137       close(out);
 138       outpipe = "sort >> " out;
 139     }
 140     else
 141       outpipe = "sort";
 142     print versions[version] | outpipe;
 143     close(outpipe);
 144
 145     delete versions[version];
 146   }
 147   for (version in versions)
 148     delete versions[version];
 149
 150   if (tofile)
 151     print "wrote", out, "for", sofullname;
 152 }
 153
 154 END {
 155   if (! parse_names)
 156     emit(0);
 157   else if (soname != "") {
 158     emit(1);
 159   }
 160 }