opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.5)
   5 AC_INIT(z8k-dis.c)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_ISC_POSIX
   9
  10 # We currently only use the version number for the name of any shared
  11 # library.  For user convenience, we always use the same version
  12 # number that BFD is using.
  13 changequote(,)dnl
  14 BFD_VERSION=`grep INIT_AUTOMAKE ${srcdir}/../bfd/configure.in | sed -n -e 's/[  ]//g' -e 's/^.*,\(.*\)).*$/\1/p'`
  15 changequote([,])dnl
  16
  17 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  18
  19 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  20 dnl to call AC_CHECK_PROG.
  21 AC_CHECK_TOOL(AR, ar)
  22 AC_CHECK_TOOL(RANLIB, ranlib, :)
  23
  24 dnl Default to a non shared library.  This may be overridden by the
  25 dnl configure option --enable-shared.
  26 AM_DISABLE_SHARED
  27
  28 AM_PROG_LIBTOOL
  29
  30 AC_ARG_ENABLE(targets,
  31 [  --enable-targets        alternative target configurations],
  32 [case "${enableval}" in
  33   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  34             ;;
  35   no)       enable_targets= ;;
  36   *)        enable_targets=$enableval ;;
  37 esac])dnl
  38 AC_ARG_ENABLE(commonbfdlib,
  39 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  40 [case "${enableval}" in
  41   yes) commonbfdlib=true ;;
  42   no)  commonbfdlib=false ;;
  43   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  44 esac])dnl
  45
  46 AM_CONFIG_HEADER(config.h:config.in)
  47
  48 if test -z "$target" ; then
  49     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  50 fi
  51 AC_ARG_PROGRAM
  52
  53 AM_MAINTAINER_MODE
  54 AM_CYGWIN32
  55 AM_EXEEXT
  56
  57 # host-specific stuff:
  58
  59 AC_PROG_CC
  60
  61 ALL_LINGUAS=
  62 CY_GNU_GETTEXT
  63
  64 . ${srcdir}/../bfd/configure.host
  65
  66 AC_SUBST(HDEFINES)
  67 AM_PROG_INSTALL
  68
  69 AC_CHECK_HEADERS(string.h strings.h stdlib.h)
  70
  71 # start-sanitize-cygnus
  72 use_cgen=no
  73 if test ${USE_MAINTAINER_MODE} = yes ; then
  74         for targ in $target $canon_targets
  75         do
  76             case $targ in
  77             all) use_cgen=yes ;;
  78             m32r-*-*) use_cgen=yes ;;
  79             esac
  80         done
  81 fi
  82 if test $use_cgen = yes ; then
  83     AC_CHECK_PROG(SCHEME, guile, guile, guile)
  84 fi
  85 # end-sanitize-cygnus
  86
  87 # Horrible hacks to build DLLs on Windows.
  88 WIN32LDFLAGS=
  89 WIN32LIBADD=
  90 case "${host}" in
  91 *-*-cygwin32*)
  92   if test "$enable_shared" = "yes"; then
  93     WIN32LDFLAGS="-no-undefined"
  94     WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -lcygwin"
  95   fi
  96   ;;
  97 esac
  98 AC_SUBST(WIN32LDFLAGS)
  99 AC_SUBST(WIN32LIBADD)
 100
 101 # target-specific stuff:
 102
 103 # Canonicalize the secondary target names.
 104 if test -n "$enable_targets" ; then
 105     for targ in `echo $enable_targets | sed 's/,/ /g'`
 106     do
 107         result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 108         if test -n "$result" ; then
 109             canon_targets="$canon_targets $result"
 110         else
 111             # Allow targets that config.sub doesn't recognize, like "all".
 112             canon_targets="$canon_targets $targ"
 113         fi
 114     done
 115 fi
 116
 117 all_targets=false
 118 selarchs=
 119 for targ in $target $canon_targets
 120 do
 121     if test "x$targ" = "xall" ; then
 122         all_targets=true
 123     else
 124         . $srcdir/../bfd/config.bfd
 125         selarchs="$selarchs $targ_archs"
 126     fi
 127 done
 128
 129 # Utility var, documents generic cgen support files.
 130
 131 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo"
 132
 133 # We don't do any links based on the target system, just makefile config.
 134
 135 if test x${all_targets} = xfalse ; then
 136
 137     # Target architecture .o files.
 138     ta=
 139
 140     for arch in $selarchs
 141     do
 142         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 143         archdefs="$archdefs -DARCH_$ad"
 144         case "$arch" in
 145         bfd_a29k_arch)          ta="$ta a29k-dis.lo" ;;
 146         bfd_alliant_arch)       ;;
 147         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 148         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo" ;;
 149         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 150         bfd_convex_arch)        ;;
 151         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 152 # start-sanitize-d30v
 153         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 154 # end-sanitize-d30v
 155         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 156         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 157         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 158         bfd_i386_arch)          ta="$ta i386-dis.lo" ;;
 159         bfd_i860_arch)          ;;
 160         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 161         bfd_m32r_arch)          ta="$ta $cgen_files m32r-opc.lo m32r-asm.lo m32r-dis.lo" ;;
 162         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 163         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 164         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 165         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 166         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 167         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 168         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 169         bfd_pyramid_arch)       ;;
 170         bfd_romp_arch)          ;;
 171         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 172         bfd_sh_arch)            ta="$ta sh-dis.lo" ;;
 173         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 174         bfd_tahoe_arch)         ;;
 175         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 176 # start-sanitize-tic80
 177         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 178 # end-sanitize-tic80
 179 # start-sanitize-sky
 180         bfd_dvp_arch)           ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo dvp-dis.lo dvp-opc.lo" ;;
 181 # end-sanitize-sky
 182         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 183 # start-sanitize-v850e
 184         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 185         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 186 # end-sanitize-v850e
 187         bfd_vax_arch)           ;;
 188         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 189         bfd_we32k_arch)         ;;
 190         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 191
 192         "")                     ;;
 193         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 194         esac
 195     done
 196
 197     # Weed out duplicate .o files.
 198     f=""
 199     for i in $ta ; do
 200         case " $f " in
 201         *" $i "*) ;;
 202         *) f="$f $i" ;;
 203         esac
 204     done
 205     ta="$f"
 206
 207     # And duplicate -D flags.
 208     f=""
 209     for i in $archdefs ; do
 210         case " $f " in
 211         *" $i "*) ;;
 212         *) f="$f $i" ;;
 213         esac
 214     done
 215     archdefs="$f"
 216
 217     BFD_MACHINES="$ta"
 218
 219 else    # all_targets is true
 220     archdefs=-DARCH_all
 221     BFD_MACHINES='$(ALL_MACHINES)'
 222 fi
 223
 224 AC_SUBST(archdefs)
 225 AC_SUBST(BFD_MACHINES)
 226
 227 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 228 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])