opcodes/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2019 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([opcodes], BFD_VERSION)
  22 AC_CONFIG_SRCDIR([z8k-dis.c])
  23
  24 AC_CANONICAL_TARGET
  25 AC_ISC_POSIX
  26
  27 AM_INIT_AUTOMAKE
  28
  29 AC_PROG_CC
  30 AC_GNU_SOURCE
  31 AC_USE_SYSTEM_EXTENSIONS
  32
  33 dnl These must be called before LT_INIT, because it may want
  34 dnl to call AC_CHECK_PROG.
  35 AC_CHECK_TOOL(AR, ar)
  36 AC_CHECK_TOOL(RANLIB, ranlib, :)
  37
  38 dnl Default to a non shared library.  This may be overridden by the
  39 dnl configure option --enable-shared.
  40 AC_DISABLE_SHARED
  41
  42 LT_INIT
  43
  44 AC_ARG_ENABLE(targets,
  45 [  --enable-targets        alternative target configurations],
  46 [case "${enableval}" in
  47   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  48             ;;
  49   no)       enable_targets= ;;
  50   *)        enable_targets=$enableval ;;
  51 esac])dnl
  52
  53 AM_BINUTILS_WARNINGS
  54
  55 AC_CONFIG_HEADERS(config.h:config.in)
  56
  57 # PR 14072
  58 AH_VERBATIM([00_CONFIG_H_CHECK],
  59 [/* Check that config.h is #included before system headers
  60    (this works only for glibc, but that should be enough).  */
  61 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
  62 #  error config.h must be #included before system headers
  63 #endif
  64 #define __CONFIG_H__ 1])
  65
  66 if test -z "$target" ; then
  67     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  68 fi
  69
  70 AM_MAINTAINER_MODE
  71 AM_INSTALL_LIBBFD
  72 AC_EXEEXT
  73
  74 # host-specific stuff:
  75
  76 ALL_LINGUAS="da de es fi fr ga id it nl pt_BR ro sr sv tr uk vi zh_CN"
  77 ZW_GNU_GETTEXT_SISTER_DIR
  78 AM_PO_SUBDIRS
  79
  80 . ${srcdir}/../bfd/configure.host
  81
  82 BFD_CC_FOR_BUILD
  83
  84 AC_SUBST(HDEFINES)
  85 AC_PROG_INSTALL
  86
  87 AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h)
  88 ACX_HEADER_STRING
  89
  90 AC_CHECK_DECLS([basename, stpcpy])
  91
  92 # Check if sigsetjmp is available.  Using AC_CHECK_FUNCS won't do
  93 # since sigsetjmp might only be defined as a macro.
  94 AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp,
  95 [AC_TRY_COMPILE([
  96 #include <setjmp.h>
  97 ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);],
  98 bfd_cv_func_sigsetjmp=yes, bfd_cv_func_sigsetjmp=no)])
  99 if test $bfd_cv_func_sigsetjmp = yes; then
 100   AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ])
 101 fi
 102
 103 cgen_maint=no
 104 cgendir='$(srcdir)/../cgen'
 105
 106 AC_ARG_ENABLE(cgen-maint,
 107 [  --enable-cgen-maint[=dir]    build cgen generated files],
 108 [case "${enableval}" in
 109   yes)  cgen_maint=yes ;;
 110   no)   cgen_maint=no ;;
 111   *)
 112         # Argument is a directory where cgen can be found.  In some
 113         # future world cgen could be installable, but right now this
 114         # is not the case.  Instead we assume the directory is a path
 115         # to the cgen source tree.
 116         cgen_maint=yes
 117         if test -r ${enableval}/iformat.scm; then
 118           # This looks like a cgen source tree.
 119           cgendir=${enableval}
 120         else
 121           AC_MSG_ERROR(${enableval} doesn't look like a cgen source tree)
 122         fi
 123         ;;
 124 esac])dnl
 125 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
 126 AC_SUBST(cgendir)
 127
 128 using_cgen=no
 129
 130 # Check if linker supports --as-needed and --no-as-needed options
 131 AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed,
 132         [bfd_cv_ld_as_needed=no
 133         if $LD --help 2>/dev/null | grep as-needed > /dev/null; then
 134                 bfd_cv_ld_as_needed=yes
 135         fi
 136         ])
 137
 138 LT_LIB_M
 139
 140 #Libs for generator progs
 141 if test "x$cross_compiling" = "xno"; then
 142   BUILD_LIBS=../libiberty/libiberty.a
 143   BUILD_LIB_DEPS=$BUILD_LIBS
 144 else
 145   # if cross-compiling, assume that the system provides -liberty
 146   # and that the version is compatible with new headers.
 147   BUILD_LIBS=-liberty
 148   BUILD_LIB_DEPS=
 149 fi
 150 BUILD_LIBS="$BUILD_LIBS $LIBINTL"
 151 BUILD_LIB_DEPS="$BUILD_LIB_DEPS $LIBINTL_DEP"
 152
 153 AC_SUBST(BUILD_LIBS)
 154 AC_SUBST(BUILD_LIB_DEPS)
 155
 156 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 157 SHARED_LDFLAGS=
 158 SHARED_LIBADD=
 159 SHARED_DEPENDENCIES=
 160 if test "$enable_shared" = "yes"; then
 161 # When building a shared libopcodes, link against the pic version of libiberty
 162 # so that apps that use libopcodes won't need libiberty just to satisfy any
 163 # libopcodes references.
 164 # We can't do that if a pic libiberty is unavailable since including non-pic
 165 # code would insert text relocations into libopcodes.
 166 # Note that linking against libbfd as we do here, which is itself linked
 167 # against libiberty, may not satisfy all the libopcodes libiberty references
 168 # since libbfd may not pull in the entirety of libiberty.
 169 changequote(,)dnl
 170   x=`sed -n -e 's/^[    ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 171 changequote([,])dnl
 172   if test -n "$x"; then
 173     SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty"
 174   fi
 175
 176   case "${host}" in
 177     *-*-cygwin*)
 178       SHARED_LDFLAGS="-no-undefined"
 179       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 180       ;;
 181    *-*-darwin*)
 182      SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib ${SHARED_LIBADD}"
 183      SHARED_DEPENDENCIES="../bfd/libbfd.la"
 184      ;;
 185     *)
 186       case "$host_vendor" in
 187         hp)
 188           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl ${SHARED_LIBADD}"
 189           ;;
 190         *)
 191           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so ${SHARED_LIBADD}"
 192           ;;
 193       esac
 194       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 195       ;;
 196   esac
 197
 198   if test -n "$SHARED_LIBADD"; then
 199     if test -n "$LIBM"; then
 200       if test x"$bfd_cv_ld_as_needed" = xyes; then
 201         # Link against libm only when needed.  Put -lc, -lm inside -Wl
 202         # to stop libtool reordering these options.
 203         SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed"
 204       else
 205         SHARED_LIBADD="$SHARED_LIBADD $LIBM"
 206       fi
 207     fi
 208   fi
 209 fi
 210 AC_SUBST(SHARED_LDFLAGS)
 211 AC_SUBST(SHARED_LIBADD)
 212 AC_SUBST(SHARED_DEPENDENCIES)
 213
 214 # target-specific stuff:
 215
 216 # Canonicalize the secondary target names.
 217 if test -n "$enable_targets" ; then
 218     for targ in `echo $enable_targets | sed 's/,/ /g'`
 219     do
 220         result=`$ac_config_sub $targ 2>/dev/null`
 221         if test -n "$result" ; then
 222             canon_targets="$canon_targets $result"
 223         else
 224             # Allow targets that config.sub doesn't recognize, like "all".
 225             canon_targets="$canon_targets $targ"
 226         fi
 227     done
 228 fi
 229
 230 all_targets=false
 231 selarchs=
 232 for targ in $target $canon_targets
 233 do
 234     if test "x$targ" = "xall" ; then
 235         all_targets=true
 236     else
 237         . $srcdir/../bfd/config.bfd
 238         selarchs="$selarchs $targ_archs"
 239     fi
 240 done
 241
 242 # Utility var, documents generic cgen support files.
 243
 244 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 245
 246 # We don't do any links based on the target system, just makefile config.
 247
 248 if test x${all_targets} = xfalse ; then
 249
 250     # Target architecture .o files.
 251     ta=
 252
 253     for arch in $selarchs
 254     do
 255         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 256         archdefs="$archdefs -DARCH_$ad"
 257         case "$arch" in
 258         bfd_aarch64_arch)       ta="$ta aarch64-asm.lo aarch64-dis.lo aarch64-opc.lo aarch64-asm-2.lo aarch64-dis-2.lo aarch64-opc-2.lo" ;;
 259         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 260         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 261         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 262         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 263         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 264         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 265         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 266         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 267         bfd_csky_arch)          ta="$ta csky-dis.lo" ;;
 268         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 269         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 270         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 271         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 272         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 273         bfd_ft32_arch)          ta="$ta ft32-opc.lo ft32-dis.lo" ;;
 274         bfd_moxie_arch)         ta="$ta moxie-dis.lo moxie-opc.lo" ;;
 275         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 276         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 277         bfd_i386_arch|bfd_iamcu_arch|bfd_l1om_arch|bfd_k1om_arch)
 278                                 ta="$ta i386-dis.lo i386-opc.lo" ;;
 279         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 280         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 281         bfd_epiphany_arch)      ta="$ta epiphany-asm.lo epiphany-desc.lo epiphany-dis.lo epiphany-ibld.lo epiphany-opc.lo" using_cgen=yes ;;
 282         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 283         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 284         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 285         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 286         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 287         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 288         bfd_m9s12x_arch)        ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 289         bfd_m9s12xg_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 290         bfd_s12z_arch)          ta="$ta s12z-dis.lo s12z-opc.lo" ;;
 291         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 292         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 293         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 294         bfd_metag_arch)         ta="$ta metag-dis.lo" ;;
 295         bfd_microblaze_arch)    ta="$ta microblaze-dis.lo" ;;
 296         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo micromips-opc.lo" ;;
 297         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 298         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 299         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 300         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 301         bfd_msp430_arch)        ta="$ta msp430-dis.lo msp430-decode.lo" ;;
 302         bfd_nds32_arch)         ta="$ta nds32-asm.lo nds32-dis.lo" ;;
 303         bfd_nfp_arch)           ta="$ta nfp-dis.lo" ;;
 304         bfd_nios2_arch)         ta="$ta nios2-dis.lo nios2-opc.lo" ;;
 305         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 306         bfd_or1k_arch)          ta="$ta or1k-asm.lo or1k-desc.lo or1k-dis.lo or1k-ibld.lo or1k-opc.lo" using_cgen=yes ;;
 307         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 308         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 309         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 310         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 311         bfd_pru_arch)           ta="$ta pru-dis.lo pru-opc.lo" ;;
 312         bfd_pyramid_arch)       ;;
 313         bfd_romp_arch)          ;;
 314         bfd_riscv_arch)         ta="$ta riscv-dis.lo riscv-opc.lo" ;;
 315         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 316         bfd_rl78_arch)          ta="$ta rl78-dis.lo rl78-decode.lo";;
 317         bfd_rx_arch)            ta="$ta rx-dis.lo rx-decode.lo";;
 318         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 319         bfd_score_arch)         ta="$ta score-dis.lo score7-dis.lo" ;;
 320         bfd_sh_arch)            ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 321         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 322         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 323         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 324         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 325         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 326         bfd_tic6x_arch)         ta="$ta tic6x-dis.lo" ;;
 327         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 328         bfd_tilegx_arch)        ta="$ta tilegx-dis.lo tilegx-opc.lo" ;;
 329         bfd_tilepro_arch)       ta="$ta tilepro-dis.lo tilepro-opc.lo" ;;
 330         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 331         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 332         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 333         bfd_v850_rh850_arch)    ta="$ta v850-opc.lo v850-dis.lo" ;;
 334         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 335         bfd_visium_arch)        ta="$ta visium-dis.lo visium-opc.lo" ;;
 336         bfd_wasm32_arch)        ta="$ta wasm32-dis.lo" ;;
 337         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 338         bfd_xgate_arch)         ta="$ta xgate-dis.lo xgate-opc.lo" ;;
 339         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 340         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 341         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 342         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 343
 344         "")                     ;;
 345         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 346         esac
 347     done
 348
 349     if test $using_cgen = yes ; then
 350         ta="$ta $cgen_files"
 351     fi
 352
 353     # Weed out duplicate .o files.
 354     f=""
 355     for i in $ta ; do
 356         case " $f " in
 357         *" $i "*) ;;
 358         *) f="$f $i" ;;
 359         esac
 360     done
 361     ta="$f"
 362
 363     # And duplicate -D flags.
 364     f=""
 365     for i in $archdefs ; do
 366         case " $f " in
 367         *" $i "*) ;;
 368         *) f="$f $i" ;;
 369         esac
 370     done
 371     archdefs="$f"
 372
 373     BFD_MACHINES="$ta"
 374
 375 else    # all_targets is true
 376     archdefs=-DARCH_all
 377     BFD_MACHINES='$(ALL_MACHINES)'
 378 fi
 379
 380 AC_SUBST(archdefs)
 381 AC_SUBST(BFD_MACHINES)
 382
 383 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 384 AC_OUTPUT