samples/gpu/CMakeLists.txt

   1 SET(OPENCV_CUDA_SAMPLES_REQUIRED_DEPS opencv_core opencv_flann opencv_imgproc opencv_imgcodecs opencv_videoio opencv_highgui
   2                                      opencv_ml opencv_video opencv_objdetect opencv_features2d
   3                                      opencv_calib3d opencv_superres
   4                                      opencv_cudaarithm opencv_cudafilters opencv_cudawarping opencv_cudaimgproc
   5                                      opencv_cudafeatures2d opencv_cudaoptflow opencv_cudabgsegm
   6                                      opencv_cudastereo opencv_cudalegacy opencv_cudaobjdetect)
   7
   8 ocv_check_dependencies(${OPENCV_CUDA_SAMPLES_REQUIRED_DEPS})
   9
  10 if(BUILD_EXAMPLES AND OCV_DEPENDENCIES_FOUND)
  11   set(project "gpu")
  12   string(TOUPPER "${project}" project_upper)
  13
  14   project("${project}_samples")
  15
  16   ocv_include_modules_recurse(${OPENCV_CUDA_SAMPLES_REQUIRED_DEPS})
  17
  18   if(HAVE_opencv_xfeatures2d)
  19     ocv_include_modules_recurse(opencv_xfeatures2d)
  20   endif()
  21
  22   if(HAVE_opencv_cudacodec)
  23     ocv_include_modules_recurse(opencv_cudacodec)
  24   endif()
  25
  26   if(HAVE_CUDA)
  27     ocv_include_directories(${CUDA_INCLUDE_DIRS})
  28   endif()
  29
  30   if(CMAKE_COMPILER_IS_GNUCXX AND NOT ENABLE_NOISY_WARNINGS)
  31     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-function")
  32   endif()
  33
  34   # ---------------------------------------------
  35   #      Define executable targets
  36   # ---------------------------------------------
  37   MACRO(OPENCV_DEFINE_CUDA_EXAMPLE name srcs)
  38     set(the_target "example_${project}_${name}")
  39     add_executable(${the_target} ${srcs})
  40
  41     ocv_target_link_libraries(${the_target} ${OPENCV_LINKER_LIBS} ${OPENCV_CUDA_SAMPLES_REQUIRED_DEPS})
  42
  43     if(HAVE_CUDA AND NOT ANDROID)
  44       ocv_target_link_libraries(${the_target} ${CUDA_CUDA_LIBRARY})
  45     endif()
  46
  47     if(HAVE_opencv_xfeatures2d)
  48       ocv_target_link_libraries(${the_target} opencv_xfeatures2d)
  49     endif()
  50     if(HAVE_opencv_cudacodec)
  51       ocv_target_link_libraries(${the_target} opencv_cudacodec)
  52     endif()
  53
  54     if(HAVE_opencv_ocl)
  55       ocv_target_link_libraries(${the_target} opencv_ocl)
  56     endif()
  57
  58     set_target_properties(${the_target} PROPERTIES
  59       OUTPUT_NAME "${project}-example-${name}"
  60       PROJECT_LABEL "(EXAMPLE_${project_upper}) ${name}")
  61
  62     if(ENABLE_SOLUTION_FOLDERS)
  63       set_target_properties(${the_target} PROPERTIES FOLDER "samples//${project}")
  64     endif()
  65
  66     if(WIN32)
  67       if(MSVC AND NOT BUILD_SHARED_LIBS)
  68         set_target_properties(${the_target} PROPERTIES LINK_FLAGS "/NODEFAULTLIB:atlthunk.lib /NODEFAULTLIB:atlsd.lib /DEBUG")
  69       endif()
  70       install(TARGETS ${the_target} RUNTIME DESTINATION "${OPENCV_SAMPLES_BIN_INSTALL_PATH}/${project}" COMPONENT samples)
  71     endif()
  72   ENDMACRO()
  73
  74   file(GLOB all_samples RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.cpp)
  75
  76   if(NOT HAVE_OPENGL)
  77     list(REMOVE_ITEM all_samples "opengl.cpp")
  78   endif()
  79
  80   foreach(sample_filename ${all_samples})
  81     get_filename_component(sample ${sample_filename} NAME_WE)
  82     file(GLOB sample_srcs RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} ${sample}.*)
  83     OPENCV_DEFINE_CUDA_EXAMPLE(${sample} ${sample_srcs})
  84   endforeach()
  85
  86   include("performance/CMakeLists.txt")
  87 endif()
  88
  89 if(INSTALL_C_EXAMPLES AND NOT WIN32)
  90   file(GLOB install_list *.c *.cpp *.jpg *.png *.data makefile.* build_all.sh *.dsp *.cmd )
  91   if(NOT HAVE_OPENGL)
  92     list(REMOVE_ITEM install_list "opengl.cpp")
  93   endif()
  94   install(FILES ${install_list}
  95           DESTINATION ${OPENCV_SAMPLES_SRC_INSTALL_PATH}/gpu
  96           PERMISSIONS OWNER_READ GROUP_READ WORLD_READ COMPONENT samples)
  97 endif()