samples/CMakeLists.txt

   1 if(NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_LIST_DIR)
   2 #===================================================================================================
   3 #
   4 # Build as part of OpenCV
   5 #
   6 #===================================================================================================
   7
   8 include("${CMAKE_CURRENT_LIST_DIR}/samples_utils.cmake")
   9
  10 function(ocv_install_example_src relpath)
  11   if(INSTALL_C_EXAMPLES)
  12     file(GLOB files ${ARGN})
  13     install(FILES ${files}
  14             DESTINATION "${OPENCV_SAMPLES_SRC_INSTALL_PATH}/${relpath}"
  15             COMPONENT samples)
  16   endif()
  17 endfunction()
  18
  19 if((TARGET Threads::Threads OR HAVE_PTHREAD OR MSVC OR APPLE) AND NOT OPENCV_EXAMPLES_DISABLE_THREADS)
  20   add_definitions(-DHAVE_THREADS=1)
  21 endif()
  22
  23 add_subdirectory(cpp)
  24 add_subdirectory(java/tutorial_code)
  25 add_subdirectory(dnn)
  26 add_subdirectory(gpu)
  27 add_subdirectory(tapi)
  28 add_subdirectory(opencl)
  29 add_subdirectory(sycl)
  30 if(WIN32 AND HAVE_DIRECTX)
  31   add_subdirectory(directx)
  32 endif()
  33 if((NOT ANDROID) AND HAVE_OPENGL)
  34   add_subdirectory(opengl)
  35 endif()
  36 if(HAVE_OPENVX)
  37   add_subdirectory(openvx)
  38 endif()
  39 if(UNIX AND NOT ANDROID AND HAVE_VA)
  40   add_subdirectory(va_intel)
  41 endif()
  42 if(ANDROID AND (BUILD_ANDROID_EXAMPLES OR INSTALL_ANDROID_EXAMPLES))
  43   add_subdirectory(android)
  44 endif()
  45 if(INSTALL_PYTHON_EXAMPLES)
  46   add_subdirectory(python)
  47 endif()
  48 # The examples in this folder will work with a semihosting version of
  49 # OpenCV. For more information about semihosting, see
  50 # https://developer.arm.com/documentation/100863/latest
  51 if(OPENCV_SEMIHOSTING)
  52   add_subdirectory(semihosting)
  53 endif()
  54 ocv_install_example_src("." CMakeLists.txt samples_utils.cmake)
  55 if(INSTALL_C_EXAMPLES)
  56   install(DIRECTORY data DESTINATION "${OPENCV_SAMPLES_SRC_INSTALL_PATH}" COMPONENT samples_data)
  57 endif()
  58
  59 else()
  60 #===================================================================================================
  61 #
  62 #  Standalone mode
  63 #
  64 #===================================================================================================
  65 cmake_minimum_required(VERSION 3.1)
  66
  67 project(samples C CXX)
  68 option(BUILD_EXAMPLES "Build samples" ON)
  69
  70 # Assuming following installation folder structure (default for UNIX):
  71 # <install_root>/share/
  72 # └── OpenCV/  <-- OPENCV_CONFIG_INSTALL_PATH
  73 #     ├── OpenCVConfig.cmake  <-- file to be found by find_package
  74 #     ├── ...
  75 #     ├── samples/  <-- OPENCV_SAMPLES_SRC_INSTALL_PATH
  76 #     │   ├── CMakeLists.txt  <-- this file
  77 #     │   ├── cpp/
  78 find_package(OpenCV REQUIRED PATHS "..")
  79
  80 include("${CMAKE_CURRENT_LIST_DIR}/samples_utils.cmake")
  81
  82 function(ocv_install_example_src)
  83   # not used in this branch
  84 endfunction()
  85
  86 if(MSVC)
  87   if(NOT ENABLE_BUILD_HARDENING)
  88     add_definitions(-D_CRT_SECURE_NO_WARNINGS)
  89   endif()
  90
  91   if(NOT OpenCV_SHARED)
  92     foreach(flag_var
  93             CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
  94             CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  95             CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
  96             CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
  97       if(${flag_var} MATCHES "/MD")
  98         string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  99       endif()
 100       if(${flag_var} MATCHES "/MDd")
 101         string(REGEX REPLACE "/MDd" "/MTd" ${flag_var} "${${flag_var}}")
 102       endif()
 103     endforeach(flag_var)
 104
 105     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /NODEFAULTLIB:atlthunk.lib /NODEFAULTLIB:msvcrt.lib /NODEFAULTLIB:msvcrtd.lib")
 106     if(NOT BUILD_WITH_STATIC_CRT)
 107       set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} /NODEFAULTLIB:libcmt.lib")
 108       set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libcmtd.lib")
 109     endif()
 110   endif()
 111 endif()
 112
 113 if(OPENCV_EXAMPLES_DISABLE_THREADS)
 114   # nothing
 115 elseif(MSVC OR APPLE)
 116   set(HAVE_THREADS 1)
 117 else()
 118   find_package(Threads)
 119 endif()
 120 if((TARGET Threads::Threads OR HAVE_THREADS) AND NOT OPENCV_EXAMPLES_DISABLE_THREADS)
 121   set(HAVE_THREADS 1)
 122   add_definitions(-DHAVE_THREADS=1)
 123 endif()
 124
 125 add_subdirectory(cpp)
 126 if(WIN32)
 127   add_subdirectory(directx)
 128 endif()
 129 add_subdirectory(dnn)
 130 # add_subdirectory(gpu)
 131 add_subdirectory(opencl)
 132 add_subdirectory(sycl)
 133 # add_subdirectory(opengl)
 134 # add_subdirectory(openvx)
 135 add_subdirectory(tapi)
 136 # add_subdirectory(va_intel)
 137
 138 endif()