opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright 2012 Free Software Foundation
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 AC_INIT
  22 AC_CONFIG_SRCDIR([z8k-dis.c])
  23
  24 AC_CANONICAL_TARGET
  25 AC_ISC_POSIX
  26
  27 # We currently only use the version number for the name of any shared
  28 # library.  For user convenience, we always use the same version
  29 # number that BFD is using.
  30 changequote(,)dnl
  31 BFD_VERSION=`${srcdir}/../bfd/configure --version | sed -n -e '1s,.* ,,p'`
  32 changequote([,])dnl
  33
  34 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  35
  36 AC_PROG_CC
  37 AC_GNU_SOURCE
  38 AC_USE_SYSTEM_EXTENSIONS
  39
  40 dnl These must be called before LT_INIT, because it may want
  41 dnl to call AC_CHECK_PROG.
  42 AC_CHECK_TOOL(AR, ar)
  43 AC_CHECK_TOOL(RANLIB, ranlib, :)
  44
  45 dnl Default to a non shared library.  This may be overridden by the
  46 dnl configure option --enable-shared.
  47 AC_DISABLE_SHARED
  48
  49 LT_INIT
  50
  51 AC_ARG_ENABLE(targets,
  52 [  --enable-targets        alternative target configurations],
  53 [case "${enableval}" in
  54   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  55             ;;
  56   no)       enable_targets= ;;
  57   *)        enable_targets=$enableval ;;
  58 esac])dnl
  59
  60 AM_BINUTILS_WARNINGS
  61 ACX_PROG_CC_WARNING_OPTS([-Wno-missing-field-initializers],
  62                          [NO_WMISSING_FIELD_INITIALIZERS])
  63
  64 AC_CONFIG_HEADERS(config.h:config.in)
  65
  66 # PR 14072
  67 AH_VERBATIM([00_CONFIG_H_CHECK],
  68 [/* Check that config.h is #included before system headers
  69    (this works only for glibc, but that should be enough).  */
  70 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  71 #  error config.h must be #included before system headers
  72 #endif
  73 #define __CONFIG_H__ 1])
  74
  75 if test -z "$target" ; then
  76     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  77 fi
  78
  79 AM_MAINTAINER_MODE
  80 AM_INSTALL_LIBBFD
  81 AC_EXEEXT
  82
  83 # host-specific stuff:
  84
  85 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN it uk"
  86 ZW_GNU_GETTEXT_SISTER_DIR
  87 AM_PO_SUBDIRS
  88
  89 . ${srcdir}/../bfd/configure.host
  90
  91 BFD_CC_FOR_BUILD
  92
  93 AC_SUBST(HDEFINES)
  94 AC_PROG_INSTALL
  95
  96 AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h)
  97 ACX_HEADER_STRING
  98
  99 AC_CHECK_DECLS([basename, stpcpy])
 100
 101 cgen_maint=no
 102 cgendir='$(srcdir)/../cgen'
 103
 104 AC_ARG_ENABLE(cgen-maint,
 105 [  --enable-cgen-maint[=dir]    build cgen generated files],
 106 [case "${enableval}" in
 107   yes)  cgen_maint=yes ;;
 108   no)   cgen_maint=no ;;
 109   *)
 110         # argument is cgen install directory (not implemented yet).
 111         # Having a `share' directory might be more appropriate for the .scm,
 112         # .cpu, etc. files.
 113         cgen_maint=yes
 114         cgendir=${cgen_maint}/lib/cgen
 115         ;;
 116 esac])dnl
 117 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 118 AC_SUBST(cgendir)
 119
 120 using_cgen=no
 121
 122 # Check if linker supports --as-needed and --no-as-needed options
 123 AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed,
 124         [bfd_cv_ld_as_needed=no
 125         if $LD --help 2>/dev/null | grep as-needed > /dev/null; then
 126                 bfd_cv_ld_as_needed=yes
 127         fi
 128         ])
 129
 130 LT_LIB_M
 131
 132 #Libs for generator progs
 133 if test "x$cross_compiling" = "xno"; then
 134   BUILD_LIBS=../libiberty/libiberty.a
 135   BUILD_LIB_DEPS=$BUILD_LIBS
 136 else
 137   # if cross-compiling, assume that the system provides -liberty
 138   # and that the version is compatible with new headers.
 139   BUILD_LIBS=-liberty
 140   BUILD_LIB_DEPS=
 141 fi
 142 BUILD_LIBS="$BUILD_LIBS $LIBINTL"
 143 BUILD_LIB_DEPS="$BUILD_LIB_DEPS $LIBINTL_DEP"
 144
 145 AC_SUBST(BUILD_LIBS)
 146 AC_SUBST(BUILD_LIB_DEPS)
 147
 148 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 149 SHARED_LDFLAGS=
 150 SHARED_LIBADD=
 151 SHARED_DEPENDENCIES=
 152 if test "$enable_shared" = "yes"; then
 153 # When building a shared libopcodes, link against the pic version of libiberty
 154 # so that apps that use libopcodes won't need libiberty just to satisfy any
 155 # libopcodes references.
 156 # We can't do that if a pic libiberty is unavailable since including non-pic
 157 # code would insert text relocations into libopcodes.
 158 # Note that linking against libbfd as we do here, which is itself linked
 159 # against libiberty, may not satisfy all the libopcodes libiberty references
 160 # since libbfd may not pull in the entirety of libiberty.
 161 changequote(,)dnl
 162   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 163 changequote([,])dnl
 164   if test -n "$x"; then
 165     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 166   fi
 167
 168   case "${host}" in
 169     *-*-cygwin*)
 170       SHARED_LDFLAGS="-no-undefined"
 171       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 172       ;;
 173    *-*-darwin*)
 174      SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib ${SHARED_LIBADD}"
 175      SHARED_DEPENDENCIES="../bfd/libbfd.la"
 176      ;;
 177     *)
 178       case "$host_vendor" in
 179         hp)
 180           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl ${SHARED_LIBADD}"
 181           ;;
 182         *)
 183           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so ${SHARED_LIBADD}"
 184           ;;
 185       esac
 186       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 187       ;;
 188   esac
 189
 190   if test -n "$SHARED_LIBADD"; then
 191     if test -n "$LIBM"; then
 192       if test x"$bfd_cv_ld_as_needed" = xyes; then
 193         # Link against libm only when needed.  Put -lc, -lm inside -Wl
 194         # to stop libtool reordering these options.
 195         SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed"
 196       else
 197         SHARED_LIBADD="$SHARED_LIBADD $LIBM"
 198       fi
 199     fi
 200   fi
 201 fi
 202 AC_SUBST(SHARED_LDFLAGS)
 203 AC_SUBST(SHARED_LIBADD)
 204 AC_SUBST(SHARED_DEPENDENCIES)
 205
 206 # target-specific stuff:
 207
 208 # Canonicalize the secondary target names.
 209 if test -n "$enable_targets" ; then
 210     for targ in `echo $enable_targets | sed 's/,/ /g'`
 211     do
 212         result=`$ac_config_sub $targ 2>/dev/null`
 213         if test -n "$result" ; then
 214             canon_targets="$canon_targets $result"
 215         else
 216             # Allow targets that config.sub doesn't recognize, like "all".
 217             canon_targets="$canon_targets $targ"
 218         fi
 219     done
 220 fi
 221
 222 all_targets=false
 223 selarchs=
 224 for targ in $target $canon_targets
 225 do
 226     if test "x$targ" = "xall" ; then
 227         all_targets=true
 228     else
 229         . $srcdir/../bfd/config.bfd
 230         selarchs="$selarchs $targ_archs"
 231     fi
 232 done
 233
 234 # Utility var, documents generic cgen support files.
 235
 236 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 237
 238 # We don't do any links based on the target system, just makefile config.
 239
 240 if test x${all_targets} = xfalse ; then
 241
 242     # Target architecture .o files.
 243     ta=
 244
 245     for arch in $selarchs
 246     do
 247         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 248         archdefs="$archdefs -DARCH_$ad"
 249         case "$arch" in
 250         bfd_aarch64_arch)       ta="$ta aarch64-asm.lo aarch64-dis.lo aarch64-opc.lo aarch64-asm-2.lo aarch64-dis-2.lo aarch64-opc-2.lo" ;;
 251         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 252         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 253         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 254         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 255         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 256         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 257         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 258         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 259         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 260         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 261         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 262         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 263         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 264         bfd_moxie_arch)         ta="$ta moxie-dis.lo moxie-opc.lo" ;;
 265         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 266         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 267         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 268         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 269         bfd_i386_arch|bfd_l1om_arch|bfd_k1om_arch)
 270                                 ta="$ta i386-dis.lo i386-opc.lo" ;;
 271         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 272         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 273         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 274         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 275         bfd_epiphany_arch)      ta="$ta epiphany-asm.lo epiphany-desc.lo epiphany-dis.lo epiphany-ibld.lo epiphany-opc.lo" using_cgen=yes ;;
 276         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 277         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 278         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 279         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 280         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 281         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 282         bfd_m9s12x_arch)        ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 283         bfd_m9s12xg_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 284         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 285         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 286         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 287         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 288         bfd_metag_arch)         ta="$ta metag-dis.lo" ;;
 289         bfd_microblaze_arch)    ta="$ta microblaze-dis.lo" ;;
 290         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo micromips-opc.lo" ;;
 291         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 292         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 293         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 294         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 295         bfd_msp430_arch)        ta="$ta msp430-dis.lo msp430-decode.lo" ;;
 296         bfd_nds32_arch)         ta="$ta nds32-asm.lo nds32-dis.lo" ;;
 297         bfd_nios2_arch)         ta="$ta nios2-dis.lo nios2-opc.lo" ;;
 298         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 299         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 300         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 301         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 302         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 303         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 304         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 305         bfd_pyramid_arch)       ;;
 306         bfd_romp_arch)          ;;
 307         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 308         bfd_rl78_arch)          ta="$ta rl78-dis.lo rl78-decode.lo";;
 309         bfd_rx_arch)            ta="$ta rx-dis.lo rx-decode.lo";;
 310         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 311         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 312         bfd_sh_arch)
 313           # We can't decide what we want just from the CPU family.
 314           # We want SH5 support unless a specific version of sh is
 315           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 316           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 317           for t in $target $canon_targets; do
 318             case $t in
 319               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 320               sh-*-linux* | shl-*-linux*)
 321                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 322                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 323                                 break;;
 324             esac;
 325           done
 326                                 ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 327         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 328         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 329         bfd_tahoe_arch)         ;;
 330         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 331         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 332         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 333         bfd_tic6x_arch)         ta="$ta tic6x-dis.lo" ;;
 334         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 335         bfd_tilegx_arch)        ta="$ta tilegx-dis.lo tilegx-opc.lo" ;;
 336         bfd_tilepro_arch)       ta="$ta tilepro-dis.lo tilepro-opc.lo" ;;
 337         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 338         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 339         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 340         bfd_v850_rh850_arch)    ta="$ta v850-opc.lo v850-dis.lo" ;;
 341         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 342         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 343         bfd_we32k_arch)         ;;
 344         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 345         bfd_xgate_arch)         ta="$ta xgate-dis.lo xgate-opc.lo" ;;
 346         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 347         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 348         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 349         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 350
 351         "")                     ;;
 352         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 353         esac
 354     done
 355
 356     if test $using_cgen = yes ; then
 357         ta="$ta $cgen_files"
 358     fi
 359
 360     # Weed out duplicate .o files.
 361     f=""
 362     for i in $ta ; do
 363         case " $f " in
 364         *" $i "*) ;;
 365         *) f="$f $i" ;;
 366         esac
 367     done
 368     ta="$f"
 369
 370     # And duplicate -D flags.
 371     f=""
 372     for i in $archdefs ; do
 373         case " $f " in
 374         *" $i "*) ;;
 375         *) f="$f $i" ;;
 376         esac
 377     done
 378     archdefs="$f"
 379
 380     BFD_MACHINES="$ta"
 381
 382 else    # all_targets is true
 383     archdefs=-DARCH_all
 384     BFD_MACHINES='$(ALL_MACHINES)'
 385 fi
 386
 387 AC_SUBST(archdefs)
 388 AC_SUBST(BFD_MACHINES)
 389
 390 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 391 AC_OUTPUT