samples/c/CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  CMake file for C samples. See root CMakeLists.txt
   3 #
   4 # ----------------------------------------------------------------------------
   5
   6 SET(OPENCV_C_SAMPLES_REQUIRED_DEPS opencv_core opencv_flann opencv_imgproc
   7     opencv_highgui opencv_ml opencv_video opencv_objdetect opencv_photo opencv_nonfree
   8     opencv_features2d opencv_calib3d opencv_legacy opencv_contrib)
   9
  10 ocv_check_dependencies(${OPENCV_C_SAMPLES_REQUIRED_DEPS})
  11
  12 if(BUILD_EXAMPLES AND OCV_DEPENDENCIES_FOUND)
  13   project(c_samples)
  14
  15   if(CMAKE_COMPILER_IS_GNUCXX AND NOT ENABLE_NOISY_WARNINGS)
  16     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-function")
  17   endif()
  18
  19   ocv_include_modules(${OPENCV_C_SAMPLES_REQUIRED_DEPS})
  20
  21   # ---------------------------------------------
  22   #      Define executable targets
  23   # ---------------------------------------------
  24   MACRO(OPENCV_DEFINE_C_EXAMPLE name srcs)
  25     set(the_target "example_${name}")
  26     add_executable(${the_target} ${srcs})
  27     target_link_libraries(${the_target} ${OPENCV_LINKER_LIBS} ${OPENCV_C_SAMPLES_REQUIRED_DEPS})
  28
  29     set_target_properties(${the_target} PROPERTIES
  30       OUTPUT_NAME "c-example-${name}"
  31       PROJECT_LABEL "(EXAMPLE) ${name}")
  32
  33     if(ENABLE_SOLUTION_FOLDERS)
  34       set_target_properties(${the_target} PROPERTIES FOLDER "samples//c")
  35     endif()
  36
  37     if(WIN32)
  38       if(MSVC AND NOT BUILD_SHARED_LIBS)
  39         set_target_properties(${the_target} PROPERTIES LINK_FLAGS "/NODEFAULTLIB:atlthunk.lib /NODEFAULTLIB:atlsd.lib /DEBUG")
  40       endif()
  41       install(TARGETS ${the_target}
  42               RUNTIME DESTINATION "${OPENCV_SAMPLES_BIN_INSTALL_PATH}/c" COMPONENT samples)
  43     endif()
  44   ENDMACRO()
  45
  46   file(GLOB cpp_samples RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *.cpp *.c)
  47
  48   foreach(sample_filename ${cpp_samples})
  49     get_filename_component(sample ${sample_filename} NAME_WE)
  50     OPENCV_DEFINE_C_EXAMPLE(${sample} ${sample_filename})
  51   endforeach()
  52 endif()
  53
  54 if(INSTALL_C_EXAMPLES AND NOT WIN32)
  55   file(GLOB C_SAMPLES *.c *.cpp *.jpg *.png *.data makefile.* build_all.sh *.dsp *.cmd )
  56   install(FILES ${C_SAMPLES}
  57           DESTINATION ${OPENCV_SAMPLES_SRC_INSTALL_PATH}/c
  58           PERMISSIONS OWNER_READ GROUP_READ WORLD_READ COMPONENT samples)
  59 endif ()