nouveau/meson.build

   1 # Copyright © 2017-2018 Intel Corporation
   2
   3 # Permission is hereby granted, free of charge, to any person obtaining a copy
   4 # of this software and associated documentation files (the "Software"), to deal
   5 # in the Software without restriction, including without limitation the rights
   6 # to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   7 # copies of the Software, and to permit persons to whom the Software is
   8 # furnished to do so, subject to the following conditions:
   9
  10 # The above copyright notice and this permission notice shall be included in
  11 # all copies or substantial portions of the Software.
  12
  13 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  14 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  15 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  16 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  17 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  18 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  19 # SOFTWARE.
  20
  21
  22 libdrm_nouveau = library(
  23   'drm_nouveau',
  24   [files( 'nouveau.c', 'pushbuf.c', 'bufctx.c', 'abi16.c'), config_file],
  25   c_args : libdrm_c_args,
  26   gnu_symbol_visibility : 'hidden',
  27   include_directories : [inc_root, inc_drm],
  28   link_with : libdrm,
  29   dependencies : [dep_threads, dep_atomic_ops],
  30   version : '2.0.0',
  31   install : true,
  32 )
  33
  34 ext_libdrm_nouveau = declare_dependency(
  35   link_with : [libdrm, libdrm_nouveau],
  36   include_directories : [inc_drm, include_directories('.')],
  37 )
  38
  39 if meson.version().version_compare('>= 0.54.0')
  40   meson.override_dependency('libdrm_nouveau', ext_libdrm_nouveau)
  41 endif
  42
  43 install_headers('nouveau.h', subdir : 'libdrm/nouveau')
  44 install_headers(
  45   'nvif/class.h', 'nvif/cl0080.h', 'nvif/cl9097.h', 'nvif/if0002.h',
  46   'nvif/if0003.h', 'nvif/ioctl.h', 'nvif/unpack.h',
  47   subdir : 'libdrm/nouveau/nvif'
  48 )
  49
  50 pkg.generate(
  51   libdrm_nouveau,
  52   name : 'libdrm_nouveau',
  53   subdirs : ['.', 'libdrm', 'libdrm/nouveau'],
  54   description : 'Userspace interface to nouveau kernel DRM services',
  55 )
  56
  57 test(
  58   'nouveau-symbols-check',
  59   symbols_check,
  60   args : [
  61     '--lib', libdrm_nouveau,
  62     '--symbols-file', files('nouveau-symbols.txt'),
  63     '--nm', prog_nm.full_path(),
  64   ],
  65 )