scripts/abilist.awk

   1 # This awk script processes the output of objdump --dynamic-syms
   2 # into a simple format that should not change when the ABI is not changing.
   3
   4 BEGIN {
   5   if (combine_fullname)
   6     combine = 1;
   7   if (combine)
   8     parse_names = 1;
   9 }
  10
  11 # Per-file header.
  12 /[^ :]+\.so\.[0-9.]+:[  ]+.file format .*$/ {
  13   emit(0);
  14
  15   seen_opd = 0;
  16
  17   sofullname = $1;
  18   sub(/:$/, "", sofullname);
  19   soname = sofullname;
  20   sub(/^.*\//, "", soname);
  21   sub(/\.so\.[0-9.]+$/, "", soname);
  22
  23   suppress = ((filename_regexp != "" && sofullname !~ filename_regexp) \
  24               || (libname_regexp != "" && soname !~ libname_regexp));
  25
  26   next
  27 }
  28
  29 suppress { next }
  30
  31 # Normalize columns.
  32 /^[0-9a-fA-F]+      / { sub(/      /, "  -   ") }
  33
  34 # Skip undefineds.
  35 $4 == "*UND*" { next }
  36
  37 # Skip locals.
  38 $2 == "l" { next }
  39
  40 $2 == "g" || $2 == "w" && NF == 7 {
  41   weak = $2;
  42   type = $3;
  43   size = $5;
  44   sub(/^0*/, "", size);
  45   size = " 0x" size;
  46   version = $6;
  47   symbol = $7;
  48   gsub(/[()]/, "", version);
  49
  50   if (version == "GLIBC_PRIVATE") next;
  51
  52   desc = "";
  53   if (type == "D" && $4 == ".tbss") {
  54     type = "T";
  55   }
  56   else if (type == "D" && $4 == ".opd") {
  57     type = "F";
  58     size = "";
  59     if (seen_opd < 0)
  60       type = "O";
  61     seen_opd = 1;
  62   }
  63   else if ($4 == "*ABS*") {
  64     type = "A";
  65     size = "";
  66   }
  67   else if (type == "DO") {
  68     type = "D";
  69   }
  70   else if (type == "DF") {
  71     if (symbol ~ /^\./ && seen_opd >= 0)
  72       next;
  73     seen_opd = -1;
  74     type = "F";
  75     size = "";
  76   }
  77   else if (type == "iD" && $4 == ".text") {
  78     # Indirect functions.
  79     type = "F";
  80     size = "";
  81   }
  82   else {
  83     desc = symbol " " version " " weak " ? " type " " $4 " " $5;
  84   }
  85   if (size == " 0x") {
  86     desc = symbol " " version " " weak " ? " type " " $4 " " $5;
  87   }
  88
  89   # Disabled -- weakness should not matter to shared library ABIs any more.
  90   #if (weak == "w") type = tolower(type);
  91   if (desc == "")
  92     desc = " " symbol " " type size;
  93
  94   if (combine)
  95     version = soname " " version (combine_fullname ? " " sofullname : "");
  96
  97   if (version in versions) {
  98     versions[version] = versions[version] "\n" desc;
  99   }
 100   else {
 101     versions[version] = desc;
 102   }
 103   next;
 104 }
 105
 106 # Header crapola.
 107 NF == 0 || /DYNAMIC SYMBOL TABLE/ || /file format/ { next }
 108
 109 {
 110   print "Don't grok this line:", $0
 111 }
 112
 113 function emit(end) {
 114   if (!end && (combine || ! parse_names || soname == ""))
 115     return;
 116   tofile = parse_names && !combine;
 117
 118   nverslist = 0;
 119   for (version in versions) {
 120     if (nverslist == 0) {
 121       verslist = version;
 122       nverslist = 1;
 123       continue;
 124     }
 125     split(verslist, s, "\n");
 126     if (version < s[1]) {
 127       verslist = version;
 128       for (i = 1; i <= nverslist; ++i) {
 129         verslist = verslist "\n" s[i];
 130       }
 131     }
 132     else {
 133       verslist = s[1];
 134       for (i = 2; i <= nverslist; ++i) {
 135         if (version < s[i]) break;
 136         verslist = verslist "\n" s[i];
 137       }
 138       verslist = verslist "\n" version;
 139       for (; i <= nverslist; ++i) {
 140         verslist = verslist "\n" s[i];
 141       }
 142     }
 143     ++nverslist;
 144   }
 145
 146   if (tofile) {
 147     out = prefix soname ".symlist";
 148     if (soname in outfiles)
 149       out = out "." ++outfiles[soname];
 150     else
 151       outfiles[soname] = 1;
 152     printf "" > out;
 153   }
 154
 155   split(verslist, order, "\n");
 156   for (i = 1; i <= nverslist; ++i) {
 157     version = order[i];
 158
 159     if (tofile) {
 160       print version >> out;
 161       close(out);
 162       outpipe = "sort >> " out;
 163     }
 164     else {
 165       if (combine)
 166         print "";
 167       print prefix version;
 168       outpipe = "sort";
 169     }
 170     print versions[version] | outpipe;
 171     close(outpipe);
 172
 173     delete versions[version];
 174   }
 175   for (version in versions)
 176     delete versions[version];
 177
 178   if (tofile)
 179     print "wrote", out, "for", sofullname;
 180 }
 181
 182 END {
 183   emit(1);
 184 }