platforms/linux/arm-gnueabi.toolchain.cmake

   1 set(CMAKE_SYSTEM_NAME Linux)
   2 set(CMAKE_SYSTEM_VERSION 1)
   3 set(CMAKE_SYSTEM_PROCESSOR arm)
   4
   5 set(GCC_COMPILER_VERSION "4.6" CACHE STRING "GCC Compiler version")
   6
   7 set(FLOAT_ABI_SUFFIX "")
   8
   9 if (NOT SOFTFP)
  10   set(FLOAT_ABI_SUFFIX "hf")
  11 endif()
  12
  13 set(CMAKE_C_COMPILER    arm-linux-gnueabi${FLOAT_ABI_SUFFIX}-gcc-${GCC_COMPILER_VERSION})
  14 set(CMAKE_CXX_COMPILER  arm-linux-gnueabi${FLOAT_ABI_SUFFIX}-g++-${GCC_COMPILER_VERSION})
  15 set(ARM_LINUX_SYSROOT /usr/arm-linux-gnueabi${FLOAT_ABI_SUFFIX} CACHE PATH "ARM cross compilation system root")
  16
  17 set(CMAKE_CXX_FLAGS           ""                    CACHE STRING "c++ flags")
  18 set(CMAKE_C_FLAGS             ""                    CACHE STRING "c flags")
  19 set(CMAKE_SHARED_LINKER_FLAGS ""                    CACHE STRING "shared linker flags")
  20 set(CMAKE_MODULE_LINKER_FLAGS ""                    CACHE STRING "module linker flags")
  21 set(CMAKE_EXE_LINKER_FLAGS    "-Wl,-z,nocopyreloc"  CACHE STRING "executable linker flags")
  22
  23 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mthumb -fdata-sections -Wa,--noexecstack -fsigned-char -Wno-psabi")
  24 set(CMAKE_C_FLAGS   "${CMAKE_C_FLAGS} -mthumb -fdata-sections -Wa,--noexecstack -fsigned-char -Wno-psabi")
  25
  26 set(CMAKE_SHARED_LINKER_FLAGS "-Wl,--fix-cortex-a8 -Wl,--no-undefined -Wl,--gc-sections -Wl,-z,noexecstack -Wl,-z,relro -Wl,-z,now ${CMAKE_SHARED_LINKER_FLAGS}")
  27 set(CMAKE_MODULE_LINKER_FLAGS "-Wl,--fix-cortex-a8 -Wl,--no-undefined -Wl,--gc-sections -Wl,-z,noexecstack -Wl,-z,relro -Wl,-z,now ${CMAKE_MODULE_LINKER_FLAGS}")
  28 set(CMAKE_EXE_LINKER_FLAGS    "-Wl,--fix-cortex-a8 -Wl,--no-undefined -Wl,--gc-sections -Wl,-z,noexecstack -Wl,-z,relro -Wl,-z,now ${CMAKE_EXE_LINKER_FLAGS}")
  29
  30 if(USE_NEON)
  31   message(WARNING "You use obsolete variable USE_NEON to enable NEON instruction set. Use -DENABLE_NEON=ON instead." )
  32   set(ENABLE_NEON TRUE)
  33 elseif(USE_VFPV3)
  34   message(WARNING "You use obsolete variable USE_VFPV3 to enable VFPV3 instruction set. Use -DENABLE_VFPV3=ON instead." )
  35   set(ENABLE_VFPV3 TRUE)
  36 endif()
  37
  38 set(CMAKE_FIND_ROOT_PATH ${CMAKE_FIND_ROOT_PATH} ${ARM_LINUX_SYSROOT})
  39
  40 if(EXISTS ${CUDA_TOOLKIT_ROOT_DIR})
  41     set(CMAKE_FIND_ROOT_PATH ${CMAKE_FIND_ROOT_PATH} ${CUDA_TOOLKIT_ROOT_DIR})
  42 endif()
  43
  44 set( CMAKE_SKIP_RPATH TRUE CACHE BOOL "If set, runtime paths are not added when using shared libraries." )
  45 set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
  46 set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
  47 set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM ONLY)
  48
  49 # macro to find programs on the host OS
  50 macro( find_host_program )
  51  set( CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER )
  52  set( CMAKE_FIND_ROOT_PATH_MODE_LIBRARY NEVER )
  53  set( CMAKE_FIND_ROOT_PATH_MODE_INCLUDE NEVER )
  54  if( CMAKE_HOST_WIN32 )
  55   SET( WIN32 1 )
  56   SET( UNIX )
  57  elseif( CMAKE_HOST_APPLE )
  58   SET( APPLE 1 )
  59   SET( UNIX )
  60  endif()
  61  find_program( ${ARGN} )
  62  SET( WIN32 )
  63  SET( APPLE )
  64  SET( UNIX 1 )
  65  set( CMAKE_FIND_ROOT_PATH_MODE_PROGRAM ONLY )
  66  set( CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY )
  67  set( CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY )
  68 endmacro()
  69
  70 # macro to find packages on the host OS
  71 macro( find_host_package )
  72  set( CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER )
  73  set( CMAKE_FIND_ROOT_PATH_MODE_LIBRARY NEVER )
  74  set( CMAKE_FIND_ROOT_PATH_MODE_INCLUDE NEVER )
  75  if( CMAKE_HOST_WIN32 )
  76   SET( WIN32 1 )
  77   SET( UNIX )
  78  elseif( CMAKE_HOST_APPLE )
  79   SET( APPLE 1 )
  80   SET( UNIX )
  81  endif()
  82  find_package( ${ARGN} )
  83  SET( WIN32 )
  84  SET( APPLE )
  85  SET( UNIX 1 )
  86  set( CMAKE_FIND_ROOT_PATH_MODE_PROGRAM ONLY )
  87  set( CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY )
  88  set( CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY )
  89 endmacro()