mpn/sparc32/v8/submul_1.asm

   1 dnl  SPARC v8 mpn_submul_1 -- Multiply a limb vector with a limb and
   2 dnl  subtract the result from a second limb vector.
   3
   4 dnl  Copyright 1992, 1993, 1994, 2000 Free Software Foundation, Inc.
   5
   6 dnl  This file is part of the GNU MP Library.
   7
   8 dnl  The GNU MP Library is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of the GNU Lesser General Public License as published
  10 dnl  by the Free Software Foundation; either version 3 of the License, or (at
  11 dnl  your option) any later version.
  12
  13 dnl  The GNU MP Library is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  16 dnl  License for more details.
  17
  18 dnl  You should have received a copy of the GNU Lesser General Public License
  19 dnl  along with the GNU MP Library.  If not, see http://www.gnu.org/licenses/.
  20
  21
  22 include(`../config.m4')
  23
  24 C INPUT PARAMETERS
  25 C res_ptr       o0
  26 C s1_ptr        o1
  27 C size          o2
  28 C s2_limb       o3
  29
  30 ASM_START()
  31 PROLOGUE(mpn_submul_1)
  32         sub     %g0,%o2,%o2             C negate ...
  33         sll     %o2,2,%o2               C ... and scale size
  34         sub     %o1,%o2,%o1             C o1 is offset s1_ptr
  35         sub     %o0,%o2,%g1             C g1 is offset res_ptr
  36
  37         mov     0,%o0                   C clear cy_limb
  38
  39 L(loop):
  40         ld      [%o1+%o2],%o4
  41         ld      [%g1+%o2],%g2
  42         umul    %o4,%o3,%o5
  43         rd      %y,%g3
  44         addcc   %o5,%o0,%o5
  45         addx    %g3,0,%o0
  46         subcc   %g2,%o5,%g2
  47         addx    %o0,0,%o0
  48         st      %g2,[%g1+%o2]
  49
  50         addcc   %o2,4,%o2
  51         bne     L(loop)
  52          nop
  53
  54         retl
  55          nop
  56 EPILOGUE(mpn_submul_1)