run.cmd

   1 @if not defined _echo @echo off
   2 setlocal
   3
   4 :: Default to highest Visual Studio version available
   5 ::
   6 :: For VS2015 (and prior), only a single instance is allowed to be installed on a box
   7 :: and VS140COMNTOOLS is set as a global environment variable by the installer. This
   8 :: allows users to locate where the instance of VS2015 is installed.
   9 ::
  10 :: For VS2017, multiple instances can be installed on the same box SxS and VS150COMNTOOLS
  11 :: is no longer set as a global environment variable and is instead only set if the user
  12 :: has launched the VS2017 Developer Command Prompt.
  13 ::
  14 :: Following this logic, we will default to the VS2017 toolset if VS150COMNTOOLS tools is
  15 :: set, as this indicates the user is running from the VS2017 Developer Command Prompt and
  16 :: is already configured to use that toolset. Otherwise, we will fallback to using the VS2015
  17 :: toolset if it is installed. Finally, we will fail the script if no supported VS instance
  18 :: can be found.
  19 if defined VisualStudioVersion (
  20     if not defined __VSVersion echo %__MsgPrefix%Detected Visual Studio %VisualStudioVersion% developer command ^prompt environment
  21     goto :Run
  22 )
  23
  24 set _VSWHERE="%ProgramFiles(x86)%\Microsoft Visual Studio\Installer\vswhere.exe"
  25 if exist %_VSWHERE% (
  26   for /f "usebackq tokens=*" %%i in (`%_VSWHERE% -latest -prerelease -property installationPath`) do set _VSCOMNTOOLS=%%i\Common7\Tools
  27 )
  28 if not exist "%_VSCOMNTOOLS%" set _VSCOMNTOOLS=%VS140COMNTOOLS%
  29 if not exist "%_VSCOMNTOOLS%" (
  30   echo %__MsgPrefix%Error: Visual Studio 2015 or 2017 required.
  31   echo        Please see https://github.com/dotnet/corefx/blob/master/Documentation/project-docs/developer-guide.md for build instructions.
  32   exit /b 1
  33 )
  34
  35 call "%_VSCOMNTOOLS%\VsDevCmd.bat"
  36
  37 :Run
  38 :: Clear the 'Platform' env variable for this session, as it's a per-project setting within the build, and
  39 :: misleading value (such as 'MCD' in HP PCs) may lead to build breakage (issue: #69).
  40 set Platform=
  41
  42 :: Restore the Tools directory
  43 call %~dp0init-tools.cmd
  44 if NOT [%ERRORLEVEL%]==[0] (
  45   exit /b 1
  46 )
  47
  48 set _toolRuntime=%~dp0Tools
  49 set _dotnet=%_toolRuntime%\dotnetcli\dotnet.exe
  50 set _json=%~dp0config.json
  51
  52 :: run.exe depends on running in the root directory, notably because the config.json specifies
  53 :: a relative path to the binclash logger
  54
  55 pushd %~dp0
  56 echo Running: %_dotnet% %_toolRuntime%\run.exe %~dp0config.json %*
  57 call %_dotnet% %_toolRuntime%\run.exe "%_json%" %*
  58 popd
  59 if NOT [%ERRORLEVEL%]==[0] (
  60   exit /b 1
  61 )
  62
  63 exit /b 0