opcodes/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2016 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([opcodes], BFD_VERSION)
  23 AC_CONFIG_SRCDIR([z8k-dis.c])
  24
  25 AC_CANONICAL_TARGET
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34 dnl These must be called before LT_INIT, because it may want
  35 dnl to call AC_CHECK_PROG.
  36 AC_CHECK_TOOL(AR, ar)
  37 AC_CHECK_TOOL(RANLIB, ranlib, :)
  38
  39 dnl Default to a non shared library.  This may be overridden by the
  40 dnl configure option --enable-shared.
  41 AC_DISABLE_SHARED
  42
  43 LT_INIT
  44
  45 AC_ARG_ENABLE(targets,
  46 [  --enable-targets        alternative target configurations],
  47 [case "${enableval}" in
  48   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  49             ;;
  50   no)       enable_targets= ;;
  51   *)        enable_targets=$enableval ;;
  52 esac])dnl
  53
  54 AM_BINUTILS_WARNINGS
  55 ACX_PROG_CC_WARNING_OPTS([-Wno-missing-field-initializers],
  56                          [NO_WMISSING_FIELD_INITIALIZERS])
  57
  58 AC_CONFIG_HEADERS(config.h:config.in)
  59
  60 # PR 14072
  61 AH_VERBATIM([00_CONFIG_H_CHECK],
  62 [/* Check that config.h is #included before system headers
  63    (this works only for glibc, but that should be enough).  */
  64 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  65 #  error config.h must be #included before system headers
  66 #endif
  67 #define __CONFIG_H__ 1])
  68
  69 if test -z "$target" ; then
  70     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  71 fi
  72
  73 AM_MAINTAINER_MODE
  74 AM_INSTALL_LIBBFD
  75 AC_EXEEXT
  76
  77 # host-specific stuff:
  78
  79 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN it uk"
  80 ZW_GNU_GETTEXT_SISTER_DIR
  81 AM_PO_SUBDIRS
  82
  83 . ${srcdir}/../bfd/configure.host
  84
  85 BFD_CC_FOR_BUILD
  86
  87 AC_SUBST(HDEFINES)
  88 AC_PROG_INSTALL
  89
  90 AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h)
  91 ACX_HEADER_STRING
  92
  93 AC_CHECK_DECLS([basename, stpcpy])
  94
  95 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
  96 # since sigsetjmp might only be defined as a macro.
  97 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
  98 [AC_TRY_COMPILE([
  99 #include <setjmp.h>
 100 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
 101 bfd_cv_func_sigsetjmp=yes, bfd_cv_func_sigsetjmp=no)])
 102 if test $bfd_cv_func_sigsetjmp = yes; then
 103   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 104 fi
 105
 106 cgen_maint=no
 107 cgendir='$(srcdir)/../cgen'
 108
 109 AC_ARG_ENABLE(cgen-maint,
 110 [  --enable-cgen-maint[=dir]    build cgen generated files],
 111 [case "${enableval}" in
 112   yes)  cgen_maint=yes ;;
 113   no)   cgen_maint=no ;;
 114   *)
 115         # argument is cgen install directory (not implemented yet).
 116         # Having a `share' directory might be more appropriate for the .scm,
 117         # .cpu, etc. files.
 118         cgen_maint=yes
 119         cgendir=${cgen_maint}/lib/cgen
 120         ;;
 121 esac])dnl
 122 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 123 AC_SUBST(cgendir)
 124
 125 using_cgen=no
 126
 127 # Check if linker supports --as-needed and --no-as-needed options
 128 AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed,
 129         [bfd_cv_ld_as_needed=no
 130         if $LD --help 2>/dev/null | grep as-needed > /dev/null; then
 131                 bfd_cv_ld_as_needed=yes
 132         fi
 133         ])
 134
 135 LT_LIB_M
 136
 137 #Libs for generator progs
 138 if test "x$cross_compiling" = "xno"; then
 139   BUILD_LIBS=../libiberty/libiberty.a
 140   BUILD_LIB_DEPS=$BUILD_LIBS
 141 else
 142   # if cross-compiling, assume that the system provides -liberty
 143   # and that the version is compatible with new headers.
 144   BUILD_LIBS=-liberty
 145   BUILD_LIB_DEPS=
 146 fi
 147 BUILD_LIBS="$BUILD_LIBS $LIBINTL"
 148 BUILD_LIB_DEPS="$BUILD_LIB_DEPS $LIBINTL_DEP"
 149
 150 AC_SUBST(BUILD_LIBS)
 151 AC_SUBST(BUILD_LIB_DEPS)
 152
 153 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 154 SHARED_LDFLAGS=
 155 SHARED_LIBADD=
 156 SHARED_DEPENDENCIES=
 157 if test "$enable_shared" = "yes"; then
 158 # When building a shared libopcodes, link against the pic version of libiberty
 159 # so that apps that use libopcodes won't need libiberty just to satisfy any
 160 # libopcodes references.
 161 # We can't do that if a pic libiberty is unavailable since including non-pic
 162 # code would insert text relocations into libopcodes.
 163 # Note that linking against libbfd as we do here, which is itself linked
 164 # against libiberty, may not satisfy all the libopcodes libiberty references
 165 # since libbfd may not pull in the entirety of libiberty.
 166 changequote(,)dnl
 167   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 168 changequote([,])dnl
 169   if test -n "$x"; then
 170     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 171   fi
 172
 173   case "${host}" in
 174     *-*-cygwin*)
 175       SHARED_LDFLAGS="-no-undefined"
 176       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 177       ;;
 178    *-*-darwin*)
 179      SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib ${SHARED_LIBADD}"
 180      SHARED_DEPENDENCIES="../bfd/libbfd.la"
 181      ;;
 182     *)
 183       case "$host_vendor" in
 184         hp)
 185           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl ${SHARED_LIBADD}"
 186           ;;
 187         *)
 188           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so ${SHARED_LIBADD}"
 189           ;;
 190       esac
 191       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 192       ;;
 193   esac
 194
 195   if test -n "$SHARED_LIBADD"; then
 196     if test -n "$LIBM"; then
 197       if test x"$bfd_cv_ld_as_needed" = xyes; then
 198         # Link against libm only when needed.  Put -lc, -lm inside -Wl
 199         # to stop libtool reordering these options.
 200         SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed"
 201       else
 202         SHARED_LIBADD="$SHARED_LIBADD $LIBM"
 203       fi
 204     fi
 205   fi
 206 fi
 207 AC_SUBST(SHARED_LDFLAGS)
 208 AC_SUBST(SHARED_LIBADD)
 209 AC_SUBST(SHARED_DEPENDENCIES)
 210
 211 # target-specific stuff:
 212
 213 # Canonicalize the secondary target names.
 214 if test -n "$enable_targets" ; then
 215     for targ in `echo $enable_targets | sed 's/,/ /g'`
 216     do
 217         result=`$ac_config_sub $targ 2>/dev/null`
 218         if test -n "$result" ; then
 219             canon_targets="$canon_targets $result"
 220         else
 221             # Allow targets that config.sub doesn't recognize, like "all".
 222             canon_targets="$canon_targets $targ"
 223         fi
 224     done
 225 fi
 226
 227 all_targets=false
 228 selarchs=
 229 for targ in $target $canon_targets
 230 do
 231     if test "x$targ" = "xall" ; then
 232         all_targets=true
 233     else
 234         . $srcdir/../bfd/config.bfd
 235         selarchs="$selarchs $targ_archs"
 236     fi
 237 done
 238
 239 # Utility var, documents generic cgen support files.
 240
 241 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 242
 243 # We don't do any links based on the target system, just makefile config.
 244
 245 if test x${all_targets} = xfalse ; then
 246
 247     # Target architecture .o files.
 248     ta=
 249
 250     for arch in $selarchs
 251     do
 252         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 253         archdefs="$archdefs -DARCH_$ad"
 254         case "$arch" in
 255         bfd_aarch64_arch)       ta="$ta aarch64-asm.lo aarch64-dis.lo aarch64-opc.lo aarch64-asm-2.lo aarch64-dis-2.lo aarch64-opc-2.lo" ;;
 256         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 257         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 258         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 259         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 260         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 261         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 262         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 263         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 264         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 265         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 266         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 267         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 268         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 269         bfd_ft32_arch)          ta="$ta ft32-opc.lo ft32-dis.lo" ;;
 270         bfd_moxie_arch)         ta="$ta moxie-dis.lo moxie-opc.lo" ;;
 271         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 272         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 273         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 274         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 275         bfd_i386_arch|bfd_iamcu_arch|bfd_l1om_arch|bfd_k1om_arch)
 276                                 ta="$ta i386-dis.lo i386-opc.lo" ;;
 277         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 278         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 279         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 280         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 281         bfd_epiphany_arch)      ta="$ta epiphany-asm.lo epiphany-desc.lo epiphany-dis.lo epiphany-ibld.lo epiphany-opc.lo" using_cgen=yes ;;
 282         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 283         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 284         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 285         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 286         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 287         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 288         bfd_m9s12x_arch)        ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 289         bfd_m9s12xg_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 290         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 291         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 292         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 293         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 294         bfd_metag_arch)         ta="$ta metag-dis.lo" ;;
 295         bfd_microblaze_arch)    ta="$ta microblaze-dis.lo" ;;
 296         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo micromips-opc.lo" ;;
 297         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 298         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 299         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 300         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 301         bfd_msp430_arch)        ta="$ta msp430-dis.lo msp430-decode.lo" ;;
 302         bfd_nds32_arch)         ta="$ta nds32-asm.lo nds32-dis.lo" ;;
 303         bfd_nios2_arch)         ta="$ta nios2-dis.lo nios2-opc.lo" ;;
 304         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 305         bfd_or1k_arch)          ta="$ta or1k-asm.lo or1k-desc.lo or1k-dis.lo or1k-ibld.lo or1k-opc.lo" using_cgen=yes ;;
 306         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 307         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 308         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 309         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 310         bfd_pyramid_arch)       ;;
 311         bfd_romp_arch)          ;;
 312         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 313         bfd_rl78_arch)          ta="$ta rl78-dis.lo rl78-decode.lo";;
 314         bfd_rx_arch)            ta="$ta rx-dis.lo rx-decode.lo";;
 315         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 316         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 317         bfd_sh_arch)
 318           # We can't decide what we want just from the CPU family.
 319           # We want SH5 support unless a specific version of sh is
 320           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 321           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 322           for t in $target $canon_targets; do
 323             case $t in
 324               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 325               sh-*-linux* | shl-*-linux*)
 326                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 327                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 328                                 break;;
 329             esac;
 330           done
 331                                 ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 332         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 333         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 334         bfd_tahoe_arch)         ;;
 335         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 336         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 337         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 338         bfd_tic6x_arch)         ta="$ta tic6x-dis.lo" ;;
 339         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 340         bfd_tilegx_arch)        ta="$ta tilegx-dis.lo tilegx-opc.lo" ;;
 341         bfd_tilepro_arch)       ta="$ta tilepro-dis.lo tilepro-opc.lo" ;;
 342         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 343         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 344         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 345         bfd_v850_rh850_arch)    ta="$ta v850-opc.lo v850-dis.lo" ;;
 346         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 347         bfd_visium_arch)        ta="$ta visium-dis.lo visium-opc.lo" ;;
 348         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 349         bfd_we32k_arch)         ;;
 350         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 351         bfd_xgate_arch)         ta="$ta xgate-dis.lo xgate-opc.lo" ;;
 352         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 353         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 354         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 355         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 356
 357         "")                     ;;
 358         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 359         esac
 360     done
 361
 362     if test $using_cgen = yes ; then
 363         ta="$ta $cgen_files"
 364     fi
 365
 366     # Weed out duplicate .o files.
 367     f=""
 368     for i in $ta ; do
 369         case " $f " in
 370         *" $i "*) ;;
 371         *) f="$f $i" ;;
 372         esac
 373     done
 374     ta="$f"
 375
 376     # And duplicate -D flags.
 377     f=""
 378     for i in $archdefs ; do
 379         case " $f " in
 380         *" $i "*) ;;
 381         *) f="$f $i" ;;
 382         esac
 383     done
 384     archdefs="$f"
 385
 386     BFD_MACHINES="$ta"
 387
 388 else    # all_targets is true
 389     archdefs=-DARCH_all
 390     BFD_MACHINES='$(ALL_MACHINES)'
 391 fi
 392
 393 AC_SUBST(archdefs)
 394 AC_SUBST(BFD_MACHINES)
 395
 396 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 397 AC_OUTPUT