pgosupport.cmake

   1 function(clr_pgo_unknown_arch)
   2     if (WIN32)
   3         message(FATAL_ERROR "Only AMD64, ARM and I386 are supported for PGO")
   4     else()
   5         message(FATAL_ERROR "PGO not currently supported on the current platform")
   6     endif()
   7 endfunction(clr_pgo_unknown_arch)
   8
   9 # Adds Profile Guided Optimization (PGO) flags to the current target
  10 function(add_pgo TargetName)
  11     if(WIN32)
  12         set(ProfileFileName "${TargetName}.pgd")
  13     else(WIN32)
  14         set(ProfileFileName "${TargetName}.profdata")
  15     endif(WIN32)
  16
  17     set(CLR_CMAKE_OPTDATA_PACKAGEWITHRID "optimization.${CLR_CMAKE_TARGET_OS}-${CLR_CMAKE_TARGET_ARCH}.PGO.CoreCLR")
  18
  19     # On case-sensitive file systems, NuGet packages are restored to lowercase paths
  20     string(TOLOWER "${CLR_CMAKE_OPTDATA_PACKAGEWITHRID}/${CLR_CMAKE_OPTDATA_VERSION}" OptDataVersionedSubPath)
  21
  22     file(TO_NATIVE_PATH
  23         "${CLR_CMAKE_PACKAGES_DIR}/${OptDataVersionedSubPath}/data/${ProfileFileName}"
  24         ProfilePath
  25     )
  26
  27     if(CLR_CMAKE_PGO_INSTRUMENT)
  28         if(WIN32)
  29             set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS_RELEASE        " /LTCG /GENPROFILE")
  30             set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS_RELWITHDEBINFO " /LTCG /GENPROFILE")
  31         else(WIN32)
  32             if(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
  33                 target_compile_options(${TargetName} PRIVATE -flto -fprofile-instr-generate)
  34                 set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS " -flto -fuse-ld=gold -fprofile-instr-generate")
  35             endif(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
  36         endif(WIN32)
  37     else(CLR_CMAKE_PGO_INSTRUMENT)
  38         # If we don't have profile data availble, gracefully fall back to a non-PGO opt build
  39         if(EXISTS ${ProfilePath})
  40             if(WIN32)
  41                 set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS_RELEASE        " /LTCG /USEPROFILE:PGD=${ProfilePath}")
  42                 set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS_RELWITHDEBINFO " /LTCG /USEPROFILE:PGD=${ProfilePath}")
  43             else(WIN32)
  44                 if(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
  45                     if(HAVE_LTO)
  46                         target_compile_options(${TargetName} PRIVATE -flto -fprofile-instr-use=${ProfilePath} -Wno-profile-instr-out-of-date)
  47                         set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS " -flto -fuse-ld=gold -fprofile-instr-use=${ProfilePath}")
  48                     endif(HAVE_LTO)
  49                 endif(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
  50             endif(WIN32)
  51         endif(EXISTS ${ProfilePath})
  52     endif(CLR_CMAKE_PGO_INSTRUMENT)
  53 endfunction(add_pgo)
  54
  55 if(WIN32)
  56   if(CLR_CMAKE_PGO_INSTRUMENT)
  57     # Instrumented PGO binaries on Windows introduce an additional runtime dependency, pgort<ver>.dll.
  58     # Make sure we copy it next to the installed product to make it easier to redistribute the package.
  59
  60     string(SUBSTRING ${CMAKE_VS_PLATFORM_TOOLSET} 1 -1 VS_PLATFORM_VERSION_NUMBER)
  61     set(PGORT_FILENAME "pgort${VS_PLATFORM_VERSION_NUMBER}.dll")
  62
  63     get_filename_component(PATH_CXX_ROOTDIR ${CMAKE_CXX_COMPILER} DIRECTORY)
  64
  65     if(CLR_CMAKE_PLATFORM_ARCH_I386)
  66       set(PATH_VS_PGORT_DLL "${PATH_CXX_ROOTDIR}/${PGORT_FILENAME}")
  67     elseif(CLR_CMAKE_PLATFORM_ARCH_AMD64)
  68       set(PATH_VS_PGORT_DLL "${PATH_CXX_ROOTDIR}/../amd64/${PGORT_FILENAME}")
  69     elseif(CLR_CMAKE_PLATFORM_ARCH_ARM)
  70       set(PATH_VS_PGORT_DLL "${PATH_CXX_ROOTDIR}/../arm/${PGORT_FILENAME}")
  71     else()
  72       clr_pgo_unknown_arch()
  73     endif()
  74
  75     if (EXISTS ${PATH_VS_PGORT_DLL})
  76       message(STATUS "Found PGO runtime: ${PATH_VS_PGORT_DLL}")
  77       install(PROGRAMS ${PATH_VS_PGORT_DLL} DESTINATION .)
  78     else()
  79       message(FATAL_ERROR "file not found: ${PATH_VS_PGORT_DLL}")
  80     endif()
  81
  82   endif(CLR_CMAKE_PGO_INSTRUMENT)
  83 endif(WIN32)