pgosupport.cmake

   1 function(clr_pgo_unknown_arch)
   2     if (WIN32)
   3         message(FATAL_ERROR "Only AMD64, ARM and I386 are supported for PGO")
   4     else()
   5         message(FATAL_ERROR "PGO not currently supported on the current platform")
   6     endif()
   7 endfunction(clr_pgo_unknown_arch)
   8
   9 # Adds Profile Guided Optimization (PGO) flags to the current target
  10 function(add_pgo TargetName)
  11     if(WIN32)
  12         set(ProfileFileName "${TargetName}.pgd")
  13     endif(WIN32)
  14
  15     set(CLR_CMAKE_OPTDATA_PACKAGEWITHRID "optimization.${CLR_CMAKE_TARGET_OS}-${CLR_CMAKE_TARGET_ARCH}.PGO.CoreCLR")
  16     file(TO_NATIVE_PATH
  17         "${CLR_CMAKE_PACKAGES_DIR}/${CLR_CMAKE_OPTDATA_PACKAGEWITHRID}/${CLR_CMAKE_OPTDATA_VERSION}/data/${ProfileFileName}"
  18         ProfilePath
  19     )
  20
  21     # Enable PGO only for optimized configs
  22     set(ConfigTypeList RELEASE RELWITHDEBINFO)
  23
  24     foreach(ConfigType IN LISTS ConfigTypeList)
  25         set(LinkFlagsProperty "LINK_FLAGS_${ConfigType}")
  26         if(CLR_CMAKE_PGO_INSTRUMENT)
  27             if(WIN32)
  28                 set_property(TARGET ${TargetName} APPEND_STRING PROPERTY ${LinkFlagsProperty} "/LTCG /GENPROFILE")
  29             endif(WIN32)
  30         else(CLR_CMAKE_PGO_INSTRUMENT)
  31             # If we don't have profile data availble, gracefully fall back to a non-PGO opt build
  32             if(EXISTS ${ProfilePath})
  33                 if(WIN32)
  34                     set_property(TARGET ${TargetName} APPEND_STRING PROPERTY ${LinkFlagsProperty} "/LTCG /USEPROFILE:PGD=${ProfilePath}")
  35                 endif(WIN32)
  36             endif(EXISTS ${ProfilePath})
  37         endif(CLR_CMAKE_PGO_INSTRUMENT)
  38     endforeach(ConfigType)
  39 endfunction(add_pgo)
  40
  41 if(WIN32)
  42   if(CLR_CMAKE_PGO_INSTRUMENT)
  43     # Instrumented PGO binaries on Windows introduce an additional runtime dependency, pgort<ver>.dll.
  44     # Make sure we copy it next to the installed product to make it easier to redistribute the package.
  45
  46     string(SUBSTRING ${CMAKE_VS_PLATFORM_TOOLSET} 1 -1 VS_PLATFORM_VERSION_NUMBER)
  47     set(PGORT_FILENAME "pgort${VS_PLATFORM_VERSION_NUMBER}.dll")
  48
  49     get_filename_component(PATH_CXX_ROOTDIR ${CMAKE_CXX_COMPILER} DIRECTORY)
  50
  51     if(CLR_CMAKE_PLATFORM_ARCH_I386)
  52       set(PATH_VS_PGORT_DLL "${PATH_CXX_ROOTDIR}/${PGORT_FILENAME}")
  53     elseif(CLR_CMAKE_PLATFORM_ARCH_AMD64)
  54       set(PATH_VS_PGORT_DLL "${PATH_CXX_ROOTDIR}/../amd64/${PGORT_FILENAME}")
  55     elseif(CLR_CMAKE_PLATFORM_ARCH_ARM)
  56       set(PATH_VS_PGORT_DLL "${PATH_CXX_ROOTDIR}/../arm/${PGORT_FILENAME}")
  57     else()
  58       clr_pgo_unknown_arch()
  59     endif()
  60
  61     if (EXISTS ${PATH_VS_PGORT_DLL})
  62       message(STATUS "Found PGO runtime: ${PATH_VS_PGORT_DLL}")
  63       install(PROGRAMS ${PATH_VS_PGORT_DLL} DESTINATION .)
  64     else()
  65       message(FATAL_ERROR "file not found: ${PATH_VS_PGORT_DLL}")
  66     endif()
  67
  68   endif(CLR_CMAKE_PGO_INSTRUMENT)
  69 endif(WIN32)