pgosupport.cmake

   1 function(clr_pgo_unknown_arch)
   2     if (WIN32)
   3         message(FATAL_ERROR "Only AMD64, ARM and I386 are supported for PGO")
   4     else()
   5         message(FATAL_ERROR "PGO not currently supported on the current platform")
   6     endif()
   7 endfunction(clr_pgo_unknown_arch)
   8
   9 # Adds Profile Guided Optimization (PGO) flags to the current target
  10 function(add_pgo TargetName)
  11     if(WIN32)
  12         set(ProfileFileName "${TargetName}.pgd")
  13     else(WIN32)
  14         # Clang/LLVM uses one profdata file for the entire repo
  15         set(ProfileFileName "coreclr.profdata")
  16     endif(WIN32)
  17
  18     set(CLR_CMAKE_OPTDATA_PACKAGEWITHRID "optimization.${CLR_CMAKE_TARGET_OS}-${CLR_CMAKE_TARGET_ARCH}.PGO.CoreCLR")
  19     file(TO_NATIVE_PATH
  20         "${CLR_CMAKE_PACKAGES_DIR}/${CLR_CMAKE_OPTDATA_PACKAGEWITHRID}/${CLR_CMAKE_OPTDATA_VERSION}/data/${ProfileFileName}"
  21         ProfilePath
  22     )
  23     # NuGet packages are restored to lowercase paths
  24     string(TOLOWER "${ProfilePath}" ProfilePath)
  25
  26     if(CLR_CMAKE_PGO_INSTRUMENT)
  27         if(WIN32)
  28             set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS_RELEASE        " /LTCG /GENPROFILE")
  29             set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS_RELWITHDEBINFO " /LTCG /GENPROFILE")
  30         else(WIN32)
  31             if(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
  32                 target_compile_options(${TargetName} PRIVATE -flto -fprofile-instr-generate)
  33                 set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS " -flto -fuse-ld=gold -fprofile-instr-generate")
  34             endif(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
  35         endif(WIN32)
  36     else(CLR_CMAKE_PGO_INSTRUMENT)
  37         # If we don't have profile data availble, gracefully fall back to a non-PGO opt build
  38         if(EXISTS ${ProfilePath})
  39             if(WIN32)
  40                 set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS_RELEASE        " /LTCG /USEPROFILE:PGD=${ProfilePath}")
  41                 set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS_RELWITHDEBINFO " /LTCG /USEPROFILE:PGD=${ProfilePath}")
  42             else(WIN32)
  43                 if(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
  44                     if(HAVE_LTO)
  45                         target_compile_options(${TargetName} PRIVATE -flto -fprofile-instr-use=${ProfilePath} -Wno-profile-instr-out-of-date)
  46                         set_property(TARGET ${TargetName} APPEND_STRING PROPERTY LINK_FLAGS " -flto -fuse-ld=gold -fprofile-instr-use=${ProfilePath}")
  47                     endif(HAVE_LTO)
  48                 endif(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
  49             endif(WIN32)
  50         endif(EXISTS ${ProfilePath})
  51     endif(CLR_CMAKE_PGO_INSTRUMENT)
  52 endfunction(add_pgo)
  53
  54 if(WIN32)
  55   if(CLR_CMAKE_PGO_INSTRUMENT)
  56     # Instrumented PGO binaries on Windows introduce an additional runtime dependency, pgort<ver>.dll.
  57     # Make sure we copy it next to the installed product to make it easier to redistribute the package.
  58
  59     string(SUBSTRING ${CMAKE_VS_PLATFORM_TOOLSET} 1 -1 VS_PLATFORM_VERSION_NUMBER)
  60     set(PGORT_FILENAME "pgort${VS_PLATFORM_VERSION_NUMBER}.dll")
  61
  62     get_filename_component(PATH_CXX_ROOTDIR ${CMAKE_CXX_COMPILER} DIRECTORY)
  63
  64     if(CLR_CMAKE_PLATFORM_ARCH_I386)
  65       set(PATH_VS_PGORT_DLL "${PATH_CXX_ROOTDIR}/${PGORT_FILENAME}")
  66     elseif(CLR_CMAKE_PLATFORM_ARCH_AMD64)
  67       set(PATH_VS_PGORT_DLL "${PATH_CXX_ROOTDIR}/../amd64/${PGORT_FILENAME}")
  68     elseif(CLR_CMAKE_PLATFORM_ARCH_ARM)
  69       set(PATH_VS_PGORT_DLL "${PATH_CXX_ROOTDIR}/../arm/${PGORT_FILENAME}")
  70     else()
  71       clr_pgo_unknown_arch()
  72     endif()
  73
  74     if (EXISTS ${PATH_VS_PGORT_DLL})
  75       message(STATUS "Found PGO runtime: ${PATH_VS_PGORT_DLL}")
  76       install(PROGRAMS ${PATH_VS_PGORT_DLL} DESTINATION .)
  77     else()
  78       message(FATAL_ERROR "file not found: ${PATH_VS_PGORT_DLL}")
  79     endif()
  80
  81   endif(CLR_CMAKE_PGO_INSTRUMENT)
  82 endif(WIN32)