platforms/ios/cmake/Modules/Platform/iOS.cmake

   1 # This file is based off of the Platform/Darwin.cmake and Platform/UnixPaths.cmake
   2 # files which are included with CMake 2.8.4
   3 # It has been altered for iOS development
   4 set (UNIX 1)
   5 set (APPLE 1)
   6 set (IOS 1)
   7
   8 # Darwin versions:
   9 #   6.x == Mac OSX 10.2
  10 #   7.x == Mac OSX 10.3
  11 #   8.x == Mac OSX 10.4
  12 #   9.x == Mac OSX 10.5
  13 #  10.x == Mac OSX 10.6 (Snow Leopard)
  14 string (REGEX REPLACE "^([0-9]+)\\.([0-9]+).*$" "\\1" DARWIN_MAJOR_VERSION "${CMAKE_SYSTEM_VERSION}")
  15 string (REGEX REPLACE "^([0-9]+)\\.([0-9]+).*$" "\\2" DARWIN_MINOR_VERSION "${CMAKE_SYSTEM_VERSION}")
  16
  17 # Do not use the "-Wl,-search_paths_first" flag with the OSX 10.2 compiler.
  18 # Done this way because it is too early to do a TRY_COMPILE.
  19 if (NOT DEFINED HAVE_FLAG_SEARCH_PATHS_FIRST)
  20     set (HAVE_FLAG_SEARCH_PATHS_FIRST 0)
  21     if ("${DARWIN_MAJOR_VERSION}" GREATER 6)
  22         set (HAVE_FLAG_SEARCH_PATHS_FIRST 1)
  23     endif ("${DARWIN_MAJOR_VERSION}" GREATER 6)
  24 endif (NOT DEFINED HAVE_FLAG_SEARCH_PATHS_FIRST)
  25 # More desirable, but does not work:
  26 #INCLUDE(CheckCXXCompilerFlag)
  27 #CHECK_CXX_COMPILER_FLAG("-Wl,-search_paths_first" HAVE_FLAG_SEARCH_PATHS_FIRST)
  28
  29 set (CMAKE_SHARED_LIBRARY_PREFIX "lib")
  30 set (CMAKE_SHARED_LIBRARY_SUFFIX ".dylib")
  31 set (CMAKE_SHARED_MODULE_PREFIX "lib")
  32 set (CMAKE_SHARED_MODULE_SUFFIX ".so")
  33 set (CMAKE_MODULE_EXISTS 1)
  34 set (CMAKE_DL_LIBS "")
  35
  36 set (CMAKE_C_OSX_COMPATIBILITY_VERSION_FLAG "-compatibility_version ")
  37 set (CMAKE_C_OSX_CURRENT_VERSION_FLAG "-current_version ")
  38 set (CMAKE_CXX_OSX_COMPATIBILITY_VERSION_FLAG "${CMAKE_C_OSX_COMPATIBILITY_VERSION_FLAG}")
  39 set (CMAKE_CXX_OSX_CURRENT_VERSION_FLAG "${CMAKE_C_OSX_CURRENT_VERSION_FLAG}")
  40
  41 # Hidden visibilty is required for cxx on iOS
  42 set (CMAKE_C_FLAGS "")
  43 set (CMAKE_CXX_FLAGS "-stdlib=libc++ -headerpad_max_install_names -fvisibility=hidden -fvisibility-inlines-hidden")
  44
  45 set (CMAKE_CXX_FLAGS_RELEASE "-DNDEBUG -O3 -fomit-frame-pointer -ffast-math")
  46
  47 if (HAVE_FLAG_SEARCH_PATHS_FIRST)
  48     set (CMAKE_C_LINK_FLAGS "-Wl,-search_paths_first ${CMAKE_C_LINK_FLAGS}")
  49     set (CMAKE_CXX_LINK_FLAGS "-Wl,-search_paths_first ${CMAKE_CXX_LINK_FLAGS}")
  50 endif (HAVE_FLAG_SEARCH_PATHS_FIRST)
  51
  52 set (CMAKE_PLATFORM_HAS_INSTALLNAME 1)
  53 set (CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS "-dynamiclib -headerpad_max_install_names")
  54 set (CMAKE_SHARED_MODULE_CREATE_C_FLAGS "-bundle -headerpad_max_install_names")
  55 set (CMAKE_SHARED_MODULE_LOADER_C_FLAG "-Wl,-bundle_loader,")
  56 set (CMAKE_SHARED_MODULE_LOADER_CXX_FLAG "-Wl,-bundle_loader,")
  57 set (CMAKE_FIND_LIBRARY_SUFFIXES ".dylib" ".so" ".a")
  58
  59 # hack: if a new cmake (which uses CMAKE_INSTALL_NAME_TOOL) runs on an old build tree
  60 # (where install_name_tool was hardcoded) and where CMAKE_INSTALL_NAME_TOOL isn't in the cache
  61 # and still cmake didn't fail in CMakeFindBinUtils.cmake (because it isn't rerun)
  62 # hardcode CMAKE_INSTALL_NAME_TOOL here to install_name_tool, so it behaves as it did before, Alex
  63 if (NOT DEFINED CMAKE_INSTALL_NAME_TOOL)
  64     find_program(CMAKE_INSTALL_NAME_TOOL install_name_tool)
  65 endif (NOT DEFINED CMAKE_INSTALL_NAME_TOOL)
  66
  67 # Setup iOS developer location
  68 if (IPHONEOS)
  69     set (_CMAKE_IOS_DEVELOPER_ROOT "/Developer/Platforms/iPhoneOS.platform/Developer")
  70 else ()
  71     if (IPHONESIMULATOR)
  72         set (_CMAKE_IOS_DEVELOPER_ROOT "/Developer/Platforms/iPhoneSimulator.platform/Developer")
  73     endif ()
  74 endif ()
  75 # Find installed iOS SDKs
  76 file (GLOB _CMAKE_IOS_SDKS "${_CMAKE_IOS_DEVELOPER_ROOT}/SDKs/*")
  77
  78 # Find and use the most recent iOS sdk
  79 if (_CMAKE_IOS_SDKS)
  80     list (SORT _CMAKE_IOS_SDKS)
  81     list (REVERSE _CMAKE_IOS_SDKS)
  82     list (GET _CMAKE_IOS_SDKS 0 _CMAKE_IOS_SDK_ROOT)
  83
  84     # Set the sysroot default to the most recent SDK
  85     set (CMAKE_OSX_SYSROOT ${_CMAKE_IOS_SDK_ROOT} CACHE PATH "Sysroot used for iOS support")
  86
  87     # set the architecture for iOS - this env var sets armv6,armv7 and appears to be XCode's standard. The other found is ARCHS_UNIVERSAL_IPHONE_OS but that is armv7 only
  88     set (CMAKE_OSX_ARCHITECTURES "$(ARCHS_STANDARD_32_BIT)" CACHE string  "Build architecture for iOS")
  89
  90     # Set the default based on this file and not the environment variable
  91     set (CMAKE_FIND_ROOT_PATH ${_CMAKE_IOS_DEVELOPER_ROOT} ${_CMAKE_IOS_SDK_ROOT} CACHE string  "iOS library search path root")
  92
  93     # default to searching for frameworks first
  94     set (CMAKE_FIND_FRAMEWORK FIRST)
  95
  96     # set up the default search directories for frameworks
  97     set (CMAKE_SYSTEM_FRAMEWORK_PATH
  98         ${_CMAKE_IOS_SDK_ROOT}/System/Library/Frameworks
  99         ${_CMAKE_IOS_SDK_ROOT}/System/Library/PrivateFrameworks
 100         ${_CMAKE_IOS_SDK_ROOT}/Developer/Library/Frameworks
 101     )
 102 endif (_CMAKE_IOS_SDKS)
 103
 104 if ("${CMAKE_BACKWARDS_COMPATIBILITY}" MATCHES "^1\\.[0-6]$")
 105     set (CMAKE_SHARED_MODULE_CREATE_C_FLAGS "${CMAKE_SHARED_MODULE_CREATE_C_FLAGS} -flat_namespace -undefined suppress")
 106 endif ("${CMAKE_BACKWARDS_COMPATIBILITY}" MATCHES "^1\\.[0-6]$")
 107
 108 if (NOT XCODE)
 109       # Enable shared library versioning.  This flag is not actually referenced
 110       # but the fact that the setting exists will cause the generators to support
 111       # soname computation.
 112       set (CMAKE_SHARED_LIBRARY_SONAME_C_FLAG "-install_name")
 113 endif (NOT XCODE)
 114
 115 # Xcode does not support -isystem yet.
 116 if (XCODE)
 117     set (CMAKE_INCLUDE_SYSTEM_FLAG_C)
 118     set (CMAKE_INCLUDE_SYSTEM_FLAG_CXX)
 119 endif (XCODE)
 120
 121 # Need to list dependent shared libraries on link line.  When building
 122 # with -isysroot (for universal binaries), the linker always looks for
 123 # dependent libraries under the sysroot.  Listing them on the link
 124 # line works around the problem.
 125 set (CMAKE_LINK_DEPENDENT_LIBRARY_FILES 1)
 126
 127 set (CMAKE_C_CREATE_SHARED_LIBRARY_FORBIDDEN_FLAGS -w)
 128 set (CMAKE_CXX_CREATE_SHARED_LIBRARY_FORBIDDEN_FLAGS -w)
 129
 130 set (CMAKE_C_CREATE_SHARED_LIBRARY
 131     "<CMAKE_C_COMPILER> <LANGUAGE_COMPILE_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS> <LINK_FLAGS> -o <TARGET> -install_name <TARGET_INSTALLNAME_DIR><TARGET_SONAME> <OBJECTS> <LINK_LIBRARIES>")
 132 set (CMAKE_CXX_CREATE_SHARED_LIBRARY
 133     "<CMAKE_CXX_COMPILER> <LANGUAGE_COMPILE_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS> <LINK_FLAGS> -o <TARGET> -install_name <TARGET_INSTALLNAME_DIR><TARGET_SONAME> <OBJECTS> <LINK_LIBRARIES>")
 134
 135 set (CMAKE_CXX_CREATE_SHARED_MODULE
 136     "<CMAKE_CXX_COMPILER> <LANGUAGE_COMPILE_FLAGS> <CMAKE_SHARED_MODULE_CREATE_CXX_FLAGS> <LINK_FLAGS> -o <TARGET> <OBJECTS> <LINK_LIBRARIES>")
 137
 138 set (CMAKE_C_CREATE_SHARED_MODULE
 139     "<CMAKE_C_COMPILER>  <LANGUAGE_COMPILE_FLAGS> <CMAKE_SHARED_MODULE_CREATE_C_FLAGS> <LINK_FLAGS> -o <TARGET> <OBJECTS> <LINK_LIBRARIES>")
 140
 141 set (CMAKE_C_CREATE_MACOSX_FRAMEWORK
 142     "<CMAKE_C_COMPILER> <LANGUAGE_COMPILE_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_C_FLAGS> <LINK_FLAGS> -o <TARGET> -install_name <TARGET_INSTALLNAME_DIR><TARGET_SONAME> <OBJECTS> <LINK_LIBRARIES>")
 143 set (CMAKE_CXX_CREATE_MACOSX_FRAMEWORK
 144     "<CMAKE_CXX_COMPILER> <LANGUAGE_COMPILE_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_CXX_FLAGS> <LINK_FLAGS> -o <TARGET> -install_name <TARGET_INSTALLNAME_DIR><TARGET_SONAME> <OBJECTS> <LINK_LIBRARIES>")
 145
 146
 147 # Add the install directory of the running cmake to the search directories
 148 # CMAKE_ROOT is CMAKE_INSTALL_PREFIX/share/cmake, so we need to go two levels up
 149 get_filename_component (_CMAKE_INSTALL_DIR "${CMAKE_ROOT}" PATH)
 150 get_filename_component (_CMAKE_INSTALL_DIR "${_CMAKE_INSTALL_DIR}" PATH)
 151
 152 # List common installation prefixes.  These will be used for all search types
 153 list (APPEND CMAKE_SYSTEM_PREFIX_PATH
 154     # Standard
 155     ${_CMAKE_IOS_DEVELOPER_ROOT}/usr
 156     ${_CMAKE_IOS_SDK_ROOT}/usr
 157
 158     # CMake install location
 159     "${_CMAKE_INSTALL_DIR}"
 160
 161     # Project install destination.
 162     "${CMAKE_INSTALL_PREFIX}"
 163 )