samples/cpp/CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  CMake file for C samples. See root CMakeLists.txt
   3 #
   4 # ----------------------------------------------------------------------------
   5
   6 SET(OPENCV_CPP_SAMPLES_REQUIRED_DEPS opencv_core opencv_flann opencv_imgproc
   7     opencv_highgui opencv_ml opencv_video opencv_objdetect opencv_photo opencv_nonfree
   8     opencv_features2d opencv_calib3d opencv_legacy opencv_contrib opencv_stitching opencv_videostab)
   9
  10 ocv_check_dependencies(${OPENCV_CPP_SAMPLES_REQUIRED_DEPS})
  11
  12
  13 if(BUILD_EXAMPLES AND OCV_DEPENDENCIES_FOUND)
  14   project(cpp_samples)
  15
  16   ocv_include_directories("${OpenCV_SOURCE_DIR}/include")#for opencv.hpp
  17   ocv_include_modules(${OPENCV_CPP_SAMPLES_REQUIRED_DEPS})
  18
  19   if (HAVE_opencv_gpu)
  20     ocv_include_directories("${OpenCV_SOURCE_DIR}/modules/gpu/include")
  21   endif()
  22
  23   if(CMAKE_COMPILER_IS_GNUCXX AND NOT ENABLE_NOISY_WARNINGS)
  24     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-function")
  25   endif()
  26
  27   # ---------------------------------------------
  28   #      Define executable targets
  29   # ---------------------------------------------
  30   MACRO(OPENCV_DEFINE_CPP_EXAMPLE name srcs)
  31     set(the_target "example_${name}")
  32     add_executable(${the_target} ${srcs})
  33     target_link_libraries(${the_target} ${OPENCV_LINKER_LIBS} ${OPENCV_CPP_SAMPLES_REQUIRED_DEPS})
  34
  35     if (HAVE_opencv_gpu)
  36       target_link_libraries(${the_target} opencv_gpu)
  37     endif()
  38
  39     set_target_properties(${the_target} PROPERTIES
  40       OUTPUT_NAME "${name}"
  41       PROJECT_LABEL "(EXAMPLE) ${name}")
  42
  43     if(ENABLE_SOLUTION_FOLDERS)
  44       set_target_properties(${the_target} PROPERTIES FOLDER "samples//cpp")
  45     endif()
  46
  47     if(WIN32)
  48       if (MSVC AND NOT BUILD_SHARED_LIBS)
  49         set_target_properties(${the_target} PROPERTIES LINK_FLAGS "/NODEFAULTLIB:atlthunk.lib /NODEFAULTLIB:atlsd.lib /DEBUG")
  50       endif()
  51       install(TARGETS ${the_target}
  52               RUNTIME DESTINATION "samples/cpp" COMPONENT main)
  53     endif()
  54   ENDMACRO()
  55
  56   file(GLOB cpp_samples RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.cpp)
  57
  58   foreach(sample_filename ${cpp_samples})
  59     get_filename_component(sample ${sample_filename} NAME_WE)
  60     OPENCV_DEFINE_CPP_EXAMPLE(${sample}  ${sample_filename})
  61   endforeach()
  62 endif()
  63
  64 if (INSTALL_C_EXAMPLES AND NOT WIN32)
  65   file(GLOB C_SAMPLES *.c *.cpp *.jpg *.png *.data makefile.* build_all.sh *.dsp *.cmd )
  66   install(FILES ${C_SAMPLES}
  67           DESTINATION share/OpenCV/samples/cpp
  68           PERMISSIONS OWNER_READ GROUP_READ WORLD_READ)
  69 endif()
  70