opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.5)
   5 AC_INIT(z8k-dis.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 # We currently only use the version number for the name of any shared
  11 # library.  For user convenience, we always use the same version
  12 # number that BFD is using.
  13 changequote(,)dnl
  14 BFD_VERSION=`grep INIT_AUTOMAKE ${srcdir}/../bfd/configure.in | sed -n -e 's/[  ]//g' -e 's/^.*,\(.*\)).*$/\1/p'`
  15 changequote([,])dnl
  16
  17 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  18
  19 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  20 dnl to call AC_CHECK_PROG.
  21 AC_CHECK_TOOL(AR, ar)
  22 AC_CHECK_TOOL(RANLIB, ranlib, :)
  23
  24 dnl Default to a non shared library.  This may be overridden by the
  25 dnl configure option --enable-shared.
  26 AM_DISABLE_SHARED
  27
  28 AM_PROG_LIBTOOL
  29
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  44 esac])dnl
  45
  46 AM_CONFIG_HEADER(config.h:config.in)
  47
  48 if test -z "$target" ; then
  49     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  50 fi
  51 AC_ARG_PROGRAM
  52
  53 AM_MAINTAINER_MODE
  54 AM_CYGWIN32
  55 AM_EXEEXT
  56
  57 # host-specific stuff:
  58
  59 AC_PROG_CC
  60
  61 ALL_LINGUAS=
  62 CY_GNU_GETTEXT
  63
  64 . ${srcdir}/../bfd/configure.host
  65
  66 AC_SUBST(HDEFINES)
  67 AM_PROG_INSTALL
  68
  69 AC_CHECK_HEADERS(string.h strings.h stdlib.h)
  70
  71 # start-sanitize-cygnus
  72 cgen_maint=no
  73 # Default is to use one in build tree.
  74 cgen=../cgen/cgen
  75 cgendir='$(srcdir)/../cgen'
  76 # Having --enable-maintainer-mode take arguments is another way to go.
  77 # ??? One can argue --with is more appropriate if one wants to specify
  78 # a directory name, but what we're doing here is an enable/disable kind
  79 # of thing and specifying both --enable and --with is klunky.
  80 # If you reeely want this to be --with, go ahead and change it.
  81 AC_ARG_ENABLE(cgen-maint,
  82 [  --enable-cgen-maint[=dir]    build cgen generated files],
  83 [case "${enableval}" in
  84   yes)  cgen_maint=yes ;;
  85   no)   cgen_maint=no ;;
  86   *)
  87         # argument is cgen install directory (not implemented yet).
  88         # Having a `share' directory might be more appropriate for the .scm,
  89         # .cpu, etc. files.
  90         cgen_maint=yes
  91         cgendir=${cgen_maint}/lib/cgen
  92         cgen=${cgendir}/bin/cgen
  93         ;;
  94 esac])dnl
  95 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
  96 AC_SUBST(cgendir)
  97 AC_SUBST(cgen)
  98 # end-sanitize-cygnus
  99
 100 # Horrible hacks to build DLLs on Windows.
 101 WIN32LDFLAGS=
 102 WIN32LIBADD=
 103 case "${host}" in
 104 *-*-cygwin*)
 105   if test "$enable_shared" = "yes"; then
 106     WIN32LDFLAGS="-no-undefined"
 107     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 108   fi
 109   ;;
 110 esac
 111 AC_SUBST(WIN32LDFLAGS)
 112 AC_SUBST(WIN32LIBADD)
 113
 114 # target-specific stuff:
 115
 116 # Canonicalize the secondary target names.
 117 if test -n "$enable_targets" ; then
 118     for targ in `echo $enable_targets | sed 's/,/ /g'`
 119     do
 120         result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 121         if test -n "$result" ; then
 122             canon_targets="$canon_targets $result"
 123         else
 124             # Allow targets that config.sub doesn't recognize, like "all".
 125             canon_targets="$canon_targets $targ"
 126         fi
 127     done
 128 fi
 129
 130 all_targets=false
 131 selarchs=
 132 for targ in $target $canon_targets
 133 do
 134     if test "x$targ" = "xall" ; then
 135         all_targets=true
 136     else
 137         . $srcdir/../bfd/config.bfd
 138         selarchs="$selarchs $targ_archs"
 139     fi
 140 done
 141
 142 # Utility var, documents generic cgen support files.
 143
 144 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo"
 145
 146 # We don't do any links based on the target system, just makefile config.
 147
 148 if test x${all_targets} = xfalse ; then
 149
 150     # Target architecture .o files.
 151     ta=
 152
 153     for arch in $selarchs
 154     do
 155         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 156         archdefs="$archdefs -DARCH_$ad"
 157         case "$arch" in
 158         bfd_a29k_arch)          ta="$ta a29k-dis.lo" ;;
 159         bfd_alliant_arch)       ;;
 160         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 161         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo" ;;
 162         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 163         bfd_convex_arch)        ;;
 164         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 165         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 166         bfd_fr30_arch)          ta="$ta $cgen_files fr30-opc.lo fr30-asm.lo fr30-dis.lo" ;;
 167         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 168         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 169         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 170         bfd_i386_arch)          ta="$ta i386-dis.lo" ;;
 171         bfd_i860_arch)          ;;
 172         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 173         bfd_m32r_arch)          ta="$ta $cgen_files m32r-opc.lo m32r-asm.lo m32r-dis.lo" ;;
 174         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 175         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 176         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 177         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 178         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 179         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 180         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 181         bfd_pyramid_arch)       ;;
 182         bfd_romp_arch)          ;;
 183         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 184         bfd_sh_arch)            ta="$ta sh-dis.lo" ;;
 185         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 186         bfd_tahoe_arch)         ;;
 187         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 188 # start-sanitize-tic80
 189         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 190 # end-sanitize-tic80
 191 # start-sanitize-sky
 192         bfd_dvp_arch)           ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo dvp-dis.lo dvp-opc.lo" ;;
 193 # end-sanitize-sky
 194         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 195 # start-sanitize-v850e
 196         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 197         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 198 # end-sanitize-v850e
 199         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 200         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 201         bfd_we32k_arch)         ;;
 202         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 203
 204         "")                     ;;
 205         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 206         esac
 207     done
 208
 209     # Weed out duplicate .o files.
 210     f=""
 211     for i in $ta ; do
 212         case " $f " in
 213         *" $i "*) ;;
 214         *) f="$f $i" ;;
 215         esac
 216     done
 217     ta="$f"
 218
 219     # And duplicate -D flags.
 220     f=""
 221     for i in $archdefs ; do
 222         case " $f " in
 223         *" $i "*) ;;
 224         *) f="$f $i" ;;
 225         esac
 226     done
 227     archdefs="$f"
 228
 229     BFD_MACHINES="$ta"
 230
 231 else    # all_targets is true
 232     archdefs=-DARCH_all
 233     BFD_MACHINES='$(ALL_MACHINES)'
 234 fi
 235
 236 AC_SUBST(archdefs)
 237 AC_SUBST(BFD_MACHINES)
 238
 239 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 240 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])