opcodes/configure.in

   1 AC_PREREQ(2.0)
   2 AC_INIT(z8k-dis.c)
   3 #    configure.in script for the opcodes library.
   4 #    Copyright (C) 1995 Free Software Foundation, Inc.
   5 #    Written by Cygnus Support.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 AC_ARG_ENABLE(targets,
  22 [  --enable-targets        alternative target configurations],
  23 [case "${enableval}" in
  24   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  25             ;;
  26   no)       enable_targets= ;;
  27   *)        enable_targets=$enableval ;;
  28 esac])dnl
  29
  30 # host-specific stuff:
  31
  32 . ${srcdir}/../bfd/configure.host
  33
  34 AC_PROG_CC
  35 AC_SUBST(CFLAGS)
  36 AC_SUBST(HDEFINES)
  37 AR=${AR-ar}
  38 AC_SUBST(AR)
  39 AC_PROG_RANLIB
  40 AC_PROG_INSTALL
  41
  42 AC_CHECK_HEADERS(string.h strings.h)
  43
  44 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  45 AC_CANONICAL_SYSTEM
  46 if test -z "$target" ; then
  47     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  48 fi
  49 if test -z "$host" ; then
  50     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  51 fi
  52 AC_ARG_PROGRAM
  53
  54 # target-specific stuff:
  55
  56 # Canonicalize the secondary target names.
  57 if test -n "$enable_targets" ; then
  58     for targ in `echo $enable_targets | sed 's/,/ /g'`
  59     do
  60         result=`$ac_config_sub $targ 2>/dev/null`
  61         if test -n "$result" ; then
  62             canon_targets="$canon_targets $result"
  63         else
  64             # Allow targets that config.sub doesn't recognize, like "all".
  65             canon_targets="$canon_targets $targ"
  66         fi
  67     done
  68 fi
  69
  70 all_targets=false
  71 selarchs=
  72 for targ in $target $canon_targets
  73 do
  74     if test "x$targ" = "xall" ; then
  75         all_targets=true
  76     else
  77         . $srcdir/../bfd/config.bfd
  78         selarchs="$selarchs $targ_archs"
  79     fi
  80 done
  81
  82 # We don't do any links based on the target system, just makefile config.
  83
  84 if test x${all_targets} = xfalse ; then
  85
  86     # Target architecture .o files.
  87     ta=
  88
  89     for arch in $selarchs
  90     do
  91         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
  92         archdefs="$archdefs -DARCH_$ad"
  93         case "$arch" in
  94         bfd_a29k_arch)          ta="$ta a29k-dis.o" ;;
  95         bfd_alpha_arch)         ta="$ta alpha-dis.o" ;;
  96 # start-sanitize-arc
  97         bfd_arc_arch)           ta="$ta arc-dis.o arc-opc.o" ;;
  98 # end-sanitize-arc
  99         bfd_arm_arch)           ta="$ta arm-dis.o" ;;
 100         bfd_h8300_arch)         ta="$ta h8300-dis.o" ;;
 101         bfd_h8500_arch)         ta="$ta h8500-dis.o" ;;
 102         bfd_hppa_arch)          ta="$ta hppa-dis.o" ;;
 103         bfd_i386_arch)          ta="$ta i386-dis.o" ;;
 104         bfd_i960_arch)          ta="$ta i960-dis.o" ;;
 105         bfd_m68k_arch)          ta="$ta m68k-dis.o m68k-opc.o" ;;
 106         bfd_m88k_arch)          ta="$ta m88k-dis.o" ;;
 107         bfd_mips_arch)          ta="$ta mips-dis.o mips-opc.o" ;;
 108         bfd_ns32k_arch)         ta="$ta ns32k-dis.o" ;;
 109         bfd_powerpc_arch)       ta="$ta ppc-dis.o ppc-opc.o" ;;
 110         bfd_rs6000_arch)        ta="$ta ppc-dis.o ppc-opc.o" ;;
 111         bfd_sh_arch)            ta="$ta sh-dis.o" ;;
 112 # start-sanitize-rce
 113         bfd_rce_arch)           ta="$ta rce-dis.o" ;;
 114 # end-sanitize-rce
 115         bfd_sparc_arch)         ta="$ta sparc-dis.o sparc-opc.o" ;;
 116         bfd_vax_arch)           ;;
 117         bfd_we32k_arch)         ;;
 118         bfd_z8k_arch)           ta="$ta z8k-dis.o" ;;
 119         bfd_w65_arch)           ta="$ta w65-dis.o" ;;
 120
 121         "")                     ;;
 122         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 123         esac
 124     done
 125
 126     # Weed out duplicate .o files.
 127     f=""
 128     for i in $ta ; do
 129         case " $f " in
 130         *" $i "*) ;;
 131         *) f="$f $i" ;;
 132         esac
 133     done
 134     ta="$f"
 135
 136     # And duplicate -D flags.
 137     f=""
 138     for i in $archdefs ; do
 139         case " $f " in
 140         *" $i "*) ;;
 141         *) f="$f $i" ;;
 142         esac
 143     done
 144     archdefs="$f"
 145
 146     BFD_MACHINES="$ta"
 147
 148 else    # all_targets is true
 149     archdefs=-DARCH_all
 150     BFD_MACHINES='$(ALL_MACHINES)'
 151 fi
 152
 153 AC_SUBST(archdefs)
 154 AC_SUBST(BFD_MACHINES)
 155
 156 AC_CONFIG_HEADER(config.h:config.in)
 157 AC_OUTPUT(Makefile)