run.bat

   1 @echo off
   2 REM Helper script to build and run IoTivity on Windows
   3 SETLOCAL ENABLEDELAYEDEXPANSION
   4
   5 if [%1]==[] goto USAGE
   6
   7 set IOTIVITY_DIR=%~dp0
   8 set HOME=%USERPROFILE%
   9
  10 IF /I "%1" == "msys" (
  11   set BUILD_MSYS="YES"
  12   SHIFT
  13 ) ELSE (
  14   set BUILD_MSYS=
  15 )
  16
  17 REM *** Default BUILD OPTIONS ***
  18 set TARGET_OS=windows
  19
  20 if "%TARGET_ARCH%" == "" (
  21   set TARGET_ARCH=amd64
  22 )
  23
  24 if "%TEST%" == "" (
  25   set TEST=1
  26 )
  27
  28 if "%LOGGING%" == "" (
  29   set LOGGING=0
  30 )
  31
  32 if "%RELEASE%" == "" (
  33   set RELEASE=0
  34 )
  35
  36 if "%WITH_TCP%" == "" (
  37   set WITH_TCP=1
  38 )
  39
  40 if "%SECURED%" == "" (
  41   set SECURED=1
  42 )
  43
  44 if "%MULTIPLE_OWNER%" == "" (
  45   set MULTIPLE_OWNER=1
  46 )
  47
  48 set THREAD_COUNT=%NUMBER_OF_PROCESSORS%
  49
  50 set ROUTING=EP
  51 set WITH_UPSTREAM_LIBCOAP=1
  52 set BINDIR=debug
  53 set RD_MODE=CLIENT,SERVER
  54
  55 set RUN_ARG=%1
  56 SHIFT
  57
  58 set DEBUG=
  59
  60 :processArgs
  61 IF NOT "%1"=="" (
  62   IF /I "%1"=="-arch" (
  63     SET TARGET_ARCH=%2
  64     SHIFT
  65   )
  66   IF /I "%1"=="-threads" (
  67     SET THREAD_COUNT=%2
  68     SHIFT
  69   )
  70   IF /I "%1"=="-noTest" (
  71     SET TEST=0
  72   )
  73   IF /I "%1"=="-logging" (
  74     SET LOGGING=1
  75   )
  76   IF /I "%1"=="-debugger" (
  77     set DEBUG="%ProgramFiles(x86)%\Windows Kits\10\Debuggers\x64\cdb.exe" -2 -c "g"
  78   )
  79   IF /I "%1"=="-release" (
  80     SET RELEASE=1
  81   )
  82   IF /I "%1"=="-noTCP" (
  83     SET WITH_TCP=0
  84   )
  85   IF /I "%1"=="-noSecurity" (
  86     set SECURED=0
  87   )
  88   IF /I "%1"=="-noMOT" (
  89     set MULTIPLE_OWNER=0
  90   )
  91
  92   SHIFT
  93   GOTO :processArgs
  94 )
  95
  96 IF %RELEASE% == 1 (
  97   set BINDIR=release
  98 )
  99
 100 REM We need to append the "PATH" so the octbstack.dll can be found by executables
 101 IF "%BUILD_MSYS%" == "" (
 102   set BUILD_DIR=out\windows\%TARGET_ARCH%\%BINDIR%
 103   set PATH=!PATH!;!IOTIVITY_DIR!!BUILD_DIR!;
 104 ) ELSE (
 105   set BUILD_DIR=out\msys_nt\x86_64\%BINDIR%
 106   set PATH=!PATH!;!BUILD_DIR!;C:\msys64\mingw64\bin
 107 )
 108
 109 set BUILD_OPTIONS= TARGET_OS=%TARGET_OS% TARGET_ARCH=%TARGET_ARCH% RELEASE=%RELEASE% WITH_RA=0 TARGET_TRANSPORT=IP SECURED=%SECURED% WITH_TCP=%WITH_TCP% BUILD_SAMPLE=ON LOGGING=%LOGGING% TEST=%TEST% RD_MODE=%RD_MODE% ROUTING=%ROUTING% WITH_UPSTREAM_LIBCOAP=%WITH_UPSTREAM_LIBCOAP% MULTIPLE_OWNER=%MULTIPLE_OWNER% -j %THREAD_COUNT%
 110
 111 REM Use MSVC_VERSION=12.0 for VS2013, or MSVC_VERSION=14.0 for VS2015.
 112 REM If MSVC_VERSION has not been defined here, SCons chooses automatically a VS version.
 113 IF NOT "%MSVC_VERSION%" == "" (
 114   set BUILD_OPTIONS=%BUILD_OPTIONS% MSVC_VERSION=%MSVC_VERSION%
 115 )
 116
 117 REM *** BUILD OPTIONS ***
 118
 119 if "!RUN_ARG!"=="server" (
 120   cd %BUILD_DIR%\resource\examples
 121   %DEBUG% simpleserver.exe
 122 ) else if "!RUN_ARG!"=="client" (
 123   cd %BUILD_DIR%\resource\examples
 124   %DEBUG% simpleclient.exe
 125 ) else if "!RUN_ARG!"=="serverhq" (
 126   cd %BUILD_DIR%\resource\examples
 127   %DEBUG% simpleserverHQ.exe
 128 ) else if "!RUN_ARG!"=="clienthq" (
 129   cd %BUILD_DIR%\resource\examples
 130   %DEBUG% simpleclientHQ.exe
 131 ) else if "!RUN_ARG!"=="mediaclient" (
 132   cd %BUILD_DIR%\resource\examples
 133   %DEBUG% mediaclient.exe
 134 ) else if "!RUN_ARG!"=="mediaserver" (
 135   cd %BUILD_DIR%\resource\examples
 136   %DEBUG% mediaserver.exe
 137 ) else if "!RUN_ARG!"=="winuiclient" (
 138   cd %BUILD_DIR%\resource\examples
 139   %DEBUG% winuiclient.exe
 140 ) else if "!RUN_ARG!"=="occlient" (
 141   cd %BUILD_DIR%\resource\csdk\stack\samples\linux\SimpleClientServer
 142   %DEBUG% occlientbasicops.exe -u 0 -t 3 -c 1
 143 ) else if "!RUN_ARG!"=="ocserver" (
 144   cd %BUILD_DIR%\resource\csdk\stack\samples\linux\SimpleClientServer
 145   %DEBUG% ocserverbasicops.exe
 146 ) else if "!RUN_ARG!"=="provclient" (
 147   cd %BUILD_DIR%\resource\csdk\security\provisioning\sample
 148   %DEBUG% provisioningclient.exe
 149 ) else if "!RUN_ARG!"=="justworks" (
 150   cd %BUILD_DIR%\resource\csdk\security\provisioning\sample
 151   %DEBUG% sampleserver_justworks.exe
 152 ) else if "!RUN_ARG!"=="test" (
 153   %DEBUG% %BUILD_DIR%\resource\csdk\connectivity\test\catests.exe
 154   %DEBUG% %BUILD_DIR%\resource\csdk\stack\test\stacktests.exe
 155   %DEBUG% %BUILD_DIR%\resource\csdk\stack\test\cbortests.exe
 156   %DEBUG% %BUILD_DIR%\resource\csdk\security\unittest\unittest.exe
 157   %DEBUG% %BUILD_DIR%\resource\csdk\security\provisioning\unittest\unittest.exe
 158   %DEBUG% %BUILD_DIR%\resource\c_common\ocrandom\test\randomtests.exe
 159   %DEBUG% %BUILD_DIR%\resource\c_common\oic_malloc\test\malloctests.exe
 160   %DEBUG% %BUILD_DIR%\resource\c_common\oic_string\test\stringtests.exe
 161   %DEBUG% %BUILD_DIR%\resource\c_common\oic_time\test\timetests.exe
 162   %DEBUG% %BUILD_DIR%\resource\unittests\unittests.exe
 163 ) else if "!RUN_ARG!"=="build" (
 164   echo Starting IoTivity build with these options:
 165   echo   TARGET_OS=%TARGET_OS%
 166   echo   TARGET_ARCH=%TARGET_ARCH%
 167   echo   SECURED=%SECURED%
 168   echo   RELEASE=%RELEASE%
 169   echo   TEST=%TEST%
 170   echo   LOGGING=%LOGGING%
 171   echo   ROUTING=%ROUTING%
 172   echo   WITH_TCP=%WITH_TCP%
 173   echo   WITH_UPSTREAM_LIBCOAP=%WITH_UPSTREAM_LIBCOAP%
 174   echo   MULTIPLE_OWNER=%MULTIPLE_OWNER%
 175   echo   MSVC_VERSION=%MSVC_VERSION%
 176   echo   THREAD_COUNT=%THREAD_COUNT%
 177   echo.scons VERBOSE=1 %BUILD_OPTIONS%
 178   scons VERBOSE=1 %BUILD_OPTIONS%
 179 ) else if "!RUN_ARG!"=="clean" (
 180   del /S *.ilk
 181   scons VERBOSE=1 %BUILD_OPTIONS% -c
 182 ) else if "!RUN_ARG!"=="cleangtest" (
 183   rd /s /q extlibs\gtest\googletest-release-1.7.0
 184   del extlibs\gtest\release-1.7.0.zip
 185 ) else (
 186     echo.%0 - Script requires a valid argument!
 187     goto :EOF
 188 )
 189
 190 cd %IOTIVITY_DIR%
 191
 192 echo Done!
 193
 194 goto EOF
 195
 196 :USAGE
 197 echo %0 - Helper to build/test iotivity.  Requires an argument.
 198 echo Installation: Drop this into your iotivity root directory to use it.
 199 echo.
 200 echo. Default build settings are: debug binaries run unittests and no logging
 201 echo.
 202 echo. Default build parameters can be overridden using the following arguments
 203 echo.
 204 REM At a quick look, the "Build either amd64 or x86 architecture binaries" message
 205 REM below seems out of alignment with the other messages underneath it. But, "^|"
 206 REM gets echoed as a single character, so the messages are actually aligned correctly
 207 REM in the output of "run.bat".
 208 echo   -arch [x86 ^| amd64]          - Build either amd64 or x86 architecture binaries
 209 echo.
 210 echo   -noTest                      - Don't run the unittests after building the binaries
 211 echo.
 212 echo   -logging                     - Enable logging while building the binaries
 213 echo.
 214 echo   -debugger                    - Debug the requested application
 215 echo.
 216 echo   -release                     - Build release binaries
 217 echo.
 218 echo   -threads [NUMBER_OF_THREADS] - Build in parallel using [NUMBER_OF_THREADS] threads. Default: %NUMBER_OF_PROCESSORS%.
 219 echo.
 220 echo   -noTCP                       - Build with the TCP adapter disabled
 221 echo.
 222 echo   -noSecurity                  - Remove security support (results in code that cannot be certified by OCF)
 223 echo.
 224 echo   -noMOT                       - Remove Multiple Ownership Transfer support.
 225 echo.
 226 echo. Usage examples:
 227 echo.
 228 echo   Launch SimpleClient with debugger:
 229 echo      %0 client -debugger
 230 echo.
 231 echo   Launch SimpleServer:
 232 echo      %0 server
 233 echo.
 234 echo   Launch WinUIClient built in msys:
 235 echo      %0 msys winuiclient
 236 echo.
 237 echo   Build amd64 debug binaries and run unit tests:
 238 echo      %0 build
 239 echo.
 240 echo   Build amd64 release binaries w/o running tests:
 241 echo      %0 build -arch amd64 -noTest -release
 242 echo.
 243 echo   Build x86 debug binaries and run unit tests:
 244 echo      %0 build -arch x86
 245 echo.
 246 echo   Build amd64 release binaries with logging enabled:
 247 echo      %0 build -arch amd64 -release -logging
 248 echo.
 249 echo   Build using only one thread:
 250 echo      %0 build -threads 1
 251 echo.
 252 echo   Build with TCP adapter disabled and run unit tests:
 253 echo      %0 build -noTCP
 254 echo.
 255 echo   Build without security support and run unit tests:
 256 echo      %0 build -noSecurity
 257 echo.
 258 echo   Build without Multiple Ownership Transfer support and run unit tests:
 259 echo      %0 build -noMOT
 260 echo.
 261 echo   Run all tests:
 262 echo      %0 test
 263 echo.
 264 echo   Clean:
 265 echo      %0 clean
 266
 267 :EOF